XMLSignatureValidator  - AS3

De geldigheidsstatus van de cryptografische handtekening die berekend is over het handtekeningelement SignedInfo.

De status is:

• geldig — Als de handtekening cryptografisch geldig is.
• ongeldig — Als de samenvatting na ondertekening is gewijzigd.
• onbekend — Als de methode verify() niet is aangeroepen.

Opmerking: als de digestStatus ongeldig is, worden identityStatus en referencesStatus niet gecontroleerd en gerapporteerd als onbekend.

De geldigheidsstatus van het ondertekenende certificaat.

De status kan zijn:

• geldig — Het certificaat is niet verlopen, is door de intrekkingscontrole gekomen en is gekoppeld aan een vertrouwd hoofdcertificaat.
• onbekend — Het certificaat is niet verlopen en is door de intrekkingscontrole gekomen maar is niet gekoppeld aan een vertrouwd hoofdcertificaat. De status onbekend wordt ook gemeld als de status niet is gecontroleerd, ofwel omdat de methode verify() niet is aangeroepen ofwel omdat de cryptografische handtekening van het element SignedInfo (digestStatus) ongeldig is.
• ongeldig — Het certificaat is verlopen of is niet door de intrekkingscontrole gekomen.

De certificaten die zijn toegevoegd met de methode addCertificate() en de eigenschappen van revocationCheckSetting en useSystemTrustStore kunnen worden gewijzigd, ongeacht of een certificaat geldig is bevonden.

Opmerking: als de identityStatus ongeldig is, wordt referencesStatus niet gecontroleerd en gerapporteerd als onbekend. Bovendien worden verwijzingen niet gecontroleerd wanneer de identityStatus onbekend is, tenzij referencesValidationSetting gelijk is aan validOrUnknownIdentity.

Verwante API-elementen

 import flash.security.XMLSignatureValidator;
 
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var identityResult:String = verifier.identityStatus;

De eigenschap isSupported is ingesteld op true als de klasse XMLSignatureValidator op het huidige platform wordt ondersteund. Als dit niet het geval is, is de eigenschap ingesteld op false.

De geldigheidsstatus van de gegevens in de verwijzingen in het handtekeningelement SignedInfo.

De status kan zijn:

• geldig — Als alle verwijzingen geldig zijn.
• ongeldig — Als een verwijzing ongeldig is.
• unknown — Als niet is geverifieerd. Verwijzingen kunnen in de volgende omstandigheden ongeverifieerd blijven:
  • De methode verify() is niet aangeroepen.
  • De cryptografische handtekening van het element SignedInfo (digestStatus) is ongeldig.
  • Het handtekeningcertificaat (identityStatus) is ongeldig.
  • referencesValidationSetting is validIdentity (dit is de standaardinstelling) en de identityStatus van het handtekeningcertificaat is onbekend.
  • De referencesValidationSetting is never.

Belangrijk: externe bronnen worden niet gevalideerd, tenzij er rechtstreeks naar wordt verwezen in een element SignedInfo in het handtekeningdocument. Externe bronnen waarnaar wordt verwezen door een secundaire verwijzing, worden niet gevalideerd. Als een XML-handtekening bijvoorbeeld een manifest-element ondertekent, wordt alleen de integriteit van het manifest-element zelf geverifieerd. De bestanden die in het manifest zijn vermeld, worden niet gecontroleerd.

Verwante API-elementen

 import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var dataResult:String = verifier.referencesStatus;

Hiermee wordt opgegeven onder welke voorwaarden verwijzingen worden gecontroleerd.

Gebruik constanten die zijn gedefinieerd in de klasse ReferencesValidationSetting om deze eigenschap in te stellen. Voorbeelden van instellingen zijn:

• ReferencesValidationSetting.VALID_IDENTITY — Verwijzingen alleen controleren als het handtekeningcertificaat geldig is en is gekoppeld aan een vertrouwd hoofdcertificaat. Dit is de standaardinstelling.
• ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY — Verwijzingen controleren als het handtekeningcertificaat geldig is, ook als het niet is gekoppeld aan een vertrouwd hoofdcertificaat.
• ReferencesValidationSetting.NEVER — Verwijzingen nooit controleren.

Gebruik de standaardinstelling validIdentity met handtekeningen die zijn ondertekend met een commercieel certificaat of wanneer u uw eigen certificaat gebruikt als vertrouwensanker met de methode addCertificate(). Hiermee voorkomt u dat de geldigheid van verwijzingen wordt gecontroleerd wanneer het ondertekende document toch wordt geweigerd.

Gebruik de instelling validOrUnknownIdentity met handtekeningen die zijn ondertekend met zelfondertekende certificaten. Met deze instelling kunt u controleren of de ondertekende gegevens niet zijn gewijzigd, maar krijgt u geen garantie over de identiteit van de ondertekenaar.

Gebruik de instelling never om te voorkomen dat verwijzingen worden gevalideerd wanneer dat niet belangrijk is in de context van uw toepassing.

Verwante API-elementen

 import flash.security.ReferencesValidationSetting;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.referencesValidationSetting = ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY;

Geeft aan hoe intrekking van certificaten wordt gecontroleerd.

Gebruik constanten die zijn gedefinieerd in de klasse RevocationSettings om deze eigenschap in te stellen. Voorbeelden van instellingen zijn:

• RevocationCheckSettings.NEVER — De intrekking van certificaten niet controleren.
• RevocationCheckSettings.BEST_EFFORT — De intrekking van certificaten controleren, als er informatie over intrekking beschikbaar is en de status van de intrekking kan worden verkregen. Als er geen positieve status voor de intrekking kan worden vastgesteld, wordt het certificaat niet geweigerd.
• RevocationCheckSettings.REQUIRED_IF_AVAILABLE — Als het certificaat intrekkingsinformatie bevat, moet de status van de intrekking positief worden vastgesteld om het certificaat te valideren.
• RevocationCheckSettings.ALWAYS_REQUIRED — De intrekking van certificaten altijd controleren. Certificaten zonder informatie over intrekking worden geweigerd.

Verwante API-elementen

Het veld Common Name van het ondertekenende certificaat.

 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var commonName:String = verifier.signerCN;

Het veld Distinguished Name van het ondertekenende certificaat.

 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var distinguishedName:String = verifier.signerDN;

Een array met de Extended Key Usages OID's in het ondertekenende certificaat.

Elk gebruik van uitgebreide sleutels wordt in de vorm van een numerieke OID gemeld.

 import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var extendedKeyOIDs:Array = verifier.signerExtendedKeyUsages;

Een array met de vertrouwde instellingen van het ondertekenende certificaat.

Vertrouwensinstellingen worden van het systeem afgeleid en de belangrijkste gebruiks-OID's die in het certificaat zijn ingesloten. Constanten voor de tekenreeksen die staan voor de herkende vertrouwensinstellingen zijn gedefinieerd in de klasse SignerTrustSettings.

De signerTrustSettings-array van een certificaat met de status onbekend of ongeldig is leeg.

Wijzigen van de array wijzigt de vertrouwensinstellingen van het certificaat niet.

Verwante API-elementen

 import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var certificateTrustedFor:Array = verifier.signerTrustSettings;

De IURIDereferencer-implementatie.

Een IURIDereferencer-implementatie moet worden opgegeven voordat u een handtekening gaat controleren.

Verwante API-elementen

 import com.example.SignedMessageDereferencer; //A custom class implementing IURIDereferencer
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.uriDereferencer = new SignedMessageDereferencer();

Geeft aan dat certificaten in de vertrouwde opslag van het systeem worden gebruikt voor ketenopbouw.

Als true is, dan worden de vertrouwensankers in de vertrouwde opslag van het systeem gebruikt als vertrouwde hoofdpunten. De vertrouwde opslag van het systeem wordt niet standaard gebruikt.

 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.useSystemTrustStore = true;

De geldigheidsstatus van een gecontroleerde XML-handtekening.

De XML-handtekening wordt geverifieerd door de cryptografische handtekening van het element SignedInfo, het handtekeningcertificaat en de gegevens waarnaar wordt verwezen in het element SignedInfo, te valideren. De geldigheid van al deze elementen worden afzonderlijk gemeld door respectievelijk de eigenschappen digestStatus, identityStatus() en referencesStatus.

De status van een XML-handtekening kan geldig, ongeldig of onbekend zijn. De algemene status hangt af van de verificatiestatus van de afzonderlijke componenten van het handtekeningbestand:

• digestStatus — De geldigheid van de cryptografische handtekening die berekend is over het SignedInfo-element.
• identityStatus — De geldigheid van het handtekeningcertificaat.
• referencesStatus — De geldigheid is de samenvatting van de referenties in het SignedInfo-element van de handtekening.

De geldigheid van de handtekening die wordt gemeld door de eigenschap validityStatus kan zijn:

• geldig — Als referencesStatus, digestStatus en identityStatus allemaal geldig zijn.
• ongeldig -- Als een individuele status ongeldig is.
• onbekend -- Als een individuele status onbekend is.

Verwante API-elementen

 import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate the signature...
  
 var validationResult:String = verifier.validityStatus;

Maakt een object van het type XMLSignatureValidator.

U moet de eigenschap uriDereferencer instellen voordat u de methode verify() van het nieuwe object aanroept.

Verwante API-elementen

 
import com.example.EnvelopedDereferencer; //Your custom IURIDereferencer implementation

//Create the object
var verifier:XMLSignatureValidator = new XMLSignatureValidator();

//Provide the IURIDerferencer
verifier.uriDereferencer = new EnvelopedDereferencer(xmlDoc);

//Set validation options
verifier.referencesValidationSetting = ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY;
verifier.revocationCheckSetting = RevocationCheckSettings.NEVER;
verifier.useSystemTrustStore = true;

//Add listeners to handle results
verifier.addEventListener(Event.COMPLETE, verificationComplete);
verifier.addEventListener(ErrorEvent.ERROR, verificationError);

Voegt een x509-certificaat toe voor het opbouwen van de keten.

Het toegevoegde certificaats moet een DER-gecodeerd x509-certificaat zijn.

Als de parameter trusted true is, wordt het certificaat beschouwd als een vertrouwensanker.

Opmerking: Een XML-handtekening kan certificaten bevatten voor het opbouwen van de certificaatketen van de ondertekenaar. De klasse XMLSignatureValidator gebruikt deze certificaten voor de ketenopbouw, maar niet als vertrouwde hoofdpunten (standaard).

Parameters

 import flash.utils.ByteArray;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 var certificate:ByteArray = new ByteArray();
 
 var certFile:File = new File("certificate.cer");
 var certFileStream:FileStream = new FileStream();
 certFileStream.open(certFile, FileMode.READ);
 certFileStream.readBytes(certificate, 0, certFileStream.bytesAvailable);

 verifier.addCertificate(certificate, true);

Controleert de opgegeven handtekening.

Verificatie is asynchroon. Het object XMLSignatureValidator verzendt een gebeurtenis complete wanneer de verificatie succesvol is afgerond of een gebeurtenis error als de verificatie door fouten niet kon worden voltooid.

Het verificatieproces kan niet worden geannuleerd. Gedurende een verificatieproces zullen verdere aanroepen van de methode verify() mislukken. Na voltooiing van de huidige verificatie kunt u de methode verify() weer aanroepen.

Opmerking: omdat XMLSignatureValidator alleen een subset van de W3C-aanbeveling voor syntaxis en verwerking van XML-handtekeningen implementeert, kunnen niet alle geldige XML-handtekeningen worden gecontroleerd.

Parameters

import flash.filesystem.File;
import flash.filesystem.FileStream;
import com.example.SignedMessageDereferencer; //Your IURIDereferencer implementation
 
const xmlSignatureNS:Namespace = new Namespace( "http://www.w3.org/2000/09/xmldsig#" );

var verifier:XMLSignatureValidator = new XMLSignatureValidator();
verifier.uriDereferencer = new SignedMessageDereferencer();

var signatureFile:File = new File( "path/to/XMLSignatureDocument.xml" );
var sigFileStream:FileStream = new FileStream();
sigFileStream.open( signatureFile, FileMode.READ );

var xmlDoc:XML = XML( sigFileStream.readUTFBytes(sigFileStream.bytesAvailable) );
var xmlSig:XML = XML( xmlDoc..xmlSignatureNS::Signature );

verifier.verify( xmlSig );

Wordt verzonden wanneer verificatie voltooid is.

Een gebeurtenis complete betekent nog niet dat de handtekening geldig is. Controleer de eigenschap validityStatus van het object XMLSignatureValidator om het resultaat van de handtekeningverificatie te bepalen.

Deze gebeurtenis heeft de volgende eigenschappen:

private function verificationComplete(event:Event):void{
    var validator:XMLSignatureValidator = event.target as XMLSignatureValidator;
    trace("Digest status: " + validator.digestStatus);
    trace("Identity status: " + validator.identityStatus);
    trace("Reference status: " + validator.referencesStatus);
    trace("Signature status: " + validator.validityStatus);    
}

Verwante API-elementen

Wordt verzonden als verificatie door fouten niet kan worden voltooid.

Deze gebeurtenis heeft de volgende eigenschappen:

private function verificationError(event:ErrorEvent):void{
    trace("Verification error: " + event.text);                
}