QName  - AS3

O nome local do objeto QName.

O URI (Uniform Resource Identifier) do objeto QName.

Cria um objeto QName que é uma cópia de outro objeto QName. Se o parâmetro transmitido ao construtor for um objeto QName, uma cópia desse objeto QName será criada. Se o parâmetro não for um objeto QName, ele será convertido em uma string e atribuído à propriedade localName do nova ocorrência de QName. Se o parâmetro for undefined ou não especificado, um novo objeto QName será criado com a propriedade localName definida como uma string vazia.

Nota: esta classe mostra duas entradas de construtor, uma vez que cada forma aceita diferentes parâmetros. O construtor se comporta de forma diferente dependendo do tipo e do número de parâmetros transmitidos, conforme detalhado em cada entrada. O ActionScript 3.0 não oferece suporte à sobrecarga de métodos ou construtores.

Cria um objeto QName com um URI a partir de um objeto Namespace e um localName a partir de um objeto QName. Se um desses parâmetros não for o tipo de dados esperado, ele será convertido em uma string e atribuído à propriedade correspondente do novo objeto QName. Por exemplo, se ambos os parâmetros forem strings, um novo objeto QName será retornado com uma propriedade uri definida como o primeiro parâmetro e uma propriedade localName definida como o segundo parâmetro. Portanto, são formas válidas do construtor as seguintes permutações, dentre muitas outras:

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

Se você transmitir null para o parâmetro uri, a propriedade uri do novo objeto QName será definida como null.

Nota: esta classe mostra duas entradas de construtor, uma vez que cada forma aceita diferentes parâmetros. O construtor se comporta de forma diferente dependendo do tipo e do número de parâmetros transmitidos, conforme detalhado em cada entrada. O ActionScript 3.0 não oferece suporte à sobrecarga de métodos ou construtores.

Retorna uma string composta do URI e do nome local do objeto QName, separada por "::".

O formato depende da propriedade uri do objeto QName:

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

Retorna o objeto QName.

1. Criação de uma ocorrência de Namespace e uso dessa ocorrência como entrada para o construtor QName. Essa abordagem será mais conveniente se você quiser usar a propriedade Namespace.prefix para outras finalidades mais tarde.
2. Criação de uma ocorrência de QName usando um valor de string simples para o parâmetro uri no construtor QName.

Esse código faz o seguinte:

1. Define uma variável XML denominada rssXML.
2. Cria um novo objeto Namespace com o prefixo dc.
3. Cria um novo objeto QName usando o objeto Namespace e o nome local creator.
4. Chama o método showDescendants(), que usa o método XML.descendants() para obter uma ocorrência de XMLList contendo todos os elementos descendentes cujo nome qualificado corresponda à ocorrência de QName específica.
5. Exibe o nome qualificado e o valor de texto de cada elemento na lista usando uma repetição for each.
6. Cria outro objeto QName usando um valor de string para o parâmetro uri e o nome local date.
7. Chama novamente o método showDescendants() para exibir o nome o valor de texto dos elementos descendentes.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}