CameraRoll  - AS3

Sprawdź, czy system otrzymał pozwolenie na dostęp do rolki z aparatu.

Powiązane elementy interfejsu API

Wskazuje, czy metoda CameraRoll.addBitmapData() jest obsługiwana. Obecnie ta funkcja jest obsługiwana wyłącznie w aplikacjach AIR na urządzeniach przenośnych.

Wskazuje, czy jest obsługiwana metoda CameraRoll.browseForImage(). Obecnie ta funkcja jest obsługiwana wyłącznie w aplikacjach AIR na urządzeniach przenośnych.

Tworzy obiekt CameraRoll.

W języku ActionScript jest obsługiwana tylko jedna biblioteka multimediów. Obrazy ze wszystkich obiektów CameraRoll są zapisywane w tym samym repozytorium obrazów.

Dodaje obraz do albumu „Rolka z aparatu” na telefonie iPhone.

Aby w czasie wykonywania sprawdzić, czy aplikacja obsługuje metodę CameraRoll.addBitmapData(), należy odczytać właściwość CameraRoll.supportsAddBitmapData.

Parametry

Otwiera okno dialogowe przeglądarki obrazów, aby umożliwić użytkownikowi wybranie istniejącego obrazu z albumu „Rolka z aparatu” na urządzeniu.

Gdy użytkownik wybiera obraz, wystąpienie klasy CameraRoll wywołuje zdarzenie select zawierające obiekt MediaEvent. Aby wczytać obraz, należy użyć właściwości data obiektu MediaEvent. Właściwość data jest obiektem MediaPromise. Można go wczytać za pomocą metody loadFilePromise() klasy Loader. Obiekt MediaPromise zawiera prawidłowy obiekt File na niektórych platformach (BlackBerry Tablet OS), ale nie zawiera go na pozostałych (iOS i Android). W przypadku użycia metody loadFilePromise() obraz zostaje wczytany poprawnie na wszystkich platformach. Aby uzyskać dostęp do danych surowych z obiektu multimedialnego, można otworzyć źródło danych dostarczone przez przyrzeczony element multimedialny i odczytać dane za pomocą metod interfejsu IDataInput.

Aby w czasie wykonywania sprawdzić, czy aplikacja obsługuje metodę CameraRoll.browseForImage(), należy odczytać właściwość CameraRoll.supportsBrowseForImage.

W systemie iOS (tylko na tabletach iPad) można wygenerować żądanie określonego rozmiaru okna dialogowego przeglądarki obrazów. Można również określić obszar ekranu, który nie powinien zostać przykryty przez okno dialogowe aplikacji do przeglądania. To żądanie działa tylko na tabletach iPad, ponieważ na tych urządzeniach przeglądarka obrazów nie zajmuje całego ekranu.

Aby określić żądany rozmiar i opcje położenia aplikacji do przeglądania (dla tabletów iPad), należy przekazać obiekt CameraRollBrowseOptions do metody browseForImage(). Jeśli nie określono żadnych parametrów, metoda ta umieszcza okno dialogowe w lewym górnym rogu wyświetlacza i używa domyślnych wymiarów okna dialogowego systemu.

Parametry

Więcej informacji

Powiązane elementy interfejsu API

package flash.media.examples
{
        import flash.media.CameraRoll;
        import flash.media.MediaPromise;
        import flash.media.MediaType;
        import flash.events.MediaEvent;
        import flash.events.Event;
        import flash.display.Loader;
        import flash.display.Sprite;
        import flash.events.IOErrorEvent;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        
        public class CameraRollTest extends Sprite{
            private var mediaSource:CameraRoll = new CameraRoll();
            
            public function CameraRollTest() {
                this.stage.align = StageAlign.TOP_LEFT;
                this.stage.scaleMode = StageScaleMode.NO_SCALE;
                
                if( CameraRoll.supportsBrowseForImage )
                {
                    log( "Browsing for image..." );
                    mediaSource.addEventListener( MediaEvent.SELECT, imageSelected );
                    mediaSource.addEventListener( Event.CANCEL, browseCanceled );
                    
                    mediaSource.browseForImage();
                }
                else
                {
                    log( "Browsing in camera roll is not supported.");
                }
            }
            
            private var imageLoader:Loader; 
            private function imageSelected( event:MediaEvent ):void
            {
                log( "Image selected..." );
                
                var imagePromise:MediaPromise = event.data;
                
                imageLoader = new Loader();
                if( imagePromise.isAsync )
                {
                    log( "Asynchronous media promise." );
                    imageLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, imageLoaded );
                    imageLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, imageLoadFailed );
                    imageLoader.loadFilePromise( imagePromise );
                }
                else
                {
                    log( "Synchronous media promise." );
                    imageLoader.loadFilePromise( imagePromise );
                    this.addChild( imageLoader );
                }
            }
            
            private function browseCanceled( event:Event ):void
            {
                log( "Image browse canceled." );
            }
            
            private function imageLoaded( event:Event ):void
            {
                log( "Image loaded asynchronously." );
                this.addChild( imageLoader );
            }
            
            private function imageLoadFailed( event:Event ):void
            {
                log( "Image load failed." );
            }
            
            private function log( text:String ):void
            {
                trace( text );
            }
            
        }
        
    }

Wysyła żądanie dostępu do biblioteki multimediów systemu lub „rolki z aparatu”.

Wywoływane, jeśli użytkownik anuluje operację przeglądania w celu wybrania obrazu, nie wybierając obrazu.

To zdarzenie ma następujące właściwości:

Wskazuje, że operacja addBitmapData() zakończyła się pomyślnie.

To zdarzenie ma następujące właściwości:

Zdarzenie error jest wywoływane w przypadku wystąpienia błędu.

Niektóre źródła błędów:

• Nie można otworzyć aplikacji do przeglądania w poszukiwaniu obrazów.
• Aplikacja do przeglądania w poszukiwaniu obrazów jest już używana.
• Aplikacja AIR próbuje przeglądać w poszukiwaniu obrazu, gdy działa w tle.
• Obraz nie może zostać dodawany do biblioteki multimediów.
• Następuje wywołanie metody nieobsługiwanej na urządzeniu.
• Aplikacja AIR próbuje wczytywać zdalny obraz bez połączenia z internetem.

To zdarzenie ma następujące właściwości:

Rozsyłane, gdy aplikacja zażąda pozwolenia na dostęp do rolki z aparatu. Sprawdź wartość właściwości status, aby zobaczyć, czy pozwolenie zostało udzielone czy nie.

Powiązane elementy interfejsu API

Wywoływane, gdy użytkownik wybierze obraz z biblioteki multimediów urządzenia.

Obiekt MediaEvent wywoływany dla tego zdarzenia pozwala uzyskać dostęp do wybranego elementu multimedialnego.

Definiuje wartość właściwości type obiektu zdarzenia MediaEvent. To zdarzenie ma następujące właściwości: