SharedObject  - AS3

콜백 메서드가 호출되는 객체를 나타냅니다. 기본 객체는 this입니다. client 속성을 다른 객체로 설정하여, 이 객체에서 콜백 메서드를 호출할 수도 있습니다.

객체의 data 속성에 할당된 특성 모음입니다. 이러한 특성은 공유 및 저장이 가능합니다. 각 특성은 Array, Number, Boolean, ByteArray, XML 등 어떤 ActionScript 또는 JavaScript 유형의 객체도 될 수 있습니다. 예를 들어 다음 예제는 공유 객체의 다양한 속성에 값을 지정합니다.

     var items_array:Array = new Array(101, 346, 483);
     var currentUserIsAdmin:Boolean = true;
     var currentUserName:String = "Ramona";
     
     var my_so:SharedObject = SharedObject.getLocal("superfoo");
     my_so.data.itemNumbers = items_array;
     my_so.data.adminPrivileges = currentUserIsAdmin;
     my_so.data.userName = currentUserName;
     
     for (var prop in my_so.data) {
       trace(prop+": "+my_so.data[prop]);
     }
     

공유 객체가 영구적이면 data 속성의 모든 특성이 저장되고, 이 공유 객체에는 다음 정보가 포함됩니다.

     userName: Ramona
     adminPrivileges: true
     itemNumbers: 101,346,483
     

참고: 공유 객체의 data 속성에 직접 값을 할당하지 마십시오(예: so.data = someValue). 이러한 할당은 무시됩니다.

로컬 공유 객체의 특성을 삭제하려면 delete so.data.attributeName과 같은 코드를 사용합니다. 로컬 공유 객체의 특성을 null 또는 undefined로 설정해도 특성이 삭제되지는 않습니다.

공유 객체에 대하여 전용 값, 즉 객체가 사용 중인 동안 클라이언트 인스턴스에만 사용할 수 있으며 객체가 닫힐 때 객체와 함께 저장되지 않는 값을 작성하려면 다음 예제와 같이 값을 저장할 속성을 작성할 때 data라는 이름을 붙이지 않습니다.

     var my_so:SharedObject = SharedObject.getLocal("superfoo");
     my_so.favoriteColor = "blue";
     my_so.favoriteNightClub = "The Bluenote Tavern";
     my_so.favoriteSong = "My World is Blue";
     
     for (var prop in my_so) {
       trace(prop+": "+my_so[prop]);
     }
     

공유 객체에는 다음 데이터가 포함됩니다.

     favoriteSong: My World is Blue
     favoriteNightClub: The Bluenote Tavern
     favoriteColor: blue
     data: [object Object]
     

서버와 함께 사용된 원격 공유 객체의 경우 data 속성의 모든 특성을 공유 객체에 연결된 모든 클라이언트가 사용할 수 있습니다. 객체가 영구적일 경우 모든 특성은 저장됩니다. 한 클라이언트가 특성 값을 변경하면 모든 클라이언트는 새로운 값을 보게 됩니다.

관련 API 요소

SWF 파일에서 만들어진 모든 로컬 공유 객체에 대한 기본 객체 인코딩(AMF 버전)입니다. 로컬 공유 객체가 디스크에 기록될 때 SharedObject.defaultObjectEncoding 속성은 ActionScript 3.0 형식(AMF3) 또는 ActionScript 1.0이나 2.0 형식(AMF0) 중 어떤 Action Message Format 버전을 사용해야 할지를 나타냅니다.

로컬 및 원격 공유 객체 인코딩의 차이점을 비롯하여 객체 인코딩에 대한 자세한 내용은 objectEncoding 속성의 설명을 참조하십시오.

SharedObject.defaultObjectEncoding의 기본값은 ActionScript 3.0 형식인 AMF3을 사용하는 것으로 설정됩니다. ActionScript 2.0이나 1.0 SWF 파일에서 읽을 수 있는 로컬 공유 객체를 써야 할 경우, 로컬 공유 객체를 만들기 전에 스크립트 시작 부분에서 SharedObject.defaultObjectEncoding을 flash.net.ObjectEncoding.AMF0으로 설정하여 ActionScript 1.0 또는 ActionScript 2.0 형식을 사용하게 합니다. 이후로 만들어지는 모든 로컬 공유 객체는 AMF0 인코딩을 사용하며 기존의 컨텐츠와 상호 작용할 수 있습니다. 로컬 공유 객체가 만들어진 후에는 SharedObject.defaultObjectEncoding을 설정하여 기존 로컬 공유 객체의 objectEncoding 값을 변경할 수 없습니다.

SWF 파일에서 만들어진 모든 공유 객체를 대상으로 하지 않고 객체별로 객체 인코딩을 설정하려면 로컬 공유 객체의 objectEncoding 속성을 대신 설정합니다.

관련 API 요소

공유 객체에 대한 클라이언트의 변경이 서버로 전송되는 초당 횟수를 지정합니다.

클라이언트와 서버 간의 트래픽 양을 제어하고 싶을 때 이 메서드를 사용합니다. 예를 들어 클라이언트와 서버 간의 연결이 상대적으로 느리다면 fps를 상대적으로 낮은 값으로 설정할 수 있습니다. 반대로 시간이 중요한 다중 사용자 응용 프로그램에 클라이언트가 연결된 경우 fps를 상대적으로 높은 값으로 설정할 수도 있습니다.

fps를 설정하면 sync 이벤트가 트리거되고 모든 변경 사항이 서버에 업데이트됩니다. 서버를 수동으로만 업데이트하려면 fps를 0으로 설정합니다.

sync 이벤트가 전달될 때까지는 변경 사항이 서버로 전송되지 않습니다. 즉 서버의 응답 시간이 느리다면 이 속성에서 지정된 값보다 더 적은 빈도로 서버에 업데이트가 전송될 수 있습니다.

이 공유 객체의 객체 인코딩(AMF 버전)입니다. 로컬 공유 객체가 디스크에 기록될 때 objectEncoding 속성은 ActionScript 3.0 형식(AMF3) 또는 ActionScript 1.0이나 2.0 형식(AMF0) 중 어떤 Action Message Format 버전을 사용해야 할지를 나타냅니다.

객체 인코딩은 해당 공유 객체가 로컬 객체인지 원격 객체인지에 따라 다르게 처리됩니다.

• 로컬 공유 객체. 로컬 공유 객체의 objectEncoding 속성 값을 가져오거나 설정할 수 있습니다. objectEncoding 값은 이 로컬 공유 객체 쓰기에서 어떤 형식이 사용되는가에 영향을 줍니다. 이 로컬 공유 객체를 ActionScript 2.0 또는 1.0 SWF 파일에서 읽을 수 있어야 한다면 objectEncoding을 ObjectEncoding.AMF0으로 설정합니다. 객체 인코딩이 AMF3을 쓰도록 설정되었더라도 Flash Player는 AMF0 로컬 공유 객체를 읽을 수 있습니다. 즉, 이 속성의 기본값 ObjectEncoding.AMF3을 사용할 경우에도 SWF 파일은 ActionScript 2.0 또는 1.0 SWF 파일에서 만들어진 공유 객체를 읽을 수 있습니다.
• 원격 공유 객체. 서버와 연결되었을 때, 원격 공유 객체는 연관된 NetConnection 인스턴스(원격 공유 객체 연결에 사용된 인스턴스)로부터 objectEncoding 설정을 상속합니다. 서버에 연결되지 않았으면 원격 공유 객체는 연관된 NetConnection 인스턴스로부터 defaultObjectEncoding 설정을 상속합니다. 원격 공유 객체의 objectEncoding 속성 값이 NetConnection 인스턴스에 의해 결정되므로, 이 속성은 원격 공유 객체에게 읽기 전용입니다.

관련 API 요소

로컬 공유 객체를 iOS 클라우드 백업 서비스에 백업할지 여부를 지정합니다.

true 또는 false를 지정합니다.

• true - 모든 로컬 공유 객체를 iOS 백업 클라우드 서비스에 백업하지 못하도록 차단합니다.
• false(기본값) - 로컬 공유 객체를 iOS 백업 클라우드 서비스에 백업할 수 있습니다.

이 속성은 로컬 공유 객체에만 적용되며 iOS인 경우에만 적용됩니다.

공유 객체의 현재 크기(바이트)입니다.

Flash는 공유 객체의 모든 데이터 속성을 조사하여 객체의 크기를 계산합니다. 객체의 데이터 속성이 많을수록 크기를 계산하는 데 시간이 더 오래 걸립니다. 객체 크기를 계산하는 데 상당한 시간이 걸릴 수 있으므로 반드시 필요한 경우가 아니면 이 메서드를 사용하지 않는 것이 좋습니다.

import flash.net.SharedObject;

// if these get copied or not
var mySo:SharedObject = SharedObject.getLocal("thehobbit");
mySo.data.username = "bilbobaggins";
trace(mySo.size); // 55

로컬 공유 객체의 경우, 모든 데이터를 제거하고 디스크에서 공유 객체를 삭제합니다. 공유 객체에 대한 참조는 여전히 활성 상태이지만, 그 데이터 속성은 삭제됩니다.

Flash Media Server와 함께 사용된 원격 공유 객체의 경우 clear()가 객체의 연결을 끊고 모든 데이터를 삭제합니다. 공유 객체가 로컬에 영구적으로 존재하는 경우, 이 메서드가 디스크에서 공유 객체도 삭제합니다. 공유 객체에 대한 참조는 여전히 활성 상태이지만, 그 데이터 속성은 삭제됩니다.

package {
    import flash.net.SharedObject;

    public class SharedObject_clear {
        private var hostName:String = "yourDomain";
        private var username:String = "yourUsername";

        public function SharedObject_clear() {
            var mySo:SharedObject = SharedObject.getLocal(hostName);
            if(mySo.data.username == null) {
                mySo.data.username = username;
                trace("set: " + mySo.data.username); // yourUsername
            }
            else {
                mySo.clear();
                trace("cleared: " + mySo.data.username); // undefined
            }
        }
    }
}

원격 공유 객체와 서버 간의 연결을 종료합니다. 원격 공유 객체가 로컬에 영구 저장 중이면 사용자는 이 메서드 호출 후 객체의 로컬 복사본을 변경할 수 있습니다. 다음에 사용자가 원격 공유 객체에 연결하면 로컬 객체의 변경 사항이 서버로 전송됩니다.

지정된 NetConnection 객체를 통해 서버의 원격 공유 객체에 연결합니다. 이 메서드를 사용하기 전에 getRemote()를 호출합니다. 연결이 성공적으로 이루어지면 sync 이벤트가 전달됩니다.

원격 공유 객체와의 작업을 시도하기 전에 먼저 오류를 점검하기 위해 try..catch..finally 문을 사용합니다. 그런 다음 sync 이벤트를 확인해서 처리하고 공유 객체를 변경합니다. 로컬에서 이루어진 변경 내용— sync 이벤트가 전달되기 전 —은 사라집니다.

connect() 메서드를 호출해서 원격 공유 객체로 연결합니다. 예:

     var myRemoteSO:SharedObject = SharedObject.getRemote("mo", myNC.uri, false);
     myRemoteSO.connect(myNC);
     

매개 변수

관련 API 요소

로컬 영구 공유 객체를 로컬 파일에 즉시 기록합니다. 이 메서드를 사용하지 않으면 공유 객체는 공유 객체 세션이 끝날 때 즉, SWF 파일이 닫힐 때, 공유 객체에 대한 참조가 존재하지 않아 가비지 수집 작업에 의해 메모리에서 제거될 때 또는 SharedObject.clear()나 SharedObject.close()를 호출할 때 파일에 기록됩니다.

이 메서드가 SharedObjectFlushStatus.PENDING을 반환하면, Flash Player는 현재 도메인에서 객체가 사용할 수 있는 디스크 공간을 늘릴 것인지 묻는 대화 상자를 표시합니다. 나중에 공유 객체를 저장할 때 공간을 늘릴 수 있도록 허용하여 PENDING 값이 반환되지 않게 하려면 minDiskSpace에 값을 전달합니다. Flash Player는 파일을 기록할 때 현재 크기에서 공유 객체를 저장하기에 충분한 공간을 찾는 대신 minDiskSpace에 전달된 바이트 수만큼의 공간을 찾습니다.

예를 들어 공유 객체의 크기가 최대 500바이트까지 늘어날 것으로 예상된다면, 훨씬 작은 크기로 시작하더라도 minDiskSpace의 값으로 500을 전달합니다. Flash는 공유 객체를 위한 디스크 공간을 할당할 것을 요구할 때 500바이트를 요구하게 됩니다. 필요한 만큼의 공간이 할당되면 나중에 객체를 저장할 때 크기가 500바이트를 넘지 않는 한 추가로 공간을 요구하지 않습니다.

사용자가 대화 상자에 응답한 다음 이 메서드가 다시 호출됩니다. netStatus 이벤트가 SharedObject.Flush.Success 또는 SharedObject.Flush.Failed의 code 속성과 함께 전달됩니다.

매개 변수

관련 API 요소

package {
    import flash.net.SharedObject;

    public class SharedObject_flush {
        private var hostName:String = "yourDomain";
        private var username:String = "yourUsername";

        public function SharedObject_flush() {
            var mySo:SharedObject = SharedObject.getLocal(hostName);
            mySo.data.username = username;
            var flushResult:Object = mySo.flush();
            trace("flushResult: " + flushResult);
            trace(mySo.data.username); // yourUsername
        }
    }
}

현재 클라이언트에만 사용 가능한 로컬 영구 공유 객체에 대한 참조를 반환합니다. 공유 객체가 없으면 이 메서드가 만듭니다. getLocal()로 전달된 값이 잘못되었거나 호출이 실패할 경우 Flash Player에서는 예외가 발생합니다.

다음 코드는 반환된 공유 객체 참조를 변수에 할당하는 방법을 보여 줍니다.

var so:SharedObject = SharedObject.getLocal("savedData");

참고: 사용자가 이 도메인의 로컬 저장을 허용하지 않기로 선택한 경우 localPath의 값이 지정되더라도 객체는 로컬에 저장되지 않습니다. 로컬 내용에는 이 규칙이 적용되지 않습니다. 로컬 내용은 타사 공유 객체를 디스크에 쓰는 것이 허용되지 않는 경우를 포함하여 항상 타사 공유 객체(현재 브라우저 주소 막대에 있는 도메인 이외의 도메인)를 디스크에 쓸 수 있습니다.

이름 충돌을 피하기 위해 Flash는 공유 객체를 생성하는 SWF 파일의 위치를 찾습니다. 예를 들어 www.myCompany.com/apps/stockwatcher.swf에 있는 SWF 파일이 portfolio라는 공유 객체를 작성하는 경우, 이 공유 객체의 이름은 www.yourCompany.com/photoshoot.swf에 있는 SWF 파일에서 만든 portfolio라는 또 다른 객체와 이름 충돌을 일으키지 않습니다. 그 이유는 두 SWF 파일의 시작 디렉토리가 다르기 때문입니다.

localPath 매개 변수가 선택 사항이기는 하지만 특히 다른 SWF 파일에서 공유 객체에 액세스해야 할 경우에는 이 매개 변수의 사용을 고려해야 합니다. 공유 객체의 데이터가 다른 위치로 이동되지 않을 특정 SWF 파일과 관련된 경우에는 기본값을 사용하는 것이 적합합니다. 다른 SWF 파일이 공유 객체에 액세스해야 하거나 공유 객체를 만드는 SWF 파일이 나중에 이동될 경우, 이 매개 변수의 값은 공유 객체에 액세스하는 방법에 영향을 줍니다. 예를 들어 localPath가 SWF 파일 전체 경로의 기본값으로 설정된 상태에서 공유 객체를 만들 경우, 다른 어떤 SWF 파일도 해당 공유 객체에 액세스할 수 없습니다. 나중에 원래의 SWF 파일을 다른 위치로 이동하면 그 SWF 파일 역시 공유 객체에 이미 저장된 데이터에 액세스할 수 없습니다.

실수로 공유 객체 액세스를 제한하는 것을 방지하려면 localpath 매개 변수를 사용합니다. 가장 허용적인 방법은 localPath를 /(슬래시)로 설정하는 것입니다. 이렇게 하면 도메인의 모든 SWF 파일에서 공유 객체를 사용할 수 있지만 도메인의 다른 공유 객체와 이름이 충돌할 가능성이 커집니다. 더 제한적인 방법은 localPath에 SWF 파일 전체 경로에 있는 폴더 이름을 추가하는 것입니다. 예를 들어 www.myCompany.com/apps/stockwatcher.swf에 있는 SWF 파일이 생성한 portfolio 공유 객체의 경우 localPath 매개 변수를 /, /apps 또는 /apps/stockwatcher.swf로 설정할 수 있습니다. 해당 응용 프로그램에서 어떤 방법이 최적의 유연성을 발휘할 것인지 판단해야 합니다.

이 메서드를 사용할 경우 다음과 같은 보안 모델을 생각해 볼 수 있습니다.

• 샌드박스 경계를 넘어 공유 객체에 액세스할 수 없습니다.
• 사용자는 Flash Player [설정] 대화 상자 또는 설정 관리자를 사용하여 공유 객체 액세스를 제한할 수 있습니다. 기본적으로 응용 프로그램에서는 도메인당 최대 100KB의 데이터로 공유 객체를 만들 수 있습니다. 관리자 및 사용자 역시 파일 시스템 쓰기 권한을 제한할 수 있습니다.

로컬 파일로 재생할 SWF 파일 컨텐츠(로컬에 설치되는 SWF 파일 또는 EXE 파일)를 제작하고 둘 이상의 로컬 SWF 파일로부터 특정 공유 객체에 액세스해야 한다고 가정합니다. 이 경우 로컬 파일에 대해서는 서로 다른 두 위치가 공유 객체 저장에 사용될 수 있습니다. 사용되는 도메인은 공유 객체를 만든 로컬 파일에 부여된 보안 권한에 따라 달라집니다. 로컬 파일에는 다음과 같은 세 가지 수준의 권한이 있습니다.

1. 로컬 파일 시스템에만 액세스합니다.
2. 네트워크에만 액세스합니다.
3. 네트워크와 로컬 파일 시스템 모두에 액세스합니다.

로컬 파일 시스템에 액세스할 수 있는(레벨 1 또는 3) 로컬 파일은 한 위치에 공유 객체를 저장합니다. 로컬 파일 시스템에 대한 액세스 권한이 없는(레벨 2) 로컬 파일은 다른 위치에 공유 객체를 저장합니다.

SWF 내용이 들어 있는 HTML 페이지에서 allowNetworking 매개 변수(object 및 embed 태그)를 설정하여 SWF 파일에서 이 메서드를 사용하지 않게 할 수 있습니다.

자세한 내용은 Flash Player 개발자 센터 항목(보안)을 참조하십시오.

매개 변수

  ~ % & \ ; : " ' , < > ? # 
  

다수의 클라이언트가 액세스할 수 있는 Flash Media Server의 공유 객체로 참조를 반환합니다. 원격 공유 객체가 없으면 이 메서드가 만듭니다.

원격 공유 객체를 만들려면 원격 공유 객체를 서버에 연결하기 위한 getRemote() 와 connect()를 호출합니다.

     var nc:NetConnection = new NetConnection();
     nc.connect("rtmp://somedomain.com/applicationName");
     var myRemoteSO:SharedObject = SharedObject.getRemote("mo", nc.uri, false);
     myRemoteSO.connect(nc);
     

로컬 및 원격 공유 객체 복사본이 동기화되었는지 확인하려면 sync 이벤트에 주의를 기울여 처리합니다. 이 객체를 공유하려고 하는 모든 클라이언트는 name 및 remotePath 매개 변수에 동일한 값을 전달해야 합니다.

현재 클라이언트에서만 사용할 수 있는 공유 객체를 만들려면 SharedObject.getLocal()을 사용합니다.

매개 변수

    ~ % & \ ; :  " ' , > ? ? #

관련 API 요소

메시지를 보낸 클라이언트를 포함해 원격 공유 객체에 연결된 모든 클라이언트로 메시지를 브로드캐스트합니다. 이 메시지를 처리하고 응답하려면 공유 객체에 첨부된 콜백 함수를 만듭니다.

매개 변수

공유 객체의 속성 값이 변경되었음을 서버에 알립니다. 이 메서드는 속성을 dirty로 표시, 즉 변경된 것으로 표시합니다.

SharedObject.setProperty()를 호출해 공유 객체를 위한 속성을 생성합니다.

SharedObject.setProperty() 메서드는 setDirty()를 구현합니다. 속성 값이 String이나 Number 같은 프리미티브 유형일 때처럼 대부분의 경우setProperty()를 setDirty() 대신 호출할 수 있습니다. 그러나 속성 값이 고유의 속성을 포함하는 객체인 경우에는 해당 객체의 값이 변경되었을 때 setDirty()를 호출하여 알릴 수 있습니다.

매개 변수

관련 API 요소

공유 객체의 속성 값을 업데이트하고 해당 속성 값이 변경되었음을 서버에 알립니다. setProperty() 메서드는 속성을 변경된 것(dirty)으로 표시합니다.

원격 공유 객체에 대한 자세한 내용은 Flash Media Server 설명서를 참조하십시오.

참고: SharedObject.setProperty() 메서드는 setDirty() 메서드를 구현합니다. 속성 값이 String, Number와 같은 프리미티브 유형일 때처럼 대부분의 경우 setDirty 대신 setProperty()를 사용합니다. 그러나 속성 값이 고유의 속성을 포함하는 객체인 경우에는 해당 객체의 값이 변경되었을 때 setDirty()를 사용하여 알릴 수 있습니다. 일반적으로 setDirty()보다는 setProperty()를 호출하는 것이 좋습니다. setProperty()는 값이 변경된 경우에만 속성 값을 업데이트하지만 setDirty()는 모든 구독 클라이언트에서 동기화를 수행하기 때문입니다.

매개 변수

관련 API 요소

기본 비동기 코드에서 비동기적으로 예외가 발생할 때 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

SharedObject 인스턴스가 상태 또는 오류 상황을 보고할 때 전달됩니다. netStatus 이벤트에는 연결 시도의 성공 여부 또는 공유 객체가 로컬 디스크에 성공적으로 쓰여졌는지 여부와 같이 이벤트에 대한 특정 정보가 포함된 정보 객체인 info 속성이 포함되어 있습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

서버에서 원격 공유 객체를 업데이트하면 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소