XMLDocument

Pakket	flash.xml
Klasse	public class XMLDocument
Overerving	XMLDocument XMLNode Object

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

De klasse XMLDocument vertegenwoordigt het oudere XML-object dat zich in ActionScript 2.0 bevindt. Het object is in ActionScript 3.0 naar XMLDocument hernoemd om naamconflicten met de nieuwe klasse XML in ActionScript 3.0 te voorkomen. In ActionScript 3.0 kunt u het best de nieuwe klasse XML en verwante klassen gebruiken die E4X (ECMAScript for XML) ondersteunen.

De klassen XMLDocument, XMLNode en XMLNodeType zijn aanwezig voor achterwaartse compatibiliteit. De functionaliteit voor het laden van XML-documenten vindt u in de klasse URLLoader.

Bekijk de voorbeelden

Verwante API-elementen

flash.net.URLLoader
XML, klasse

Openbare eigenschappen

Overerfde openbare eigenschappen verbergen

Overerfde openbare eigenschappen weergeven

	Eigenschap		Gedefinieerd door
		attributes : Object Object dat alle kenmerken bevat van de opgegeven instantie XMLNode.	XMLNode
		childNodes : Array [alleen-lezen] Een array van de opgegeven onderliggende items van het object XMLNode.	XMLNode
		constructor : Object Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie.	Object
		docTypeDecl : Object = null Hiermee wordt informatie over de declaratie DOCTYPE van het XML-document opgegeven.	XMLDocument
		firstChild : XMLNode Evalueert het opgegeven object XMLDocument en verwijst naar het eerste item in de lijst met onderliggende items van het bovenliggende knooppunt.	XMLNode
		idMap : Object Een object met de knooppunten van de XML met toegewezen id-kenmerk.	XMLDocument
		ignoreWhite : Boolean = false Wanneer deze eigenschap op true is ingesteld, worden tekstknooppunten die alleen witruimte bevatten tijdens het parseringsproces genegeerd.	XMLDocument
		lastChild : XMLNode Een XMLNode-waarde die verwijst naar het laatste item in de lijst met onderliggende items van dit knooppunt.	XMLNode
		localName : String [alleen-lezen] Het gedeelte met de lokale naam van het XML-knooppunt.	XMLNode
		namespaceURI : String [alleen-lezen] Wanneer het XML-knooppunt een voorvoegsel bevat, is namespaceURI de waarde van de declaratie xmlns voor dat voorvoegsel (de URI) die doorgaans de naamruimte-URI wordt genoemd.	XMLNode
		nextSibling : XMLNode Een XMLNode-waarde die verwijst naar het volgende item op hetzelfde niveau in de lijst met onderliggende items van het bovenliggende knooppunt.	XMLNode
		nodeName : String Tekenreeks die de knooppuntnaam van het object XMLNode vertegenwoordigt.	XMLNode
		nodeType : uint Constante waarde voor nodeType: XMLNodeType.ELEMENT_NODE voor een XML-element of XMLNodeType.TEXT_NODE voor een tekstknooppunt	XMLNode
		nodeValue : String De knooppuntwaarde van het object XMLDocument.	XMLNode
		parentNode : XMLNode Een XMLNode-waarde die verwijst naar het bovenliggende knooppunt van het opgegeven XML-object of die leeg retourneert wanneer het knooppunt geen bovenliggend item heeft	XMLNode
		prefix : String [alleen-lezen] Het gedeelte met het voorvoegsel van de naam van het XML-knooppunt.	XMLNode
		previousSibling : XMLNode Een XMLNode-waarde die verwijst naar het vorige item op hetzelfde niveau in de lijst met onderliggende items van het bovenliggende knooppunt.	XMLNode
		xmlDecl : Object = null Een tekenreeks die gegevens over de declaratie XML van een document opgeeft.	XMLDocument

Openbare methoden

Overerfde openbare methoden verbergen

Overerfde openbare methoden weergeven

	Methode		Gedefinieerd door
		XMLDocument(source:String = null) Hiermee wordt een nieuw object XMLDocument gemaakt.	XMLDocument
		appendChild(node:XMLNode):void Voegt het opgegeven knooppunt toe aan de lijst met onderliggende items van het object XML.	XMLNode
		cloneNode(deep:Boolean):XMLNode Vormt en retourneert een nieuw XML-knooppunt van hetzelfde type en met dezelfde naam, waarde en kenmerken als het opgegeven object XML.	XMLNode
		createElement(name:String):XMLNode Hiermee wordt een nieuw object XMLNode gemaakt met de naam die in de parameter is opgegeven.	XMLDocument
		createTextNode(text:String):XMLNode Maakt een nieuw XML-tekstknooppunt met de opgegeven tekst.	XMLDocument
		getNamespaceForPrefix(prefix:String):String Retourneert de naamruimte-URI die aan het opgegeven voorvoegsel voor het knooppunt is gekoppeld.	XMLNode
		getPrefixForNamespace(ns:String):String Retourneert het voorvoegsel dat aan de opgegeven naamruimte-URI voor het knooppunt is gekoppeld.	XMLNode
		hasChildNodes():Boolean Geeft aan of het opgegeven object XMLNode onderliggende knooppunten bevat.	XMLNode
		hasOwnProperty(name:String):Boolean Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd.	Object
		insertBefore(node:XMLNode, before:XMLNode):void Voegt een nieuw onderliggend knooppunt toe in de lijst met onderliggende items van het object XML voor het knooppunt beforeNode.	XMLNode
		isPrototypeOf(theClass:Object):Boolean Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven.	Object
		parseXML(source:String):void Hiermee wordt de XML-tekst geparseerd die is opgegeven in de parameter value en wordt het opgegeven object XMLDocument gevuld met de resulterende XML-structuur.	XMLDocument
		propertyIsEnumerable(name:String):Boolean Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd.	Object
		removeNode():void Verwijdert het opgegeven object XML uit het bovenliggende item.	XMLNode
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in.	Object
		toLocaleString():String Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies.	Object
		toString():String [overschrijven] Retourneert een tekenreeksrepresentatie van het XML-object.	XMLDocument
		valueOf():Object Retourneert de primitieve waarde van het opgegeven object.	Object

Eigenschapdetails

docTypeDecl

eigenschap

public var docTypeDecl:Object = null

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Hiermee wordt informatie over de declaratie DOCTYPE van het XML-document opgegeven. Nadat de XML-tekst in een object XMLDocument is geparseerd, wordt de eigenschap XMLDocument.docTypeDecl van het object XMLDocument ingesteld op de tekst van de declaratie DOCTYPE van het document (bijvoorbeeld, <!DOCTYPE greeting SYSTEM "hello.dtd">). Deze eigenschap wordt ingesteld via een tekenreeksrepresentatie van de declaratie DOCTYPE, niet met een object XMLNode.

De oudere ActionScript XML-parser is geen validerende parser. De declaratie DOCTYPE wordt door de parser gelezen en in de eigenschap XMLDocument.docTypeDecl opgeslagen, maar er wordt geen DTD-validatie uitgevoerd.

Wanneer tijdens een parseerbewerking geen declaratie DOCTYPE wordt gevonden, wordt de eigenschap XMLDocument.docTypeDecl op null ingesteld. De methode XML.toString() genereert de inhoud van XML.docTypeDecl direct na de declaratie XML die in XML.xmlDecl is opgeslagen en vóór eventuele andere tekst in het XML-object. Wanneer XMLDocument.docTypeDecl null is, wordt er geen declaratie DOCTYPE gegenereerd.

idMap

eigenschap

public var idMap:Object

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Een object met de knooppunten van de XML met een toegewezen kenmerk id. De namen van de eigenschappen van het object (met elk een knooppunt) komen overeen met de waarden van de kenmerken id.

Bekijk het volgende object XMLDocument:

     <employee id='41'>
         <name>
             John Doe
         </name>
         <address>
             601 Townsend St.
         </address>
     </employee>
     
     <employee id='42'>
         <name>
             Jane Q. Public
         </name>
     </employee>
     <department id="IT">
         Information Technology
     </department>

In dit voorbeeld is de eigenschap idMap voor dit object XMLDocument een object met drie eigenschappen. 41, 42 en IT. Elk van deze eigenschappen is een XMLNode die de overeenkomende waarde id bevat. De eigenschap IT van het object idMap is bijvoorbeeld dit knooppunt:

     <department id="IT">
         Information Technology
     </department>

U moet de methode parseXML() op het object XMLDocument gebruiken zodat een instantie van de eigenschap idMap wordt gemaakt.

Wanneer er meer dan één XMLNode met dezelfde waarde id is, is de overeenkomende eigenschap van het object idNode het laatste knooppunt dat is geparseerd. Bijvoorbeeld:

     var x1:XML = new XMLDocument("<a id='1'><b id='2' /><c id='1' /></a>");
     x2 = new XMLDocument();
     x2.parseXML(x1);
     trace(x2.idMap['1']);

Hiermee wordt het knooppunt <c> weergegeven:

     <c id='1' />

ignoreWhite

eigenschap

public var ignoreWhite:Boolean = false

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Wanneer deze eigenschap op true is ingesteld, worden tekstknooppunten die alleen witruimte bevatten, tijdens het parseringsproces genegeerd. Tekstknooppunten die beginnen of eindigen met witruimte, worden hierdoor niet beïnvloed. De standaardinstelling is false.

U kunt de eigenschap ignoreWhite voor afzonderlijke objecten XMLDocument instellen, zoals wordt getoond in de volgende code:

     my_xml.ignoreWhite = true;

xmlDecl

eigenschap

public var xmlDecl:Object = null

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Een tekenreeks die gegevens over de declaratie XML van een document opgeeft. Nadat het XML-document in een object XMLDocument is geparseerd, wordt deze eigenschap ingesteld op de tekst van de declaratie XML van het document. Deze eigenschap wordt ingesteld via een tekenreeksrepresentatie van de declaratie XML, niet met een object XMLNode. Wanneer tijdens een parseerbewerking geen declaratie XML wordt gevonden, wordt de eigenschap op null ingesteld. De methode XMLDocument.toString() genereert de inhoud van de eigenschap XML.xmlDecl voor andere tekst in het XML-object. Wanneer de eigenschap XML.xmlDecl dat null bevat, wordt geen declaratie XML gegenereerd.

Constructordetails

()

Constructor

public function XMLDocument(source:String = null)

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Hiermee wordt een nieuw object XMLDocument gemaakt. U moet de constructor gebruiken om een object XMLDocument te maken voordat u een van de methoden van de klasse XMLDocument aanroept.

Opmerking: gebruik de methoden createElement() en createTextNode() om elementen en tekstknooppunten aan een XML-documentstructuur toe te voegen.

Parameters

source:String (default = null) — De XML-tekst die wordt geparseerd om het nieuwe object XMLDocument te maken.

Verwante API-elementen

XMLDocument.createElement()
XMLDocument.createTextNode()

Methodedetails

createElement

()

methode

public function createElement(name:String):XMLNode

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Hiermee wordt een nieuw object XMLNode gemaakt met de naam die in de parameter is opgegeven. Het nieuwe knooppunt heeft aanvankelijk geen bovenliggende elementen, onderliggende elementen of elementen op hetzelfde niveau. De methode retourneert een verwijzing naar het nieuwe object XMLNode dat het element vertegenwoordigt. Deze methode en de methode XMLDocument.createTextNode() zijn de constructormethoden voor het maken van knooppunten voor een object XMLDocument.

Parameters

name:String — De tagnaam van het XMLDocument-element dat wordt gemaakt.

Geretourneerde waarde

XMLNode — Een object XMLNode.

Verwante API-elementen

XMLDocument.createTextNode()

createTextNode

()

methode

public function createTextNode(text:String):XMLNode

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Maakt een nieuw XML-tekstknooppunt met de opgegeven tekst. Het nieuwe knooppunt heeft aanvankelijk geen bovenliggend knooppunt en tekstknooppunten kunnen geen onderliggende knooppunten of knooppunten op hetzelfde niveau hebben. De methode retourneert een verwijzing naar het nieuwe object XMLDocument dat het element vertegenwoordigt. Deze methode en de methode XMLDocument.createElement() zijn de constructormethoden voor het maken van knooppunten voor een object XMLDocument.

Parameters

text:String — De tekst die wordt gebruikt om het nieuwe tekstknooppunt te maken.

Geretourneerde waarde

XMLNode — Een object XMLNode.

Verwante API-elementen

XMLDocument.createElement()

parseXML

()

methode

public function parseXML(source:String):void

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Hiermee wordt de XML-tekst geparseerd die is opgegeven in de parameter value en wordt het opgegeven object XMLDocument gevuld met de resulterende XML-structuur. Eventuele bestaande structuren in het object XMLDocument worden genegeerd.

Parameters

source:String — De XML-tekst die moet worden geparseerd en aan het opgegeven object XMLDocument moet worden doorgegeven.

toString

()

methode

override public function toString():String

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Retourneert een tekenreeksrepresentatie van het XML-object.

Geretourneerde waarde

String — De tekenreeksrepresentatie van het XML-object.

Voorbeelden Hoe dit voorbeeld te gebruiken

XMLDocumentExample.as

In het volgende voorbeeld worden de klassen XMLDocument en XMLNode gebruikt om een XML-document te parseren en op te maken. In plaats van het laden van een extern XML-bestand, wordt in het voorbeeld de klasse XML op hoofdniveau gebruikt om een XML-document te maken en vervolgens te parseren.

package {
    import flash.display.Sprite;
    import flash.xml.XMLDocument;
    import flash.xml.XMLNode;
    import flash.xml.XMLNodeType;

    public class XMLDocumentExample extends Sprite {
        public function XMLDocumentExample() {
            var result:XMLDocument = new XMLDocument();
            result.ignoreWhite = true;
            result.parseXML(getXMLString());

            var books:Array = parseBooks(result.firstChild);
            trace("books: \n" + books);
        }

        private function parseBooks(node:XMLNode):Array {
            var books:Array = new Array();

            var kids:Array = node.childNodes;
            for each(var item:XMLNode in kids) {
                parseBook(item, books);
            }

            return books;
        }

        private function parseBook(node:XMLNode, books:Array):void {
            var item:Book = new Book();
            item.setPublisher(node.attributes.publisher);
            item.setName(node.attributes.name);
            books.push(item);
        }

        private function getXMLString():String {
            var list:XML = <books>
                                <book publisher="Addison-Wesley" name="Design Patterns" />
                                <book publisher="Addison-Wesley" name="The Pragmatic Programmer" />
                                <book publisher="Addison-Wesley" name="Test Driven Development" />
                                <book publisher="Addison-Wesley" name="Refactoring to Patterns" />
                                <book publisher="O'Reilly Media" name="The Cathedral & the Bazaar" />
                                <book publisher="O'Reilly Media" name="Unit Test Frameworks" />
                            </books>;
            return list.toXMLString();
        }
    }

}
class Book {
    private var publisher:String;
    private var name:String;

    public function setPublisher(publisher:String):void {
        this.publisher = publisher;
    }

    public function setName(name:String):void {
        this.name = name;
    }

    public function toString():String {
        return "[Book name: " + name + " publisher: " + publisher + "]\n";
    }
}

Juridische kennisgeving | Online privacybeleid

XMLDocument - AS3

Pakkettenx

Taalelementen

Bijlagen

Pakket flash.xml

docTypeDecl

idMap

ignoreWhite

xmlDecl

XMLDocument

createElement

createTextNode

parseXML

toString