TextConverter - Adobe ActionScript® 3 (AS3 ) API 참조 설명서

패키지	flashx.textLayout.conversion
클래스	public class TextConverter
상속	TextConverter Object

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

가져오기 및 내보내기를 처리하기 위한 게이트웨이 클래스입니다. Text Layout Framework의 변환 기능에 대한 단일 액세스 포인트 역할을 합니다. 미리 정의되었거나 사용자가 정의한 입력 및/또는 출력 변환기의 레지스트리 및 변환 메서드 세트가 들어 있습니다.

변환된 데이터의 형식은 미리 정의되지 않습니다. 사용자가 작성한 변환기는 어떤 형식을 선택하든 자유롭게 사용하고 반환할 수 있습니다. 자주 사용되는 형식은 문자열, XML 및 ByteArray 인스턴스입니다. 변환기 작성자는 어떤 형식이 지원되는지 문서화해야 합니다.

예제 보기

기타 예제

Creating a TextFlow object with the TextConverter class

공용 속성

상속되는 공용 속성 숨기기

상속되는 공용 속성 표시

	속성		정의 주체
		constructor : Object 지정된 객체 인스턴스의 클래스 객체 또는 생성자 함수에 대한 참조입니다.	Object
		numFormats : int [정적] [읽기 전용] 형식 수입니다.	TextConverter

공용 메서드

상속되는 공용 메서드 숨기기

상속되는 공용 메서드 표시

	메서드		정의 주체
		addFormat(format:String, importerClass:Class, exporterClass:Class, clipboardFormat:String):void [정적] 새 가져오기/내보내기 형식을 등록합니다.	TextConverter
		addFormatAt(index:int, format:String, importerClass:Class, exporterClass:Class = null, clipboardFormat:String = null):void [정적] 지정된 위치에 새 가져오기/내보내기 형식을 등록합니다.	TextConverter
		export(source:flashx.textLayout.elements:TextFlow, format:String, conversionType:String):Object [정적] TextFlow를 지정된 형식으로 내보냅니다.	TextConverter
		getExporter(format:String):flashx.textLayout.conversion:ITextExporter [정적] 나중에 TextFlow에서 소스 문자열 또는 XML 객체로 내보낼 때 사용할 수 있는 내보내기 변환기를 생성하여 반환합니다.	TextConverter
		getFormatAt(index:int):String [정적] 인덱스 형식의 이름을 반환합니다.	TextConverter
		getFormatDescriptorAt(index:int):FormatDescriptor [정적] 인덱스 형식의 FormatDescriptor를 반환합니다.	TextConverter
		getImporter(format:String, config:IConfiguration = null):flashx.textLayout.conversion:ITextImporter [정적] 소스 문자열, XML 객체 또는 사용자 정의 데이터 형식에서 TextFlow로 가져올 때 사용할 수 있는 가져오기 변환기를 생성하여 변환합니다.	TextConverter
		hasOwnProperty(name:String):Boolean 지정된 속성이 객체에 정의되어 있는지 여부를 나타냅니다.	Object
		importToFlow(source:Object, format:String, config:IConfiguration = null):flashx.textLayout.elements:TextFlow [정적] 소스 내용에서 지정된 형식으로 TextFlow를 만듭니다.	TextConverter
		isPrototypeOf(theClass:Object):Boolean Object 클래스의 인스턴스가 매개 변수로 지정된 객체의 프로토타입 체인에 있는지 여부를 나타냅니다.	Object
		propertyIsEnumerable(name:String):Boolean 지정된 속성이 존재하고 열거 가능한지 여부를 나타냅니다.	Object
		removeFormat(format:String):void [정적] 형식을 제거합니다.	TextConverter
		removeFormatAt(index:int):void [정적] 인덱스 위치에서 형식을 제거합니다.	TextConverter
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 루프 작업에서 동적 속성을 사용할 수 있는지 여부를 설정합니다.	Object
		toLocaleString():String 로캘별 규칙에 따라 서식이 지정된 이 객체의 문자열 표현을 반환합니다.	Object
		toString():String 지정된 객체의 문자열 표현을 반환합니다.	Object
		valueOf():Object 지정된 객체의 프리미티브 값을 반환합니다.	Object

공용 상수

	상수		정의 주체
		PLAIN_TEXT_FORMAT : String = "plainTextFormat" [정적] 일반 텍스트 형식입니다.	TextConverter
		TEXT_FIELD_HTML_FORMAT : String = "textFieldHTMLFormat" [정적] HTML 형식입니다.	TextConverter
		TEXT_LAYOUT_FORMAT : String = "textLayoutFormat" [정적] TextLayout 형식입니다.	TextConverter

속성 세부 정보

numFormats

속성

numFormats:int [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

형식 수입니다.

구현
public static function get numFormats():int

메서드 세부 정보

addFormat

()

메서드

public static function addFormat(format:String, importerClass:Class, exporterClass:Class, clipboardFormat:String):void

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

새 가져오기/내보내기 형식을 등록합니다. 새 형식이 마지막에 가장 낮은 우선 순위로 추가됩니다. 외부 클립보드에서 가져오는 경우와 같이, 사용 형식에 대해 여러 옵션이 있는 클라이언트에는 위치가 중요할 수 있습니다. 새 형식이 가져오기 및/또는 내보내기를 지원할 수 있습니다. 이미 형식이 추가되었으면 여러 위치에 저장됩니다. 제일 먼저 발견되는 것을 사용합니다.

매개 변수

	`format:String` — 등록할 가져오기 변환기 클래스 또는 null입니다.

	`importerClass:Class` — 등록할 내보내기 변환기 클래스 또는 null입니다.

	`exporterClass:Class` — 변환기 클래스에 태그를 지정하는 형식 문자열입니다. 형식은 어떤 이름이든 될 수 있지만 고유해야 합니다.

	`clipboardFormat:String` — 클립보드에서 또는 클립보드로 변환할 때 클립보드 형식으로 사용되는 문자열입니다. 형식이 클립보드 액세스를 지원하지 않으면 null로 설정합니다.

addFormatAt

()

메서드

 public static function addFormatAt(index:int, format:String, importerClass:Class, exporterClass:Class = null, clipboardFormat:String = null):void

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

지정된 위치에 새 가져오기/내보내기 형식을 등록합니다. 외부 클립보드에서 가져오는 경우와 같이, 사용 형식에 대해 여러 옵션이 있는 클라이언트에는 위치가 중요할 수 있습니다. 숫자가 낮을수록 우선 순위가 높습니다. 숫자가 낮은 변환기를 먼저 시도합니다. 새 형식이 가져오기 및/또는 내보내기를 지원할 수 있습니다. 이미 형식이 추가되었으면 여러 위치에 저장됩니다. 제일 먼저 발견되는 것을 사용합니다.

매개 변수

	`index:int` — 등록할 가져오기 변환기 클래스 또는 null입니다.

	`format:String` — 등록할 내보내기 변환기 클래스 또는 null입니다.

	`importerClass:Class` — 변환기 클래스에 태그를 지정하는 형식 문자열입니다.

	`exporterClass:Class` (default = `null`) — 클립보드에서 또는 클립보드로 변환할 때 클립보드 형식으로 사용되는 문자열입니다. 형식이 클립보드 액세스를 지원하지 않으면 null로 설정합니다.

	`clipboardFormat:String` (default = `null`)

export

()

메서드

public static function export(source:flashx.textLayout.elements:TextFlow, format:String, conversionType:String):Object

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

TextFlow를 지정된 형식으로 내보냅니다.

사용자 정의 내보내기 도구가 format 매개 변수를 지정할 때 이 클래스로 제공되는 정적 상수 중 하나, MIME 유형 또는 사용자 정의 형식을 사용합니다.

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

ConversionType 클래스를 통해 제공되는 정적 상수 중 하나 또는 사용자 정의 내보내기 도구의 사용자 정의 데이터 유형을 사용하여 내보내는 데이터 형식을 conversionType 매개 변수에 지정합니다.

ConversionType.STRING_TYPE
ConversionType.XML_TYPE

TextFlow의 지정된 형식 표현을 반환하거나 오류 발생 시 null을 반환합니다.

매개 변수

	`source:flashx.textLayout.elements:TextFlow` — 소스 내용입니다.

	`format:String` — 출력 형식입니다.

	`conversionType:String` — 내보낸 데이터의 유형입니다.

반환값

Object — TextFlow에서 가져온 객체입니다.또는 오류 발생 시 null입니다.

getExporter

()

메서드

public static function getExporter(format:String):flashx.textLayout.conversion:ITextExporter

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

나중에 TextFlow에서 소스 문자열 또는 XML 객체로 내보낼 때 사용할 수 있는 내보내기 변환기를 생성하여 반환합니다. 수행할 별개의 내보내기가 많은 경우 이 함수를 사용합니다. flashx.textLayout.conversion.TextConverter.export()를 호출하는 것과 같습니다.

이 클래스와 함께 제공된 정적 상수 중 하나를 사용하여 format 매개 변수를 지정합니다.

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

형식이 여러 번 추가되면 처음 발견된 형식이 사용됩니다.

매개 변수

format:String — 내보낸 데이터의 대상 형식입니다.

반환값

flashx.textLayout.conversion:ITextExporter — 지정된 형식으로 내보낼 수 있는 ITextExporter 텍스트 변환기입니다.

예제 ( 예제 사용 방법 )

이 코드 단편은 getExporter 메서드를 사용하여 서식 있는 텍스트 내보내기를 반복적으로 수행하는 것을 보여 줍니다.


package flashx.textLayout.conversion.examples
{
    import flashx.textLayout.conversion.ConversionType;
    import flashx.textLayout.conversion.ITextExporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;
    
    public class getExporter_example 
    {
        // Serialize the TextFlow into a String
        public function export(textFlow:TextFlow):String
        {
            var exporter:ITextExporter = TextConverter.getExporter(TextConverter.TEXT_LAYOUT_FORMAT);
            return exporter.export(textFlow, ConversionType.STRING_TYPE) as String;
        }
    }
}

getFormatAt

()

메서드

public static function getFormatAt(index:int):String

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

인덱스 형식의 이름을 반환합니다.

매개 변수

index:int

반환값

String

getFormatDescriptorAt

()

메서드

public static function getFormatDescriptorAt(index:int):FormatDescriptor

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

인덱스 형식의 FormatDescriptor를 반환합니다.

매개 변수

index:int

반환값

FormatDescriptor

getImporter

()

메서드

 public static function getImporter(format:String, config:IConfiguration = null):flashx.textLayout.conversion:ITextImporter

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

소스 문자열, XML 객체 또는 사용자 정의 데이터 형식에서 TextFlow로 가져올 때 사용할 수 있는 가져오기 변환기를 생성하여 변환합니다. 별도의 가져오기를 많이 수행해야 하거나 가져오기 동안 오류를 처리하려면 이 메서드를 사용합니다. flashx.textLayout.conversion.TextConverter.importToFlow()를 호출하는 것과 같습니다.

이 클래스를 통해 제공되는 정적 상수 중 하나를 사용하여 format 매개 변수, MIME 유형 또는 사용자 정의 데이터 형식을 지정합니다.

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

형식이 여러 번 추가되면 처음 발견된 형식이 사용됩니다.

매개 변수

	`format:String` — 소스 내용의 형식입니다. flashx.textLayout.conversion.TextConverter.TEXT_LAYOUT_FORMAT, PLAIN_TEXT_FORMAT, TEXT_FIELD_HTML_FORMAT 등의 상수, MIME 유형 또는 사용자 정의 형식을 사용합니다.

	`config:IConfiguration` (default = `null`) — 이 가져오기 동안 사용할 구성입니다. null은 현재 기본값을 사용함을 의미합니다. `ITextImporter.configuration` 속성을 사용하여 구성을 설정할 수도 있습니다.

반환값

flashx.textLayout.conversion:ITextImporter — 소스 데이터를 가져올 수 있는 ITextImporter 텍스트 가져오기 도구입니다.

예제 ( 예제 사용 방법 )

이 코드 단편은 getImporter 메서드를 사용하여 서식 있는 텍스트 가져오기를 반복적으로 수행하는 것을 보여 줍니다. 각각의 importToFlow 호출 시작 부분에서 오류가 제거되는 것에 유의합니다.


package flashx.textLayout.conversion.examples
{
    import flashx.textLayout.conversion.ITextImporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;
    
    public class getImporter_example 
    {
        public function importAndCheckErrors():TextFlow
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'><p><span>Hello, World</span></p></TextFlow>";
            var importer:ITextImporter = TextConverter.getImporter(TextConverter.TEXT_LAYOUT_FORMAT);
            importer.throwOnError = false;
            var textFlow:TextFlow = importer.importToFlow(markup);
            if (!textFlow)
            {
                var errors:Vector.<String> = importer.errors;
                //deal with import errors
            }
            return textFlow;
        }
    }
}

importToFlow

()

메서드

 public static function importToFlow(source:Object, format:String, config:IConfiguration = null):flashx.textLayout.elements:TextFlow

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

소스 내용에서 지정된 형식으로 TextFlow를 만듭니다.

이 클래스를 통해 제공되는 정적 상수 중 하나 또는 MIME 유형을 사용하여 format 매개 변수를 지정하거나 사용자가 등록한 가져오기 도구의 경우 사용자 정의 값을 사용합니다.

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

매개 변수

	`source:Object` — 소스 내용입니다.

	`format:String` — 소스 내용의 형식입니다.

	`config:IConfiguration` (default = `null`) — 새 TextFlow를 만들 때 사용할 IConfiguration입니다.

반환값

flashx.textLayout.elements:TextFlow — 소스에서 생성된 TextFlow 또는 오류 발생 시 null입니다.

removeFormat

()

메서드

public static function removeFormat(format:String):void

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

형식을 제거합니다. 형식이 여러 번 추가되면 제일 처음 발견된 형식만 제거됩니다.

매개 변수

format:String — 제거할 변환기 형식 문자열입니다.

removeFormatAt

()

메서드

public static function removeFormatAt(index:int):void

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

인덱스 위치에서 형식을 제거합니다.

매개 변수

index:int — 제거할 형식입니다.

상수 세부 정보

PLAIN_TEXT_FORMAT

상수

public static const PLAIN_TEXT_FORMAT:String = "plainTextFormat"

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

일반 텍스트 형식입니다. 간단한 서식 없는 문자열에서 TextFlow를 만들거나 TextFlow에서 간단한 서식 없는 문자열을 만들 때 사용합니다.

TEXT_FIELD_HTML_FORMAT

상수

public static const TEXT_FIELD_HTML_FORMAT:String = "textFieldHTMLFormat"

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

HTML 형식입니다. HTML 형식을 사용하여 TextFlow에서 가져오거나 TextFlow로 내보낼 때 사용합니다. Text Layout Framework HTML은 flash.text 패키지의 TextField 클래스에서 지원하는 태그 및 특성 중 일부를 지원합니다.

다음 표에는 가져오기 및 내보내기 프로세스에 대해 지원되는 HTML 태그와 특성이 나와 있습니다. TextField에서는 지원하지만 Text Layout Framework에서는 지원하지 않는 태그와 특성은 지원되지 않는 것으로 설명되어 있습니다.

태그	설명
앵커 태그	`<a>` 태그는 하이퍼링크를 만들며 다음 특성을 지원합니다. `target`: 페이지를 로드할 대상 윈도우의 이름을 지정합니다. 사용 가능한 옵션에는 `_self`, `_blank`, `_parent` 및 `_top` 등이 있습니다. `_self` 옵션은 현재 윈도우의 현재 프레임을 지정하고, `_blank`는 새로운 윈도우를 지정하고, `_parent`는 현재 프레임의 부모를 지정하고, `_top`은 현재 윈도우의 최상위 프레임을 지정합니다. `href`: URL을 지정합니다. URL은 절대 주소이거나, 페이지를 로드하는 SWF 파일 위치를 기준으로 한 상대 주소일 수 있습니다. URL에 대한 절대 참조의 예제로는 `http://www.adobe.com`을, 상대 참조의 예제로`/index.html`을 들 수 있습니다. 절대 URL 앞에는 http:// 접두어가 있어야 합니다. 그렇지 않으면 해당 URL이 상대 URL로 간주됩니다. 참고: TextField 클래스와 달리, ActionScript `link` 이벤트는 지원되지 않습니다. `a:link`, `a:hover` 및 `a:active` 스타일도 지원되지 않습니다.
굵게 태그	`<b>` 태그는 텍스트를 굵은 글꼴로 렌더링합니다. 이때 사용된 글꼴이 굵은 글꼴을 지원해야 합니다.
행 분리 태그	`<br>` 태그는 텍스트에서 줄을 바꿉니다.
글꼴 태그	`<font>` 태그는 텍스트를 표시할 글꼴 또는 글꼴 목록을 지정합니다. 지원되는 특성은 다음과 같습니다. `color`: 16진수 색상(`#FFFFFF`) 값만 지원됩니다. `face`: 사용할 글꼴의 이름을 지정합니다. 다음 예제와 같이 글꼴 이름 목록을 쉼표로 구분하여 지정할 수도 있습니다. 이 경우 Flash Player에서는 사용 가능한 첫 번째 글꼴이 선택됩니다. 지정된 글꼴이 로컬 컴퓨터 시스템에 설치되어 있지 않거나 SWF에 포함되어 있지 않으면 Flash Player에서 대체 글꼴이 선택됩니다. `size`: 글꼴의 크기를 지정합니다. 16 또는 18과 같이 절대 픽셀 크기를 사용할 수도 있고, +2 또는 -4와 같이 상대 포인트 크기를 사용할 수도 있습니다. `letterspacing`: 각 문자의 오른쪽에 적용할 자간(수동 커닝)을 픽셀 단위로 지정합니다. `kerning`: 커닝이 활성화되는지 아니면 비활성화되는지를 지정합니다. 0이 아닌 값을 사용하면 커닝이 활성화되고, 0을 사용하면 비활성화됩니다.
이미지 태그	`<img>` 태그를 사용하면 외부 이미지 파일(JPEG, GIF, PNG), SWF 파일 및 동영상 클립을 텍스트 내에 포함할 수 있습니다. `<img>` 태그는 다음 특성을 지원합니다. `src`: 이미지나 SWF 파일에 대한 URL 또는 라이브러리의 동영상 클립 심볼에 대한 링크 식별자를 지정합니다. 이 특성은 필수이며, 그 외의 다른 특성은 선택 사항입니다. 외부 파일(JPEG, GIF, PNG 및 SWF 파일)은 완전히 다운로드될 때까지 표시되지 않습니다. `width`: 삽입할 이미지, SWF 파일 또는 동영상 클립의 폭(픽셀 단위)입니다. `height`: 삽입할 이미지, SWF 파일 또는 동영상 클립의 높이(픽셀 단위)입니다. 참고: TextField 클래스와 달리, `align`, `hspace`, `vspace`, `id` 및 `checkPolicyFile` 특성은 지원되지 않습니다.
기울임체 태그	`<i>` 태그는 대상 텍스트를 기울임체로 표시합니다. 이때 사용된 글꼴이 기울임체를 지원해야 합니다.
목록 항목 태그	참고: TextField 클래스와 달리, 목록 항목 태그는 지원되지 않습니다.
단락 태그	`<p>` 태그는 새로운 단락을 만듭니다. `<p>` 태그는 다음 특성을 지원합니다. align: 단락 내에서 텍스트 정렬 방법을 지정합니다. `left`, `right`, `justify` 및 `center` 값을 사용할 수 있습니다. class: 스타일 지정에 사용할 수 있는 클래스 이름을 지정합니다.
span 태그	`<span>` 태그는 다음 특성을 지원합니다. class: 스타일 지정에 사용할 수 있는 클래스 이름을 지정합니다. span 태그는 스타일 시트에 정의된 스타일을 설정하는 데 사용되는 경우가 많지만 TLFTextField 인스턴스는 스타일 시트를 지원하지 않습니다. span 태그를 TLFTextField 인스턴스에 사용하여 스타일 속성이 있는 클래스를 참조할 수 있습니다. 또는 `<span fontFamily="Arial">Hi there</span>`와 같이 속성을 직접 span 태그에 넣을 수도 있습니다. 그러나 중첩된 span 태그는 지원되지 않습니다.
텍스트 서식 태그	`<textformat>` 태그를 사용하면 행간, 들여쓰기, 여백, 탭 위치 등 TextFormat 클래스의 단락 서식 속성 하위 집합을 텍스트 필드 내에서 사용할 수 있습니다. `<textformat>` 태그는 내장된 HTML 태그와 함께 사용할 수 있습니다. `<textformat>` 태그에는 다음과 같은 특성이 있습니다. `indent`: 왼쪽 여백에서 단락의 첫 글자 사이의 들여쓰기를 지정하며 `TextFormat.indent`에 해당합니다. 양수와 음수를 모두 사용할 수 있습니다. `blockindent`: 단락의 모든 줄에 적용하는 들여쓰기를 지정합니다. `leftmargin`: 단락의 왼쪽 여백을 포인트 단위로 지정하며 `TextFormat.leftMargin`에 해당합니다. `rightmargin`: 단락의 오른쪽 여백을 포인트 단위로 지정하며 `TextFormat.rightMargin`에 해당합니다. `leading`: 이전 줄의 디센트와 현재 줄의 어센트 간의 행간(줄 높이)을 픽셀 단위로 지정합니다. `tabstops`: 단락의 탭 정지 위치 목록을 쉼표로 구분하여 지정합니다.
밑줄 태그	`<u>` 태그는 대상 텍스트에 밑줄을 긋습니다.

가져온 태그가 알 수 없는 태그인 경우 textFieldHTMLFormat 가져오기 도구는 단일 FlowElement의 typeName 속성을 해당 태그 이름으로 설정하거나 typeName 속성을 태그 이름으로 설정한 상태로 DivElement 또는 SubParagraphGroupElement를 만듭니다.

기본값과 다르면 textFieldHTMLFormat 내보내기 도구가 typeName을 XML 태그로 내보냅니다.

TEXT_LAYOUT_FORMAT

상수

public static const TEXT_LAYOUT_FORMAT:String = "textLayoutFormat"

언어 버전:

ActionScript 3.0

런타임 버전:

Flash Player 10, AIR 1.5

TextLayout 형식입니다. TextLayout 마크업 형식을 사용하여 TextFlow에서 가져오거나 TextFlow로 내보낼 때 사용합니다. 텍스트 레이아웃 형식은 다음 오류를 감지합니다.

예상치 못한 네임스페이스
알 수 없는 요소
알 수 없는 속성

예제 예제 사용 방법

TextConverter_example.as

다음 예제에서는 TextConverter 변환 클래스의 사용 방법을 보여 줍니다. 표준 마크업 형식의 텍스트를 TextFlow 객체로 가져온 후 표시합니다. 그런 다음 텍스트를 XML 형식으로 내보냅니다.

package flashx.textLayout.conversion.examples 
{
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.conversion.ConversionType;

    public class TextConverter_example extends Sprite
    {
        public function TextConverter_example()
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'><p><span>Hello, World</span></p></TextFlow>";
            var textFlow:TextFlow = TextConverter.importToFlow(markup, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this, 200, 50));
            textFlow.flowComposer.updateAllControllers();
            //export to XML
            var xmlOut:XML = TextConverter.export(textFlow,TextConverter.TEXT_LAYOUT_FORMAT, ConversionType.XML_TYPE) as XML;
        }
    }
}

법적 고지 사항 | 온라인 개인 정보 보호 정책

TextConverter - AS3

클래스 x

numFormats

addFormat

addFormatAt

export

getExporter

getFormatAt

getFormatDescriptorAt

getImporter

importToFlow

removeFormat

removeFormatAt

PLAIN_TEXT_FORMAT

TEXT_FIELD_HTML_FORMAT

TEXT_LAYOUT_FORMAT