XML

Pacote	Nível superior
Classe	public final dynamic class XML
Herança	XML Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

A classe XML contém métodos e propriedades para trabalhar com objetos XML. A classe XML (junto com as classes XMLList, Namespace e QName) implementa eficientes padrões de manipulação de XML definidos na especificação ECMAScript para XML (E4X) (ECMA-357 edição 2).

Use o método toXMLString() para retornar uma representação de string do objeto XML, independentemente deste objeto XML ter conteúdo simples ou complexo.

Observação: A classe XML (junto com as classes relacionadas) do ActionScript 2.0 foi renomeada como XMLDocument e movida para o pacote flash.xml. Ela está inclusa no ActionScript 3.0 por questões de compatibilidade com versões anteriores.

Veja os exemplos

Saiba mais

Especificação ECMAScript para XML (E4X) (ECMA-357 edição 2)

Elementos da API relacionados

Namespace
QName
XMLList
XML.toXMLString()

Propriedades públicas

Ocultar propriedades públicas herdadas

Mostrar propriedades públicas herdadas

	Propriedade		Definido por
		constructor : Object Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto.	Object
		ignoreComments : Boolean [estático] Determina se comentários XML são ignorados quando objetos XML analisam os dados XML de origem.	XML
		ignoreProcessingInstructions : Boolean [estático] Determina se instruções de processamento XML são ignoradas quando objetos XML analisam os dados XML de origem.	XML
		ignoreWhitespace : Boolean [estático] Determina se caracteres de espaço em branco no início e no final de nós de texto são ignorados durante a análise.	XML
		prettyIndent : int [estático] Determina a quantidade de recuo aplicada pelos métodos toString() e toXMLString() quando a propriedade XML.prettyPrinting é definida como "true".	XML
		prettyPrinting : Boolean [estático] Determina se os métodos toString() e toXMLString() normalizam caracteres de espaço em branco entre algumas marcas.	XML

Métodos públicos

Ocultar métodos públicos herdados

Mostrar métodos públicos herdados

	Método		Definido por
		XML(value:Object) Cria um novo objeto XML.	XML
		addNamespace(ns:Object):XML Adiciona um namespace ao conjunto de namespaces em escopo para o objeto XML.	XML
		appendChild(child:Object):XML Acrescenta o filho especificado ao final das propriedades do objeto XML.	XML
		attribute(attributeName:*):XMLList Retorna o valor XML do atributo cujo nome corresponde ao parâmetro nomeAtributo.	XML
		attributes():XMLList Retorna uma lista de valores de atributos para o objeto XML especificado.	XML
		child(propertyName:Object):XMLList Lista os filhos de um objeto XML.	XML
		childIndex():int Identifica a posição com índice zero deste objeto XML no contexto de seu pai.	XML
		children():XMLList Lista os filhos do objeto XML na sequência em que aparecem.	XML
		comments():XMLList Lista as propriedades do objeto XML que contêm comentários XML.	XML
		contains(value:XML):Boolean Compara o objeto XML com base no parâmetro "valor" especificado.	XML
		copy():XML Retorna uma cópia do objeto XML especificado.	XML
		defaultSettings():Object [estático] Retorna um objeto com as seguintes propriedades definidas como valores padrão: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting.	XML
		descendants(name:Object = *):XMLList Retorna todos os descendentes (filhos, netos, bisnetos e assim por diante) do objeto XML que possui o parâmetro "nome" especificado.	XML
		elements(name:Object = *):XMLList Lista os elementos de um objeto XML.	XML
		hasComplexContent():Boolean Verifica se o objeto XML tem conteúdo complexo.	XML
		hasOwnProperty(p:String):Boolean Verifica se o objeto tem a propriedade especificada pelo parâmetro p.	XML
		hasSimpleContent():Boolean Verifica se o objeto XML tem conteúdo simples.	XML
		inScopeNamespaces():Array Lista os namespaces do objeto XML, com base no pai do objeto.	XML
		insertChildAfter(child1:Object, child2:Object):* Insere o parâmetro child2 especificado após o parâmetro child1 neste objeto XML e retorna o objeto resultante.	XML
		insertChildBefore(child1:Object, child2:Object):* Insere o parâmetro child2 especificado antes do parâmetro child1 neste objeto XML e retorna o objeto resultante.	XML
		isPrototypeOf(theClass:Object):Boolean Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro.	Object
		length():int Para objetos XML, esse método sempre retorna o inteiro 1.	XML
		localName():Object Fornece a parte de nome local do nome qualificado do objeto XML.	XML
		name():Object Fornece o nome qualificado do objeto XML.	XML
		namespace(prefix:String = null):* Se nenhum parâmetro for fornecido, fornece o namespace associado ao nome qualificado deste objeto XML.	XML
		namespaceDeclarations():Array Lista declarações de namespace associadas ao objeto XML no contexto de seu pai.	XML
		nodeKind():String Especifica o tipo de player. texto, comentário, instrução de processamento, atributo ou elemento.	XML
		normalize():XML Para o objeto XML e todos os objetos XML descendentes, mescla os nós de texto adjacentes e elimina nós de texto vazios.	XML
		parent():* Retorna o pai do objeto XML.	XML
		prependChild(value:Object):XML Insere uma cópia do objeto-filho fornecido no elemento XML antes de qualquer propriedade XML existente para esse elemento.	XML
		processingInstructions(name:String = "*"):XMLList Se um parâmetro de nome for fornecido, lista todos os filhos do objeto XML que contêm instruções de processamento com esse nome.	XML
		propertyIsEnumerable(p:String):Boolean Verifica se a propriedade p está no conjunto de propriedades que podem ser iteradas em uma instrução for..in aplicada ao objeto XML.	XML
		removeNamespace(ns:Namespace):XML Remove o namespace especificado para esse objeto e todos os descendentes.	XML
		replace(propertyName:Object, value:XML):XML Substitui as propriedades especificadas pelo parâmetro nomePropriedade pelo parâmetro "valor" especificado.	XML
		setChildren(value:Object):XML Substitui as propriedades-filho do objeto XML pelo conjunto especificado de propriedades XML fornecido no parâmetro "valor".	XML
		setLocalName(name:String):void Altera o nome local do objeto XML para o parâmetro "nome" especificado.	XML
		setName(name:String):void Define o nome do objeto XML como o nome ou o nome de atributo qualificado especificado.	XML
		setNamespace(ns:Namespace):void Define o namespace associado ao objeto XML.	XML
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Define a disponibilidade de uma propriedade dinâmica para operações de repetição.	Object
		setSettings(... rest):void [estático] Define valores para as seguintes propriedades XML: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent, e prettyPrinting.	XML
		settings():Object [estático] Recupera as seguintes propriedades: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting.	XML
		text():XMLList Retorna um objeto XMLList de todas as propriedades XML do objeto XML que representam nós de texto XML.	XML
		toJSON(k:String):* Fornece um método que pode ser substituído para personalizar a codificação JSON de valores em um objeto XML.	XML
		toLocaleString():String Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade.	Object
		toString():String Retorna uma representação de string do objeto XML.	XML
		toXMLString():String Retorna uma representação de string do objeto XML.	XML
		valueOf():XML Retorna o objeto XML.	XML

Detalhes da propriedade

ignoreComments

propriedade

ignoreComments:Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Determina se comentários XML são ignorados quando objetos XML analisam os dados XML de origem. Por padrão, os comentários são ignorados (true). Para incluir comentários XML, defina essa propriedade como false. A propriedade ignoreComments é usada apenas durante a análise do XML e não durante a chamada a um método como myXMLObject.child(*).toXMLString(). Se o XML de origem incluir nós de comentário, eles serão mantidos ou descartados durante a análise do XML.

Implementação
public static function get ignoreComments():Boolean
public static function set ignoreComments(value:Boolean):void

Elementos da API relacionados

XML.child()
XML.toXMLString()

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o efeito de definir XML.ignoreComments como false e true:

XML.ignoreComments = false;
var xml1:XML = 
        <foo>
            <!-- comment -->
        </foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>

XML.ignoreComments = true;
var xml2:XML = 
        <foo>
            <!-- example -->
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreProcessingInstructions

propriedade

ignoreProcessingInstructions:Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Determina se instruções de processamento XML são ignoradas quando objetos XML analisam os dados XML de origem. Por padrão, as instruções de processamento são ignoradas (true). Para incluir instruções de processamento XML, defina essa propriedade como false. A propriedade ignoreProcessingInstructions é usada apenas durante a análise do XML e não durante a chamada a um método como myXMLObject.child(*).toXMLString(). Se o XML de origem incluir nós de instruções de processamento, eles serão mantidos ou descartados durante a análise do XML.

Implementação
public static function get ignoreProcessingInstructions():Boolean
public static function set ignoreProcessingInstructions(value:Boolean):void

Elementos da API relacionados

XML.child()
XML.toXMLString()

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o efeito de definir XML.ignoreProcessingInstructions como false e true:

XML.ignoreProcessingInstructions = false;
var xml1:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>

XML.ignoreProcessingInstructions = true;
var xml2:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreWhitespace

propriedade

ignoreWhitespace:Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Determina se caracteres de espaço em branco no início e no final de nós de texto são ignorados durante a análise. Por padrão, o espaço em branco é ignorado (true). Se um nó de texto for 100% de espaço em branco e a propriedade ignoreWhitespace estiver definida como true, o nó não será criado. Para mostrar o espaço em branco em um nó de texto, defina a propriedade ignoreWhitespace como false.

Quando você cria um objeto XML, ele coloca no cache o valor atual da propriedade ignoreWhitespace. A modificação de ignoreWhitespace não altera o comportamento de objetos XML existentes.

Implementação
public static function get ignoreWhitespace():Boolean
public static function set ignoreWhitespace(value:Boolean):void

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o efeito de definir XML.ignoreWhitespace como false e true:

XML.ignoreWhitespace = false;
var xml1:XML = <foo>    </foo>;
trace(xml1.children().length()); // 1

XML.ignoreWhitespace = true;
var xml2:XML = <foo>    </foo>;
trace(xml2.children().length()); // 0

prettyIndent

propriedade

prettyIndent:int

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Determina a quantidade de recuo aplicada pelos métodos toString() e toXMLString() quando a propriedade XML.prettyPrinting é definida como true. O recuo é aplicado com o caractere de espaço e não com o caractere de tabulação. O valor padrão é 2.

Implementação
public static function get prettyIndent():int
public static function set prettyIndent(value:int):void

Elementos da API relacionados

prettyPrinting
toString()
toXMLString()

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o efeito de definir a propriedade estática XML.prettyIndent:

var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());

XML.prettyIndent = 1;
trace(xml.toXMLString());

XML.prettyIndent = 2;
trace(xml.toXMLString());

prettyPrinting

propriedade

prettyPrinting:Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Determina se os métodos toString() e toXMLString() normalizam caracteres de espaço em branco entre algumas marcas. O valor padrão é true.

Implementação
public static function get prettyPrinting():Boolean
public static function set prettyPrinting(value:Boolean):void

Elementos da API relacionados

prettyIndent
toString()
toXMLString()

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o efeito de definir a propriedade estática XML.prettyPrinting:

var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());

XML.prettyPrinting = true;
trace(xml.toXMLString());

Detalhes do construtor

()

Construtor

public function XML(value:Object)

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Cria um novo objeto XML. Você deve usar o construtor para criar um objeto XML antes de chamar qualquer um dos métodos da classe XML.

Use o método toXMLString() para retornar uma representação de string do objeto XML, independentemente deste objeto XML ter conteúdo simples ou complexo.

Parâmetros

value:Object — Qualquer objeto que possa ser convertido em XML com a função XML() de nível superior.

Elementos da API relacionados

função global XML()
XML.toXMLString()

Exemplo ( Como usar este exemplo )

O seguinte exemplo mostra como você pode carregar um documento de XML remoto no ActionScript 3.0 usando a classe URLLoader no Flash Professional. Exemplo fornecido por ActionScriptExamples.com .

//
// Requires:
//   - TextArea control UI component in the Flash Professional Library.
//
import fl.controls.TextArea;
 
var xml:XML;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
 
var urlLoader:URLLoader = new URLLoader();
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
var textArea:TextArea = new TextArea();
textArea.move(5, 5);
textArea.setSize(stage.stageWidth - 10, stage.stageHeight - 10);
addChild(textArea);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.currentTarget.data);
    textArea.text = xml.toXMLString();
}

Aqui está outra variação que usa todo o ActionScript. Exemplo fornecido por ActionScriptExamples.com .

var xml:XML;
var textArea:TextField = new TextField();
textArea.width = 300;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.target.data);
    textArea.text = xml.toXMLString();
    addChild(textArea);
}

Detalhes do método

addNamespace

()

método

AS3 function addNamespace(ns:Object):XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Adiciona um namespace ao conjunto de namespaces em escopo para o objeto XML. Se o namespace já existir nos namespaces em escopo para o objeto XML (com um prefixo correspondente ao do parâmetro especificado), o prefixo do namespace existente será definido como undefined. Se o parâmetro de entrada for um objeto Namespace, ele será usado diretamente. Se for um objeto QName, o URI do parâmetro de entrada será usado para criar um novo namespace; caso contrário, será convertido em String e um namespace será criado a partir da String.

Parâmetros

ns:Object — O namespace a ser adicionado ao objeto XML.

Retorna

XML — O novo objeto XML, com o namespace adicionado.

Exemplo ( Como usar este exemplo )

Esse exemplo usa um namespace definido em um objeto XML e o aplica a outro objeto XML:

var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();

var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>

appendChild

()

método

AS3 function appendChild(child:Object):XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Acrescenta o filho especificado ao final das propriedades do objeto XML. O método appendChild() usa um objeto XML, um objeto XMLList ou qualquer outro tipo de dados que, em seguida, é convertido em String.

Use o operador delete (XML) para remover nós XML.

Parâmetros

child:Object — O objeto XML a ser acrescentado.

Retorna

XML — O objeto XML resultante.

Elementos da API relacionados

operador "delete" (XML)

Exemplo ( Como usar este exemplo )

Esse exemplo acrescenta um novo elemento ao final da lista-filho de um objeto XML:

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.appendChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>

attribute

()

método

AS3 function attribute(attributeName:*):XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna o valor XML do atributo cujo nome corresponde ao parâmetro attributeName. Atributos são encontrados em elementos XML. No exemplo a seguir, o elemento tem um atributo denominado "gender" com o valor de "boy": <first gender="boy">John</first>.

O parâmetro attributeName pode ser qualquer tipo de dados. Entretanto, String é o tipo de dados mais comum para uso. Ao transmitir um objeto diferente de QName, o parâmetro attributeName usa o método toString() para converter esse parâmetro em uma string.

Se você precisar de uma referência de nome qualificado, poderá transmitir um objeto QName. Um objeto QName define um namespace e o nome local, que você pode usar para definir o nome qualificado de um atributo. Portanto, chamar attribute(qname) não é o mesmo que chamar attribute(qname.toString()).

Parâmetros

attributeName:* — O nome do atributo.

Retorna

XMLList — Um objeto XMLList ou um objeto XMLList vazio. Retorna um objeto XMLList vazio quando um valor de atributo não foi definido.

Elementos da API relacionados

XML.attributes()
QName
Namespace
XML.elements()
operador de identificador de atributo (@)

Exemplo ( Como usar este exemplo )

Esse exemplo mostra um objeto QName transmitido no método attribute(). A propriedade localName é attr e a propriedade namespace é ns.

 var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />       
 var qn:QName = new QName("http://uri", "attr");
 trace (xml.attribute(qn)); // 7

Para retornar um atributo com um nome que corresponda a uma palavra reservada do ActionScript, use o método attribute() no lugar do operador de identificador de atributo (@), como no exemplo a seguir:

 var xml:XML = <example class="first" />
 trace(xml.attribute("class"));

attributes

()

método

AS3 function attributes():XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna uma lista de valores de atributos para o objeto XML especificado. Use o método name() com o método attributes() para retornar o nome de um atributo. O uso de xml.attributes() é equivalente a xml.@*.

Retorna

XMLList — A lista de valores de atributos.

Elementos da API relacionados

XML.attribute()
XML.name()
operador @

Exemplo ( Como usar este exemplo )

O exemplo a seguir retorna o nome do atributo:

var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color

Esse exemplo retorna os nomes de todos os atributos:

 
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;

trace (attNamesList is XMLList); // true
trace (attNamesList.length()); // 2

for (var i:int = 0; i < attNamesList.length(); i++)
{ 
    trace (typeof (attNamesList[i])); // xml
    trace (attNamesList[i].nodeKind()); // attribute
    trace (attNamesList[i].name()); // id and color
}

child

()

método

AS3 function child(propertyName:Object):XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Lista os filhos de um objeto XML. Um filho XML é um elemento, nó de texto, comentário ou instrução de processamento XML.

Use o parâmetro propertyName para listar o conteúdo de um filho XML específico. Por exemplo, para retornar os conteúdos de um filho denominado <first>, chame child("first") no objeto XML. Você pode gerar o mesmo resultado usando o número de índice do filho. O número de índice identifica a posição do filho na lista de outros filhos XML. Por exemplo, child(0) retorna o primeiro filho em uma lista.

Use um asterisco (*) para processar a saída de todos os filhos em um documento XML. Por exemplo, doc.child("*").

Use o método length() com o parâmetro de asterisco (*) do método child() para processar a saída do número total de filhos. Por exemplo, numChildren = doc.child("*").length().

Parâmetros

propertyName:Object — O nome de elemento ou inteiro do filho XML.

Retorna

XMLList — Um objeto XMLList de nós-filho que correspondem ao parâmetro de entrada.

Elementos da API relacionados

XML.elements()
Classe XMLList
XML.length()

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o uso do método child() para identificar elementos-filho com um nome especificado:

var xml:XML = 
        <foo>
            <bar>text1</bar>
            <bar>text2</bar>
        </foo>;
trace(xml.child("bar").length());  // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>

childIndex

()

método

AS3 function childIndex():int

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Identifica a posição com índice zero deste objeto XML no contexto de seu pai.

Retorna

int — A posição do objeto. Retorna -1 e também inteiros positivos.

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o uso do método childIndex():

var xml:XML = 
            <foo>
                <bar />
                text
                <bob />
            </foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2

children

()

método

AS3 function children():XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Lista os filhos do objeto XML na sequência em que aparecem. Um filho XML é um elemento, nó de texto, comentário ou instrução de processamento XML.

Retorna

XMLList — Um objeto XMLList dos do objeto XML.

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o uso do método children():

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML = 
        <foo id="22">
            <bar>44</bar>
            text
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>

comments

()

método

AS3 function comments():XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Lista as propriedades do objeto XML que contêm comentários XML.

Retorna

XMLList — Um objeto XMLList das propriedades que contêm comentários.

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o uso do método comments():

XML.ignoreComments = false;
var xml:XML = 
        <foo>
            <!-- example -->
            <!-- example2 -->
        </foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->

contains

()

método

AS3 function contains(value:XML):Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Compara o objeto XML com base no parâmetro value especificado.

Parâmetros

value:XML — Um valor a ser comparado com base no objeto XML atual.

Retorna

Boolean — Se o objeto XML corresponder ao parâmetro value, true; caso contrário, false.

Exemplo ( Como usar este exemplo )

Esse exemplo mostra o uso do método contains():

var xml:XML = 
        <order>
            <item>Rice</item>
            <item>Kung Pao Shrimp</item>
        </order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false

copy

()

método

AS3 function copy():XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna uma cópia do objeto XML especificado. A cópia é uma duplicata da árvore de nós inteira. O objeto XML copiado não tem pai e retornará null se você tentar chamar o método parent().

Retorna

XML — A cópia do objeto.

Exemplo ( Como usar este exemplo )

Esse exemplo mostra que o método copy() cria uma nova ocorrência de um objeto XML. Quando você modifica a cópia, o original permanece inalterado:

var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1

defaultSettings

()

método

AS3 static function defaultSettings():Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna um objeto com as seguintes propriedades definidas como valores padrão: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting. Os valores padrão são os seguintes:

ignoreComments = true
ignoreProcessingInstructions = true
ignoreWhitespace = true
prettyIndent = 2
prettyPrinting = true

Observação: Não aplique esse método a uma ocorrência da classe XML; aplique-o a XML, como no código a seguir: var df:Object = XML.defaultSettings().

Retorna

Object — Um objeto com propriedades definidas como as configurações padrão.

Elementos da API relacionados

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.setSettings()
XML.settings()

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra: como aplicar algumas configurações personalizadas (para a inclusão de comentários e instruções de processamento) antes da definição de um objeto XML; como, em seguida, reverter para as configurações padrão antes de definir outro objeto XML e, então, como definir novamente essas configurações personalizadas (para a definição de mais objetos XML):

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

descendants

()

método

AS3 function descendants(name:Object = *):XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna todos os descendentes (filhos, netos, bisnetos e assim por diante) do objeto XML que possui o parâmetro name especificado. O parâmetro name é opcional. O parâmetro name pode ser um objeto QName, um tipo de dados String ou qualquer outro tipo de dados que seja subsequentemente convertido em um tipo de dados String.

Para retornar todos os descendentes, use o parâmetro "*". Se nenhum parâmetro for transmitido, a string "*" será transmitida e retornará todos os descendentes do objeto XML.

Parâmetros

name:Object (default = *) — O nome do elemento a ser correspondido.

Retorna

XMLList — Um objeto XMLList de descendentes correspondentes. Se não houver descendentes, retornará um objeto XMLList vazio.

Elementos da API relacionados

acessador do descendente (..) operador

Exemplo ( Como usar este exemplo )

Para retornar descendentes com nomes que correspondem a palavras reservadas do ActionScript, use o método descendants() no lugar do operador (..) do descendente, como no exemplo a seguir:

var xml:XML = 
  <enrollees>
    <student id="239">
        <class name="Algebra" />
        <class name="Spanish 2"/>
    </student>
    <student id="206">
        <class name="Trigonometry" />
        <class name="Spanish 2" />
    </student>
  </enrollees>
trace(xml.descendants("class"));

O exemplo a seguir mostra que o método descendants() retorna um objeto XMLList que contém todos os objetos descendentes, incluindo filhos, netos e assim por diante:

XML.ignoreComments = false;
var xml:XML = 
        <body>
            <!-- comment -->
            text1
            <a>
                <b>text2</b>
            </a>
        </body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>

elements

()

método

AS3 function elements(name:Object = *):XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Lista os elementos de um objeto XML. Um elemento consiste de um marca inicial e uma marca final; por exemplo, <first></first>. O parâmetro name é opcional. O parâmetro name pode ser um objeto QName, um tipo de dados String ou qualquer outro tipo de dados que seja subsequentemente convertido em um tipo de dados String. Use o parâmetro name para listar um elemento específico. Por exemplo, o elemento "first" retorna "John" neste exemplo: <first>John</first>.

Para listar todos os elementos, use o asterisco (*) como parâmetro. O asterisco também é o parâmetro padrão.

Use o método length() com o parâmetro de asterisco para processar a saída do número total de elementos. Por exemplo, numElement = addressbook.elements("*").length().

Parâmetros

name:Object (default = *) — O nome do elemento. O nome de um elemento é delimitado por sinais de maior e menor. Por exemplo, "first" é o name neste exemplo: <first></first>.

Retorna

XMLList — Um objeto XMLList do conteúdo do elemento. O conteúdo do elemento se enquadra entre as marcas inicial e final. Se você usar o asterisco (*) para chamar todos os elementos, tanto as marcas do elemento quanto o seu conteúdo serão retornados.

Elementos da API relacionados

XML.child()
Classe XMLList
XML.length()
XML.attribute()
XML dot (.) operador

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra que o método elements() retorna uma lista de elementos somente e não de comentários, propriedades de texto ou instruções de processamento:

var xml:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
            text
            <a>1</a>
            <b>2</b>
        </foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b>

Para retornar elementos com nomes que correspondem a palavras reservadas do ActionScript, use o método elements() no lugar do operador XML dot (.), como no exemplo a seguir:

var xml:XML =
 <student id="206">
    <class name="Trigonometry" />
    <class name="Spanish 2" />
 </student>
trace(xml.elements("class"));

hasComplexContent

()

método

AS3 function hasComplexContent():Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Verifica se o objeto XML tem conteúdo complexo. Um objeto XML tem conteúdo complexo quando possui elementos-filho. Objetos XML que representam atributos, comentários, instruções de processamento e nós de texto não têm conteúdo complexo. Entretanto, um objeto que contém esses itens ainda pode ser considerado como tendo conteúdo complexo (se o objeto tiver elementos-filho).

Retorna

Boolean — Se o objeto XML contiver conteúdo complexo, true; caso contrário, false.

Elementos da API relacionados

XML.hasSimpleContent()

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra um objeto XML com uma propriedade a que tem conteúdo simples e uma propriedade a que tem conteúdo complexo:

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

hasOwnProperty

()

método

AS3 function hasOwnProperty(p:String):Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Verifica se o objeto tem a propriedade especificada pelo parâmetro p.

Parâmetros

p:String — A propriedade a ser correspondida.

Retorna

Boolean — Se a propriedade existir, true; caso contrário false.

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa o método hasOwnProperty() para garantir que uma propriedade (b) exista antes de avaliar uma expressão (b == "11") que usa a propriedade:

var xml:XML = 
        <foo>
            <a />
            <a>
                <b>10</b>
            </a>
            <a>
                <b>11</b>
            </a>
        </foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11"));

Se a última linha neste exemplo fosse a seguinte, o Flash Player lançaria uma exceção, já que o primeiro elemento a não tem uma propriedade b:

trace(xml.a.(b == "11"));

O exemplo a seguir usa o método hasOwnProperty() para garantir que uma propriedade (item) exista antes de avaliar uma expressão (item.contains("toothbrush")) que usa a propriedade:

var xml:XML = 
        <orders>
            <order id='1'>
                <item>toothbrush</item>
                <item>toothpaste</item>
            </order>
            <order>
                <returnItem>shoe polish</returnItem>
            </order>
        </orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush")));

hasSimpleContent

()

método

AS3 function hasSimpleContent():Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Verifica se o objeto XML tem conteúdo simples. Um objeto XML terá conteúdo simples se representar um nó de texto, nó de atributo ou elemento XML que não tem elementos-filho. Objetos XML que representam comentários e instruções de processamento não têm conteúdo simples.

Retorna

Boolean — Se o objeto XML contiver conteúdo simples, true; caso contrário, false.

Elementos da API relacionados

XML.hasComplexContent()

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra um objeto XML com uma propriedade a que tem conteúdo simples e uma propriedade a que tem conteúdo complexo:

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

inScopeNamespaces

()

método

AS3 function inScopeNamespaces():Array

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Lista os namespaces do objeto XML, com base no pai do objeto.

Retorna

Array — Uma matriz de objetos Namespace.

insertChildAfter

()

método

AS3 function insertChildAfter(child1:Object, child2:Object):*

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Insere o parâmetro child2 especificado após o parâmetro child1 neste objeto XML e retorna o objeto resultante. Se o parâmetro child1 for null, o método inserirá o conteúdo de child2 antes de todos os filhos do objeto XML (em outras palavras, depois de none). Se child1 for fornecido, mas não existir no objeto XML, este não será modificado e undefined será retornado.

Se você chamar esse método em um filho XML que não é um elemento (texto, atributos, comentários, pi e assim por diante), undefined será retornado.

Use o operador delete (XML) para remover nós XML.

Parâmetros

	`child1:Object` — O objeto no objeto de origem que é inserido antes de `child2`.

	`child2:Object` — O objeto a ser inserido.

Retorna

* — O objeto XML resultante ou undefined.

Elementos da API relacionados

XML.insertChildBefore()
operador "delete" (XML)

Exemplo ( Como usar este exemplo )

O exemplo a seguir acrescenta um elemento ao final dos elementos-filho de um objeto XML:

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

A saída de trace() é a seguinte:

 <menu>
     <item>burger</item>
     <saleItem>fries</saleItem>
     <item>soda</item>
 </menu>

insertChildBefore

()

método

AS3 function insertChildBefore(child1:Object, child2:Object):*

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Insere o parâmetro child2 especificado antes do parâmetro child1 neste objeto XML e retorna o objeto resultante. Se o parâmetro child1 for none, o método inserirá o conteúdo de child2 depois de todos os filhos do objeto XML (em outras palavras, antes de none). Se child1 for fornecido, mas não existir no objeto XML, este não será modificado e undefined será retornado.

Se você chamar esse método em um filho XML que não é um elemento (texto, atributos, comentários, pi e assim por diante), undefined será retornado.

Use o operador delete (XML) para remover nós XML.

Parâmetros

	`child1:Object` — O objeto no objeto de origem que é inserido depois de `child2`.

	`child2:Object` — O objeto a ser inserido.

Retorna

* — O objeto XML resultante ou undefined.

Elementos da API relacionados

XML.insertChildAfter()
operador "delete" (XML)

Exemplo ( Como usar este exemplo )

O exemplo a seguir acrescenta um elemento ao final dos elementos-filho de um objeto XML:

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildBefore(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

A saída de trace() é a seguinte:

 <menu>
     <saleItem>fries</saleItem>
     <item>burger</item>
     <item>soda</item>
 </menu>

length

()

método

AS3 function length():int

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Para objetos XML, esse método sempre retorna o inteiro 1. O método length() da classe XMLList retorna um valor de 1 para um objeto XMLList que contém apenas um valor.

Retorna

int — Sempre retorna 1 para qualquer objeto XML.

localName

()

método

AS3 function localName():Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Fornece a parte de nome local do nome qualificado do objeto XML.

Retorna

Object — O nome local é String ou null.

Exemplo ( Como usar este exemplo )

O exemplo a seguir ilustra o uso do método localName():

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.localName()); // Envelope

name

()

método

AS3 function name():Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Fornece o nome qualificado do objeto XML.

Retorna

Object — O nome qualificado é QName ou null.

Elementos da API relacionados

XML.attributes()
identificador de atributo

Exemplo ( Como usar este exemplo )

O exemplo a seguir ilustra o uso do método name() para obter o nome qualificado de um objeto XML:

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope"

O exemplo a seguir ilustra o uso do método name() chamado em uma propriedade XML, em um elemento de texto e em um atributo:

var xml:XML = 
        <foo x="15" y="22">
            text
        </foo>;
        
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x

namespace

()

método

AS3 function namespace(prefix:String = null):*

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Se nenhum parâmetro for fornecido, fornece o namespace associado ao nome qualificado deste objeto XML. Se um parâmetro prefix for especificado, o método retornará o namespace que corresponde a esse parâmetro prefix e que está no escopo do objeto XML. Se esse namespace não existir, o método retornará undefined.

Parâmetros

prefix:String (default = null) — O prefixo que você deseja corresponder.

Retorna

* — Retorna null, undefined ou um namespace.

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa o método namespace() para obter o namespace de um objeto XML e atribuí-lo a um objeto Namespace denominado soap, que é então usado na identificação de uma propriedade do objeto xml (xml.soap::Body[0]):

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope

var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather"

O exemplo a seguir usa o método namespace() para obter o namespace padrão de um nó, bem como o namespace de um prefixo específico ("dc"):

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">
                <!-- ... -->
        </rdf:RDF>;
                    
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined

namespaceDeclarations

()

método

AS3 function namespaceDeclarations():Array

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Lista declarações de namespace associadas ao objeto XML no contexto de seu pai.

Retorna

Array — Uma matriz de objetos Namespace.

Elementos da API relacionados

XML.namespace()

Exemplo ( Como usar este exemplo )

O exemplo a seguir processa a saída das declarações de namespace de um objeto XML:

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">

            <!-- ... -->
            
        </rdf:RDF>;
                    
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
    var ns:Namespace = xml.namespaceDeclarations()[i]; 
    var prefix:String = ns.prefix;
    if (prefix == "") {
        prefix = "(default)";
    }
    trace(prefix + ":" , ns.uri);
}

A saída de trace() é a seguinte:

rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
 dc: http://purl.org/dc/elements/1.1/
 (default): http://purl.org/rss/1.0/

nodeKind

()

método

AS3 function nodeKind():String

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Especifica o tipo de player. texto, comentário, instrução de processamento, atributo ou elemento.

Retorna

String — O tipo de nó usado.

Elementos da API relacionados

identificador de atributo

Exemplo ( Como usar este exemplo )

Esse exemplo rastreia todos os cinco tipos de nó:

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;

var xml:XML = 
    <example id="10">
        <!-- this is a comment -->
        <?test this is a pi ?>
        and some text
    </example>;

trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute

normalize

()

método

AS3 function normalize():XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Para o objeto XML e todos os objetos XML descendentes, mescla os nós de texto adjacentes e elimina nós de texto vazios.

Retorna

XML — O objeto XML normalizado resultante.

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra o efeito de chamar o método normalize():

var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1

parent

()

método

AS3 function parent():*

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna o pai do objeto XML. Se o objeto XML não tiver pai, o método retornará undefined.

Retorna

* — Uma referência XML do nó pai, ou undefined, se o objeto XML não tiver pai.

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa o método parent() para identificar o elemento-pai de um elemento específico em uma estrutura XML:

var xml:XML = 
    <body>
        <p id="p1">Hello</p>
        <p id="p2">Test:
            <ul>
                <li>1</li>
                <li>2</li>
            </ul>
        </p>
    </body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2

prependChild

()

método

AS3 function prependChild(value:Object):XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Insere uma cópia do objeto-child fornecido no elemento XML antes de qualquer propriedade XML existente para esse elemento.

Use o operador delete (XML) para remover nós XML.

Parâmetros

value:Object — O objeto a ser inserido.

Retorna

XML — O objeto XML resultante.

Elementos da API relacionados

operador "delete" (XML)

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa o método prependChild() para adicionar um elemento ao início de uma lista-filho de um objeto XML:

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.prependChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>

processingInstructions

()

método

AS3 function processingInstructions(name:String = "*"):XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Se um parâmetro name for fornecido, lista todos os filhos do objeto XML que contêm instruções de processamento com esse name. Sem parâmetros, o método lista todos os filhos do objeto XML que contêm instruções de processamento.

Parâmetros

name:String (default = "*") — O nome das instruções de processamento a serem correspondidas.

Retorna

XMLList — Uma lista de objetos-filho correspondentes.

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa o método processingInstructions() para obter uma matriz de instruções de processamento para um objeto XML:

XML.ignoreProcessingInstructions = false;
var xml:XML =
    <body>
            foo
            <?xml-stylesheet href="headlines.css" type="text/css" ?>
            <?instructionX ?>
            
    </body>;

trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet

propertyIsEnumerable

()

método

AS3 function propertyIsEnumerable(p:String):Boolean

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Verifica se a propriedade p está no conjunto de propriedades que podem ser iteradas em uma instrução for..in aplicada ao objeto XML. Retorna true somente se toString(p) == "0".

Parâmetros

p:String — A propriedade que você deseja verificar.

Retorna

Boolean — Se a propriedade puder ser iterada em uma instrução for..in, true; caso contrário, false.

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra que, para um objeto XML, o método propertyNameIsEnumerable() retorna um valor de true somente para o valor 0; enquanto para um objeto XMLList, o valor de retorno é true para cada valor de índice válido do objeto XMLList:

var xml:XML = 
        <body>
             <p>Hello</p>
               <p>World</p>
        </body>;

trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false

for (var propertyName:String in xml) {
    trace(xml[propertyName]);
}

var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false

for (var propertyName:String in list) { 
    trace(list[propertyName]);
}

removeNamespace

()

método

AS3 function removeNamespace(ns:Namespace):XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Remove o namespace especificado para esse objeto e todos os descendentes. O método removeNamespaces() não removerá um namespace se ele for referenciado pelo nome qualificado desse objeto ou pelo nome qualificado dos atributos desse objeto.

Parâmetros

ns:Namespace — O namespace a ser removido.

Retorna

XML — Uma cópia do objeto XML resultante.

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra como remover uma declaração de namespace de um objeto XML:

var xml:XML = 
    <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
        xmlns:dc="http://purl.org/dc/elements/1.1/" 
        xmlns="http://purl.org/rss/1.0/">
    
        <!-- ... -->
        
    </rdf:RDF>;

trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); // 
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2

replace

()

método

AS3 function replace(propertyName:Object, value:XML):XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Substitui as propriedades especificadas pelo parâmetro propertyName pelo parâmetro value especificado. Se nenhuma propriedade corresponder a propertyName, o objeto XML permanecerá inalterado.

Parâmetros

	`propertyName:Object` — Pode ser um valor numérico, um nome não qualificado para um conjunto de elementos XML, um nome qualificado para um conjunto de elementos XML ou o caractere curinga de asterisco ("*"). Use um nome não qualificado para identificar elementos XML no namespace padrão.

	`value:XML` — O valor de substituição. Pode ser um objeto XML, um objeto XMLList ou qualquer valor que possa ser convertido com `toString()`.

Retorna

XML — O objeto XML resultante, com as propriedades correspondentes substituídas.

Exemplo ( Como usar este exemplo )

O exemplo a seguir ilustra a chamada do método replace() com um inteiro como primeiro parâmetro:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace(1, <p>Bob</p>);
trace(xml);

Isso resulta na seguinte saída de trace():


 <body>
     <p>Hello</p>
     <p>Bob</p>
     <hr/>
 </body>

O exemplo a seguir chama o método replace() com uma string como primeiro parâmetro:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("p", <p>Hi</p>); 
trace(xml);

Isso resulta na seguinte saída de trace():


 <body>
     <p>Hi</p>
     <hr/>
 </body>;

O exemplo a seguir ilustra a chamada do método replace() com QName como primeiro parâmetro:

var xml:XML = 
    <ns:body xmlns:ns = "myNS">
        <ns:p>Hello</ns:p>
        <ns:p>World</ns:p>
        <hr/>
    </ns:body>;

var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);

Isso resulta na seguinte saída de trace():


 <ns:body xmlns:ns = "myNS">
     <p>Bob</p>
     <hr/>
 </ns:body>

O exemplo a seguir ilustra a chamada do método replace() com a string "*" como primeiro parâmetro:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("*", <img src = "hello.jpg"/>);
trace(xml);

Isso resulta na seguinte saída de trace():


 <body>
     <img src="hello.jpg"/>
 </body>

setChildren

()

método

AS3 function setChildren(value:Object):XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Substitui as propriedades-filho do objeto XML pelo conjunto especificado de propriedades XML fornecido no parâmetro value

Parâmetros

value:Object — As propriedades XML de substituição. Pode ser um objeto XML simples ou um objeto XMLList.

Retorna

XML — O objeto XML resultante.

Exemplo ( Como usar este exemplo )

O exemplo a seguir ilustra a chamada do método setChildren(), primeiro usando um objeto XML como parâmetro e depois, um objeto XMLList como parâmetro:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
    </body>;

var list:XMLList = xml.p;

xml.setChildren(<p>hello</p>);
trace(xml);

//    <body>
//        <p>hello</p>
//    </body>

xml.setChildren(list);
trace(xml);

//    <body>
//        <p>Hello</p>
//        <p>World</p>
//    </body>

setLocalName

()

método

AS3 function setLocalName(name:String):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Altera o nome local do objeto XML para o parâmetro name especificado.

Parâmetros

name:String — O nome de substituição para o nome local.

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa o método setLocalName() para alterar o nome local de um elemento XML:

var xml:XML = 
    <ns:item xmlns:ns="http://example.com">
        toothbrush
    </ns:item>;
    
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>

setName

()

método

AS3 function setName(name:String):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Define o nome do objeto XML como o nome ou o nome de atributo qualificado especificado.

Parâmetros

name:String — O novo nome para o objeto.

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa o método setName() para alterar o nome de um elemento XML:

var xml:XML = 
    <item>
        toothbrush
    </item>;
    
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>

setNamespace

()

método

AS3 function setNamespace(ns:Namespace):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Define o namespace associado ao objeto XML.

Parâmetros

ns:Namespace — O novo namespace.

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa um namespace soap definido em um objeto XML e o aplica ao namespace de outro objeto XML (xml2):

var xml1:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
            <!-- ... -->
        </soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");

var xml2:XML = 
    <Envelope>
        <Body/>
    </Envelope>;
    
xml2.setNamespace(ns);

trace(xml2);

setSettings

()

método

AS3 static function setSettings(... rest):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Define valores para as seguintes propriedades XML: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting. As configurações a seguir são padrão, sendo aplicadas se nenhum parâmetro setObj for fornecido:

XML.ignoreComments = true
XML.ignoreProcessingInstructions = true
XML.ignoreWhitespace = true
XML.prettyIndent = 2
XML.prettyPrinting = true

Observação: Não aplique esse método a uma ocorrência da classe XML; aplique-o a XML, como no código a seguir: XML.setSettings().

Parâmetros

... rest — Um objeto com cada uma das propriedades a seguir:

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

Elementos da API relacionados

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting
defaultSettings()
settings()

Exemplo ( Como usar este exemplo )

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

settings

()

método

AS3 static function settings():Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Recupera as seguintes propriedades: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting.

Retorna

Object — Um objeto com as seguintes propriedades XML:

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

Elementos da API relacionados

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.defaultSettings()
XML.setSettings()

Exemplo ( Como usar este exemplo )

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

text

()

método

AS3 function text():XMLList

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna um objeto XMLList de todas as propriedades XML do objeto XML que representam nós de texto XML.

Retorna

XMLList — A lista de propriedades.

Exemplo ( Como usar este exemplo )

O exemplo a seguir usa o método text() para alterar os nós de texto de um objeto XML:

var xml:XML =
        <body>
            text1
            <hr/>
            text2
        </body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2

toJSON

()

método

AS3 function toJSON(k:String):*

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 11, AIR 3, Flash Lite 4

Fornece um método que pode ser substituído para personalizar a codificação JSON de valores em um objeto XML.

O método JSON.stringify() procura um método toJSON() em cada objeto que percorre. Se o método toJSON() for encontrado, JSON.stringify() o invocará para cada valor que encontrar, passando a chave pareada ao valor.

O XML fornece uma implementação padrão de toJSON () que simplesmente retorna o nome da classe. Os clientes que desejam exportar objetos XML para JSON devem fornecer a sua própria implementação. Isso pode ser feito com a redefinição do método toJSON() no protótipo da classe.

O método toJSON() pode retornar um valor de qualquer tipo. Se retornar um objeto, stringify() aplicará funções recursivas a esse objeto. Se toJSON() retornar uma string, stringify() não usará funções recursivas e continuará sua travessia.

Parâmetros

k:String — A chave de um par de chave/valor que JSON.stringify() encontrou durante a travessia desse objeto

Retorna

* — A string do nome da classe.

Elementos da API relacionados

'Objeto'
Object.prototype

toString

()

método

AS3 function toString():String

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna uma representação de string do objeto XML. As regras para essa conversão dependem de o objeto XML ter conteúdo simples ou complexo:

Se o objeto XML tiver conteúdo simples, toString() retornará o conteúdo de string do objeto XML removendo o seguinte: a marca inicial, atributos, declarações de namespace e a marca final.

Se o objeto XML tiver conteúdo complexo, toString() retornará uma String codificada em XML representando o objeto XML inteiro, incluindo a marca inicial, os atributos, as declarações de namespace e a marca final.

Para sempre retornar o objeto XML inteiro, use toXMLString().

Retorna

String — A representação de string do objeto XML.

Elementos da API relacionados

XML.hasSimpleContent()
XML.hasComplexContent()
XML.toXMLString()

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra o que o método toString() retorna quando o objeto XML tem conteúdo simples:

var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example

O exemplo a seguir mostra o que o método toString() retorna quando o objeto XML tem conteúdo complexo:

var test:XML = 
<type name="Joe">
    <base name="Bob"></base>
    example
</type>;
trace(test.toString());
  // <type name="Joe">
  // <base name="Bob"/>
  // example
  // </type>

toXMLString

()

método

AS3 function toXMLString():String

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna uma representação de string do objeto XML. Ao contrário do método toString(), toXMLString() sempre retorna a marca inicial, os atributos e a marca final do objeto XML, independentemente do objeto XML ter conteúdo simples ou complexo. (O método toString() remove esses itens para objetos XML que têm conteúdo simples.)

Retorna

String — A representação de string do objeto XML.

Elementos da API relacionados

XML.toString()

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra a diferença entre usar o método toString() (que é aplicado a todos os parâmetros de um método trace(), por padrão) e usar o método toXMLString():

var xml:XML =
        <p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>

valueOf

()

método

AS3 function valueOf():XML

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

Retorna o objeto XML.

Retorna

XML — O valor primitivo de uma ocorrência de XML.

Exemplo ( Como usar este exemplo )

O exemplo a seguir mostra que o valor retornado pelo método valueOf() é o mesmo que o objeto XML de origem:

var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true

Exemplos Como usar este exemplo

XMLExample.as

O exemplo a seguir cria primeiro uma variável XML e adiciona nós a ela. Em seguida, as propriedades XML são usadas para localizar e imprimir nós XML. Observe que o símbolo "arroba" (@) é usado em várias das chamadas trace() para localizar informações por nome de atributo.

package {
    import flash.display.Sprite;

    public class XmlExample extends Sprite {        
        public function XmlExample() {
            var employees:XML =
                <employees>
                    <employee ssn="123-123-1234">
                        <name first="John" last="Doe"/>
                        <address>
                            <street>11 Main St.</street>
                            <city>San Francisco</city>
                            <state>CA</state>
                            <zip>98765</zip>
                        </address>
                    </employee>
                    <employee ssn="789-789-7890">
                        <name first="Mary" last="Roe"/>
                        <address>
                            <street>99 Broad St.</street>
                            <city>Newton</city>
                            <state>MA</state>
                            <zip>01234</zip>
                        </address>
                    </employee>
                </employees>;

            trace(employees.employee[0].address.zip);   // 98765

            trace(employees.employee[1].@ssn);          // 789-789-7890

            trace(employees.employee.name);             // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees..zip[0]);                   // 98765

            trace(employees..@ssn[1]);                  // 789-789-7890

            trace(employees..name);                     // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees.employee[0].address.*);     // <street>11 Main St.</street>    
                                                        // <city>San Francisco</city>
                                                        // <state>CA</state>
                                                        // <zip>98765</zip>
            var node:String = "zip";
            trace(employees.employee[0].address[node]); // 98765
            
            var attribute:String = "ssn";
            trace(employees.employee[1].@[attribute]);  // 789-789-7890
            
            for each (var num:XML in employees..@ssn) {
                trace(num);                             // 123-123-1234
            }                                           // 789-789-7890
            
            var ssnToFind:String = "789-789-7890";
            trace(employees.employee.(@ssn == ssnToFind).toXMLString());
                                                        // <employee ssn="789-789-7890">
                                                        // <name first="Mary" last="Roe"/>
                                                        // <address>
                                                        // <street>99 Broad St.</street>
                                                        // <city>Newton</city>
                                                        // <state>MA</state>
                                                        // <zip>01234</zip>
                                                        // </address>
                                                        // </employee>
        }
    }
}

Aspectos jurídicos | Política de privacidade on-line

XML - AS3

Pacotesx

Elementos de linguagem

Apêndices

Classes x

ignoreComments

ignoreProcessingInstructions

ignoreWhitespace

prettyIndent

prettyPrinting

XML

addNamespace

appendChild

attribute

attributes

child

childIndex

children

comments

contains

copy

defaultSettings

descendants

elements

hasComplexContent

hasOwnProperty

hasSimpleContent

inScopeNamespaces

insertChildAfter

insertChildBefore

length

localName

name

namespace

namespaceDeclarations

nodeKind

normalize

parent

prependChild

processingInstructions

propertyIsEnumerable

removeNamespace

replace

setChildren

setLocalName

setName

setNamespace

setSettings

settings

text

toJSON

toString

toXMLString

valueOf