XMLSocket  - AS3

この XMLSocket オブジェクトが現在、接続されているかどうかを示します。connect イベントと ioError イベントに対して登録を行い、接続が成功したかどうかを調べることもできます。

関連する API エレメント

接続までの待ち時間（ミリ秒数）を示します。

指定した時間内に接続できなかったときは、接続が失敗することになります。デフォルト値は 20,000 (20 秒) です。

新しい XMLSocket オブジェクトを作成します。 パラメーターを指定しないと、初期状態では未接続のソケットが作成されます。パラメーターを指定すると、指定したホストおよびポートへの接続が試行されます。

注意：パラメーターを指定せずにコンストラクターフォームを使用し、さらにいずれかのイベントリスナーを追加し、connect メソッドを呼び出すことを強く推奨します（ホストおよびポートをパラメーターに指定する）。このシーケンスによって、すべてのイベントリスナーが正しく動作するようになります。

関連する API エレメント

XMLSocket オブジェクトで指定された接続を閉じます。close イベントは、サーバーにより接続が閉じられたときのみ送出されます。close() メソッドを呼び出しても送出されません。

関連する API エレメント

指定された TCP ポートを使用して指定されたインターネットホストへの接続を確立します。

null を host パラメーターに対して指定した場合は、XMLSocket.connect() を呼び出すファイルが存在するホストに接続します。例えば、www.adobe.com から呼び出し元ファイルをダウンロードした場合は、host パラメーターに null を指定することは、www.adobe.com に接続することを意味します。

ファイルがこのメソッドを使用しないようにするには、SWF コンテンツを含む HTML ページに allowNetworking パラメーター（object タグおよび embed タグ）を設定します。

詳細については、Flash Player デベロッパーセンターのトピック：セキュリティを参照してください。

パラメーター

関連する API エレメント

object パラメーターで指定された XML オブジェクトまたはデータをストリングに変換し、その後ろにゼロ（0）バイトを付加してサーバーに転送します。object が XML オブジェクトである場合、ストリングは XML オブジェクトの XML テキスト表現です。送信操作は非同期です。つまり、転送処理はただちに終了しますが、データが転送されるのは、その後です。XMLSocket.send() メソッドは、データが正常に転送されたかどうかを示す値を返しません。

XMLSocket.connect() を使用して、XMLSocket オブジェクトをサーバーに接続していない場合、XMLSocket.send() 操作は失敗します。

パラメーター

関連する API エレメント

サーバーによりソケット接続が閉じられたときに送出されます。close イベントは、サーバーにより接続が閉じられたときのみ送出されます。XMLSocket.close() メソッドを呼び出しても送出されません。

このイベントには、次のプロパティがあります。

XMLSocket.connect() メソッドの呼び出しが成功した後に送出されます。

このイベントには、次のプロパティがあります。

未処理のデータが送受信された後に送出されます。

このイベントには、次のプロパティがあります。

入出力エラーが発生して送信または受信操作が失敗したときに送出されます。

このイベントには、次のプロパティがあります。

XMLSocket.connect() メソッドの呼び出しによって、呼び出し元のセキュリティサンドボックスの外にあるサーバーや 1024 未満のポート番号に対して接続しようとしたときに送出されます。

このイベントには、次のプロパティがあります。

関連する API エレメント

1. XMLSocketExample コンストラクターが socket という名前の XMLSocket インスタンスを作成し、socket を後述の ConfigureListeners() に渡します。次に XMLSocket の connect() メソッドを呼び出します。この呼び出しには、ホスト名 "localhost" とポート番号 8080 を使用します。
2. configureListeners()メソッドを呼び出して、サポートされる各 XMLSocket イベントのリスナーを追加します。
   • closeHandler()：close イベントをリッスンします。このイベントはネットワーク接続が閉じられた後に送出されます。
   • connectHandler()：connect イベントをリッスンします。このイベントはネットワーク接続が確立されたときに送出されます。
   • dataHandler()：data イベントをリッスンします。このイベントは XMLSocket が新しいデータを受け取るたびに送出されます。
   • progressHandler()：progress イベントをリッスンします。このイベントは send() が呼び出されたとき、送信中に送出されます。
   • securityErrorHandler()：securityError イベントをリッスンします。このイベントは、ローカルでの再生に関するセキュリティを誤って設定して、または 1024 より小さいポートを使用して、XMLSocket にアクセスしようとしたときに送出されます。
   • ioErrorHandler()：ioError イベントをリッスンします。このイベントはデータの送信または受信操作に失敗すると発生します。

注意：

• 「ローカルでの再生に関するセキュリティ」を「ネットワークにのみアクセスする」に設定して SWF ファイルをコンパイルする必要があります。
• このコード例が動作するには、ポート 8080 を使用して、ドメイン名上で実行しているサーバーが必要です。
• Flash Player 9.0.124.0 以降のバージョンを実行しているときは、ドメインからポート 8080 へのソケット接続を許可するソケットポリシーファイルをサーバー上に置く必要があります。ソケットポリシーファイルの提供については、Flash Player デベロッパーセンターのトピックソケットポリシーファイルサーバーの設定を参照してください。

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.XMLSocket;

    public class XMLSocketExample extends Sprite {
        private var hostName:String = "localhost";
        private var port:uint = 8080;
        private var socket:XMLSocket;

        public function XMLSocketExample() {
            socket = new XMLSocket();
            configureListeners(socket);
            if (hostName && port) {
                socket.connect(hostName, port);
            }
        }

        public function send(data:Object):void {
            socket.send(data);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
        }

        private function dataHandler(event:DataEvent):void {
            trace("dataHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}