FlowElement  - AS3

TextLayoutFormat: 도미넌트 기준선 정렬의 기준이 되는 기준선을 지정합니다. 예를 들어 dominantBaseline을 ASCENT로 설정한 경우 alignmentBaseline을 DESCENT로 설정하면 텍스트의 위쪽이 DESCENT 기준선으로 정렬되거나 해당 줄 아래에 정렬됩니다. 일반적으로 줄에서 가장 큰 요소가 기준선을 결정합니다.

올바른 값은 TextBaseline.ROMAN, TextBaseline.ASCENT, TextBaseline.DESCENT, TextBaseline.IDEOGRAPHIC_TOP, TextBaseline.IDEOGRAPHIC_CENTER, TextBaseline.IDEOGRAPHIC_BOTTOM, TextBaseline.USE_DOMINANT_BASELINE, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 TextBaseline.USE_DOMINANT_BASELINE이 됩니다.

관련 API 요소

TextLayoutFormat: 배경에 대한 알파(투명도) 값입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 값이 0이면 완전하게 투명한 상태이며 값이 1이면 완전하게 불투명한 상태입니다. alpha가 0으로 설정된 표시 객체는 눈에 보이지는 않지만 활성화되어 있습니다.

올바른 값은 0~1 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 1입니다.

TextLayoutFormat: 텍스트의 배경색입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 상수 값 BackgroundColor.TRANSPARENT 또는 3개의 8비트 RGB(빨강, 녹색, 파랑) 값을 지정하는 16진수 값(예: 0xFF0000는 빨강, 0x00FF00은 녹색) 중 하나일 수 있습니다.

올바른 문자열 값은 BackgroundColor.TRANSPARENT, FormatValue.INHERIT 및 0x0~0xffffffff 범위의 uint입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 BackgroundColor.TRANSPARENT입니다.

관련 API 요소

TextLayoutFormat: dominantBaseline 값에서 기준선을 이동하는 정도입니다. 단위는 fontSize의 픽셀 또는 퍼센트(예: 140% 등의 문자열 값 입력)입니다. 양수 값으로 설정하면 가로쓰기 텍스트의 줄이 위로 이동(세로쓰기 텍스트의 경우 오른쪽으로 이동)하며 음수 값으로 설정하면 가로쓰기 텍스트의 줄이 아래로 이동(세로쓰기 텍스트의 경우 왼쪽으로 이동)합니다.

올바른 값은 BaselineShift.SUPERSCRIPT, BaselineShift.SUBSCRIPT, FormatValue.INHERIT입니다.

올바른 값은 -1000에서 1000 사이의 숫자입니다.

올바른 퍼센트 값은 -1000에서 1000 사이의 숫자입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0.0입니다.

관련 API 요소

TextLayoutFormat: 줄 배치의 수직 또는 수평 진행을 지정합니다. 줄은 위에서 아래로 배치(BlockProgression.TB, 가로쓰기 텍스트에서 사용됨)되거나 오른쪽에서 왼쪽으로 배치(BlockProgression.RL, 세로쓰기 텍스트에서 사용됨)될 수 있습니다.

올바른 값은 BlockProgression.RL, BlockProgression.TB, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 BlockProgression.TB가 됩니다.

관련 API 요소

TextLayoutFormat: 텍스트를 줄 바꿈하여 여러 줄로 나눌 때 줄을 나눌 수 있는 위치를 제어합니다. BreakOpportunity.AUTO로 설정하면 텍스트가 일반적인 방식으로 분리됩니다. BreakOpportunity.NONE로 설정하면 텍스트가 기준을 초과하거나 줄을 분리할 수 있는 다른 위치가 없지 않는 한 텍스트가 분리되지 않습니다. BreakOpportunity.ANY로 설정하면 단어 사이가 아닌 아무 곳에서나 줄 분리됩니다. BreakOpportunity.ALL로 설정하면 각 입력 클러스터가 개별적인 줄에 배치됩니다. 이는 패스 위에 배치된 텍스트에 유용합니다.

올바른 값은 BreakOpportunity.ALL, BreakOpportunity.ANY, BreakOpportunity.AUTO, BreakOpportunity.NONE, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 BreakOpportunity.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 이 텍스트에 사용된 CFF 힌팅 유형입니다. CFF 힌팅은 Flash 런타임에서 굵은 가로 스템을 하위 픽셀 격자에 강제로 맞출지 여부를 결정합니다. 이 속성은 renderingMode 속성이 RenderingMode.CFF로 설정되고, fontLookup 속성이 FontLookup.EMBEDDED_CFF로 설정되어 해당 글꼴이 포함된 경우에만 적용됩니다. 화면 크기가 작은 경우 힌팅을 통해 텍스트의 선명함과 가독성을 높일 수 있습니다.

올바른 값은 CFFHinting.NONE, CFFHinting.HORIZONTAL_STEM, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 CFFHinting.HORIZONTAL_STEM이 됩니다.

관련 API 요소

TextLayoutFormat: 부동 항목 주변 텍스트의 배열 방식을 제어합니다. 값이 none이면 텍스트가 부동 항목 주위를 가장 밀접하게 감싸게 됩니다. 값이 left이면 텍스트가 컨테이너에서 왼쪽 부동 항목이 있는 부분을 건너뛰고, 값이 right이면 컨테이너에서 오른쪽 부동 항목이 있는 부분을 건너뜁니다. 값이 both이면 텍스트가 모든 부동 항목을 건너뜁니다.

올바른 값은 ClearFloats.START, ClearFloats.END, ClearFloats.LEFT, ClearFloats.RIGHT, ClearFloats.BOTH, ClearFloats.NONE, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 ClearFloats.NONE입니다.

관련 API 요소

TextLayoutFormat: 텍스트의 색상입니다. 3개의 8비트 RGB(빨강, 녹색, 파랑) 값을 지정하는 16진수입니다. 예를 들어 0xFF0000는 빨강, 0x00FF00은 녹색입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0입니다.

TextLayoutFormat: 텍스트 열 수입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 열 수는 다른 열 설정을 재정의합니다. 값은 정수이거나 지정되지 않은 경우 AUTO입니다. columnCount가 지정되지 않은 경우 columnWidth를 사용하여 컨테이너에 맞는 수만큼 열을 만듭니다.

올바른 문자열 값은 FormatValue.AUTO, FormatValue.INHERIT 및 1~50 범위의 int입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 열 사이에 남겨 둘 제본용 여백 공간의 크기(픽셀 단위)를 지정합니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 값은 숫자입니다.

올바른 값은 0~1,000 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 20입니다.

TextLayoutFormat: 픽셀 단위의 열 폭입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 열의 수가 아닌 열의 폭을 지정한 경우 컨테이너 폭과 columnGap 설정이 지정되어 있으면 TextLayout에서 해당 폭의 열을 가능한 수만큼 만듭니다. 나머지 공백은 마지막 열 뒤에 남습니다. 값은 숫자입니다.

올바른 문자열 값은 FormatValue.AUTO, FormatValue.INHERIT 및 0~8,000 범위의 숫자입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

이 요소에 적용되는 계산된 서식 속성을 반환합니다. 부모 인스턴스의 속성 상속을 고려합니다.

관련 API 요소

이 FlowElement에 대한 coreStyles를 반환합니다. getter가 기본 스타일 사전의 복사본을 만듭니다. coreStyles 객체는 TextLayoutFormat을 통해 정의되고 TextLayoutFormat.description에 저장되는 형식을 캡슐화합니다. coreStyles 객체는 스타일 이름-값 쌍의 배열로 구성됩니다.

관련 API 요소

TextLayoutFormat: 이 텍스트에 사용된 숫자 케이스 유형입니다. 값을 DigitCase.OLD_STYLE로 설정하면 다양한 어센더와 디센더를 사용하여 소문자 서체와 유사하게 됩니다. 숫자는 비례적으로 공간이 지정됩니다. 이 스타일은 선택한 서체에서만 사용할 수 있으며 보조 또는 전문가 글꼴에서 가장 일반적입니다. DigitCase.LINING 설정을 사용하면 모두 대문자 크기로 지정되고 일반적으로 차트에서 고정 폭으로 정렬됩니다.

올바른 값은 DigitCase.DEFAULT, DigitCase.LINING, DigitCase.OLD_STYLE, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 DigitCase.DEFAULT가 됩니다.

관련 API 요소

TextLayoutFormat: 이 텍스트에 사용된 숫자 폭 유형입니다. 이 값은 개별 숫자를 표시하는 데 가장 적합한 DigitWidth.PROPORTIONAL 또는 표, 차트, 세로 줄에서 숫자를 표시하는 데 가장 적합한 DigitWidth.TABULAR일 수 있습니다.

올바른 값은 DigitWidth.DEFAULT, DigitWidth.PROPORTIONAL, DigitWidth.TABULAR, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 DigitWidth.DEFAULT가 됩니다.

관련 API 요소

TextLayoutFormat: 텍스트 블록에 있는 텍스트의 기본 양방향 포함 수준을 지정합니다. 왼쪽에서 오른쪽 읽기 순서(예: 라틴어 스타일 스크립트) 또는 오른쪽에서 왼쪽 읽기 순서(예: 아랍어 또는 히브리어)입니다. 또한 이 속성은 컨테이너 수준에서 적용될 때 열 방향에 영향을 줍니다. 열은 텍스트와 마찬가지로 왼쪽에서 오른쪽 또는 오른쪽에서 왼쪽 방향이 될 수 있습니다. 아래에 몇 가지 예가 나와 있습니다.

올바른 값은 Direction.LTR, Direction.RTL, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 Direction.LTR이 됩니다.

관련 API 요소

TextLayoutFormat: 줄에 있는 요소의 세로 위치를 결정하기 위해 alignmentBaseline에 정렬될 요소 기준선을 지정합니다. TextBaseline.AUTO 값은 부모 단락의 locale 속성에 기반한 도미넌트 기준선을 선택합니다. 일본어와 중국어의 경우 선택한 기준선 값은 TextBaseline.IDEOGRAPHIC_CENTER이고 그 외의 모든 언어는 TextBaseline.ROMAN입니다. 이러한 기준선은 글꼴 및 글꼴 크기에 따라 선택됩니다.

올바른 값은 FormatValue.AUTO, TextBaseline.ROMAN, TextBaseline.ASCENT, TextBaseline.DESCENT, TextBaseline.IDEOGRAPHIC_TOP, TextBaseline.IDEOGRAPHIC_CENTER, TextBaseline.IDEOGRAPHIC_BOTTOM, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 컨테이너에서 첫 번째 줄의 기준선 위치를 지정합니다. 이 속성에서 참조하는 기준선은 컨테이너 수준 로캘에 따라 달라집니다. 일본어와 중국어의 경우 _BOTTOM이고 그 외의 모든 언어는 ROMAN입니다. 첫 번째 줄의 기준선에 대한 컨테이너의 위쪽 인세트(blockProgression이 RL인 경우 오른쪽 인세트)에서부터의 오프셋은 BaselineOffset.ASCENT(줄의 어센트와 동일), BaselineOffset.LINE_HEIGHT(첫 번째 줄의 높이와 동일) 또는 절대 거리를 지정하는 고정된 값의 수일 수 있습니다. BaselineOffset.AUTO로 설정하면 줄의 어센트가 컨테이너 위쪽 인세트에 맞춰 정렬됩니다.

올바른 문자열 값은 BaselineOffset.AUTO, BaselineOffset.ASCENT, BaselineOffset.LINE_HEIGHT, FormatValue.INHERIT 및 0~1,000 범위의 숫자입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 BaselineOffset.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 사용할 글꼴의 이름 또는 쉼표로 구분한 글꼴 이름 목록입니다. Flash 런타임은 목록에서 사용 가능한 첫 번째 글꼴을 사용하여 요소를 렌더링합니다. 예를 들어 목록이 Arial, Helvetica, _sans인 경우 플레이어는 Arial을 검색하고 Arial이 없을 경우 Helvetica를 검색하며 둘 다 없을 경우 _sans를 검색합니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 Arial입니다.

TextLayoutFormat: 사용할 글꼴 조회입니다. FontLookup.DEVICE를 지정하면 SWF 파일을 실행하는 시스템에 설치되어 있는 글꼴이 사용됩니다. 장치 글꼴을 사용하면 동영상 크기가 작아지지만 텍스트는 다른 시스템 및 플랫폼에서도 항상 동일하게 렌더링됩니다. FontLookup.EMBEDDED_CFF를 지정하면 제작된 SWF 파일에 포함된 글꼴 외곽선이 사용됩니다. 포함된 글꼴을 사용하면 SWF 파일의 크기가 증가하고 경우에 따라 매우 커질 수 있지만 텍스트는 항상 선택된 글꼴로 표시됩니다.

올바른 값은 FontLookup.DEVICE, FontLookup.EMBEDDED_CFF, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 FontLookup.DEVICE가 됩니다.

관련 API 요소

TextLayoutFormat: 텍스트의 크기(픽셀 단위)입니다.

올바른 값은 1~720 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 12입니다.

TextLayoutFormat: 텍스트의 스타일입니다. 일반 텍스트인 경우 FontPosture.NORMAL, 이탤릭체인 경우 FontPosture.ITALIC입니다. 이 속성은 장치 글꼴에만 적용합니다. 즉, fontLookup 속성이 flash.text.engine.FontLookup.DEVICE로 설정됩니다.

올바른 값은 FontPosture.NORMAL, FontPosture.ITALIC, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 FontPosture.NORMAL이 됩니다.

관련 API 요소

TextLayoutFormat: 텍스트의 두께입니다. 일반 텍스트인 경우 FontWeight.NORMAL, 굵은체인 경우 FontWeight.BOLD입니다. 장치 글꼴에만 적용합니다. 즉, fontLookup 속성이 flash.text.engine.FontLookup.DEVICE로 설정됩니다.

올바른 값은 FontWeight.NORMAL, FontWeight.BOLD, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 FontWeight.NORMAL이 됩니다.

관련 API 요소

TextLayoutFormat 속성은 이 요소에 직접 적용됩니다.

각 요소는 서식의 일부로 해당 요소에 적용되는 속성을 가질 수 있습니다. 이 요소에 적용되는 속성이 부모에서 상속되는 속성을 재정의합니다. 이 요소에 적용되는 속성은 요소의 자식에서 재정의되지 않는 한 다시 자식으로 상속됩니다. 요소에 속성이 적용되지 않은 경우에는 null이 됩니다.

관련 API 요소

요소에 식별 이름을 지정하면 id를 참조하여 요소의 스타일을 설정할 수 있습니다. 예를 들어 다음 줄은 span1의 id를 가진 SpanElement 객체의 색상을 설정합니다.

         textFlow.getElementByID("span1").setStyle("color", 0xFF0000);
         

관련 API 요소

TextLayoutFormat: 단락에서 텍스트를 양쪽 정렬하는 데 사용되는 규칙입니다. 기본값은 FormatValue.AUTO이며 단락의 locale 속성에 기반하여 텍스트를 양쪽 정렬합니다. 일본어와 중국어를 제외한 모든 언어의 경우 FormatValue.AUTO가 JustificationRule.SPACE가 되며 공백 문자에 추가 공백을 추가합니다. 일본어와 중국어의 경우 FormatValue.AUTO가 JustficationRule.EAST_ASIAN가 됩니다. 양쪽 정렬은 구두점 간격에 어느 정도 영향을 줍니다. 로마자 텍스트에서 쉼표와 일본어 마침표는 전체 문자 폭을 차지하지만, 동아시아어 텍스트에서는 문자 폭의 반만 차지합니다. 또한 전통적인 동아시아어 텍스트의 경우 동아시아 입력 체계 규칙에 따라 순차적인 문장 부호 사이의 간격이 더욱 좁아집니다. 또한 아래 예제에서 단락의 두번 째 줄에 적용되는 행간에서도 차이가 있습니다. 동아시아어 버전에서는 마지막 두 줄이 왼쪽으로 밀리고 로마어 버전에서는 두 번째와 그 다음 줄이 왼쪽으로 밀립니다.

올바른 값은 JustificationRule.EAST_ASIAN, JustificationRule.SPACE, FormatValue.AUTO, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 단락의 양쪽 정렬에 사용되는 스타일입니다. JustificationRule.EAST_ASIAN의 justificationRule 설정과 결합해서만 사용합니다. 기본값 FormatValue.AUTO는 모든 로캘에서 JustificationStyle.PUSH_IN_KINSOKU로 확인됩니다. JustificationStyle 클래스에서 정의된 상수는 금칙 문자(줄의 시작 부분이나 끝에 나올 수 없는 일본어 문자)를 처리하는 옵션을 지정합니다. 좀 더 간격이 넓은 텍스트를 원할 경우에는 JustificationStyle.PUSH-OUT-ONLY를 지정합니다. JustificationRule.SPACE의 justificationRule로 얻을 수 있는 것과 비슷한 비헤이비어를 원할 경우에는 JustificationStyle.PRIORITIZE-LEAST-ADJUSTMENT를 사용합니다.

올바른 값은 JustificationStyle.PRIORITIZE_LEAST_ADJUSTMENT, JustificationStyle.PUSH_IN_KINSOKU, JustificationStyle.PUSH_OUT_ONLY, FormatValue.AUTO, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 커닝은 가독성을 향상시키기 위해 특정 문자 쌍 사이의 픽셀을 조정합니다. 커닝은 커닝 표가 있는 모든 글꼴에서 지원됩니다.

올바른 값은 Kerning.ON, Kerning.OFF, Kerning.AUTO, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 Kerning.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 행간 기준과 행간 방향이 결합된 행간 모델을 지정합니다. 행간 기본은 lineHeight 속성이 참조하는 기준선입니다. 행간 방향은 lineHeight 속성에서 줄의 기준선 거리를, 이전 줄 기준선으로부터 참조하는지 아니면 이후 줄의 기준선으로부터 참조하는지 여부를 결정합니다. 기본값 FormatValue.AUTO는 단락의 locale 속성에 따라 해석됩니다. 일본어와 중국어의 경우 LeadingModel.IDEOGRAPHIC_TOP_DOWN이고 그 외의 모든 언어는 LeadingModel.ROMAN_UP입니다.

행간 기본:

행간 방향:

올바른 값은 LeadingModel.ROMAN_UP, LeadingModel.IDEOGRAPHIC_TOP_UP, LeadingModel.IDEOGRAPHIC_CENTER_UP, LeadingModel.IDEOGRAPHIC_TOP_DOWN, LeadingModel.IDEOGRAPHIC_CENTER_DOWN, LeadingModel.APPROXIMATE_TEXT_FIELD, LeadingModel.ASCENT_DESCENT_UP, LeadingModel.BOX, LeadingModel.AUTO, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 LeadingModel.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 글꼴에 정의된 합자 중 텍스트에 사용할 수 있는 합자를 제어합니다. 이러한 각 설정에 대해 나타나는 합자는 글꼴에 따라 다릅니다. 합자는 둘 이상의 글자 모양을 결합하여 단일 글리프를 만드는 것입니다. 합자는 일반적으로 공통 구성 요소를 공유하는 연속된 문자(예: 'fi', 'fl' 또는 'ae' 글자 쌍)를 대체합니다. 합자는 라틴어 및 라틴어가 아닌 문자 세트에 모두 사용됩니다. LigatureLevel 클래스의 값(MINIMUM, COMMON, UNCOMMON 및 EXOTIC)에 의해 활성화된 합자가 추가되었습니다. 각 값은 새로운 합자 집합을 활성화할 뿐 아니라 이전 유형의 합자도 포함합니다.

참고: 아랍어나 시리아어 글꼴에 대한 작업을 할 때에는 ligatureLevel을 MINIMUM 이상으로 설정해야 합니다.

올바른 값은 LigatureLevel.MINIMUM, LigatureLevel.COMMON, LigatureLevel.UNCOMMON, LigatureLevel.EXOTIC, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 LigatureLevel.COMMON이 됩니다.

관련 API 요소

TextLayoutFormat: 컨테이너 내 줄 바꿈을 제어합니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 컨테이너의 텍스트는 컨테이너의 폭에 맞도록 설정(LineBreak.TO_FIT)하거나 명시적 반환 또는 줄 분리 문자에 대해서만 줄을 분리하도록 설정(LineBreak.EXPLICIT)할 수 있습니다.

올바른 값은 LineBreak.EXPLICIT, LineBreak.TO_FIT, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 LineBreak.TO_FIT입니다.

관련 API 요소

TextLayoutFormat: 텍스트에 대한 행간 컨트롤입니다. 이전 또는 다음 줄의 기준선(LeadingModel에 기반)에서 현재 줄의 기준선까지의 거리가 줄의 임의 문자에 적용되는 최대 행간 양과 같습니다. 이 값은 숫자 또는 퍼센트입니다. 퍼센트를 지정하는 경우 140%와 같이 문자열 값을 입력합니다.

올바른 값은 -720에서 720 사이의 숫자입니다.

올바른 퍼센트 값은 -1000%에서 1000% 사이의 숫자입니다.

올바른 값으로는 FormatValue.INHERIT 등이 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 120%입니다.

TextLayoutFormat: true이면 텍스트 중간에 선이 그려지는 취소선이 적용됩니다.

올바른 값은 true, false 및 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 false입니다.

TextLayoutFormat: 일반 상태의 링크에 사용되는 서식 지정 특성을 정의합니다. 이 값은 계층 아래로 내려가 하위 항목에 해당하는 모든 링크에 적용됩니다. inherit, 즉 ITextLayoutFormat을 사용하거나 멤버가 키와 값인 객체 배열을 TextLayoutFormat으로 변환합니다.

올바른 값으로는 FormatValue.INHERIT 등이 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 null이 됩니다.

TextLayoutFormat: 마우스가 링크 경계 내에 있을 때 마우스로 링크를 가리킨 상태의 링크에 사용되는 서식 지정 특성을 정의합니다. 이 값은 계층 아래로 내려가 하위 항목에 해당하는 모든 링크에 적용됩니다. inherit, 즉 ITextLayoutFormat을 사용하거나 멤버가 키와 값인 객체 배열을 TextLayoutFormat으로 변환합니다.

올바른 값으로는 FormatValue.INHERIT 등이 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 null이 됩니다.

TextLayoutFormat: 일반 상태의 링크에 사용되는 서식 지정 특성을 정의합니다. 이 값은 계층 아래로 내려가 하위 항목에 해당하는 모든 링크에 적용됩니다. inherit, 즉 ITextLayoutFormat을 사용하거나 멤버가 키와 값인 객체 배열을 TextLayoutFormat으로 변환합니다.

올바른 값으로는 FormatValue.INHERIT 등이 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 null이 됩니다.

TextLayoutFormat: 목록이 시작되는 쪽의 패딩 값이 auto인 경우 목록이 시작되는 가장자리에 자동 들여쓰기를 지정합니다.

올바른 값은 -1,000~1,000 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 40이 됩니다.

TextLayoutFormat: 서식 지정 특성 목록 표시자를 정의합니다. 이 값은 계층 아래로 내려가 하위 항목에 해당하는 모든 링크에 적용됩니다. inherit, 즉 IListMarkerFormat을 사용하거나 멤버가 키와 값인 객체 배열을 ListMarkerFormat으로 변환합니다.

올바른 값으로는 FormatValue.INHERIT 등이 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 null이 됩니다.

TextLayoutFormat:

올바른 값은 ListStylePosition.INSIDE, ListStylePosition.OUTSIDE, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 ListStylePosition.OUTSIDE가 됩니다.

관련 API 요소

TextLayoutFormat:

올바른 값은 ListStyleType.UPPER_ALPHA, ListStyleType.LOWER_ALPHA, ListStyleType.UPPER_ROMAN, ListStyleType.LOWER_ROMAN, ListStyleType.NONE, ListStyleType.DISC, ListStyleType.CIRCLE, ListStyleType.SQUARE, ListStyleType.BOX, ListStyleType.CHECK, ListStyleType.DIAMOND, ListStyleType.HYPHEN, ListStyleType.ARABIC_INDIC, ListStyleType.BENGALI, ListStyleType.DECIMAL, ListStyleType.DECIMAL_LEADING_ZERO, ListStyleType.DEVANAGARI, ListStyleType.GUJARATI, ListStyleType.GURMUKHI, ListStyleType.KANNADA, ListStyleType.PERSIAN, ListStyleType.THAI, ListStyleType.URDU, ListStyleType.CJK_EARTHLY_BRANCH, ListStyleType.CJK_HEAVENLY_STEM, ListStyleType.HANGUL, ListStyleType.HANGUL_CONSTANT, ListStyleType.HIRAGANA, ListStyleType.HIRAGANA_IROHA, ListStyleType.KATAKANA, ListStyleType.KATAKANA_IROHA, ListStyleType.LOWER_ALPHA, ListStyleType.LOWER_GREEK, ListStyleType.LOWER_LATIN, ListStyleType.UPPER_ALPHA, ListStyleType.UPPER_GREEK, ListStyleType.UPPER_LATIN, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 ListStyleType.DISC가 됩니다.

관련 API 요소

TextLayoutFormat: 텍스트의 로캘입니다. 대/소문자 변형 및 모양을 제어합니다. Unicode Technical Standard #35에 설명된 표준 로캘 식별자가 사용됩니다. 예를 들어 en, en_US 및 en-US는 모두 영어를 나타내고 ja는 일본어를 나타냅니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 en입니다.

TextLayoutFormat: 아래쪽 인세트(픽셀 단위)입니다. auto의 기본값은 시작 패딩이 45인 목록의 경우만 제외하고 0입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 컨테이너 아래쪽 가장자리와 텍스트 사이의 공간입니다. 값은 숫자 또는 auto입니다.

가로쓰기 텍스트의 경우 여러 개의 열을 포함하는 스크롤 가능한 컨테이너의 첫 번째 열과 다음 열에서 패딩은 컨테이너 아래쪽의 빈 공간으로 표시되지만 텍스트가 모두 맞지 않는 경우 마지막 열에서 패딩을 표시하기 위해 스크롤해야 할 수 있습니다.

올바른 문자열 값은 FormatValue.AUTO, FormatValue.INHERIT 및 -8,000~8,000 범위의 숫자입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 왼쪽 인세트(픽셀 단위)입니다. auto의 기본값은 시작 패딩이 45인 목록의 경우만 제외하고 0입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 컨테이너 왼쪽 가장자리와 텍스트 사이의 공간입니다. 값은 숫자 또는 auto입니다.

세로쓰기 텍스트의 경우 여러 개의 열을 포함하는 스크롤 가능한 컨테이너의 첫 번째 열과 다음 열에서 패딩은 컨테이너 끝의 빈 공간으로 표시되지만 텍스트가 모두 맞지 않는 경우 마지막 열에서 패딩을 표시하기 위해 스크롤해야 할 수 있습니다.

올바른 문자열 값은 FormatValue.AUTO, FormatValue.INHERIT 및 -8,000~8,000 범위의 숫자입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 오른쪽 인세트(픽셀 단위)입니다. auto의 기본값은 시작 패딩이 45인 목록의 경우만 제외하고 0입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 컨테이너 오른쪽 가장자리와 텍스트 사이의 공간입니다. 값은 숫자 또는 auto입니다.

올바른 문자열 값은 FormatValue.AUTO, FormatValue.INHERIT 및 -8,000~8,000 범위의 숫자입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 위쪽 인세트(픽셀 단위)입니다. auto의 기본값은 시작 패딩이 45인 목록의 경우만 제외하고 0입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 컨테이너 위쪽 가장자리와 텍스트 사이의 공간입니다. 값은 숫자 또는 auto입니다.

올바른 문자열 값은 FormatValue.AUTO, FormatValue.INHERIT 및 -8,000~8,000 범위의 숫자입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 FormatValue.AUTO가 됩니다.

관련 API 요소

TextLayoutFormat: 단락의 끝 가장자리를 들여 쓸 크기를 지정하는 숫자(픽셀 단위)입니다. 읽기 순서가 왼쪽에서 오른쪽인 텍스트에서는 오른쪽 가장자리를 참조하고 오른쪽에서 왼쪽인 텍스트에서는 왼쪽 가장자리를 참조합니다.

올바른 값은 0~8,000 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0입니다.

TextLayoutFormat: 단락 뒤에 남겨 둘 공간 크기(픽셀 단위)를 지정하는 숫자입니다. paragraphSpaceBefore로 나란히 축소합니다.

올바른 값은 0~8,000 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0입니다.

TextLayoutFormat: 단락 앞에 남겨 둘 공간 크기(픽셀 단위)를 지정하는 숫자입니다. paragraphSpaceAfter로 나란히 축소합니다.

올바른 값은 0~8,000 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0입니다.

TextLayoutFormat: 단락의 시작 가장자리를 들여 쓸 크기를 지정하는 숫자(픽셀 단위)입니다. 읽기 순서가 왼쪽에서 오른쪽인 텍스트에서는 왼쪽 가장자리를 참조하고 오른쪽에서 왼쪽인 텍스트에서는 오른쪽 가장자리를 참조합니다.

올바른 값은 0~8,000 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0입니다.

이 FlowElement 객체의 부모를 반환합니다. 모든 FlowElement은 최대 하나의 부모를 가집니다.

부모에서 이 FlowElement 객체의 상대적 끝을 반환합니다. 부모가 null이면 이 값은 항상 textLength와 같습니다. 부모가 null이면 이 값은 이 객체의 텍스트 길이와 이전의 모든 형제(다음 FlowElement 객체의 첫 번째 문자에 영향을 주는)를 더한 값입니다.

관련 API 요소

부모에서 이 FlowElement 객체의 상대적 시작을 반환합니다. 부모가 null인 경우 이 값은 항상 0입니다. 부모가 null이 아닌 경우에는 이 값이 모든 이전 형제의 텍스트 길이 합입니다.

관련 API 요소

TextLayoutFormat: 이 텍스트에 사용되는 렌더링 모드입니다. 포함된 글꼴에만 적용됩니다(fontLookup 속성이 FontLookup.EMBEDDED_CFF로 설정됨).

올바른 값은 RenderingMode.NORMAL, RenderingMode.CFF, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 RenderingMode.CFF가 됩니다.

관련 API 요소

TextLayoutFormat: 요소에 식별 클래스를 지정하면 styleName을 참조하여 요소의 스타일을 설정할 수 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의값은 null입니다.

이 FlowElement의 styles를 반환합니다. getter가 스타일 사전의 복사본을 만듭니다. 반환된 객체는 기본 및 사용자 스타일 등 format 속성에 설정된 모든 스타일을 캡슐화합니다. 반환된 객체는 스타일 이름-값 쌍의 배열로 구성되어 있습니다.

관련 API 요소

TextLayoutFormat: 단락과 연결된 탭 정지를 지정합니다. setter는 TabStopFormat 배열, 간략한 문자열 표현, undefined 또는 FormatValue.INHERIT를 사용할 수 있습니다. 간략한 문자열 표현은 항상 TabStopFormat 배열로 변환됩니다.

문자열 기반 서식은 탭 정지 목록으로 각 탭 정지가 하나 이상의 공백으로 구분됩니다.

탭 정지는 <정렬 유형><정렬 위치>|<정렬 토큰> 양식을 사용합니다.

정렬 유형은 단일 문자이며 S, E, C 또는 D(소문자 s, e, c, d)일 수 있습니다. S 또는 s는 시작, E 또는 e는 끝, C 또는 c는 가운데, D 또는 d는 소수점을 나타냅니다. 정렬 유형은 선택 사항이며 지정되지 않은 경우 S로 기본 설정됩니다.

정렬 위치는 숫자이며 숫자에 대한 FXG 사양(십진 표기법 또는 공학 표기법)에 따라 지정됩니다. 정렬 위치는 필수 사항입니다.

세로 막대는 정렬 토큰에서 정렬 위치를 분리하는 데 사용되며 정렬 토큰이 표시되는 경우에만 표시되어야 합니다.

정렬 토큰은 정렬 유형이 D인 경우 선택 사항이며 정렬 유형이 D가 아닌 경우에는 표시되지 않아야 합니다. 정렬 토큰은 탭 정지를 끝내는 공백에 의해 종료되는 문자의 시퀀스일 수도 있습니다. 마지막 탭 정지의 경우 종료 공백은 선택 사항이며 정렬 토큰의 끝이 포함됩니다. 정렬 토큰이 백슬래시(\)로 이스케이프되는 경우 공백은 정렬 토큰의 일부일 수 있습니다. 정렬 토큰이 다른 백슬래시(\\)로 이스케이프되는 경우 백슬래시는 정렬 토큰의 일부일 수 있습니다. 정렬 유형이 D이고 정렬 토큰이 지정되지 않은 경우 기본값 null을 사용합니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 null이 됩니다.

관련 API 요소

TextLayoutFormat: 컨테이너를 기준으로 한 단락의 줄 정렬입니다. TextAlign.LEFT는 컨테이너의 가장자리를 기준으로 줄을 정렬합니다. TextAlign.RIGHT는 오른쪽 가장자리를 기준으로 줄을 정렬합니다. TextAlign.CENTER는 왼쪽과 오른쪽 가장자리의 가운데에 줄을 배치합니다. TextAlign.JUSTIFY는 전체 공간에 균등하게 줄을 배치합니다. TextAlign.START는 왼쪽에서 오른쪽 방향 텍스트의 경우 왼쪽으로, 오른쪽에서 왼쪽 방향 텍스트의 경우 오른쪽으로 설정합니다. TextAlign.END는 왼쪽에서 오른쪽 방향 텍스트의 경우 오른쪽으로, 오른쪽에서 왼쪽 방향 텍스트의 경우 왼쪽으로 설정합니다.

올바른 값은 TextAlign.LEFT, TextAlign.RIGHT, TextAlign.CENTER, TextAlign.JUSTIFY, TextAlign.START, TextAlign.END, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 TextAlign.START가 됩니다.

관련 API 요소

TextLayoutFormat: 양쪽 정렬된 텍스트의 컨테이너를 기준으로 한 단락의 마지막 줄 또는 유일한 줄의 정렬입니다. textAlign을 TextAlign.JUSTIFY로 설정하면 textAlignLast에서 마지막 줄(한 줄 블록인 경우 유일한 줄)의 정렬 방식을 지정합니다. 값은 textAlign과 비슷합니다.

올바른 값은 TextAlign.LEFT, TextAlign.RIGHT, TextAlign.CENTER, TextAlign.JUSTIFY, TextAlign.START, TextAlign.END, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 TextAlign.START가 됩니다.

관련 API 요소

TextLayoutFormat: 텍스트의 알파(투명도) 값입니다. 값이 0이면 완전하게 투명한 상태이며 값이 1이면 완전하게 불투명한 상태입니다. textAlpha가 0으로 설정된 표시 객체는 눈에 보이지는 않지만 활성화되어 있습니다.

올바른 값은 0~1 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 1입니다.

TextLayoutFormat: 텍스트의 장식입니다. 밑줄을 적용하는 데 사용합니다. 기본값은 none입니다.

올바른 값은 TextDecoration.NONE, TextDecoration.UNDERLINE, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 TextDecoration.NONE이 됩니다.

관련 API 요소

TextLayoutFormat: 단락의 첫 번째 줄을 들여 쓸 크기를 지정하는 숫자(픽셀 단위)입니다. 음의 들여쓰기는 줄을 여백 안쪽으로 밀어 넣으며 줄이 컨테이너를 벗어날 수 있습니다.

올바른 값은 -8,000~ 8,000 범위의 숫자와 FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0입니다.

TextLayoutFormat: 텍스트를 양쪽 정렬하는 옵션을 지정합니다. 기본값은 TextJustify.INTER_WORD이며 여분의 공백을 공백 문자에 추가함을 나타냅니다. TextJustify.DISTRIBUTE는 공백 문자 및 각 문자의 사이에 별도의 공간을 추가합니다. JustificationRule.SPACE의 justificationRule 값과 함께 사용됩니다.

올바른 값은 TextJustify.INTER_WORD, TextJustify.DISTRIBUTE, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 TextJustify.INTER_WORD가 됩니다.

관련 API 요소

이 FlowElement 객체 및 자식이 소유하는 텍스트의 전체 길이를 반환합니다. 요소에 텍스트가 없는 경우 textLength의 값은 일반적으로 0입니다.

ParagraphElement 객체는 마지막 SpanElement 객체의 단락 종결자 문자가 포함된 마지막 범위를 가집니다. 단락 종결자는 SpanElement 객체 및 모든 부모의 textLength 값에 포함됩니다. 하지만 SpanElement의 text 속성에는 포함되지 않습니다.

관련 API 요소

TextLayoutFormat: 이 텍스트를 회전할 각도의 수를 결정합니다.

올바른 값은 TextRotation.ROTATE_0, TextRotation.ROTATE_180, TextRotation.ROTATE_270, TextRotation.ROTATE_90, TextRotation.AUTO, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 TextRotation.AUTO가 됩니다.

관련 API 요소

자간을 설정하며 trackingRight 속성과 같습니다. 픽셀 수 또는 fontSize의 비율로 지정됩니다.

관련 API 요소

TextLayoutFormat: 각 문자의 왼쪽에 적용할 자간(수동 커닝)의 크기를 나타내는 픽셀 단위의 숫자 또는 fontSize의 퍼센트(예: 120%)입니다. kerning이 활성화된 경우 trackingLeft 값이 글꼴에 대한 커닝 표의 값에 추가됩니다. kerning이 활성화되지 않은 경우 trackingLeft 값이 수동 커닝 값으로 사용됩니다. 양수 및 음수 값을 모두 지원합니다.

올바른 값은 -1000에서 1000 사이의 숫자입니다.

올바른 퍼센트 값은 -1000%에서 1000% 사이의 숫자입니다.

올바른 값으로는 FormatValue.INHERIT 등이 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0입니다.

TextLayoutFormat: 각 문자의 오른쪽에 적용할 자간(수동 커닝)의 크기를 나타내는 픽셀 단위의 숫자 또는 fontSize의 퍼센트(예: 120%)입니다. kerning이 활성화된 경우 trackingRight 값이 글꼴에 대한 커닝 표의 값에 추가됩니다. kerning이 활성화되지 않은 경우 trackingRight 값이 수동 커닝 값으로 사용됩니다. 양수 및 음수 값을 모두 지원합니다.

올바른 값은 -1000에서 1000 사이의 숫자입니다.

올바른 퍼센트 값은 -1000%에서 1000% 사이의 숫자입니다.

올바른 값으로는 FormatValue.INHERIT 등이 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 조상에서 이 값을 설정하지 않으면 이 속성의 값은 0입니다.

각 FlowElement마다 typeName이 있습니다. typeName의 기본값은 TextConverter가 사용하는 textLayoutFormat 문자열로 설정됩니다. 이 API를 사용하면 다른 typeName을 FlowElement로 설정할 수 있습니다. 일반적으로 이는 CSS에서 type 선택기를 지원하기 위한 것입니다.

사용 방법은 TEXT_FIELD_HTML_FORMAT 설명서를 참조하십시오.

관련 API 요소

TextLayoutFormat: 이 텍스트에 사용된 입력 체계 대/소문자 유형입니다. 다음에 몇 가지 예가 나와 있습니다.

올바른 값은 TLFTypographicCase.DEFAULT, TLFTypographicCase.CAPS_TO_SMALL_CAPS, TLFTypographicCase.UPPERCASE, TLFTypographicCase.LOWERCASE, TLFTypographicCase.LOWERCASE_TO_SMALL_CAPS, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 TLFTypographicCase.DEFAULT가 됩니다.

관련 API 요소

FlowElement 객체에서 사용자 스타일을 읽고 쓸 수 있도록 합니다. 이 속성을 읽으면 이 요소의 형식으로 userStyles 집합의 복사본이 만들어집니다.

TextLayoutFormat: 세로 정렬 또는 양쪽 정렬입니다. 겹쳐 놓기 동안 undefined인 경우 기본값이 사용됩니다. 컨테이너 내에서 TextFlow 요소가 정렬되는 방법을 결정합니다.

올바른 값은 VerticalAlign.TOP, VerticalAlign.MIDDLE, VerticalAlign.BOTTOM, VerticalAlign.JUSTIFY, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성의 값은 VerticalAlign.TOP입니다.

관련 API 요소

TextLayoutFormat: 텍스트를 TextFlow로 가져올 때 공백을 축소하거나 유지합니다. WhiteSpaceCollapse.PRESERVE는 모든 공백 문자를 유지합니다. WhiteSpaceCollapse.COLLAPSE는 가져온 텍스트 블록에서 새 줄, 탭, 행간 또는 후행 공백을 제거합니다. 줄 분리 태그 () 및 유니코드 줄 분리 기호 문자는 유지됩니다.

올바른 값은 WhiteSpaceCollapse.PRESERVE, WhiteSpaceCollapse.COLLAPSE, FormatValue.INHERIT입니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 WhiteSpaceCollapse.COLLAPSE가 됩니다.

관련 API 요소

TextLayoutFormat: 양쪽 정렬하는 동안 사용할 단어 사이의 최적, 최소 및 최대 간격을 보통 간격의 배수로 지정합니다. 최적 간격은 필요한 간격을 글꼴에 정의된 값보다 훨씬 작은 값으로 나타내는 데 사용합니다. 최소값과 최대값은 문자 간격으로 줄 간격을 조절하기 전에 textJustify를 분배하여 단어 사이 간격을 얼마나 넓히거나 좁힐지 결정하는 데 사용합니다.

올바른 퍼센트 값은 -1000%에서 1000% 사이의 숫자입니다.

올바른 값으로는 FormatValue.INHERIT 등이 있습니다.

기본값은 설정되지 않았음을 나타내는 undefined입니다.

겹쳐 놓기 동안 undefined인 경우 이 속성은 조상의 값을 상속합니다. 이 속성 값을 설정한 조상이 없으면 값은 100%, 50%, 150%가 됩니다.

기본 클래스 - new FlowElement()를 호출하면 오류 예외가 throw됩니다.

이 FlowElement 객체의 styleProp 매개 변수로 지정된 스타일을 지웁니다. 값을 undefined로 설정합니다.

매개 변수

관련 API 요소

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_clearStyleExample extends Sprite{    
        public function FlowElement_clearStyleExample()
        {
            // create a container and a TextFlow object
            var container:Sprite = new Sprite();
            this.addChild(container);
            var textFlow:TextFlow = new TextFlow();
            
            // create a paragraph and set lineThrough style to true 
            var paragraph:ParagraphElement = new ParagraphElement();
            paragraph.setStyle("color", 204);
            // create two spans of text
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();            
            span1.text = "After calling clearStyle(), the value of color for span1 is: ";     
            span2.text = " but the value of span1.getStyle() for color is ";
            span3.text = " because getStyle() returns the inherited value that's applied to the style.";
            span1.clearStyle("color");        // undefined
            span1.text += span1.color;
            paragraph.addChild(span1);
            paragraph.addChild(span2);
            span2.text += span1.getStyle("color");    //204 
            paragraph.addChild(span3);
            
            textFlow.addChild(paragraph);
            // add controller, then update controller to display text
            var firstController:ContainerController = new ContainerController(container, 200, 200 );
            textFlow.flowComposer.addController(firstController);
            textFlow.flowComposer.updateAllControllers(); 
        }
    }
}

두 개의 지정된 문자 위치 간의 내용을 복사하고, 복사본을 FlowElement 객체로 반환하여 이 FlowElement 객체의 전체 복사본(모든 자식 포함)을 만듭니다.

인수가 없으면 deepCopy()의 기본값은 전체 요소를 복사하도록 설정됩니다.

매개 변수

관련 API 요소

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_deepCopyExample extends Sprite{    
        public function FlowElement_deepCopyExample()
        {
            // create a container and add it to the stage
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            // add text to the spans and spans to the paragraph
            span1.text = "Hello, ";
            span2.text = "World!";
            p.fontSize = 48;
            p.addChild(span1);
            p.addChild(span2);
            // make a deep copy of paragraph p, starting at relative offset 3; copy to end
            var p2:ParagraphElement = p.deepCopy(3, -1) as ParagraphElement; 
            // add copied paragraph (p2) to textflow; add composer and controller 
            // and update controller to display text
            textFlow.addChild(p2);
            var controller:ContainerController = new ContainerController(container, 200, 200 );
            textFlow.flowComposer.addController(controller);
            textFlow.flowComposer.updateAllControllers();    // 'lo, World!'
        }
    }
}

이 클래스의 userStyles를 otherElement의 userStyles와 비교합니다.

매개 변수

관련 API 요소

텍스트 흐름에서 요소의 시작 위치를 절대 인덱스로 반환합니다. 흐름에서 첫 번째 문자는 위치 0에 있습니다.

관련 API 요소

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getAbsoluteStartExample extends Sprite
    {    
        public function FlowElement_getAbsoluteStartExample()
        {
            // create a container and add it to the stage
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            // add text to the spans, spans to the paragraph, and paragraph to the text flow
            span1.text = "The start of span2 ";
            span2.text = "in this paragraph is at index: ";
            p.fontSize = 20;
            p.addChild(span1);
            p.addChild(span2);
            textFlow.addChild(p);
            // find the starting position of span2 and update controller to display text
            span2.text += span2.getAbsoluteStart();  // 19
            var controller:ContainerController = new ContainerController(container, 200, 200 );
            textFlow.flowComposer.addController(controller);
            textFlow.flowComposer.updateAllControllers();  
        }
    }
}

FlowElement 객체에 상대적인, 지정된 위치의 문자를 반환합니다. 첫 번째 문자는 상대적 위치 0에 있습니다.

매개 변수

관련 API 요소

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getCharAtPositionExample extends Sprite
    {        
        public function FlowElement_getCharAtPositionExample()
        {
            // create a container and a controller for it and add it to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController( container, 400, 200 );
            this.stage.addChild( container );
                        
            //create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            
            // add text to the two spans, calling getCharAtPosition() to return the
            // character at relative position 27 in the first span
            span1.text = "The character at offset 27 in this paragraph is: ";
            span2.text =  span1.getCharAtPosition(27) + ".";    // i
            
            // add spans to paragraph p   
            p.addChild(span1);
            p.addChild(span2);
            
            // add paragraph p to text flow and update controller to display it
            textFlow.addChild(p);
            textFlow.flowComposer.addController( controller );                               
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

FlowElement에 상대적인, 지정된 위치의 문자 코드를 반환합니다. 첫 번째 문자는 상대적 위치 0에 있습니다.

매개 변수

관련 API 요소

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getCharCodeAtPositionExample extends Sprite
    {        
        public function FlowElement_getCharCodeAtPositionExample()
        {
            // create a container and a controller for it and add it to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController( container, 400, 200 );
            this.stage.addChild( container );
            
            //create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            
            // add text to spans; use getCharCodeAtPosition() to add char code from pos. 16
            // of span1
            
            span1.text = "The character code at offset 16 in this paragraph is: ";
            span2.text =  String(span1.getCharCodeAtPosition(16)) + ".";    // 100 (d)
            
            // add spans to paragraph p   
            p.addChild(span1);
            p.addChild(span2);
            
            // add paragraph p to text flow and update controller to display it
            textFlow.addChild(p);
            textFlow.flowComposer.addController( controller );                               
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

상위 항목 요소에 상대적인 이 요소의 시작을 반환합니다. 상위 항목 요소가 부모 체인에 있다고 가정합니다. 상위 항목 요소가 부모일 경우 this.parentRelativeStart와 같습니다. 상위 항목 요소가 부모의 부모인 경우에는 parentRelativeStart와 parent.parentRelativeStart를 더한 값과 같은 식입니다.

매개 변수

관련 API 요소

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.LinkElement;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getElementRelativeStartExample extends Sprite
    {        
        public function FlowElement_getElementRelativeStartExample()
        {
            // create a container and a controller for it and add it to the stage
            var container:Sprite = new Sprite();
            var controller:ContainerController = new ContainerController( container, 400, 200 );
            this.stage.addChild( container );
            
            //create TextFlow, ParagraphElement, SpanElement, and LinkElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var link:LinkElement = new LinkElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();
            
            // add text to first two spans
            span1.text = "The relative start of the link SpanElement (";
            span2.text =  ") in this paragraph is at position ";
            
            // create link span, add text and corresponding URL and add to link
            var linkSpan:SpanElement = new SpanElement();
            linkSpan.text = "Adobe's website";
            link.href = "http://www.adobe.com";
            link.addChild(linkSpan);
            
            // add first span, link, and second span to paragraph p   
            p.addChild(span1);
            p.addChild(link);
            p.addChild(span2);
            
            // call getElementRelativeStart() to get start of linkSpan and add to span 3
            span3.text = String(linkSpan.getElementRelativeStart(p)) + ".";  // 44.
            p.addChild(span3);
            
            // add paragraph p to text flow and update controller to display it
            textFlow.addChild(p);
            textFlow.flowComposer.addController( controller );                               
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

텍스트 흐름 계층 구조에서 다음 FlowElement 형제를 반환합니다.

관련 API 요소

package flashx.textLayout.elements.examples {
    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowElement_getNextSiblingExample extends Sprite
    {        
        public function FlowElement_getNextSiblingExample()
        {
            // create a container and add it to the stage
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var nextSpanElement:SpanElement = new SpanElement();
            // add text, set font size, add spans to paragraph, add paragraph to text flow
            span1.text = "Hello, ";
            span2.text = "World!";
            p.fontSize = 48;
            p.addChild(span1);
            p.addChild(span2);
            textFlow.addChild(p);
            // get next SpanElement for span1 and set its color to red; display text
            nextSpanElement = SpanElement(span1.getNextSibling());
            nextSpanElement.color = 0xCC0000;
            textFlow.flowComposer.addController(new ContainerController(this,stage.stageWidth,stage.stageHeight));
            textFlow.flowComposer.updateAllControllers(); 
        }
    }
}

이 요소와 연관된 ParagraphElement 객체를 반환합니다. 텍스트 흐름 계층 구조를 검색하여 첫 번째 ParagraphElement 객체를 반환합니다.

관련 API 요소