| Pakiet | flash.xml |
| Klasa | public class XMLDocument |
| Dziedziczenie | XMLDocument  XMLNode Object |
| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Klasa XMLDocument, a także klasy XMLNode i XMLNodeType, zostały zachowane ze względu na zgodność wstecz. Funkcjonalność ładowania dokumentów XML została przeniesiona do klasy URLLoader.
Powiązane elementy interfejsu API
Ukryj dziedziczone właściwości publiczne
Pokaż dziedziczone właściwości publiczne| Właściwość | Zdefiniowane przez | ||
|---|---|---|---|
 | attributes : Object
Obiekt zawierający wszystkie atrybuty określonej instancji obiektu XMLNode. | XMLNode | |
| childNodes : Array [tylko do odczytu]
Tablica potomków określonego obiektu XMLNode. | XMLNode | |
| constructor : Object
Odwołanie do obiektu klasy lub funkcji konstruktora, dotyczące danej instancji obiektu. | Object | |
| docTypeDecl : Object = null
Określa informacje o deklaracji DOCTYPE dokumentu XML. | XMLDocument | ||
| firstChild : XMLNode
Analizuje określony obiekt XMLDocument i odwołuje się do pierwszego potomka na liście potomków węzła nadrzędnego. | XMLNode | |
| idMap : Object
Obiekt zawierający węzły kodu XML, którym przypisano atrybut ID. | XMLDocument | ||
| ignoreWhite : Boolean = false
Jeśli ma wartość prawda, w trakcie analizy są pomijane tylko węzły tekstowe bez tekstu. | XMLDocument | ||
| lastChild : XMLNode
Wartość XMLNode, która odwołuje się do ostatniego potomka na liście potomków węzła. | XMLNode | |
| localName : String [tylko do odczytu]
Część nazwy węzła XML będąca nazwą lokalną. | XMLNode | |
| namespaceURI : String [tylko do odczytu]
Jeśli węzeł XML ma prefiks, parametr URIprzestrzeninazw stanowi wartość deklaracji xmlns dla tego prefiksu (identyfikator URI), którą nazywa się zwykle identyfikatorem URI przestrzeni nazw. | XMLNode | |
| nextSibling : XMLNode
Wartość XMLNode, która odwołuje się do następnego węzła siostrzanego na liście potomków węzła nadrzędnego. | XMLNode | |
| nodeName : String
Ciąg znaków reprezentujący nazwę węzła obiektu XMLNode. | XMLNode | |
| nodeType : uint
Stała będąca wartością parametru nodeType: XMLNodeType.ELEMENT_NODE w przypadku elementu XML lub XMLNodeType.TEXT_NODE w przypadku węzła tekstowego. | XMLNode | |
| nodeValue : String
Wartość węzła obiektu XMLDocument. | XMLNode | |
| parentNode : XMLNode
Wartość XMLNode, która odwołuje się do węzła macierzystego określonego obiektu XML, a jeśli węzeł nie ma węzła nadrzędnego zwraca wartość null. | XMLNode | |
| prefix : String [tylko do odczytu]
Prefiks nazwy węzła XML. | XMLNode | |
| previousSibling : XMLNode
Wartość XMLNode, która odwołuje się do poprzedniego węzła siostrzanego na liście potomków węzła nadrzędnego. | XMLNode | |
| xmlDecl : Object = null
Ciąg znaków określający informacje o deklaracji XML dokumentu. | XMLDocument | ||
| Metoda | Zdefiniowane przez | ||
|---|---|---|---|
XMLDocument(source:String = null)
Tworzy nowy obiekt XMLDocument. | XMLDocument | ||
|
Dołącza określony węzeł do listy elementów potomnych obiektu XML. | XMLNode | |
|
Konstruuje i zwraca nowy węzeł XML, którego typ, nazwa, wartość i atrybuty są identyczne jak w przypadku określonego obiektu XML. | XMLNode | |
Tworzy nowy obiekt XMLNode o nazwie określonej przez parametr. | XMLDocument | ||
Tworzy nowy węzeł tekstowy XML z określonym tekstem. | XMLDocument | ||
|
Zwraca identyfikator URI przestrzeni nazw, skojarzony z określonym prefiksem węzła. | XMLNode | |
|
Zwraca prefiks skojarzony z identyfikatorem URI przestrzeni nazw węzła. | XMLNode | |
|
Wskazuje, czy określony obiekt XMLNode ma węzły potomne. | XMLNode | |
|
Wskazuje, czy dla obiektu zdefiniowano określoną właściwość. | Object | |
|
Umieszcza nowy węzeł potomny na liście elementów potomnych obiektu XML, przed węzłem określonym za pomocą parametru przed. | XMLNode | |
|
Wskazuje, czy instancja klasy Object należy do łańcucha prototypów obiektu określonego jako parametr. | Object | |
Analizuje tekst XML określony przez parametr i umieszcza w określonym obiekcie XMLDocument wynikowe drzewo XML. | XMLDocument | ||
|
Wskazuje, czy określona właściwość istnieje i jest przeliczalna. | Object | |
|
Usuwa określony obiekt XML z obiektu nadrzędnego. | XMLNode | |
|
Ustawia dostępność właściwości dynamicznej używanej w pętlach. | Object | |
|
Zwraca ciąg reprezentujący obiekt — sformatowany zgodnie z konwencjami właściwymi dla ustawień regionalnych. | Object | |
[przesłanianie]
Zwraca ciąg reprezentujący obiekt XML. | XMLDocument | ||
|
Zwraca pierwotną wartość dla określonego obiektu. | Object | |
docTypeDecl | właściwość |
public var docTypeDecl:Object = null| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Określa informacje o deklaracji DOCTYPE dokumentu XML. Po przeanalizowaniu tekstu XML i przekształceniu go w obiekt XMLDocument właściwości XMLDocument.docTypeDecl obiektu XMLDocument jest przypisywany tekst deklaracji DOCTYPE dokumentu XML (na przykład <!DOCTYPE greeting SYSTEM "hello.dtd">). Właściwości przypisywany jest ciąg znaków reprezentujący deklarację DOCTYPE, a nie obiekt XMLNode.
Starsza wersja analizatora XML języka ActionScript nie jest analizatorem sprawdzającym poprawność. Deklaracja DOCTYPE jest odczytywana przez analizator i zapisywana we właściwości XMLDocument.docTypeDecl, ale nie jest sprawdzana poprawność deklaracji DTD.
Jeśli podczas analizowania nie zostanie napotkana deklaracja DOCTYPE, właściwość XMLDocument.docTypeDecl jest ustawiana na null. Metoda XML.toString() zwraca zawartość właściwości XML.docTypeDecl bezpośrednio po deklaracji XML przechowywanej we właściwości XML.xmlDecl i przed jakimkolwiek innym tekstem z obiektu XML. Jeśli właściwość XMLDocument.docTypeDecl jest równa, deklaracja DOCTYPE nie jest zwracana.
idMap | właściwość |
public var idMap:Object| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Obiekt zawierający węzły kodu XML, którym przypisano atrybut id. Nazwy właściwości obiektu (każda zawiera węzeł) są równe wartościom atrybutów id.
Weźmy pod uwagę następujący obiekt XMLDocument:
<employee id='41'>
<name>
John Doe
</name>
<address>
601 Townsend St.
</address>
</employee>
<employee id='42'>
<name>
Jane Q. Public
</name>
</employee>
<department id="IT">
Information Technology
</department>
W tym przykładzie właściwość idMap obiektu XMLDocument jest obiektem z trzema właściwościami: 41, 42 oraz IT. Każda z tych właściwości jest węzłem XMLNode, dla którego istnieje odpowiadająca mu wartość id. Na przykład właściwość IT obiektu idMap jest następującym węzłem:
<department id="IT">
Information Technology
</department>
Aby została utworzona instancja przypisana właściwości idMap, należy użyć metody parseXML() dla obiektu XMLDocument.
Jeśli istnieje więcej niż jeden obiekt XMLNode o tej samej wartości id, za dopasowaną właściwość obiektu idNode przyjmuje się właściwość węzła przeanalizowanego w ostatniej kolejności. Na przykład:
var x1:XML = new XMLDocument("<a id='1'><b id='2' /><c id='1' /></a>");
x2 = new XMLDocument();
x2.parseXML(x1);
trace(x2.idMap['1']);
<c>:
<c id='1' />
ignoreWhite | właściwość |
public var ignoreWhite:Boolean = false| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Jeśli ma wartość true, w trakcie analizy są pomijane tylko węzły tekstowe bez tekstu. Nie ma to wpływu na analizę węzłów tekstowych z początkowymi lub końcowymi białymi znakami. Ustawienie domyślne to false.
Można ustawiać właściwość ignoreWhite dla poszczególnych obiektów XMLDocument, co ilustruje poniższy kod:
my_xml.ignoreWhite = true;
xmlDecl | właściwość |
public var xmlDecl:Object = null| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Ciąg znaków określający informacje o deklaracji XML dokumentu. Po przeanalizowaniu dokumentu XML i przetworzeniu go w obiekt XMLDocument właściwości przypisywany jest tekst deklaracji XML dokumentu. Właściwości przypisywany jest ciąg znaków reprezentujący deklarację XML, a nie obiekt XMLNode. Jeśli podczas analizowania nie napotkano deklaracji XML, właściwość jest ustawiana na null. Metoda XMLDocument.toString() zwraca zawartość właściwości XML.xmlDecl, a dopiero po niej pozostały tekst z obiektu XML. Jeśli właściwość XML.xmlDecl zawiera wartość null, nie jest zwracana deklaracja XML.
XMLDocument | () | Konstruktor |
public function XMLDocument(source:String = null)| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Tworzy nowy obiekt XMLDocument. Przed wywołaniem którejkolwiek metody klasy XMLDocument należy za pomocą konstruktora utworzyć obiekt XMLDocument.
Uwaga: Do dodawania elementów i węzłów tekstowych do drzewa dokumentu XML należy używać metod createElement() i createTextNode().
source:String (default = null) |
Powiązane elementy interfejsu API
createElement | () | metoda |
public function createElement(name:String):XMLNode| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Tworzy nowy obiekt XMLNode o nazwie określonej przez parametr. Nowy węzeł początkowo nie ma węzła nadrzędnego, węzłów podrzędnych ani siostrzanych. Metoda zwraca odwołanie do nowo utworzonego obiektu XMLNode, który reprezentuje element. Ta metoda oraz metoda XMLDocument.createTextNode() są konstruktorami służącymi do tworzenia węzłów obiektu XMLDocument.
Parametry
name:String — Nazwa znacznika tworzonego elementu XMLDocument.
|
XMLNode — Obiekt XMLNode.
|
Powiązane elementy interfejsu API
createTextNode | () | metoda |
public function createTextNode(text:String):XMLNode| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Tworzy nowy węzeł tekstowy XML z określonym tekstem. Nowy węzeł początkowo nie ma węzła nadrzędnego, a węzły tekstowe nie mogą mieć węzłów podrzędnych ani siostrzanych. Ta metoda zwraca odwołanie do obiektu XMLDocument reprezentującego nowy węzeł tekstowy. Ta metoda oraz metoda XMLDocument.createElement() są konstruktorami służącymi do tworzenia węzłów obiektu XMLDocument.
Parametry
text:String — Tekst używany do utworzenia nowego węzła tekstowego.
|
XMLNode — Obiekt XMLNode.
|
Powiązane elementy interfejsu API
parseXML | () | metoda |
public function parseXML(source:String):void| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Analizuje tekst XML określony przez parametr value i umieszcza w określonym obiekcie XMLDocument wynikowe drzewo XML. Wszelkie drzewa istniejące w obiekcie XMLDocument są usuwane.
Parametry
source:String — Tekst XML, który ma zostać przeanalizowany i przekazany do określonego obiektu XMLDocument.
|
toString | () | metoda |
package {
import flash.display.Sprite;
import flash.xml.XMLDocument;
import flash.xml.XMLNode;
import flash.xml.XMLNodeType;
public class XMLDocumentExample extends Sprite {
public function XMLDocumentExample() {
var result:XMLDocument = new XMLDocument();
result.ignoreWhite = true;
result.parseXML(getXMLString());
var books:Array = parseBooks(result.firstChild);
trace("books: \n" + books);
}
private function parseBooks(node:XMLNode):Array {
var books:Array = new Array();
var kids:Array = node.childNodes;
for each(var item:XMLNode in kids) {
parseBook(item, books);
}
return books;
}
private function parseBook(node:XMLNode, books:Array):void {
var item:Book = new Book();
item.setPublisher(node.attributes.publisher);
item.setName(node.attributes.name);
books.push(item);
}
private function getXMLString():String {
var list:XML = <books>
<book publisher="Addison-Wesley" name="Design Patterns" />
<book publisher="Addison-Wesley" name="The Pragmatic Programmer" />
<book publisher="Addison-Wesley" name="Test Driven Development" />
<book publisher="Addison-Wesley" name="Refactoring to Patterns" />
<book publisher="O'Reilly Media" name="The Cathedral & the Bazaar" />
<book publisher="O'Reilly Media" name="Unit Test Frameworks" />
</books>;
return list.toXMLString();
}
}
}
class Book {
private var publisher:String;
private var name:String;
public function setPublisher(publisher:String):void {
this.publisher = publisher;
}
public function setName(name:String):void {
this.name = name;
}
public function toString():String {
return "[Book name: " + name + " publisher: " + publisher + "]\n";
}
}
Tue Jun 12 2018, 12:06 PM Z