Matrix3D  - AS3

Wartość Number określająca, czy macierz jest odwracalna.

Obiekt Matrix3D musi być odwracalny. W celu stwierdzenia, czy obiekt Matrix3D jest odwracalny, można użyć właściwości determinant, czyli wyznacznika macierzy. Jeśli wyznacznik jest równy zero, macierz odwrócona nie istnieje. Na przykład jeśli cały wiersz lub cała kolumna macierzy zawiera zera lub jeśli dwa wiersze lub dwie kolumny są równe, wyznacznik będzie równy zero. Wyznacznik jest także używany do rozwiązywania szeregu równań.

Wyznacznik mają tylko macierze kwadratowe, takie jak klasa Matrix3D.

Powiązane elementy interfejsu API

Obiekt Vector3D zawierający pozycję, tj. współrzędne trójwymiarowe (x,y,z) obiektu wyświetlanego w klatce referencyjnej transformacji. Właściwość position zapewnia bezpośredni dostęp do wektora translacji macierzy obiektu wyświetlanego, bez konieczności dekompozycji i ponownej kompozycji macierzy.

Za pomocą właściwości position można pobierać i ustawiać wartości elementów translacji w macierzy transformacji.

Powiązane elementy interfejsu API

Wektor 16 liczb, z których każde 4 elementy stanowią kolumnę w macierzy 4x4.

Jeśli właściwość rawData jest macierzą nieodwracalną, generowany jest wyjątek. Obiekt Matrix3D musi być odwracalny. Jeśli potrzebna jest macierz nieodwracalna, należy utworzyć podklasę obiektu Matrix3D.

Powiązane elementy interfejsu API

Tworzy obiekt Matrix3D. Obiekt Matrix3D można zainicjować za pomocą wektora zawierającego 16 liczb, gdzie każde cztery elementy definiują kolumnę. Po utworzeniu obiektu Matrix3D można uzyskiwać dostęp do elementów jego macierzy za pośrednictwem właściwości rawData.

Jeśli nie jest zdefiniowany żaden parametr, konstruktor generuje obiekt Matrix3D będący macierzą jednostkową. W zapisie macierzowym wszystkie elementy macierzy jednostkowej na przekątnej głównej mają wartości jeden, a pozostałe elementy tej macierzy mają wartość zero. Właściwość rawData macierzy jednostkowej jest równa: 1,0,0,0,0,1,0,0,0,0,1,0,0,0,0,1. Wartość położenia lub translacji macierzy jednostkowej wynosi Vector3D(0,0,0), ustawienie obrotu to Vector3D(0,0,0), a wartość skali to Vector3D(1,1,1).

Powiązane elementy interfejsu API

Dołącza macierz, mnożąc inny obiekt Matrix3D przez bieżący obiekt Matrix3D. Wynikiem jest kombinacja transformacji opisanych przez obie macierze. Jeden obiekt Matrix3D można mnożyć przez wiele macierzy. Wynikowy obiekt Matrix3D zawiera wynik wszystkich transformacji.

Mnożenie macierzy różni się od dodawania macierzy. Mnożenie macierzy nie jest przemienne. Innymi słowy, A razy B nie równa się B razy A. Metoda append() wykonuje mnożenie od lewej strony, co oznacza że obiekt Matrix3D lhs znajduje się po lewej stronie operatora mnożenia.

Po pierwszym wywołaniu metody append() wprowadza ona modyfikacje względem przestrzeni nadrzędnej. Kolejne wywołania operują na klatce referencyjnej dołączonego obiektu Matrix3D.

Metoda append() zastępuje macierz bieżącą macierzą dołączoną. Aby dołączyć dwie macierze bez zmiany macierzy bieżącej, należy skopiować macierz bieżącą za pomocą metody clone(), a następnie zastosować metodę append() do kopii.

Parametry

Powiązane elementy interfejsu API

Stosuje przyrostowy obrót do obiektu Matrix3D. Zastosowanie obiektu Matrix3D do obiektu wyświetlanego powoduje wykonanie obrotu po innych transformacjach opisanych przez obiekt Matrix3D.

Obrót obiektu wyświetlanego jest zdefiniowany przez oś, stopień przyrostowego obrotu wokół osi oraz opcjonalny punkt będący środkiem obrotu obiektu. Osią może być dowolny kierunek ogólny. Najbardziej popularne osie są następujące: X_AXIS (Vector3D(1,0,0)), Y_AXIS (Vector3D(0,1,0)) i Z_AXIS (Vector3D(0,0,1)). W terminologii lotniczej obrót wokół osi y jest nazywany odchyleniem. Obrót wokół osi x jest nazywany pochyleniem. Obrót wokół osi z jest nazywany przechyłem.

Kolejność przekształceń ma znaczenie. Obrót, po którym następuje translacja daje inny efekt niż translacja, po której następuje obrót.

Obrót nie jest bezwzględny. Następuje względem bieżącej pozycji i orientacji. Aby wprowadzić bezwzględną zmianę w macierzy transformacji, należy skorzystać z metody recompose(). Metoda appendRotation() różni się też pod względem działania od właściwości obrotu obiektu wyświetlanego, np. właściwości rotationX. Właściwość obrotu jest zawsze uwzględniana przed translacjami, podczas gdy metoda appendRotation() jest wykonywana względem aktualnego stanu macierzy. Aby uzyskać efekt podobny do uzyskiwanego za pomocą macierzy obrotu obiektu wokół osi, należy użyć metody prependRotation(), która wykonuje obrót przed innymi transformacjami w macierzy.

Zastosowanie metody appendRotation() do obiektu Matrix3D obiektu wyświetlanego powoduje unieważnienie wartości właściwości obrotu obiektu zapisanych w pamięci podręcznej.

Jednym ze sposobów obrócenia obiektu wyświetlanego wokół konkretnego punktu względem jego położenia jest translacja obiektu do określonego punktu, obrócenie obiektu za pomocą metody appendRotation() i translacja obiektu z powrotem do pierwotnego położenia. W poniższym przykładzie trójwymiarowy obiekt wyświetlany myObject obraca się w osi Y wokół współrzędnych (10,10,0).

    
    myObject.z = 1; 
    myObject.transform.matrix3D.appendTranslation(10,10,0);
    myObject.transform.matrix3D.appendRotation(1, Vector3D.Y_AXIS);
    myObject.transform.matrix3D.appendTranslation(-10,-10,0);
     
    

Parametry

Powiązane elementy interfejsu API

Stosuje do obiektu Matrix3D przyrostowe przeskalowanie wzdłuż osi x, y i z. Zastosowanie obiektu Matrix3D do obiektu wyświetlanego powoduje wykonanie skalowania po innych transformacjach opisanych przez obiekt Matrix3D. Domyślny współczynnik skali to (1.0, 1.0, 1.0).

Skala jest zdefiniowana jako zestaw trzech przyrostowych zmian wzdłuż trzech osi (x,y,z). Każdą oś można pomnożyć przez inną liczbę. Zastosowanie zmiany skali do obiektu wyświetlanego powoduje jego powiększenie lub zmniejszenie. Na przykład ustawienie wartości osi x, y i z na dwa powoduje dwukrotne powiększenie obiektu, natomiast ustawienie wartości osi na 0.5 powoduje zmniejszenie obiektu o połowę. Aby mieć pewność, że przeskalowanie będzie miało wpływ tylko na jedną oś, należy ustawić pozostałe parametry na jeden. Wartość jeden oznacza brak skalowania wzdłuż danej osi.

Metodę appendScale() można stosować do zmiany rozmiaru oraz do realizacji zniekształceń, takich jak skrócenie lub wydłużenie obiektu wyświetlanego, a także do powiększania (zoom) i zmniejszania konkretnego obszaru. Transformacje skali są wykonywane automatycznie podczas obrotów i translacji obiektu wyświetlanego.

Kolejność transformacji jest istotna. Zmiana rozmiaru, po której następuje translacja daje inny efekt niż translacja, po której następuje zmiana rozmiaru.

Parametry

Powiązane elementy interfejsu API

Stosuje do obiektu Matrix3D przyrostową translację, tj. zmianę położenia wzdłuż osi x, y i z. Zastosowanie obiektu Matrix3D do obiektu wyświetlanego powoduje wykonanie translacji po innych transformacjach opisanych przez obiekt Matrix3D.

Translacja jest zdefiniowana jako zestaw trzech przyrostowych zmian wzdłuż trzech osi (x,y,z). Zastosowanie transformacji do wyświetlanego obiektu powoduje przemieszczenie go z bieżącego położenia wzdłuż osi x, y i z o odległości określone przez parametry. Aby mieć pewność, że translacja będzie miała wpływ tylko na jedną współrzędną (oś), należy ustawić pozostałe parametry na zero. Parametr zerowy oznacza, że nie nastąpi zmiana położenia wzdłuż danej osi.

Translacje są względne. Nowe położenie jest ustalane względem bieżącego położenia i orientacji macierzy. Aby wprowadzić bezwzględną zmianę w macierzy przekształcenia, należy skorzystać z metody recompose(). Znaczenie ma także kolejność transformacji. Translacja, po której następuje obrót, da inny efekt niż obrót, po którym następuje translacja.

Parametry

Powiązane elementy interfejsu API

Zwraca nowy obiekt Matrix3D będący dokładną kopią bieżącego obiektu Matrix3D.

Kopiuje obiekt Vector3D do określonej kolumny wywołującego obiektu Matrix3D.

Parametry

Kopiuje określoną kolumnę wywołującego obiektu Matrix3D do obiektu Vector3D.

Parametry

Kopiuje wszystkie dane macierzy ze źródłowego obiektu Matrix3D do wywołującego obiektu Matrix3D.

Parametry

Kopiuje wszystkie dane wektora ze źródłowego obiektu wektora do wywołującego obiektu Matrix3D. Opcjonalny parametr index umożliwia wybranie dowolnej pozycji początkowej w wektorze.

Parametry

Kopiuje wszystkie dane macierzy z wywołującego obiektu Matrix3D do podanego wektora. Opcjonalny parametr index umożliwia wybranie dowolnej docelowej pozycji początkowej w wektorze.

Parametry

Kopiuje obiekt Vector3D do określonego wiersza wywołującego obiektu Matrix3D.

Parametry

Kopiuje określony wiersz wywołującego obiektu Matrix3D do obiektu Vector3D.

Parametry

Parametry

Zwraca ustawienia translacji, obrotu i skali macierzy transformacji jako obiekt Vector złożony z trzech obiektów Vector3D. Pierwszy obiekt Vector3D zawiera elementy translacji. Drugi obiekt Vector3D zawiera elementy obrotu. Trzeci obiekt Vector3D zawiera elementy skali.

Niektóre metody klasy Matrix3D, takie jak interpolateTo(), automatycznie dokonują dekompozycji i ponownej kompozycji macierzy w celu dokonania odpowiedniej transformacji.

Aby zmodyfikować transformację macierzy z uwzględnieniem bezwzględnej nadrzędnej klatki referencyjnej, należy pobrać ustawienia za pomocą metody decompose() i wprowadzić odpowiednie zmiany. Zmodyfikowaną transformację można ustawić w obiekcie Matrix3D za pomocą metody recompose().

Parametr metody decompose() określa styl orientacji, jaki ma być używany dla transformacji. Orientacja domyślna to eulerAngles; w tym przypadku orientacja jest zdefiniowana za pomocą trzech odrębnych kątów obrotu dla poszczególnych osi. Obroty są wykonywane jeden po drugim i nie wpływają wzajemnie na swoje osie. Właściwości obrotu osi obiektu wyświetlanego powodują transformacją ze stylem orientacji eulerAngles. Pozostałe opcje stylu orientacji to axisAngle oraz quaternion. Orientacja według osi i kąta jest zdefiniowana przez kombinację osi i kąta. Oś, wokół której obracany jest obiekt, to wektor jednostkowy reprezentujący kierunek. Kąt określa wielkość obrotu wokół wektora. Kierunek decyduje także o tym, w którą stronę jest zwrócony obiekt wyświetlany, a kąt określa, która strona obiektu jest zwrócona do góry. Orientacja axisAngle jest używana w metodach appendRotation() i prependRotation(). W orientacji quaternion stosowane są liczby zespolone i czwarty element wektora. Orientację wyznaczają trzy osie obrotu (x,y,z) oraz kąt obrotu (w). Orientacja kwaternionowa jest używana w metodzie interpolate().

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.geom.*;
    import flash.events.Event;
    
    public class Matrix3DdecomposeExample extends MovieClip {
        private var ellipse:Shape = new Shape();

        public function Matrix3DdecomposeExample():void {
            
            ellipse.x = (this.stage.stageWidth / 2);
            ellipse.y = (this.stage.stageHeight - 40);
            ellipse.z = 1;
            ellipse.graphics.beginFill(0xFF0000);
            ellipse.graphics.lineStyle(2);
            ellipse.graphics.drawEllipse(0, 0, 50, 40);
            ellipse.graphics.endFill();
            addChild(ellipse);

            ellipse.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }

        private function enterFrameHandler(e:Event):void {  

            var v3:Vector.<Vector3D> = new Vector.<Vector3D>(3);
            v3 = ellipse.transform.matrix3D.decompose();
            v3[0].incrementBy(new Vector3D(0,0,1));
            v3[2].incrementBy(new Vector3D(0.01,0,0));
            ellipse.transform.matrix3D.recompose(v3);
        }
    }
}

Stosuje macierz transformacji, z wyjątkiem elementów translacji, w celu dokonania transformacji obiektu Vector 3D ze współrzędnych jednej przestrzeni na współrzędne innej przestrzeni. Zwrócony obiekt Vector3D zawiera nowe współrzędne po zastosowaniu obrotu i skalowania. W przypadku zastosowania przez metodę deltaTransformVector() macierzy zawierającej tylko translację, zwrócony obiekt Vector3D będzie identyczny z oryginalnym obiektem Vector3D.

Metody deltaTransformVector() można używać w celu uwzględnienia przez obiekt w jednej przestrzeni współrzędnych obrotów drugiego obiektu wyświetlanego. Obrót obiektu nie jest kopiowany; nastąpi jedynie zmiana położenia obiektu uwzględniająca zmianę obrotu. Na przykład, aby użyć wywołania API display.Graphics do narysowania obracającego się trójwymiarowego obiektu wyświetlanego, należy odwzorować obracane współrzędne obiektu na punkt dwuwymiarowy. Najpierw należy pobrać współrzędne trójwymiarowego obiektu po każdym obrocie, korzystając z metody deltaTransformVector(). Następnie należy zastosować metodę local3DToGlobal() obiektu wyświetlanego w celu przetłumaczenia współrzędnych trójwymiarowych na punkty dwuwymiarowe. Następnie można użyć punktów dwuwymiarowych do narysowania obracającego się obiektu trójwymiarowego.

Uwaga: Ta metoda automatycznie ustawia składnik w przekazywanego obiektu Vector3D na 0.0.

Parametry

Powiązane elementy interfejsu API

Przekształca bieżącą macierz w macierz jednostkową. Wszystkie elementy macierzy jednostkowej na przekątnej głównej mają wartości jeden, a pozostałe elementy tej macierzy mają wartość zero. W rezultacie uzyskuje się macierz, której właściwość rawData ma wartość 1,0,0,0,0,1,0,0,0,0,1,0,0,0,0,1, ustawienie obrotu ma wartość Vector3D(0,0,0), ustawienie pozycji lub translacji ma wartość Vector3D(0,0,0), a skala ma wartość Vector3D(1,1,1). Oto reprezentacja macierzy jednostkowej.

Obiekt poddany transformacji poprzez zastosowanie macierzy jednostkowej nie ulega zmianie. Innymi słowy, pomnożenie macierzy przez macierz jednostkową daje w wyniku macierz identyczną z oryginalną.

Interpoluje przekształcenie translacji, obrotu i skalowania jednej macierzy w kierunku tego przekształcenia macierzy docelowej.

Metoda interpolate() pozwala uniknąć pewnych niepożądanych skutków użycia właściwości obrotu obiektu wokół osi. Metoda interpolate() unieważnia zapisaną w pamięci podręcznej właściwość obrotu obiektu wyświetlanego i przekształca elementy orientacji macierzy obiektu wyświetlanego do orientacji typu quaternion, a dopiero potem dokonuje interpolacji. Ta metoda gwarantuje najkrótszą, najbardziej efektywną ścieżkę obrotu. Generuje ponadto płynny obrót, przy którym obiekt nie traci stopni swobody. Sytuacja taka może wystąpić w przypadku orientacji eulerAngles, gdy obliczenia są realizowane dla każdej osi z osobna. W trakcie obrotu wokół dwóch lub większej liczby osi może dojść do równoległego ich ustawienia, co prowadzi do nieoczekiwanych wyników. Obrót z orientacją typu quaternion jest wolny od tego efektu.

Kolejne wywołania metody interpolate() umożliwiają uzyskanie efektu szybkiego rozpoczęcia ruchu obiektu, a następnie powolnego zbliżania się do innego obiektu wyświetlanego. Na przykład jeśli ustawimy parametr thisMat na zwrócony obiekt Matrix3D, parametr toMat na obiekt Matrix3D skojarzony z docelowym obiektem wyświetlanym, a parametr percent na 0.1, to obiekt wyświetlany zbliży się o dziesięć procent do obiektu docelowego. W kolejnych wywołaniach lub w kolejnych klatkach obiekt będzie zbliżał się do celu o 10% pozostałej odległości, aż do osiągnięcia celu.

Parametry

Powiązane elementy interfejsu API

Interpoluje tę macierz w kierunku przekształceń translacji, obrotu i skalowania macierzy docelowej.

Metoda interpolateTo() pozwala uniknąć niepożądanych skutków użycia właściwości obrotu obiektu wyświetlanego wokół osi. Metoda interpolateTo() unieważnia zapisaną w pamięci podręcznej właściwość obrotu obiektu wyświetlanego i przekształca elementy orientacji macierzy obiektu wyświetlanego do orientacji typu quaternion, a dopiero potem dokonuje interpolacji. Ta metoda gwarantuje najkrótszą, najbardziej efektywną ścieżkę obrotu. Generuje ponadto płynny obrót, przy którym obiekt nie traci stopni swobody. Sytuacja taka może wystąpić w przypadku orientacji eulerAngles, gdy obliczenia są realizowane dla każdej osi z osobna. W trakcie obrotu wokół dwóch lub większej liczby osi może dojść do równoległego ich ustawienia, co prowadzi do nieoczekiwanych wyników. Obrót z orientacją typu quaternion jest wolny od tego efektu.

Uwaga: W przypadku interpolacji wartość skali macierzy jest zerowana, a macierz jest normalizowana.

Kolejne wywołania metody interpolateTo() umożliwiają uzyskanie efektu szybkiego rozpoczęcia ruchu obiektu, a następnie powolnego zbliżania się do innego obiektu wyświetlanego. Na przykład ustawienie parametru percent na 0.1 spowoduje zbliżenie obiektu wyświetlanego o dziesięć procent do obiektu docelowego określonego przez parametr toMat. W kolejnych wywołaniach lub w kolejnych klatkach obiekt będzie zbliżał się do celu o 10% pozostałej odległości, aż do osiągnięcia celu.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.display.Graphics;
    import flash.geom.*;
    import flash.events.Event;

    public class InterpolateToExample extends MovieClip {
        private var ellipse1:Shape = new Shape();
        private var ellipse2:Shape = new Shape();

        public function InterpolateToExample():void {

            ellipse1 = myEllipses(250, 100, 500, 0xFF0000);
            addChild(ellipse1);
            
            ellipse2 = myEllipses(-30, 120, 1, 0x00FF00);
            addChild(ellipse2);

            addEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }

        private function myEllipses(x:Number, y:Number, z:Number, c:Number):Shape {
            var s:Shape = new Shape();                            
            s.x = x;
            s.y = y;
            s.z = z;
            s.graphics.beginFill(c);
            s.graphics.lineStyle(2);
            s.graphics.drawEllipse(100, 50, 100, 80);
            s.graphics.endFill();
            return s;
        }

        private function enterFrameHandler(e:Event) {
            ellipse1.rotationY += 1;

            ellipse2.transform.matrix3D.interpolateTo(ellipse1.transform.matrix3D, 0.1);
        }
    }
}

Odwraca bieżącą macierz Odwrócona macierz ma ten sam rozmiar co oryginalna, ale realizuje transformację przeciwną do oryginalnej. Na przykład jeśli oryginalna macierz obracała obiekt wokół osi x w jednym kierunku, odwrócona macierz będzie obracać obiekt wokół tej osi w kierunku przeciwnym. Zastosowanie macierzy odwróconej do obiektu cofa transformację wykonaną przez oryginalną macierz. Przemnożenie macierzy przez jej macierz odwróconą daje w wyniku macierz jednostkową.

Może być używana do dzielenia macierzy. Sposób na podzielenie macierzy A przez macierz B polega na pomnożeniu macierzy A przez wynik odwrócenia macierzy B. Odwrócona macierz może być także wykorzystana w przestrzeni kamery. Gdy kamera porusza się w przestrzeni globalnej, obiekt w przestrzeni globalnej musi poruszać się w kierunku przeciwnym, aby widok globalny został przetransformowany na przestrzeń kamery lub przestrzeń widoku. Na przykład gdy kamera przybliża się, obiekty będą się powiększać. Innymi słowy, jeśli kamera przemieszcza się w dół globalnej osi z, obiekt przesuwa się w górę wzdłuż globalnej osi z.

Metoda invert() zastępuje bieżącą macierz macierzą odwróconą. Aby odwrócić macierz bez zmiany macierzy źródłowej, należy najpierw skopiować macierz źródłową za pomocą metody clone(), a następnie zastosować metodę invert() do kopii.

Obiekt Matrix3D musi być odwracalny.

Powiązane elementy interfejsu API

Obraca obiekt wyświetlany w taki sposób, aby był zwrócony do określonej pozycji. Ta metoda umożliwia miejscową modyfikację orientacji. Wektor kierunku „do przodu” obiektu wyświetlanego (tj. obiekt Vector3D at) wskazuje na określoną pozycję globalną. Kierunek „do góry” obiektu wyświetlanego określany jest za pomocą obiektu Vector3D up.

Metoda pointAt() unieważnia wartość właściwości obrotu obiektu wyświetlanego zapisaną w pamięci podręcznej. Metoda dokonuje dekompozycji macierzy obiektu wyświetlanego i modyfikuje elementy obrotu w celu obrócenia obiektu do określonej pozycji. Następnie dokonuje ponownej kompozycji (aktualizacji) macierzy obiektu wyświetlanego, co powoduje zrealizowanie transformacji. Jeśli obiekt jest zwrócony w stronę ruchomego celu, np. pozycji poruszającego się obiektu, to każde kolejne wywołanie metody spowoduje obrócenie obiektu w stronę aktualnego położenia ruchomego celu.

Uwaga: Jeśli metoda Matrix3D.pointAt() zostanie użyta bez ustawienia opcjonalnych parametrów, obiekt docelowy nie będzie domyślnie zwrócony do określonej pozycji globalnej. Należy ustawić wartość półosi -y (0,-1,0) dla parametru at oraz półoś -z (0,0,-1) dla parametru up.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.display.Graphics;
    import flash.geom.*;
    import flash.events.Event;

    public class PointAtExample extends MovieClip {
        private var ellipse:Shape = new Shape();
        private var triangle:Shape = new Shape();

        public function PointAtExample():void {
            ellipse.graphics.beginFill(0xFF0000);
            ellipse.graphics.lineStyle(2);
            ellipse.graphics.drawEllipse(30, 40, 50, 40);
            ellipse.graphics.endFill();
            ellipse.x = 100;
            ellipse.y = 150;
            ellipse.z = 1;

            triangle.graphics.beginFill(0x0000FF);
            triangle.graphics.moveTo(0, 0);
            triangle.graphics.lineTo(40, 40);
            triangle.graphics.lineTo(80, 0);
            triangle.graphics.lineTo(0, 0);
            triangle.graphics.endFill();
            triangle.x = 200;
            triangle.y = 50;
            triangle.z = 1;

            addChild(ellipse);
            addChild(triangle);

            ellipse.addEventListener(Event.ENTER_FRAME, ellipseEnterFrameHandler);
            triangle.addEventListener(Event.ENTER_FRAME, triangleEnterFrameHandler);
        }

        private function ellipseEnterFrameHandler(e:Event) {
            if(e.target.y > 0) {
                e.target.y -= 1;
                e.target.x -= 1;
            }
        }
        
        private function triangleEnterFrameHandler(e:Event) {
            e.target.transform.matrix3D.pointAt(ellipse.transform.matrix3D.position,
                                                Vector3D.X_AXIS, Vector3D.Y_AXIS);
        }
    }
}

Dołącza macierz na początku transformacji, mnożąc bieżący obiekt Matrix3D przez inny obiekt Matrix3D. Wynikiem jest kombinacja transformacji opisanych przez obie macierze.

Mnożenie macierzy różni się od dodawania macierzy. Mnożenie macierzy nie jest przemienne. Innymi słowy, A razy B nie równa się B razy A. Metoda prepend() wykonuje mnożenie od prawej strony, co oznacza że obiekt Matrix3D rhs znajduje się po prawej stronie operatora mnożenia.

Metoda prepend() wprowadza modyfikacje względem przestrzeni obiektu. Innymi słowy, są one zawsze realizowane względem początkowej klatki referencyjnej obiektu.

Metoda prepend() zastępuje bieżącą macierz macierzą dołączoną. Aby dołączyć w ten sposób dwie macierze bez zmiany bieżącej macierzy, należy najpierw skopiować bieżącą macierz za pomocą metody clone(), a następnie zastosować metodę prepend() do kopii.

Parametry

Powiązane elementy interfejsu API

Poprzedzająco stosuje przyrostowy obrót do obiektu Matrix3D. Zastosowanie obiektu Matrix3D do obiektu wyświetlanego powoduje wykonanie obrotu przed innymi transformacjami opisanymi przez obiekt Matrix3D.

Obrót obiektu wyświetlanego jest zdefiniowany przez oś, stopień przyrostowego obrotu wokół osi oraz opcjonalny punkt będący środkiem obrotu obiektu. Osią może być dowolny kierunek ogólny. Najbardziej popularne osie są następujące: X_AXIS (Vector3D(1,0,0)), Y_AXIS (Vector3D(0,1,0)) i Z_AXIS (Vector3D(0,0,1)). W terminologii lotniczej obrót wokół osi y jest nazywany odchyleniem. Obrót wokół osi x jest nazywany pochyleniem. Obrót wokół osi z jest nazywany przechyłem.

Kolejność przekształceń ma znaczenie. Obrót, po którym następuje translacja daje inny efekt niż translacja, po której następuje obrót.

Obrót nie jest bezwzględny. Efekt jest realizowany względem obiektu, tj. punktu odniesienia pierwotnej pozycji i orientacji. Aby wprowadzić bezwzględną zmianę w macierzy transformacji, należy skorzystać z metody recompose().

Zastosowanie metody prependRotation() do obiektu Matrix3D obiektu wyświetlanego powoduje unieważnienie wartości właściwości obrotu obiektu zapisanych w pamięci podręcznej.

Jednym ze sposobów obrócenia obiektu wyświetlanego wokół konkretnego punktu względem jego położenia jest translacja obiektu do określonego punktu, obrócenie obiektu za pomocą metody prependRotation() i translacja obiektu z powrotem do pierwotnego położenia. W poniższym przykładzie trójwymiarowy obiekt ekranowy myObject obraca się w osi Y wokół współrzędnych (10,10,0).

    
    myObject.z = 1; 
    myObject.transform.matrix3D.prependTranslation(10,10,0);
    myObject.transform.matrix3D.prependRotation(1, Vector3D.Y_AXIS);
    myObject.transform.matrix3D.prependTranslation(-10,-10,0);
     
    

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.geom.*;
    import flash.events.MouseEvent;
    
    public class Matrix3DprependRotationExample extends MovieClip {
        private var ellipse:Shape = new Shape();

        public function Matrix3DprependRotationExample():void {

            ellipse.graphics.beginFill(0xFF0000);
            ellipse.graphics.lineStyle(2);
            ellipse.graphics.drawEllipse(-50, -40, 100, 80);
            ellipse.graphics.endFill();

            ellipse.x = (this.stage.stageWidth / 2);
            ellipse.y = (this.stage.stageHeight / 2);
            ellipse.z = 1;
            
            addChild(ellipse);

            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseMoveHandler(e:MouseEvent):void {
            var y:int;
            var x:int;
            
            if(e.localX > ellipse.x) {
                y = (Math.round(e.localX) / 100);   
            } else {
                y = -(Math.round(e.localX) / 10);   
            }
            
            if(e.localY > ellipse.y) {
                x = (Math.round(e.localY) / 100);
            } else {
                x = -(Math.round(e.localY) / 100);
            }
            
            ellipse.transform.matrix3D.prependRotation(y, Vector3D.Y_AXIS);
            ellipse.transform.matrix3D.prependRotation(x, Vector3D.X_AXIS);
        }
        
    }
}

Poprzedzająco stosuje do obiektu Matrix3D przyrostowe przeskalowanie wzdłuż osi x, y i z. Zastosowanie obiektu Matrix3D do obiektu wyświetlanego powoduje wykonanie skalowania przed innymi transformacjami opisanymi przez obiekt Matrix3D. Zmiany są realizowane względem obiektu, tj. klatki referencyjnej oryginalnej pozycji i orientacji. Domyślny współczynnik skali to (1.0, 1.0, 1.0).

Skala jest zdefiniowana jako zestaw trzech przyrostowych zmian wzdłuż trzech osi (x,y,z). Każdą oś można pomnożyć przez inną liczbę. Zastosowanie zmiany skali do obiektu wyświetlanego powoduje jego powiększenie lub zmniejszenie. Na przykład ustawienie wartości osi x, y i z na dwa powoduje dwukrotne powiększenie obiektu, natomiast ustawienie wartości osi na 0.5 powoduje zmniejszenie obiektu o połowę. Aby mieć pewność, że przeskalowanie będzie miało wpływ tylko na jedną oś, należy ustawić pozostałe parametry na jeden. Wartość jeden oznacza brak skalowania wzdłuż danej osi.

Metody prependScale() można używać zarówno do skalowania, jak i do zniekształcania obiektu wyświetlanego, np. rozciągania go lub skracania. Może również służyć do powiększania (zoom) i pomniejszania określonego obszaru. Transformacje skali są wykonywane automatycznie podczas obrotów i translacji obiektu wyświetlanego.

Kolejność transformacji jest istotna. Zmiana rozmiaru, po której następuje translacja daje inny efekt niż translacja, po której następuje zmiana rozmiaru.

Parametry

Powiązane elementy interfejsu API

Poprzedzająco stosuje do obiektu Matrix3D przyrostową translację, tj. zmianę położenia wzdłuż osi x, y i z. Zastosowanie obiektu Matrix3D do obiektu wyświetlanego powoduje wykonanie translacji przed innymi transformacjami opisanymi przez obiekt Matrix3D.

Translacja określa odległość, o jaką obiekt wyświetlany przemieści się z bieżącego położenia wzdłuż osi x, y i z. Metoda prependTranslation() realizuje translację jako zestaw trzech przyrostowych zmian wzdłuż trzech osi (x,y,z). Aby translacja wpływała tylko na jedną współrzędną (oś), należy ustawić pozostałe parametry na zero. Parametr zerowy oznacza, że nie nastąpi zmiana położenia wzdłuż danej osi.

Translacje są względne. Efekt jest realizowany względem obiektu, tj. klatki referencyjnej oryginalnej pozycji i orientacji. Aby wprowadzić bezwzględną zmianę w macierzy przekształcenia, należy skorzystać z metody recompose(). Znaczenie ma także kolejność transformacji. Translacja, po której następuje obrót, da inny efekt niż obrót, po którym następuje translacja. Po zastosowaniu metody prependTranslation() wyświetlany obiekt będzie dalej przemieszczał się w kierunku, w którym jest zwrócony, niezależnie od pozostałych transformacji. Na przykład jeśli obiekt wyświetlany był zwrócony ku dodatniej półosi x, będzie dalej przemieszczał się w kierunku określonym przez metodę prependTranslation(), niezależnie od tego, jak zostanie obrócony. Aby translacja została przeprowadzona po innych transformacjach, należy użyć metody appendTranslation().

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.geom.*;
    import flash.events.MouseEvent;

    public class Matrix3DprependTranslationExample extends MovieClip {
        private var ellipse:Sprite = new Sprite();

        public function Matrix3DprependTranslationExample():void {
            ellipse.x = this.stage.stageWidth / 2;
            ellipse.y = this.stage.stageHeight - 100;
            ellipse.z = 1;
            ellipse.graphics.beginFill(0xFF0000);
            ellipse.graphics.lineStyle(2);
            ellipse.graphics.drawEllipse(0, 0, 60, 50);
            ellipse.graphics.endFill();
            addChild(ellipse);

            ellipse.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            ellipse.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        }

        private function mouseOverHandler(e:MouseEvent):void {
            if(ellipse.y > 0) { 
                ellipse.transform.matrix3D.prependTranslation(0, -10, 0);
            } 
        }
        
        private function mouseOutHandler(e:MouseEvent):void {
            if(ellipse.y > 0) { 
                ellipse.transform.matrix3D.prependTranslation(0, -10, 0);
            } else {
                ellipse.transform.matrix3D.prependTranslation(0, 
                                     (this.stage.stageHeight - 100), 0);
            }   
        }
    }
}

Ustawia wartości translacji, obrotu i skali w macierzy. W przeciwieństwie do zmian przyrostowych wprowadzanych przez właściwości obrotu obiektu wyświetlanego lub metody obrotu obiektu Matrix3D, zmiany wprowadzane przez metodę recompose() są zmianami bezwzględnymi. Metoda recompose() nadpisuje transformację macierzy.

Aby zmodyfikować transformację macierzy z uwzględnieniem bezwzględnej nadrzędnej klatki referencyjnej, należy pobrać ustawienia za pomocą metody decompose() i wprowadzić odpowiednie zmiany. Zmodyfikowaną transformację można ustawić w obiekcie Matrix3D za pomocą metody recompose().

Parametr metody recompose() określa styl orientacji użyty do transformacji. Orientacja domyślna to eulerAngles; w tym przypadku orientacja jest zdefiniowana za pomocą trzech odrębnych kątów obrotu dla poszczególnych osi. Obroty są wykonywane jeden po drugim i nie wpływają wzajemnie na swoje osie. Właściwości obrotu osi obiektu wyświetlanego powodują transformacją ze stylem orientacji eulerAngles. Pozostałe opcje stylu orientacji to axisAngle oraz quaternion. Orientacja axisAngle jest zdefiniowana przez kombinację osi i kąta. Oś, wokół której obracany jest obiekt, to wektor jednostkowy reprezentujący kierunek. Kąt określa wielkość obrotu wokół wektora. Kierunek decyduje także o tym, w którą stronę jest zwrócony obiekt wyświetlany, a kąt określa, która strona obiektu jest zwrócona do góry. Orientacja axisAngle jest używana w metodach appendRotation() i prependRotation(). W orientacji quaternion stosowane są liczby zespolone i czwarty element wektora. Orientacja jest reprezentowana przez trzy osie obrotu (x,y,z) oraz kąt obrotu (w). Orientacja kwaternionowa jest używana w metodzie interpolate().

Parametry

Powiązane elementy interfejsu API

Stosuje macierz transformacji w celu dokonania transformacji obiektu Vector3D ze współrzędnych jednej przestrzeni na współrzędne innej przestrzeni. Zwrócony obiekt Vector3D zawiera nowe współrzędne po transformacji. Wszystkie transformacje opisane w macierzy, w tym translacja, są stosowane do obiektu Vector3D.

Jeśli wynik działania metody transformVector() został zastosowany do pozycji obiektu wyświetlanego, tylko pozycja tego obiektu ulegnie zmianie. Elementy obrotu i skali obiektu wyświetlanego nie ulegają zmianie.

Uwaga: Ta metoda automatycznie ustawia składnik w przekazywanego obiektu Vector3D na 1.0.

Parametry

Powiązane elementy interfejsu API

Stosuje macierz transformacji w celu transformacji obiektu Vector zawierającego obiekty Number z jednego układu współrzędnych na inny. Metoda tranformVectors() odczytuje każdą trójkę obiektów Number w obiekcie Vector vin jako współrzędne trójwymiarowe (x,y,z) i umieszcza przetransformowane współrzędne trójwymiarowe w obiekcie Vector vout. Wszystkie transformacje macierzowe, w tym translacja, są stosowane do obiektu Vector vin. Metody transformVectors() można użyć do renderowania i transformowania obiektu trójwymiarowego w postaci siatki. Siatka jest to zbiór wektorów definiujących kształt obiektu.

Parametry

Powiązane elementy interfejsu API

Przekształca bieżący obiekt Matrix3D w macierz, w której wiersze są zamienione na kolumny, a kolumny na wiersze. Na przykład jeśli właściwość rawData bieżącego obiektu Matrix3D zawierała wektor 16 liczb 1,2,3,4,11,12,13,14,21,22,23,24,31,32,33,34, metoda transpose() odczyta każde cztery elementy jako jeden wiersz i przekształci wiersze w kolumny. Wynikiem będzie macierz, której właściwość rawData będzie zawierać liczby: 1,11,21,31,2,12,22,32,3,13,23,33,4,14,24,34.

Metoda transpose() zastępuje macierz bieżącą macierzą przetransponowaną. Aby przetransponować macierz bez zmiany macierzy bieżącej, należy najpierw skopiować macierz bieżącą za pomocą metody clone(), a następnie zastosować metodę transpose() do kopii.

Macierz ortogonalna to taka macierz kwadratowa, dla której wynik transpozycji jest równy wynikowi odwrócenia.