Date

パッケージ	トップレベル
クラス	public final dynamic class Date
継承	Date Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date クラスは日時のデータを表します。Date クラスの 1 つのインスタンスは特定の一時点を表します。この特定の一時点について、月、日、時、秒などのプロパティを照会および変更できます。Date クラスを使用すると、世界時（グリニッジ標準時。現在の呼称は世界標準時または UTC）またはローカル時間を基準にした日付と時刻の値を取得できます。ローカル時間は、Flash Player を実行しているオペレーティングシステムに設定されているローカルタイムゾーンによって決定されます。Date クラスのメソッドは静的ではありません。メソッドを呼び出すときに指定した個々の Date オブジェクトにのみ適用されます。例外として、Date.UTC() メソッドと Date.parse() メソッドがあります。これらは静的なメソッドです。

Date クラスによる夏時間の処理方法は、オペレーティングシステムおよびランタイムのバージョンに応じて異なります。Flash Player 6 以降では、夏時間は各オペレーティングシステムで次のように処理されます。

Windows - Date オブジェクトの出力は夏時間に合わせて自動的に調整されます。Date オブジェクトは、夏時間が現在の地域で採用されているかどうかを確認します。夏時間が採用されている場合は、夏時間に移行する日付と時刻の基準を確認します。ただし、現在有効な夏時間の日付が過去と未来に適用されるために、夏時間の日付が異なる地域では、計算される夏時間の日付が過去の日付と食い違う場合があります。
Mac OS X - Date オブジェクトの出力は夏時間に合わせて自動的に調整されます。Mac OS X では、タイムゾーン情報データベースを使用して、現在または過去の日付または時刻に夏時間の時差を適用する必要があるかどうかを決定します。
Mac OS 9 - 現在の日付および時刻に夏時間の時差を適用する必要があるかどうかを判定できるだけの情報しか提供されません。したがって、Date オブジェクトは、現在の夏時間の時差が過去および将来のすべての日時に適用されると想定します。

Flash Player 5 によるオペレーティングシステム別の夏時間の対処方法は次のとおりです。

Windows - 夏時間に関する米国の規則が常に適用されるために、米国とは夏時間に移行する時期が異なるヨーロッパおよび他の地域では移行期間が食い違います。Flash は、現在の地域で採用されている夏時間を正しく検出します。

Date クラスを使用するには、new 演算子を使用して Date インスタンスを作成します。

ActionScript 3.0 は新しいアクセッサープロパティをいくつか追加しています。これらのアクセッサープロパティは、Date インスタンスにアクセスしたり、Date インスタンスを変更する多くの Date クラスメソッドの代わりに使用できます。また、ActionScript 3.0 には、ECMA-262 Edition 3 に準拠するために組み込まれている、toString() メソッドの新しい変形メソッド（Date.toLocaleString()、Date.toTimeString()、Date.toLocaleTimeString()、Date.toDateString()、および Date.toLocaleDateString()）も含まれます。

相対時間または経過時間を計算するには、flash.utils パッケージに含まれる getTimer() メソッドを参照してください。

例を表示

関連する API エレメント

flash.utils.getTimer()

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		date : Number Date オブジェクトで指定されたローカル時間による日付（1 ～ 31 の整数）です。	Date
		dateUTC : Number Date オブジェクトの世界時（UTC）による日付（1 ～ 31 の整数）です。	Date
		day : Number [読み取り専用] この Date で指定されたローカル時間による曜日（日曜日は 0、月曜日は 1 など）です。	Date
		dayUTC : Number [読み取り専用] この Date の世界時（UTC）による曜日（日曜日は 0、月曜日は 1 など）です。	Date
		fullYear : Number Date オブジェクトのローカル時間による年（2000 などの 4 桁の数字）です。	Date
		fullYearUTC : Number Date オブジェクトの世界時（UTC）による 4 桁の年です。	Date
		hours : Number Date オブジェクトのローカル時間による時（0 ～ 23 の整数）部分です。	Date
		hoursUTC : Number Date オブジェクトの世界時（UTC）による時（0 ～ 23 の整数）です。	Date
		milliseconds : Number Date オブジェクトのローカル時間によるミリ秒（0 ～ 999 の整数）部分です。	Date
		millisecondsUTC : Number Date オブジェクトの世界時（UTC）によるミリ秒（0 ～ 999 の整数）部分です。	Date
		minutes : Number Date オブジェクトのローカル時間による分（0 ～ 59 の整数）部分です。	Date
		minutesUTC : Number Date オブジェクトの世界時（UTC）による分（0 ～ 59 の整数）部分です。	Date
		month : Number Date オブジェクトのローカル時間による月（1 月は 0、2 月は 1 など）です。	Date
		monthUTC : Number Date オブジェクトの世界時（UTC）による月（0（1 月）～ 11（12 月））部分です。	Date
		seconds : Number Date オブジェクトのローカル時間による秒（0 ～ 59 の整数）部分です。	Date
		secondsUTC : Number Date オブジェクトの世界時（UTC）による秒（0 ～ 59 の整数）部分です。	Date
		time : Number Date オブジェクトの 1970 年 1 月 1 日 0 時（世界時）からのミリ秒数です。	Date
		timezoneOffset : Number [読み取り専用] 世界時（UTC）とコンピューターのローカル時間の差（分単位）です。	Date

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0) 指定された日時を保持する新しい Date オブジェクトを作成します。	Date
		getDate():Number Date オブジェクトで指定された日付（1 ～ 31 の整数）をローカル時間で返します。	Date
		getDay():Number この Date で指定された曜日（日曜日は 0、月曜日は 1 など）をローカル時間で返します。	Date
		getFullYear():Number Date オブジェクトの年（2000 などの 4 桁の数字）をローカル時間で返します。	Date
		getHours():Number Date オブジェクトの時（0 ～ 23 の整数）部分をローカル時間で返します。	Date
		getMilliseconds():Number Date オブジェクトのミリ秒（0 ～ 999 の整数）部分をローカル時間で返します。	Date
		getMinutes():Number Date オブジェクトの分（0 ～ 59 の整数）部分をローカル時間で返します。	Date
		getMonth():Number この Date の月（1 月は 0、2 月は 1 など）部分をローカル時間で返します。	Date
		getSeconds():Number Date オブジェクトの秒（0 ～ 59 の整数）部分をローカル時間で返します。	Date
		getTime():Number Date オブジェクトの 1970 年 1 月 1 日 0 時（世界時）からのミリ秒数を返します。	Date
		getTimezoneOffset():Number 世界時（UTC）とコンピューターのローカル時間の差（分単位）を返します。	Date
		getUTCDate():Number Date オブジェクトの日付（1 ～ 31 の整数）を世界時（UTC）で返します。	Date
		getUTCDay():Number この Date の曜日（日曜日は 0、月曜日は 1 など）を世界時（UTC）で返します。	Date
		getUTCFullYear():Number Date オブジェクトの 4 桁の年を世界時（UTC）で返します。	Date
		getUTCHours():Number Date オブジェクトの時（0 ～ 23 の整数）を世界時（UTC）で返します。	Date
		getUTCMilliseconds():Number Date オブジェクトのミリ秒（0 ～ 999 の整数）部分を世界時（UTC）で返します。	Date
		getUTCMinutes():Number Date オブジェクトの分（0 ～ 59 の整数）部分を世界時（UTC）で返します。	Date
		getUTCMonth():Number Date オブジェクトの月（0（1 月）～ 11（12 月））部分を世界時（UTC）で返します。	Date
		getUTCSeconds():Number Date オブジェクトの秒（0 ～ 59 の整数）部分を世界時（UTC）で返します。	Date
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		parse(date:String):Number [静的] 日付を表すストリングを、1970 年 1 月 1 日（UTC）から経過したミリ秒数に相当する数値に変換します。	Date
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		setDate(day:Number):Number 月内の日付をローカル時間で設定し、新しい時刻をミリ秒で返します。	Date
		setFullYear(year:Number, month:Number, day:Number):Number 年をローカル時間で設定し、新しい時刻をミリ秒で返します。	Date
		setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number 時をローカル時間で設定し、新しい時刻をミリ秒で返します。	Date
		setMilliseconds(millisecond:Number):Number ミリ秒をローカル時間で設定し、新しい時刻をミリ秒で返します。	Date
		setMinutes(minute:Number, second:Number, millisecond:Number):Number 分をローカル時間で設定し、新しい時刻をミリ秒で返します。	Date
		setMonth(month:Number, day:Number):Number 月と、オプションで日付をローカル時間で設定し、新しい時刻をミリ秒で返します。	Date
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		setSeconds(second:Number, millisecond:Number):Number 秒をローカル時間で設定し、新しい時刻をミリ秒で返します。	Date
		setTime(millisecond:Number):Number 日付を 1970 年 1 月 1 日 0 時からのミリ秒数で設定し、新しい時刻をミリ秒で返します。	Date
		setUTCDate(day:Number):Number 月内の日付を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。	Date
		setUTCFullYear(year:Number, month:Number, day:Number):Number 年を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。	Date
		setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number 時を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。	Date
		setUTCMilliseconds(millisecond:Number):Number ミリ秒を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。	Date
		setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number 分を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。	Date
		setUTCMonth(month:Number, day:Number):Number 月、および日（オプション）を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。	Date
		setUTCSeconds(second:Number, millisecond:Number):Number 秒、およびオプションでミリ秒を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。	Date
		toDateString():String 曜日と日付のみのストリング表現を返します。時刻またはタイムゾーンは含まれません。	Date
		toJSON(k:String):* Date オブジェクトの値の JSON エンコーディングをカスタマイズするためのオーバーライド可能なメソッドです。	Date
		toLocaleDateString():String 曜日と日付のみのストリング表現を返します。時刻またはタイムゾーンは含まれません。	Date
		toLocaleString():String 曜日、日付、時刻のストリング表現を、指定されたローカル時間で返します。	Date
		toLocaleTimeString():String 時刻のみのストリング表現を返します。曜日、日付、年、またはタイムゾーンは含まれません。	Date
		toString():String 曜日、日付、時刻、およびタイムゾーンのストリング表現を返します。	Date
		toTimeString():String 時刻とタイムゾーンのみのストリング表現を返します。曜日と日付は含まれません。	Date
		toUTCString():String 曜日、日付、および時刻のストリング表現を世界時（UTC）で返します。	Date
		UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number [静的] 1970 年 1 月 1 日 0 時（世界時）からパラメーターで指定された時刻までのミリ秒数を返します。	Date
		valueOf():Number Date オブジェクトの 1970 年 1 月 1 日 0 時（世界時）からのミリ秒数を返します。	Date

プロパティの詳細

プロパティ

date:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトで指定されたローカル時間による日付（1 ～ 31 の整数）です。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

実装
AS3 function get date():Number
AS3 function set date(value:Number):void

関連する API エレメント

getDate()
setDate()

dateUTC

プロパティ

dateUTC:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの世界時（UTC）による日付（1 ～ 31 の整数）です。

実装
AS3 function get dateUTC():Number
AS3 function set dateUTC(value:Number):void

関連する API エレメント

getUTCDate()
setUTCDate()

day

プロパティ

day:Number [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

この Date で指定されたローカル時間による曜日（日曜日は 0、月曜日は 1 など）です。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

実装
AS3 function get day():Number

関連する API エレメント

getDay()

dayUTC

プロパティ

dayUTC:Number [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

この Date の世界時（UTC）による曜日（日曜日は 0、月曜日は 1 など）です。

実装
AS3 function get dayUTC():Number

関連する API エレメント

getUTCDay()

fullYear

プロパティ

fullYear:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトのローカル時間による年（2000 などの 4 桁の数字）です。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

実装
AS3 function get fullYear():Number
AS3 function set fullYear(value:Number):void

関連する API エレメント

getFullYear()
setFullYear()

fullYearUTC

プロパティ

fullYearUTC:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの世界時（UTC）による 4 桁の年です。

実装
AS3 function get fullYearUTC():Number
AS3 function set fullYearUTC(value:Number):void

関連する API エレメント

getUTCFullYear()
setUTCFullYear()

hours

プロパティ

hours:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

Date オブジェクトのローカル時間による時（0 ～ 23 の整数）部分です。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

実装
AS3 function get hours():Number
AS3 function set hours(value:Number):void

関連する API エレメント

getHours()
setHours()

hoursUTC

プロパティ

hoursUTC:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの世界時（UTC）による時（0 ～ 23 の整数）です。

実装
AS3 function get hoursUTC():Number
AS3 function set hoursUTC(value:Number):void

関連する API エレメント

getUTCHours()
setUTCHours()

milliseconds

プロパティ

milliseconds:Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトのローカル時間によるミリ秒（0 ～ 999 の整数）部分です。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

実装
AS3 function get milliseconds():Number
AS3 function set milliseconds(value:Number):void

関連する API エレメント

プロパティ

timezoneOffset:Number [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

世界時（UTC）とコンピューターのローカル時間の差（分単位）です。つまり、この分の値をコンピューターのローカル時間に加算すると世界時と等しくなります。コンピューターの時刻が世界時より遅い時間に設定されている場合、戻り値は負の数になります。

実装
AS3 function get timezoneOffset():Number

関連する API エレメント

getTimezoneOffset()

コンストラクターの詳細

Date

()

コンストラクター

public function Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

指定された日時を保持する新しい Date オブジェクトを作成します。

Date() コンストラクターは、日付と、ミリ秒までの時刻を指定する、最大 7 つまでパラメーター（year、month、...、millisecond）を取ります。新しく作成された Date オブジェクトに含まれる日付は、渡された引数の数とデータ型により異なります。

引数が渡されなかった場合、Date オブジェクトには現在の日時が割り当てられます。
データ型 Number の引数が 1 つ渡された場合、Date オブジェクトには、1970 年 1 月 1 日 0:00:00（GMT）からその 1 つの引数で指定されたミリ秒数後の時間値が割り当てられます。
データ型 String の引数が 1 つ渡され、このストリングに有効な日付が含まれている場合は、Date オブジェクトにはその日付に基づく時間値が割り当てられます。
複数の引数が渡された場合、Date オブジェクトには、渡された引数値が表す日付の年、月、日、時、分、秒、ミリ秒に基づく時間値が割り当てられます。

Date クラスのコンストラクターにストリングを渡す場合、日付にはさまざまな形式を使用できますが、少なくとも月、日、年が含まれている必要があります。例えば、Feb 1 2005 は有効ですが、Feb 2005 は無効です。次に、有効な形式をいくつか示します。

曜日月日時:分:秒 GMT 年（例えば "Tue Feb 1 00:00:00 GMT-0800 2005"。これは toString() に対応します）。
曜日月日年時:分:秒午前（AM） / 午後（PM）（例えば "Tue Feb 1 2005 12:00:00 AM"。これは toLocaleString() に対応します）。
曜日月日年（例えば "Tue Feb 1 2005"。これは toDateString() に対応します）。
月/日/年（例えば "02/01/2005"）
月/年（例えば "02/2005"）

パラメーター

	`yearOrTimevalue:Object` — 他のパラメーターが指定されている場合、この数値は年（1965 年など）を表します。それ以外の場合は時間値を表します。数値が年を表す場合、0 ～ 99 の値は 1900 ～ 1999 を表します。それ以外の場合は年を 4 桁で指定する必要があります。数値が時間値を表す（他にパラメーターが指定されない）場合は、1970 年 1 月 1 日 0:00:00 GMT を基準とする経過時間をミリ秒単位で表す値になります。負の値は 1970 年 1 月 1 日 0:00:00 GMT よりも前の時刻を表し、正の値はそれより後の時刻を表します。

	`month:Number` — 0（1 月）～ 11（12 月）の整数です。

	`date:Number` (default = `1`) — 1 ～ 31 の整数です。

	`hour:Number` (default = `0`) — 0（0 時）～ 23（午後 11 時）の整数です。

	`minute:Number` (default = `0`) — 0 ～ 59 の整数です。

	`second:Number` (default = `0`) — 0 ～ 59 の整数です。

	`millisecond:Number` (default = `0`) — ミリ秒の 0 ～ 999 の整数です。

関連する API エレメント

getMonth()
getDate()
getFullYear()

メソッドの詳細

getDate

()

メソッド

AS3 function getDate():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトで指定された日付（1 ～ 31 の整数）をローカル時間で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

戻り値

Number — Date オブジェクトが表す日付（1 ～ 31）です。

関連する API エレメント

getMonth()
getFullYear()

例 ( この例の使用方法 )

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

getDay

()

メソッド

AS3 function getDay():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

この Date で指定された曜日（日曜日は 0、月曜日は 1 など）をローカル時間で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

戻り値

Number — Date オブジェクトが表す曜日の数値（0 ～ 6）です。

例 ( この例の使用方法 )

次の例では、新しい Array オブジェクト weekDayLabels を作成して、エレメント [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] を設定し、次に、新しい Date オブジェクト someBirthday を作成して、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に getDay() メソッドを 2 回呼び出します。1 回目は日付を 6 という数値で表示し、2 回目は weekDayLabels を使用して曜日を表示します。

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

getFullYear

()

メソッド

AS3 function getFullYear():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの年（2000 などの 4 桁の数字）をローカル時間で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

戻り値

Number — Date オブジェクトが表す 4 桁の年です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に、getFullYear() メソッドを呼び出し、4 桁の年を取得します。

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

getHours

()

メソッド

AS3 function getHours():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの時（0 ～ 23 の整数）部分をローカル時間で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

戻り値

Number — Date オブジェクトが表す時（0 ～ 23）です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に、getHours() メソッドと getMinutes() メソッドを呼び出し、時と分を 24 時間形式で取得します。最後に、ストリング localTime を作成し、関数 getUSClockTime() の呼び出し結果を割り当てます。この関数は、getHours() と getMinutes() を再度呼び出します。これにより、時間 03:05 PM が表示されます。

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num as String;
}

getMilliseconds

()

メソッド

AS3 function getMilliseconds():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトのミリ秒（0 ～ 999 の整数）部分をローカル時間で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

戻り値

Number — Date オブジェクトのミリ秒部分です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getMilliseconds() メソッドを呼び出し、Date オブジェクト now の作成時点のミリ秒数を取得します。

var now:Date = new Date();
trace(now.getMilliseconds());

getMinutes

()

メソッド

AS3 function getMinutes():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの分（0 ～ 59 の整数）部分をローカル時間で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

戻り値

Number — Date オブジェクトの分部分です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getMinutes() メソッドを呼び出し、Date オブジェクト now の作成時点の分を取得します。

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

getMonth

()

メソッド

AS3 function getMonth():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

この Date の月（1 月は 0、2 月は 1 など）部分をローカル時間で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

戻り値

Number — Date オブジェクトの月（0 ～ 11）部分です。

例 ( この例の使用方法 )

次の例では、新しい Array オブジェクト monthLabels を作成して、January から December までのエレメントを設定し、次に、パラメーターを指定せずに新しい Date オブジェクト now を作成します。次に、getMonth() メソッドを 2 回呼び出します。1 回目は、Date オブジェクト作成時点の now の月の数値を返し、2 回目は月の名前を返します。

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

getSeconds

()

メソッド

AS3 function getSeconds():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの秒（0 ～ 59 の整数）部分をローカル時間で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

戻り値

Number — Date オブジェクトの秒（0 ～ 59 の整数）部分です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getSeconds() メソッドを呼び出し、Date オブジェクト now の作成時点の秒を取得します。

var now:Date = new Date();
trace(now.getSeconds());

getTime

()

メソッド

AS3 function getTime():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの 1970 年 1 月 1 日 0 時（世界時）からのミリ秒数を返します。このメソッドは、複数の Date オブジェクトを比較する際に特定の時間を表すのに使用します。

戻り値

Number — Date オブジェクトが表す 1970 年 1 月 1 日からのミリ秒数です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト mlk を作成し、パラメーターに year（1929）、month（0 = 1 月）、day（15）を指定します。次に、getTime() メソッドを呼び出し、1970 年 1 月 1 日午前 0 時からのミリ秒数を取得します。年が 1929 に設定されているため、ミリ秒は負の値で表されます。

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

次の例では、新しい Date オブジェクト now をパラメーター指定なしで作成し、次に、以降で作成する DateMath クラスのメソッドを使用して、元の Date オブジェクト now の作成時刻に時間を追加します。

addSeconds() : now に 30 秒を追加します。
addMinutes() : now に 30 分を追加します。
addHours() : Date オブジェクト now に 6 時間を追加します。
addDays() : Date オブジェクト now に 30 日を追加します。
addWeeks() : now に 4 週間を追加します。

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}

注意：Date 演算を実行する場合には、getTime を使用することが重要です。getTime はうるう年に対応しているので、次の疑似コードのような if 文が不要です。

 function addMonths(num:Number):void {
     currentMonth = currentMonth + num;
     if(currentMonth > 12) {
         currentYear++;
         currentMonth = currentMonth - 12;
     }
 }

getTimezoneOffset

()

メソッド

AS3 function getTimezoneOffset():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

世界時（UTC）とコンピューターのローカル時間の差（分単位）を返します。

戻り値

Number — この分をコンピューターのローカル時間に加算すると世界時と等しくなります。コンピューターの時刻が世界時より遅い時間に設定されている場合、戻り値は負の数になります。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getTimezoneOffset() メソッドを呼び出し、now が作成された時刻と世界時の差（分単位）を取得します。さらに、この結果を 60 で除算して、タイムゾーンのオフセットを時間単位に変換します。

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

getUTCDate

()

メソッド

AS3 function getUTCDate():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの日付（1 ～ 31 の整数）を世界時（UTC）で返します。

戻り値

Number — Date オブジェクトが表す UTC の日付（1 ～ 31）です。

関連する API エレメント

getDate()

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。getUTCDate() メソッドを呼び出し、日付を UTC で取得します。

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

getUTCDay

()

メソッド

AS3 function getUTCDay():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

この Date の曜日（日曜日は 0、月曜日は 1 など）を世界時（UTC）で返します。

戻り値

Number — Date オブジェクトが表す UTC の曜日（0 ～ 6）です。

関連する API エレメント

getDay()

例 ( この例の使用方法 )

次の例では、新しい Array オブジェクト weekDayLabels を作成して、エレメント [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] を設定し、次に、新しい Date オブジェクト someBirthday を作成して、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に getUTCDay() メソッドを 2 回呼び出します。1 回目は日付を 6 という数値で表示し、2 回目は weekDayLabels を使用して曜日を UTC で表示します。

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

getUTCFullYear

()

メソッド

AS3 function getUTCFullYear():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの 4 桁の年を世界時（UTC）で返します。

戻り値

Number — Date オブジェクトが表す UTC の 4 桁の年です。

関連する API エレメント

getFullYear()

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に、getUTCFullYear() メソッドを呼び出し、4 桁の年を UTC で取得します。

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

getUTCHours

()

メソッド

AS3 function getUTCHours():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの時（0 ～ 23 の整数）を世界時（UTC）で返します。

戻り値

Number — Date オブジェクトが表す UTC の時（0 ～ 23）です。

関連する API エレメント

getHours()

例 ( この例の使用方法 )

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

getUTCMilliseconds

()

メソッド

AS3 function getUTCMilliseconds():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトのミリ秒（0 ～ 999 の整数）部分を世界時（UTC）で返します。

戻り値

Number — Date オブジェクトの UTC のミリ秒部分です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getUTCMilliseconds() メソッドを呼び出し、Date オブジェクト now の作成時点のミリ秒を UTC で取得します。

var now:Date = new Date();
trace(now.getUTCMilliseconds());

getUTCMinutes

()

メソッド

AS3 function getUTCMinutes():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの分（0 ～ 59 の整数）部分を世界時（UTC）で返します。

戻り値

Number — Date オブジェクトの UTC の分部分です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getUTCMinutes() メソッドを呼び出し、Date オブジェクト now の作成時点の分を UTC で取得します。

var now:Date = new Date();
trace(now.getUTCMinutes());

getUTCMonth

()

メソッド

AS3 function getUTCMonth():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの月（0（1 月）～ 11（12 月））部分を世界時（UTC）で返します。

戻り値

Number — Date オブジェクトの UTC の月部分です。

関連する API エレメント

getMonth()

例 ( この例の使用方法 )

次の例では、新しい Array オブジェクト monthLabels を作成して、January から December までのエレメントを設定し、次に、パラメーターを指定せずに新しい Date オブジェクト now を作成します。次に、getUTCMonth() メソッドを 2 回呼び出します。1 回目は、Date オブジェクト作成時点の now の月の数値を、2 回目は月の名前を UTC で返します。

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

getUTCSeconds

()

メソッド

AS3 function getUTCSeconds():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの秒（0 ～ 59 の整数）部分を世界時（UTC）で返します。

戻り値

Number — Date オブジェクトの UTC の秒部分です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getUTCSeconds() メソッドを呼び出し、Date オブジェクト now の作成時点の秒を UTC で取得します。

var now:Date = new Date();
trace(now.getUTCSeconds());

parse

()

メソッド

public static function parse(date:String):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

日付を表すストリングを、1970 年 1 月 1 日（UTC）から経過したミリ秒数に相当する数値に変換します。

パラメーター

date:String — Date.toString() の出力形式に準じた日付のストリング表現です。Date.toString() の出力の日付形式は、次のとおりです。

     Day Mon DD HH:MM:SS TZD YYYY

次に実際の使用例を示します。

     Wed Apr 12 15:30:17 GMT-0700 2006

タイムゾーン指定（TZD）は、常に GMT-HHMM または UTC-HHMM の形式になります。これは、グリニッジ標準時（GMT）を基準にした時間と分のオフセットを示します。なお、グリニッジ標準時は現在は世界時（UTC）とも呼ばれています。年、月、曜日は、スラッシュ（/）またはスペースで区切ることができますが、ダッシュ（-）で区切ることはできません。他にも、次のような形式がサポートされます。月、曜日、年だけというように、これらの形式の一部分を含めることもできます。

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD

戻り値

Number — 1970 年 1 月 1 日（UTC）から経過したミリ秒数を表す数値です。

関連する API エレメント

Date.toString()

例 ( この例の使用方法 )

次の例では、1974 年 11 月 30 日の日付ストリングを dateParsed に割り当てます。次に、Date.parse() メソッドを呼び出し、この日付を 1970 年 1 月 1 日からのミリ秒数に変換します。

var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000

setDate

()

メソッド

AS3 function setDate(day:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

月内の日付をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

パラメーター

day:Number — 1 ～ 31 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に、getDate() メソッドを呼び出し、日付を取得します。次に、setDate() を呼び出して（day パラメーターに 20 を設定）から、getDate() を再度呼び出します。これにより、新しく設定された日付を取得します。

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

setFullYear

()

メソッド

AS3 function setFullYear(year:Number, month:Number, day:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

年をローカル時間で設定し、新しい時刻をミリ秒で返します。month パラメーターと day パラメーターを指定すると、両方はローカル時間に設定されます。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

このメソッドを呼び出しても Date オブジェクトの他のフィールドは変更されませんが、このメソッドを呼び出した結果として曜日が変わった場合には、Date.getUTCDay() と Date.getDay() は新しい値を返すことがあります。

パラメーター

	`year:Number` — 年を示す 4 桁の数値です。2 桁の数値は 4 桁の年の省略形を表しません。例えば、99 は 1999 年ではなく、99 年です。

	`month:Number` — 0（1 月）～ 11（12 月）の整数です。

	`day:Number` — 1 ～ 31 の数値です。

戻り値

Number — ミリ秒で表される新しい時刻です。

関連する API エレメント

getUTCDay()
getDay()

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に、メソッド getFullYear() を呼び出し、4 桁の年を取得します。次に、setFullYear() を呼び出して（year パラメーターに 2000 を設定）から、getFullYear() を再度呼び出します。これにより、新しく設定された年を取得します。

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

setHours

()

メソッド

AS3 function setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

時をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

パラメーター

	`hour:Number` — 0（0 時）～ 23（午後 11 時）の整数です。

	`minute:Number` — 0 ～ 59 の整数です。

	`second:Number` — 0 ～ 59 の整数です。

	`millisecond:Number` — 0 ～ 999 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に、メソッド getHours() と getMinutes() を呼び出し、時と分を取得します。次に、setHours() を呼び出して（hour パラメーターに 12 を設定）から、getHours() と getMinutes() を再度呼び出します。これにより、新しく設定された時と分を取得します。

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

setMilliseconds

()

メソッド

AS3 function setMilliseconds(millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

ミリ秒をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

パラメーター

millisecond:Number — 0 ～ 999 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getMilliseconds() メソッドを呼び出し、now 作成時点のミリ秒を取得します。次に、別の Date オブジェクト before を、setMilliseconds() を追加で呼び出して（millisecond パラメーターに 4 を設定）作成します。次に、getMilliseconds() を再度呼び出して、新しく設定されたミリ秒を取得します。

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

setMinutes

()

メソッド

AS3 function setMinutes(minute:Number, second:Number, millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

分をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

パラメーター

	`minute:Number` — 0 ～ 59 の整数です。

	`second:Number` — 0 ～ 59 の整数です。

	`millisecond:Number` — 0 ～ 999 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getMinutes() メソッドを呼び出し、now 作成時点の分を取得します。次に、別の Date オブジェクト before を、setMinutes() を追加で呼び出して（minute パラメーターに 0 を設定）作成します。次に、getMinutes() を再度呼び出して、新しく設定された分を取得します。

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

setMonth

()

メソッド

AS3 function setMonth(month:Number, day:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

月と、オプションで日付をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

パラメーター

	`month:Number` — 0（1 月）～ 11（12 月）の整数です。

	`day:Number` — 1 ～ 31 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Array オブジェクト monthLabels を作成して、January から December までのエレメントを設定し、次に、パラメーターを指定せずに新しい Month オブジェクト now を作成します。次に、getMonth() メソッドを呼び出し、now 作成時点の月を取得します。次に、setMonth() を呼び出して（month パラメーターに 0 を設定）から、getMonth() を再度呼び出します。これにより、新しく設定された月を取得します。

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

setSeconds

()

メソッド

AS3 function setSeconds(second:Number, millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

秒をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash ランタイムを実行しているオペレーティングシステムによって決まります。

パラメーター

	`second:Number` — 0 ～ 59 の整数です。

	`millisecond:Number` — 0 ～ 999 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getseconds() メソッドを呼び出し、now 作成時点の秒を取得します。次に、setSeconds() を呼び出して（second パラメーターに 0 を設定）から、getSeconds() を再度呼び出します。これにより、新しく設定された秒を取得します。

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

setTime

()

メソッド

AS3 function setTime(millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

日付を 1970 年 1 月 1 日 0 時からのミリ秒数で設定し、新しい時刻をミリ秒で返します。

パラメーター

millisecond:Number — 整数値です。0 は世界時（UTC）の 1 月 1 日 0 時です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に setTime() メソッドを呼び出します。パラメーター millisecond には -1292601600000 を設定します。これにより時刻は Tue Jan 15 00:00:00 GMT-0800 1929 に設定されます。

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

setUTCDate

()

メソッド

AS3 function setUTCDate(day:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

月内の日付を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。このメソッドを呼び出しても、Date オブジェクトの他のフィールドは変更されませんが、このメソッドを呼び出した結果として曜日が変わった場合には、Date.getUTCDay() メソッドと Date.getDay() メソッドは新しい値を返すことがあります。

パラメーター

day:Number — 1 ～ 31 の整数値です。

戻り値

Number — ミリ秒で表される新しい時刻です。

関連する API エレメント

getUTCDay()
getDay()

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。getUTCDate() メソッドを呼び出すと、月内の日付が正しく返されます。次に、setUTCDate() を呼び出します。パラメーター day には 1 を設定します。trace() ステートメントで日付が正しく設定されたことを確認します。

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

setUTCFullYear

()

メソッド

AS3 function setUTCFullYear(year:Number, month:Number, day:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

年を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。

このメソッドでは、オプションで月と日を設定することもできます。このメソッドを呼び出しても他のフィールドは変更されませんが、このメソッドを呼び出した結果として曜日が変わった場合には、Date.getUTCDay() と Date.getDay() メソッドは新しい値を返すことがあります。

パラメーター

	`year:Number` — 4 桁の年（2000 など）を表す整数です。

	`month:Number` — 0（1 月）～ 11（12 月）の整数です。

	`day:Number` — 1 ～ 31 の整数です。

戻り値

Number — 整数です。

関連する API エレメント

getUTCDay()
getDay()

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。メソッド getUTCFullYear() を呼び出すと、4 桁の年が正しく返されます。次に、setUTCFullYear() を呼び出します。パラメーター year には 1975 を設定します。trace() ステートメントで年が正しく設定されたことを確認します。

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

setUTCHours

()

メソッド

AS3 function setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

時を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。オプションで、分、秒、およびミリ秒を指定することができます。

パラメーター

	`hour:Number` — 0（0 時）～ 23（午後 11 時）の整数です。

	`minute:Number` — 0 ～ 59 の整数です。

	`second:Number` — 0 ～ 59 の整数です。

	`millisecond:Number` — 0 ～ 999 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターに year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に、メソッド getHours()、getMinutes()、getUTCHours()、getUTCMinutes() を呼び出し、時と分を取得します。setUTCHours() を呼び出します。パラメーター hour には 12 を設定します。次に、メソッド getHours()、getMinutes()、getUTCHours()、getUTCMinutes() を再度呼び出し、更新された時を正しく表示します。

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

setUTCMilliseconds

()

メソッド

AS3 function setUTCMilliseconds(millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

ミリ秒を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。

パラメーター

millisecond:Number — 0 ～ 999 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getUTCMilliseconds() メソッドを呼び出し、now 作成時点の UTCMilliseconds を取得します。次に、別の Date オブジェクト before を、setUTCMilliseconds() を呼び出して（millisecond パラメーターに 4 を設定）作成します。次に、getUTCMilliseconds() を再度呼び出して、新しく設定されたミリ秒を取得します。


var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

setUTCMinutes

()

メソッド

AS3 function setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

分を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。オプションで、秒とミリ秒を指定することができます。

パラメーター

	`minute:Number` — 0 ～ 59 の整数です。

	`second:Number` — 0 ～ 59 の整数です。

	`millisecond:Number` — 0 ～ 999 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getUTCMinutes() メソッドを呼び出し、now 作成時点の UTCMinutes を取得します。次に、別の Date オブジェクト before を、setUTCMinutes() を呼び出して（minute パラメーターに 0 を設定）作成します。次に、getUTCMinutes() を再度呼び出して、新しく設定された分を取得します。

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

setUTCMonth

()

メソッド

AS3 function setUTCMonth(month:Number, day:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

月、および日（オプション）を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。このメソッドを呼び出しても他のフィールドは変更されませんが、このメソッドを呼び出した結果として曜日が変わった場合には、Date.getUTCDay() メソッドと Date.getDay() メソッドは新しい値を返すことがあります。

パラメーター

	`month:Number` — 0（1 月）～ 11（12 月）の整数です。

	`day:Number` — 1 ～ 31 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

関連する API エレメント

getDay()

例 ( この例の使用方法 )

次の例では、新しい Array オブジェクト UTCMonthLabels を作成して、January から December までのエレメントを設定し、次に、パラメーターを指定せずに新しい UTCMonth オブジェクト now を作成します。次に、getUTCMonth() メソッドを呼び出し、now 作成時点の UTCMonth を取得します。次に、setUTCMonth() を呼び出して（month パラメーターに 0 を設定）から、getUTCMonth() を再度呼び出します。これにより、新しく設定された月を取得します。

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

setUTCSeconds

()

メソッド

AS3 function setUTCSeconds(second:Number, millisecond:Number):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

秒、およびオプションでミリ秒を世界時（UTC）で設定し、新しい時刻をミリ秒で返します。

パラメーター

	`second:Number` — 0 ～ 59 の整数です。

	`millisecond:Number` — 0 ～ 999 の整数です。

戻り値

Number — ミリ秒で表される新しい時刻です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト now をパラメーターの指定なしで作成します。次に、getUTCSeconds() メソッドを呼び出し、now 作成時点の秒を取得します。次に、setUTCSeconds() を呼び出して（second パラメーターに 0 を設定）から、getUTCSeconds() を再度呼び出します。これにより、新しく設定された秒を取得します。

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

toDateString

()

メソッド

AS3 function toDateString():String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

曜日と日付のみのストリング表現を返します。時刻またはタイムゾーンは含まれません。次のメソッドと対照を成します。

Date.toTimeString() は時刻とタイムゾーンのみを返します。
Date.toString() は曜日と日付のみでなく、時刻とタイムゾーンも返します。

戻り値

String — 曜日と日付のみのストリング表現です。

関連する API エレメント

toString()

例 ( この例の使用方法 )

次の例では、パラメーター設定なしで新しい Date オブジェクト now 作成し、trace() ステートメントの中で、次のメソッドを呼び出します。

toString : now のすべてのパラメーター（now が作成されたときの）を表示します。
toDateString() : day、month、year パラメーター（now が作成されたときの）を表示します。

var now:Date = new Date();
trace(now);
trace(now.toDateString());

toJSON

()

メソッド

AS3 function toJSON(k:String):*

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 11, AIR 3, Flash Lite 4

Date オブジェクトの値の JSON エンコーディングをカスタマイズするためのオーバーライド可能なメソッドです。

JSON.stringify() メソッドは、スキャンする各オブジェクトの toJSON() メソッドを検索します。toJSON() が見つかれば、JSON.stringify() で検出された値ごとに toJSON() メソッドが呼び出され、値のペアとなっているキーが渡されます。

Date には、Date.toString() の出力を返す toJSON() のデフォルト実装が含まれます。JSON のその他の形式で Date オブジェクトを書き出す必要がある場合は、独自の実装を行うことができます。このためには、クラスのプロトタイプの toJSON() を再定義します。

toJSON() メソッドは、あらゆる型の値を返すことができます。オブジェクトを返す場合は、stringify() でそのオブジェクトが再帰的に処理されます。toJSON() が文字列を返す場合は、stringify() で再帰的な処理は行われず、オブジェクトをスキャンする処理が続行されます。

パラメーター

k:String — JSON.stringify() がこのオブジェクトをスキャンして検出されたキーと値のペアのキーです。

戻り値

* — Date.toString() のオブジェクトの値です。

関連する API エレメント

Object
Object.prototype

toLocaleDateString

()

メソッド

AS3 function toLocaleDateString():String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

曜日と日付のみのストリング表現を返します。時刻またはタイムゾーンは含まれません。このメソッドは、Date.toDateString と同じ値を返します。次のメソッドと対照を成します。

Date.toTimeString() は時刻とタイムゾーンのみを返します。
Date.toString() は曜日と日付のみでなく、時刻とタイムゾーンも返します。

戻り値

String — 曜日と日付のみの String 表現です。

toLocaleString

()

メソッド

AS3 function toLocaleString():String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

曜日、日付、時刻のストリング表現を、指定されたローカル時間で返します。同じ情報（およびタイムゾーン）をストリングの最後に年を付けて返す Date.toString() メソッドと対照を成します。

戻り値

String — Date オブジェクトのストリング表現をローカルタイムゾーンで返します。

toLocaleTimeString

()

メソッド

AS3 function toLocaleTimeString():String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

時刻のみのストリング表現を返します。曜日、日付、年、またはタイムゾーンは含まれません。時刻とタイムゾーンを返す Date.toTimeString() メソッドと対照を成します。

戻り値

String — 時刻とタイムゾーンのみのストリング表現です。

関連する API エレメント

toTimeString()

toString

()

メソッド

AS3 function toString():String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

曜日、日付、時刻、およびタイムゾーンのストリング表現を返します。出力の日付形式は、次のとおりです。

     Day Mon Date HH:MM:SS TZD YYYY

次に実際の使用例を示します。

     Wed Apr 12 15:30:17 GMT-0700 2006

戻り値

String — Date オブジェクトのストリング表現です。

例 ( この例の使用方法 )

次の例では、パラメーターを指定せずに Date オブジェクト now を作成し、次に、toString を trace() ステートメント内で呼び出します。これにより now のすべてのパラメーター（now を作成したときの）を表示します。


var now:Date = new Date();
trace(now);

toTimeString

()

メソッド

AS3 function toTimeString():String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

時刻とタイムゾーンのみのストリング表現を返します。曜日と日付は含まれません。曜日と日付のみを返す Date.toDateString() メソッドと対照を成します。

戻り値

String — 時刻とタイムゾーンのみのストリング表現です。

関連する API エレメント

toDateString()

toUTCString

()

メソッド

AS3 function toUTCString():String

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

曜日、日付、および時刻のストリング表現を世界時（UTC）で返します。例えば、2005 年 2 月 1 日を Tue Feb 1 00:00:00 2005 UTC として返します。

戻り値

String — Date オブジェクトの UTC のストリング表現です。

関連する API エレメント

toString()

UTC

()

メソッド

 public static function UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

1970 年 1 月 1 日 0 時（世界時）からパラメーターで指定された時刻までのミリ秒数を返します。このメソッドでは世界時を使用するのに対し、Date コンストラクターではローカル時間を使用します。

このメソッドは、UTC の日付を Date クラスのコンストラクターに渡す場合に便利です。Date クラスのコンストラクターはミリ秒オフセットを引数として受け取るので、Date.UTC() メソッドを使用して UTC の日付を対応のミリ秒オフセットに変換し、このオフセットを引数として Date クラスコンストラクターに送ることができます。

パラメーター

	`year:Number` — 年を表す 4 桁の整数（2000 など）です。

	`month:Number` — 0（1 月）～ 11（12 月）の整数です。

	`date:Number` (default = `1`) — 1 ～ 31 の整数です。

	`hour:Number` (default = `0`) — 0（0 時）～ 23（午後 11 時）の整数です。

	`minute:Number` (default = `0`) — 0 ～ 59 の整数です。

	`second:Number` (default = `0`) — 0 ～ 59 の整数です。

	`millisecond:Number` (default = `0`) — 0 ～ 999 の整数です。

戻り値

Number — 1970 年 1 月 1 日から指定された日時までのミリ秒数です。

例 ( この例の使用方法 )

次の例では、新しい Date オブジェクト someBirthday を作成し、パラメーターにローカル時間の year（1974）、month（10 = 11 月）、day（30）、hour（1）、minute（20）を指定します。次に、UTC() を setTime() メソッド内で呼び出し、これらのパラメーターを世界時にリセットします。

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

valueOf

()

メソッド

AS3 function valueOf():Number

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 9, AIR 1.0, Flash Lite 4

Date オブジェクトの 1970 年 1 月 1 日 0 時（世界時）からのミリ秒数を返します。

戻り値

Number — Date オブジェクトが表す 1970 年 1 月 1 日からのミリ秒数です。

例 ( この例の使用方法 )

次の例では、パラメーターを指定せずに新しい Date オブジェクト now を作成し、次に、getTime() メソッドを呼び出して、1970 年 1 月 1 日 0 時から now が作成された時刻までのミリ秒数を取得します。次に、valueOf() を呼び出して同じ値を取得します。


var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());

例この例の使用方法

DateExample.as

次の例では、次に示す変数を割り当てる場合の Date() コンストラクターの様々な使用法を示しています。

myDate1 では、パラメーターを指定せずに Date() を呼び出します。これにより、myDate1 には、使用しているシステムの日時に基づいた現在の日時が設定されます。
myDate2 では、Date() を呼び出し、パラメーターに year（2000）、month（0 = 1 月）、day（1）を渡します。
myDate3 では、Date() を呼び出し、パラメーターに year（65 = 1965）、month（2 = 3 月）、day（6）、hour（9）、minute（30）、second（15）、millisecond -+（0）を渡します。
myDate4 では、Date() を呼び出し、1970 年 1 月 1 日 0:00:00（世界時）よりも何ミリ秒前（値が負であるため）なのかを表す数値を指定します。

package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}

法律上の注意 | プライバシーポリシー

Date - AS3

パッケージx

言語エレメント

付録

クラス x

date

dateUTC

day

dayUTC

fullYear

fullYearUTC

hours

hoursUTC

milliseconds

millisecondsUTC

minutes

minutesUTC

month

monthUTC

seconds

secondsUTC

time

timezoneOffset

Date

getDate

getDay

getFullYear

getHours

getMilliseconds

getMinutes

getMonth

getSeconds

getTime

getTimezoneOffset

getUTCDate

getUTCDay

getUTCFullYear

getUTCHours

getUTCMilliseconds

getUTCMinutes

getUTCMonth

getUTCSeconds

parse

setDate

setFullYear

setHours

setMilliseconds

setMinutes

setMonth

setSeconds

setTime

setUTCDate

setUTCFullYear

setUTCHours

setUTCMilliseconds

setUTCMinutes

setUTCMonth

setUTCSeconds

toDateString

toJSON

toLocaleDateString

toLocaleString

toLocaleTimeString

toString

toTimeString

toUTCString

UTC

valueOf