DataGridEvent

パッケージ	fl.events
クラス	public class DataGridEvent
継承	DataGridEvent ListEvent Event Object

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent クラスは、DataGrid コンポーネントに関連するイベントを定義します。次のようなイベントがあります。

DataGridEvent.COLUMN_STRETCH：ユーザーが列の横方向のサイズを変更したときに送出されます。
DataGridEvent.HEADER_RELEASE：ユーザーが列ヘッダー上でマウスボタンを押して離したときに送出されます。
DataGridEvent.ITEM_EDIT_BEGIN：アイテムの編集準備が整ったときに送出されます。
DataGridEvent.ITEM_EDIT_BEGINNING：ユーザーによるアイテム編集の準備が整ったときに送出されます。例えば、ユーザーがアイテム上でマウスボタンを離したときです。
DataGridEvent.ITEM_EDIT_END：編集セッションが終了するときに送出されます。
DataGridEvent.ITEM_FOCUS_IN：アイテムにフォーカスが移ったときに送出されます。
DataGridEvent.ITEM_FOCUS_OUT：アイテムがフォーカスを失ったときに送出されます。

例を表示

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		bubbles : Boolean [読み取り専用] イベントがバブリングイベントかどうかを示します。	Event
		cancelable : Boolean [読み取り専用] イベントに関連付けられた動作を回避できるかどうかを示します。	Event
		columnIndex : int [読み取り専用] このイベントに関連するアイテム列のインデックスを取得します。	ListEvent
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		currentTarget : Object [読み取り専用] イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。	Event
		dataField : String 列に関連付けられているデータ内のフィールドまたはプロパティの名前を取得または設定します。	DataGridEvent
		eventPhase : uint [読み取り専用] イベントフローの現在の段階です。	Event
		index : int [読み取り専用] レンダラーを含んでいるセルの 0 から始まるインデックスを取得します。	ListEvent
		item : Object [読み取り専用] 現在のセルレンダラーに属するデータを取得します。	ListEvent
		itemRenderer : Object [読み取り専用] 編集中のアイテムに対応するアイテムレンダラーか、クリックまたはサイズを変更されたヘッダーレンダラーを取得します。	DataGridEvent
		reason : String [読み取り専用] itemEditEnd イベントが送出された理由を取得します。	DataGridEvent
		rowIndex : Object [読み取り専用] このイベントに関連するアイテム行のインデックスを取得します。	ListEvent
		target : Object [読み取り専用] イベントターゲットです。	Event
		type : String [読み取り専用] イベントのタイプです。	Event

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		DataGridEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, columnIndex:int = -1, rowIndex:int = -1, itemRenderer:Object = null, dataField:String = null, reason:String = null) 指定されたパラメーターで新しい DataGridEvent オブジェクトを作成します。	DataGridEvent
		clone():Event [オーバーライド] DataGridEvent オブジェクトのコピーを作成して、各プロパティの値を元のプロパティの値と一致するように設定します。	DataGridEvent
		formatToString(className:String, ... arguments):String カスタム ActionScript 3.0 Event クラスに toString() メソッドを実装するためのユーティリティ関数です。	Event
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isDefaultPrevented():Boolean イベントで preventDefault() メソッドが呼び出されたかどうかを確認します。	Event
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		preventDefault():void イベントのデフォルト動作をキャンセルできる場合に、その動作をキャンセルします。	Event
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		stopImmediatePropagation():void イベントフローの現在のノードおよび後続するノードで、イベントリスナーが処理されないようにします。	Event
		stopPropagation():void イベントフローの現在のノードに後続するノードで、イベントリスナーが処理されないようにします。	Event
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String [オーバーライド] DataGridEvent オブジェクトのすべてのプロパティを含んでいるストリングを返します。	DataGridEvent
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

パブリック定数

継承されるパブリック定数を隠す

継承されるパブリック定数を表示

	定数		定義元
		COLUMN_STRETCH : String = "columnStretch" [静的] DataGridEvent.COLUMN_STRETCH 定数は、columnStretch イベントオブジェクトの type プロパティ値を定義します。	DataGridEvent
		HEADER_RELEASE : String = "headerRelease" [静的] DataGridEvent.HEADER_RELEASE 定数は、headerRelease イベントオブジェクトの type プロパティ値を定義します。	DataGridEvent
		ITEM_EDIT_BEGIN : String = "itemEditBegin" [静的] DataGridEvent.ITEM_EDIT_BEGIN 定数は、itemEditBegin イベントオブジェクトの type プロパティ値を定義します。	DataGridEvent
		ITEM_EDIT_BEGINNING : String = "itemEditBeginning" [静的] DataGridEvent.ITEM__EDIT_BEGINNING 定数は、itemEditBeginning イベントオブジェクトの type プロパティ値を定義します。	DataGridEvent
		ITEM_EDIT_END : String = "itemEditEnd" [静的] DataGridEvent.ITEM_EDIT_END 定数は、itemEditEnd イベントオブジェクトの type プロパティ値を定義します。	DataGridEvent
		ITEM_FOCUS_IN : String = "itemFocusIn" [静的] DataGridEvent.ITEM_FOCUS_IN 定数は、itemFocusIn イベントオブジェクトの type プロパティ値を定義します。	DataGridEvent
		ITEM_FOCUS_OUT : String = "itemFocusOut" [静的] DataGridEvent.ITEM_FOCUS_OUT 定数は、itemFocusOut イベントオブジェクトの type プロパティ値を定義します。	DataGridEvent

プロパティの詳細

dataField

プロパティ

dataField:String

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

列に関連付けられているデータ内のフィールドまたはプロパティの名前を取得または設定します。

実装
public function get dataField():String
public function set dataField(value:String):void

itemRenderer

プロパティ

itemRenderer:Object [読み取り専用]

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

編集中のアイテムに対応するアイテムレンダラーか、クリックまたはサイズを変更されたヘッダーレンダラーを取得します。

実装
public function get itemRenderer():Object

reason

プロパティ

reason:String [読み取り専用]

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

itemEditEnd イベントが送出された理由を取得します。このプロパティは、DataGridEvent.ITEM_EDIT_END タイプのイベントに対してのみ有効です。

有効な値は、DataGridEventReason クラスに定義されています。

実装
public function get reason():String

コンストラクターの詳細

()

コンストラクター

public function DataGridEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, columnIndex:int = -1, rowIndex:int = -1, itemRenderer:Object = null, dataField:String = null, reason:String = null)

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

指定されたパラメーターで新しい DataGridEvent オブジェクトを作成します。

パラメーター

	`type:String` — イベントタイプ。この値は、イベントの基となるアクションを示します。

	`bubbles:Boolean` (default = `false`) — イベントが表示リスト階層を上方にバブルできるかどうかを示します。

	`cancelable:Boolean` (default = `false`) — イベントに関連付けられた動作を回避できるかどうかを示します。

	`columnIndex:int` (default = `-1`) — レンダラーを含む列の 0 から始まるインデックスです。

	`rowIndex:int` (default = `-1`) — レンダラーを含んでいる行の 0 から始まるインデックスです。

	`itemRenderer:Object` (default = `null`) — 編集中のアイテムに対応するアイテムレンダラーか、クリックまたは展開されたヘッダーレンダラーです。

	`dataField:String` (default = `null`) — 列に関連付けられているデータ内のフィールドまたはプロパティの名前です。

	`reason:String` (default = `null`) — `itemEditEnd` イベントが送出された理由です。

関連する API エレメント

DataGridEventReason

メソッドの詳細

clone

()

メソッド

override public function clone():Event

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent オブジェクトのコピーを作成して、各プロパティの値を元のプロパティの値と一致するように設定します。

戻り値

Event — 元のオブジェクトと同じパラメーター値を含む新しい DataGridEvent オブジェクトです。

toString

()

メソッド

override public function toString():String

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent オブジェクトのすべてのプロパティを含んでいるストリングを返します。ストリングは次の形式です。

[ DataGridEvent type= value bubbles= value cancelable= value columnIndex= value rowIndex= value itemRenderer= value dataField= value reason= value ]

戻り値

String — DataGridEvent オブジェクトのすべてのプロパティを含んでいるストリングです。

定数の詳細

COLUMN_STRETCH

定数

public static const COLUMN_STRETCH:String = "columnStretch"

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent.COLUMN_STRETCH 定数は、type プロパティ（columnStretch イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`columnIndex`	DataGrid オブジェクトの `columns` 配列内のヘッダー列の 0 から始まるインデックスです。
`currentTarget`	イベントリスナーで event オブジェクトをアクティブに処理しているオブジェクトです。
`dataField`	アイテムの列に関連付けられているデータ内のフィールドまたはプロパティの名前です。
`itemRenderer`	展開された列に対応するヘッダーレンダラーです。
`reason`	`null`
`rowIndex`	データプロバイダーのアイテムの 0 から始まるインデックスです。
`target`	イベントを送出したオブジェクトです。ターゲットは、必ずしもイベントを受け取るオブジェクトではありません。イベントを受け取るオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

例 ( この例の使用方法 )

次の例では、DataGrid コンポーネントを作成し、columnStretch イベントをリッスンします。


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    var column:DataGridColumn;
    var columnArray:Array = dg.columns;
    var dgColWidth:String;
    trace("resized column:", event.dataField);
    trace("columnIndex:", event.columnIndex);
    for each (column in columnArray) {
        dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
        trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
    }
    trace("----------");
}

HEADER_RELEASE

定数

public static const HEADER_RELEASE:String = "headerRelease"

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent.HEADER_RELEASE 定数は、type プロパティ（headerRelease イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`columnIndex`	DataGrid オブジェクトの `columns` 配列内のヘッダー列の 0 から始まるインデックスです。
`currentTarget`	イベントリスナーで event オブジェクトをアクティブに処理しているオブジェクトです。
`dataField`	アイテムの列に関連付けられているデータ内のフィールドまたはプロパティの名前です。
`itemRenderer`	クリックされたヘッダーレンダラーです。
`reason`	`null`
`rowIndex`	`-1`
`target`	イベントを送出したオブジェクトです。ターゲットは、必ずしもイベントを受け取るオブジェクトではありません。イベントを受け取るオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

例 ( この例の使用方法 )

次の例では、DataGrid コンポーネントインスタンスを作成し、headerRelease イベントをリッスンします。


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
    trace("sortIndex:", dg.sortIndex);
    trace("sortDescending:", dg.sortDescending);
    trace("----------");
}

ITEM_EDIT_BEGIN

定数

public static const ITEM_EDIT_BEGIN:String = "itemEditBegin"

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent.ITEM_EDIT_BEGIN 定数は、type プロパティ（itemEditBegin イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`columnIndex`	DataGrid オブジェクトの `columns` 配列内のヘッダー列の 0 から始まるインデックスです。
`currentTarget`	イベントリスナーで event オブジェクトをアクティブに処理しているオブジェクトです。
`dataField`	`null`
`itemRenderer`	編集対象のアイテムに対応するアイテムレンダラーです。
`reason`	`null`
`rowIndex`	データプロバイダーのアイテムの 0 から始まるインデックスです。
`target`	イベントを送出したオブジェクトです。ターゲットは、必ずしもイベントを受け取るオブジェクトではありません。イベントを受け取るオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

関連する API エレメント

ITEM_EDIT_BEGINNING
ITEM_EDIT_END

ITEM_EDIT_BEGINNING

定数

public static const ITEM_EDIT_BEGINNING:String = "itemEditBeginning"

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent.ITEM__EDIT_BEGINNING 定数は、type プロパティ（itemEditBeginning イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`columnIndex`	DataGrid オブジェクトの `columns` 配列内のヘッダー列の 0 から始まるインデックスです。
`currentTarget`	イベントリスナーで event オブジェクトをアクティブに処理しているオブジェクトです。
`dataField`	アイテムの列に関連付けられているデータ内のフィールドまたはプロパティの名前です。
`itemRenderer`	編集対象のアイテムに対応するアイテムレンダラーです。
`reason`	`null`
`rowIndex`	データプロバイダーのアイテムの 0 から始まるインデックスです。
`target`	イベントを送出したオブジェクトです。ターゲットは、必ずしもイベントを受け取るオブジェクトではありません。イベントを受け取るオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

関連する API エレメント

ITEM_EDIT_BEGIN
ITEM_EDIT_END

ITEM_EDIT_END

定数

public static const ITEM_EDIT_END:String = "itemEditEnd"

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent.ITEM_EDIT_END 定数は、type プロパティ（itemEditEnd イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`columnIndex`	DataGrid オブジェクトの `columns` 配列内のヘッダー列の 0 から始まるインデックスです。
`currentTarget`	イベントリスナーで event オブジェクトをアクティブに処理しているオブジェクトです。
`dataField`	アイテムの列に関連付けられているデータ内のフィールドまたはプロパティの名前です。
`itemRenderer`	編集対象のアイテムに対応するアイテムレンダラーです。
`reason`	イベントの理由を定義する定数です。値は `DataGridEventReason` クラスのメンバーである必要があります。
`rowIndex`	データプロバイダーのアイテムの 0 から始まるインデックスです。
`target`	イベントを送出したオブジェクトです。ターゲットは、必ずしもイベントを受け取るオブジェクトではありません。イベントを受け取るオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

関連する API エレメント

ITEM_EDIT_BEGIN
ITEM_EDIT_BEGINNING

ITEM_FOCUS_IN

定数

public static const ITEM_FOCUS_IN:String = "itemFocusIn"

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent.ITEM_FOCUS_IN 定数は、type プロパティ（itemFocusIn イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`columnIndex`	DataGrid オブジェクトの `columns` 配列内のヘッダー列の 0 から始まるインデックスです。
`currentTarget`	イベントリスナーで event オブジェクトをアクティブに処理しているオブジェクトです。
`dataField`	`null`
`itemRenderer`	編集対象のアイテムに対応するアイテムレンダラーです。
`reason`	`null`
`rowIndex`	データプロバイダーのアイテムの 0 から始まるインデックスです。
`target`	イベントを送出したオブジェクトです。ターゲットは、必ずしもイベントを受け取るオブジェクトではありません。イベントを受け取るオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

関連する API エレメント

ITEM_FOCUS_OUT

定数

public static const ITEM_FOCUS_OUT:String = "itemFocusOut"

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

DataGridEvent.ITEM_FOCUS_OUT 定数は、type プロパティ（itemFocusOut イベントオブジェクト）の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`columnIndex`	DataGrid オブジェクトの `columns` 配列内のヘッダー列の 0 から始まるインデックスです。
`currentTarget`	イベントリスナーで event オブジェクトをアクティブに処理しているオブジェクトです。
`dataField`	`null`
`itemRenderer`	編集対象のアイテムに対応するアイテムレンダラーです。
`reason`	`null`
`rowIndex`	データプロバイダーのアイテムの 0 から始まるインデックスです。
`target`	イベントを送出したオブジェクトです。ターゲットは、必ずしもイベントを受け取るオブジェクトではありません。イベントを受け取るオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

関連する API エレメント

ITEM_FOCUS_IN

例この例の使用方法

DataGridEventExample.as

この例では、DataGrid から送出されるイベントに応答する方法を示します。

例を実行するには、次の手順に従います。

DataGrid コンポーネントをライブラリに追加します。
このコードを FLA ファイルと同じディレクトリに DataGridEventExample.as という名前で保存します。
FLA ファイル内の Document クラスを DataGridEventExample に設定します。

package
{
    import fl.controls.DataGrid;
    import fl.data.DataProvider;
    import fl.events.DataGridEvent;
    import fl.events.DataGridEventReason;
    import flash.display.Sprite;
    
    public class DataGridEventExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridEventExample() {
            createDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;
            dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
            dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
        }
        private function announceEditBegin(e:DataGridEvent):void {
            trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);    
        }
        private function announceEditEnd(e:DataGridEvent):void {
            var reason:String;
            switch(e.reason) {
                case DataGridEventReason.CANCELLED:
                    reason = "User cancelled edit";
                    break;
                case DataGridEventReason.NEW_ROW:
                    reason = "User focused to another row";
                    break;
                case DataGridEventReason.NEW_COLUMN:
                    reason = "User focused to another column";
                    break;
                case DataGridEventReason.OTHER:
                default:
                    reason = "Edit ended for other reason";
                    reason = e.reason;
                    break;                
            }
            trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
            trace("Reason: " + reason.toString());    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
    }
}

法律上の注意 | プライバシーポリシー

DataGridEvent - AS3 Flash

クラス x

dataField

itemRenderer

reason

DataGridEvent

clone

toString

COLUMN_STRETCH

HEADER_RELEASE

ITEM_EDIT_BEGIN

ITEM_EDIT_BEGINNING

ITEM_EDIT_END

ITEM_FOCUS_IN

ITEM_FOCUS_OUT