NetGroup  - AS3

Specifica il numero previsto di membri del gruppo, in base alla densità dei vicini locali e presupponendo una distribuzione omogenea degli indirizzi di gruppo.

Elementi API correlati

Restituisce un oggetto NetGroupInfo le cui proprietà forniscono statistiche QoS (Quality of Service) relative al trasporto dati peer-to-peer RTMFP di questo NetGroup.

Elementi API correlati

Specifica l'inizio dell'intervallo di indirizzi di gruppo per il quale questo nodo è il "più vicino" e responsabile. L'intervallo viene specificato nella direzione in aumento lungo l'anello di indirizzi del gruppo mod 2²⁵⁶.

Elementi API correlati

Specifica la fine dell'intervallo di indirizzi di gruppo per il quale questo nodo è il "più vicino" e responsabile. L'intervallo viene specificato nella direzione in aumento lungo l'anello di indirizzi del gruppo mod 2²⁵⁶.

Elementi API correlati

Specifica il numero di membri del gruppo al quale questo nodo è connesso direttamente.

Elementi API correlati

Specifica la modalità di ricezione dell'indirizzamento di questo nodo come uno dei valori nella classe di enumerazione NetGroupReceiveMode.

Elementi API correlati

Specifica la strategia di recupero della replicazione oggetti. Il valore è uno di quelli enumerati nella classe NetGroupReplicationStrategy.

Elementi API correlati

Costruisce un oggetto NetGroup sull'oggetto NetConnection specificato e lo unisce al gruppo specificato da groupspec.

Nella maggior parte dei casi, un oggetto groupspec è in grado di utilizzare il collegamento di rete in uscita sul sistema locale. Quando un oggetto NetStream o NetGroup viene costruito con un groupspec, Flash Player visualizza la finestra di dialogo Privacy. La finestra chiede se Flash Player può utilizzare la connessione per condividere i dati con i peer di un utente. Se l'utente fa clic su "Consenti per questo dominio", la finestra di dialogo non viene visualizzata la volta successiva che l'utente si connette a questa applicazione. Se un utente non consente la connettività peer-to-peer, tutte le funzioni peer all'interno del gruppo (posting, indirizzamento diretto, replicazione di oggetti, multicast) vengono disattivate. Se l'autorizzazione viene concessa, viene inviato un evento NetStatusEvent al listener di eventi di NetConnection con NetGroup.Connect.Success nella proprietà code dell'oggetto info. Se l'autorizzazione viene negata, la proprietà code restituisce NetGroup.Connect.Rejected. Finché non viene ricevuto un evento NetGroup.Connect.Success, se tentate di chiamare qualsiasi metodo dell'oggetto NetGroup verrà generata un'eccezione.

Nota: quando un client sottoscrive un flusso multicast con IP nativo, la finestra di dialogo di sicurezza non viene visualizzata.

     new NetGroup(myConnection, myGroupSpecifier.groupspecWithAuthorizations());
     

Elementi API correlati

Aggiunge gli oggetti da startIndex a endIndex alla serie di oggetti che questo nodo segnala ai vicini come oggetti per i quali eseguirà le richieste. Per impostazione predefinita, la serie Have è vuota. Gli indici devono essere numeri interi compresi tra 0 e 9007199254740992.

Per ulteriori informazioni sulla replicazione degli oggetti, vedete "Replicate an object within a group" (Replicare un oggetto all'interno di un gruppo) nel manuale Flash Media Server Developer’s Guide.

Questo metodo invia un evento NetStatusEvent al listener di eventi di NetGroup con "NetGroup.Replication.Request" nella proprietà code dell'oggetto info.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Aggiunge manualmente un record per specificare che peerID è un membro del gruppo. Una connessione immediata viene tentata solo se è necessaria per la topologia.

Parametri

Elementi API correlati

Aggiunge manualmente un vicino, stabilendo immediatamente una connessione diretta all'oggetto peerID specificato, che deve già essere parte di questo gruppo. Questa connessione diretta potrebbe essere rimossa in seguito, se non è necessaria per la topologia.

Parametri

Elementi API correlati

Aggiunge gli oggetti da startIndex a endIndex alla serie di oggetti da recuperare. Gli indici devono essere numeri interi compresi tra 0 e 9007199254740992. Per impostazione predefinita, la serie Want è vuota.

Per ulteriori informazioni sulla replicazione degli oggetti, vedete "Replicate an object within a group" (Replicare un oggetto all'interno di un gruppo) nel manuale Flash Media Server Developer’s Guide.

Questo metodo invia un evento NetStatusEvent al listener di eventi di NetGroup con NetGroup.Replication.Fetch.SendNotify nella proprietà info.code. Questo evento è seguito da un evento NetGroup.Replication.Fetch.Failed o NetGroup.Replication.Fetch.Result.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Interrompe la connessione con il gruppo e chiude questo NetGroup. Questo NetGroup non è utilizzabile dopo la chiamata a questo metodo.

Converte un peerID in un indirizzo di gruppo adatto per essere utilizzato con il metodo sendToNearest().

Parametri

Elementi API correlati

Rifiuta la richiesta ricevuta in un evento NetStatusEvent NetGroup.Replication.Request relativamente a un oggetto precedentemente segnalato con addHaveObjects(). Il richiedente può richiedere questo oggetto di nuovo o finché non viene ritirato dalla serie Have.

Per ulteriori informazioni sulla replicazione degli oggetti, vedete "Replicate an object within a group" (Replicare un oggetto all'interno di un gruppo) nel manuale Flash Media Server Developer’s Guide.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Invia un messaggio a tutti i vicini di un gruppo. Per chiamare questo metodo, la proprietà GroupSpecifier.postingEnabled deve essere true nel groupspec passato alla funzione di costruzione NetGroup. Per ulteriori informazioni, vedete "Post messages to a group" (Inviare messaggi a un gruppo) nel manuale Flash Media Server Developer’s Guide.

Tutti i messaggi devono essere univoci. Un messaggio identico a un altro inviato in precedenza potrebbe non essere propagato. Utilizzate un numero di sequenza per rendere univoci i messaggi.

La consegna dei messaggi non è ordinata. La consegna dei messaggi non è garantita.

I messaggi sono serializzati in AMF. Il messaggio può essere di uno dei seguenti tipi: Object, int, Number o String. Non può invece essere un oggetto MovieClip.

Questo metodo invia un evento NetStatusEvent al listener di eventi di NetGroup con "NetGroup.Posting.SendNotify" nella proprietà info.code. L'evento "NetGroup.Posting.Notify" viene inviato al NetGroup sia sul client che sul server.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

package  {

    import flash.display.Sprite;
    import flash.events.TextEvent;
    import flash.events.MouseEvent;
    import flash.events.NetStatusEvent;
    import fl.events.ComponentEvent;
    import fl.controls.Label;
    import fl.controls.Button;
    import fl.controls.TextInput;
    import fl.controls.TextArea;
    import flash.text.TextFieldAutoSize;
    import flash.net.*;

    public class NetGroupPostExample extends Sprite{

        private var connectButton:Button;
        private var disconnectButton:Button;
        private var groupNameText:TextInput;
        private var userNameText:TextInput;
        private var chatText:TextInput;
        private var statusLog:TextArea;
        private var groupLabel:Label;
        private var userLabel:Label;

        private var netConnection:NetConnection = null;
        private var netGroup:NetGroup = null;
        private var sequenceNumber:uint = 0;
        private var connected:Boolean = false;
        private var joinedGroup:Boolean = false;

        private const SERVER:String = "rtmfp://fms.example.com/someapp";

        public function NetGroupPostExample() {
            DoUI();
        }

        // Writes messages to the TextArea.
        private function StatusMessage(msg:Object):void{
            statusLog.text += msg;
            statusLog.verticalScrollPosition = statusLog.textHeight;
            statusLog.validateNow();
        }

        // Handles all NetStatusEvents for the NetConnection and the NetGroup.
        // This code includes cases it doesn't handle so you can see the cases
        // and their info objects for learning purposes.
        private function NetStatusHandler(e:NetStatusEvent):void{
            StatusMessage(e.info.code + "\n");
            switch(e.info.code){
                case "NetConnection.Connect.Success":
                    connectButton.enabled = false;
                    disconnectButton.enabled = true;
                    OnConnect();
                    break;

                case "NetConnection.Connect.Closed":
                    OnDisconnect();
                    break;

                case "NetGroup.Connect.Success": // e.info.group
                    OnNetGroupConnect();
                    break;

                case "NetGroup.Connect.Rejected": // e.info.group
                case "NetGroup.Connect.Failed": // e.info.group
                    break;

                case "NetGroup.Posting.Notify": // e.info.message, e.info.messageID
                    OnPosting(e.info.message);
                    break;

                case "NetStream.MulticastStream.Reset":
                case "NetStream.Buffer.Full":
                    break;

                case "NetGroup.SendTo.Notify": // e.info.message, e.info.from, e.info.fromLocal
                case "NetGroup.LocalCoverage.Notify": //
                case "NetGroup.Neighbor.Connect": // e.info.neighbor
                case "NetGroup.Neighbor.Disconnect": // e.info.neighbor
                case "NetGroup.MulticastStream.PublishNotify": // e.info.name
                case "NetGroup.MulticastStream.UnpublishNotify": // e.info.name
                case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
                case "NetGroup.Replication.Fetch.Failed": // e.info.index
                case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
                case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
                default:
                    break;
                }
            }
        // Creates a NetConnection to Flash Media Server if the app isn't already connected
        // and if there's a group name in the TextInput field.
        private function DoConnect(e:MouseEvent):void{
            if(!connected && (groupNameText.length > 0)){
                StatusMessage("Connecting to \"" + SERVER + "\" ...\n");
                netConnection = new NetConnection();
                netConnection.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);
                // To connect to Flash Media Server, pass the server name.
                netConnection.connect(SERVER);
            }
            else
            {
                StatusMessage("Enter a group name");
            }
        }

        // Called in the "NetConnection.Connect.Success" case in the NetStatusEvent handler.
        private function OnConnect():void{

            StatusMessage("Connected\n");
            connected = true;

            // Create a GroupSpecifier object to pass to the NetGroup constructor.
            // The GroupSpecifier determines the properties of the group
            var groupSpecifier:GroupSpecifier;
            groupSpecifier = new GroupSpecifier("aslrexample/" + groupNameText.text);
            groupSpecifier.postingEnabled = true;
            groupSpecifier.serverChannelEnabled = true;

            netGroup = new NetGroup(netConnection, groupSpecifier.groupspecWithAuthorizations());
            netGroup.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

            StatusMessage("Join \"" + groupSpecifier.groupspecWithAuthorizations() + "\"\n");

        }

        private function OnNetGroupConnect():void{
            joinedGroup = true;
        }

        private function DoDisconnect(e:MouseEvent):void{
            if(netConnection){
                netConnection.close();
            }
        }

        private function OnDisconnect():void{
            StatusMessage("Disconnected\n");
            netConnection = null;
            netGroup = null;
            connected = false;
            joinedGroup = false;
            connectButton.enabled = true;
            disconnectButton.enabled = false;
        }

        private function ClearChatText():void{
            chatText.text = "";
        }

        // Called when you the chatText field has focus and you press Enter.
        private function DoPost(e:ComponentEvent):void{
            if(joinedGroup){
                var message:Object = new Object;
                message.user = userNameText.text;
                message.text = chatText.text;
                message.sequence = sequenceNumber++;
                message.sender = netConnection.nearID;

                netGroup.post(message);
                StatusMessage("==> " + chatText.text + "\n");
            } else {
                StatusMessage("Click Connect before sending a chat message");
            }
            ClearChatText();
        }

        private function OnPosting(message:Object):void{
            StatusMessage("<" + message.user + "> " + message.text + "\n");
        }

        private function DoUI():void {

            groupLabel = new Label();
            groupLabel.move(20, 10);
            groupLabel.autoSize = TextFieldAutoSize.LEFT
            groupLabel.text = "Group name:"
            addChild(groupLabel);

            groupNameText = new TextInput();
            groupNameText.move(90, 10);
            groupNameText.text = "channel" + (int(Math.random() * 899) + 101);
            addChild(groupNameText);

            connectButton = new Button();
            connectButton.addEventListener(MouseEvent.CLICK, DoConnect);
            connectButton.move(205, 10);
            connectButton.label = "Connect";
            addChild(connectButton);

            disconnectButton = new Button();
            disconnectButton.addEventListener(MouseEvent.CLICK, DoDisconnect);
            disconnectButton.move(310, 10);
            disconnectButton.label = "Disconnect";
            disconnectButton.enabled = false;
            addChild(disconnectButton);

            statusLog = new TextArea();
            statusLog.move(30, 38);
            statusLog.width = 360;
            statusLog.height = 215;
            statusLog.editable = false;
            addChild(statusLog);

            userLabel = new Label();
            userLabel.move(20, 270);
            userLabel.autoSize = TextFieldAutoSize.LEFT
            userLabel.text = "User name:"
            addChild(userLabel);

            userNameText = new TextInput();
            userNameText.move(80, 270);
            userNameText.text = "user " + int(Math.random() * 65536);
            addChild(userNameText);

            chatText = new TextInput();
            chatText.addEventListener(ComponentEvent.ENTER, DoPost);
            chatText.move(185, 270);
            chatText.maxChars = 255;
            chatText.width = 215;
            addChild(chatText);

        }

        public function onPlayStatus(info:Object):void {}
        public function onMetaData(info:Object):void {}
        public function onCuePoint(info:Object):void {}
        public function onTextData(info:Object):void {}

    }

}

Rimuove gli oggetti da startIndex a endIndex dalla serie di oggetti che questo nodo segnala ai vicini come oggetti per i quali eseguirà le richieste. Gli indici devono essere numeri interi compresi tra 0 e 9007199254740992.

Per ulteriori informazioni sulla replicazione degli oggetti, vedete "Replicate an object within a group" (Replicare un oggetto all'interno di un gruppo) nel manuale Flash Media Server Developer’s Guide.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Rimuove gli oggetti da startIndex a endIndex dalla serie di oggetti da recuperare. Gli indici devono essere numeri interi compresi tra 0 e 9007199254740992.

Per ulteriori informazioni sulla replicazione degli oggetti, vedete "Replicate an object within a group" (Replicare un oggetto all'interno di un gruppo) nel manuale Flash Media Server Developer’s Guide.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Invia un messaggio a tutti i vicini. Restituisce NetGroupSendResult.SENT se è stato selezionato almeno un vicino.

Per ulteriori informazioni sull'instradamento dei messaggi, vedete "Route messages directly to a peer" (Instradare messaggi direttamente a un peer) nel manuale Flash Media Server Developer’s Guide.

Quando un nodo riceve un messaggio, viene inviato un evento NetStatusEvent al listener di eventi di NetGroup con NetGroup.SendTo.Notify nella proprietà code dell'oggetto info.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Invia un messaggio al vicino (o nodo locale) più prossimo all'indirizzo di gruppo specificato. Considera i vicini dall'intero anello. Restituisce NetGroupSendResult.SENT se il messaggio è stato inviato correttamente alla destinazione.

Per ulteriori informazioni sull'instradamento dei messaggi, vedete "Route messages directly to a peer" (Instradare messaggi direttamente a un peer) nel manuale Flash Media Server Developer’s Guide.

Quando un nodo riceve un messaggio, viene inviato un evento NetStatusEvent al listener di eventi di NetGroup con NetGroup.SendTo.Notify nella proprietà code dell'oggetto info.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Invia un messaggio al vicino specificato dal parametro sendMode. Restituisce NetGroupSendResult.SENT se il messaggio è stato inviato correttamente alla destinazione richiesta.

Per ulteriori informazioni sull'instradamento dei messaggi, vedete "Route messages directly to a peer" (Instradare messaggi direttamente a un peer) nel manuale Flash Media Server Developer’s Guide.

Quando un nodo riceve un messaggio, viene inviato un evento NetStatusEvent al listener di eventi di NetGroup con NetGroup.SendTo.Notify nella proprietà code dell'oggetto info.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Soddisfa la richiesta ricevuta da NetStatusEvent NetGroup.Replication.Request relativamente a un oggetto precedentemente segnalato con il metodo addHaveObjects(). L'oggetto può essere di uno dei seguenti tipi: Object, int, Number o String. Non può invece essere un oggetto MovieClip.

Per ulteriori informazioni sulla replicazione degli oggetti, vedete "Replicate an object within a group" (Replicare un oggetto all'interno di un gruppo) nel manuale Flash Media Server Developer’s Guide.

NOTA: eseguite una prova dell'evento NetGroup.Neighbor.Connect prima di chiamare questo metodo.

Parametri

Elementi API correlati

Inviato quando un oggetto NetGroup segnala il proprio stato o una condizione di errore. L'evento netStatus contiene una proprietà info. La proprietà info è un oggetto che contiene informazioni sull'evento, ad esempio se un tentativo di connessione è riuscito o fallito.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Quando eseguite l'applicazione, potete immettere qualunque nome di gruppo nel campo di testo di input. La classe GroupSpecifier usa il nome (insieme alle eventuali proprietà GroupSpecifier che avete impostato) per creare una stringa che diventa il nome univoco e definitivo del gruppo. Per connettere un altro client al gruppo, tale client deve utilizzare lo stesso nome di gruppo. Ad esempio, se il client A utilizza il nome gruppo "firstmesh", gli altri client che intendono comunicare con il client A dovranno a loro volta utilizzare il nome gruppo "firstmesh". Se il client B usa invece il nome gruppo "kite", la connessione verrà stabilita correttamente, ma verrà creato un nuovo nome gruppo e il client B non sarà in grado di comunicare con il client A o con altri membri del gruppo "firstmesh".

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="100%" height="100%" applicationComplete="OnApplicationComplete()">
    <mx:Script>
        <![CDATA[
            private var netConnection:NetConnection = null;
            private var netStream:NetStream = null;
            private var netGroup:NetGroup = null;
            private var video:Video = null;
            private var sequenceNumber:uint = 0;
            private var resizeTimer:Timer = null;

            private const SERVER:String = "rtmfp://fms.example.com/someapp";

            [Bindable] private var connected:Boolean = false;
            [Bindable] private var joinedGroup:Boolean = false;

            private function OnApplicationComplete():void
            {
                userName.text = "user " + int(Math.random() * 65536);

                groupName.text = "channel" + (int(Math.random() * 899) + 101);

                resizeTimer = new Timer(2000.0);
                resizeTimer.addEventListener(TimerEvent.TIMER, DoResizeVideo);
                resizeTimer.start();
            }

            private function StatusMessage(msg:Object):void
            {
                statusLog.text += msg;
                statusLog.verticalScrollPosition = statusLog.textHeight;
                statusLog.validateNow();
            }

            private function NetStatusHandler(e:NetStatusEvent):void
            {
                StatusMessage(e.info.code);
                switch(e.info.code)
                {
                case "NetConnection.Connect.Success":
                    OnConnect();
                    break;

                case "NetConnection.Connect.Closed":
                case "NetConnection.Connect.Failed":
                case "NetConnection.Connect.Rejected":
                case "NetConnection.Connect.AppShutdown":
                case "NetConnection.Connect.InvalidApp":
                    OnDisconnect();
                    break;

                case "NetStream.Connect.Success": // e.info.stream
                    OnNetStreamConnect();
                    break;

                case "NetStream.Connect.Rejected": // e.info.stream
                case "NetStream.Connect.Failed": // e.info.stream
                    DoDisconnect();
                    break;

                case "NetGroup.Connect.Success": // e.info.group
                    OnNetGroupConnect();
                    break;

                case "NetGroup.Connect.Rejected": // e.info.group
                case "NetGroup.Connect.Failed": // e.info.group
                    DoDisconnect();
                    break;

                case "NetGroup.Posting.Notify": // e.info.message, e.info.messageID
                    OnPosting(e.info.message);
                    break;


                case "NetStream.MulticastStream.Reset":
                case "NetStream.Buffer.Full":
                    DoResizeVideo();
                    break;

                case "NetGroup.SendTo.Notify": // e.info.message, e.info.from, e.info.fromLocal
                case "NetGroup.LocalCoverage.Notify": //
                case "NetGroup.Neighbor.Connect": // e.info.neighbor
                case "NetGroup.Neighbor.Disconnect": // e.info.neighbor
                case "NetGroup.MulticastStream.PublishNotify": // e.info.name
                case "NetGroup.MulticastStream.UnpublishNotify": // e.info.name
                case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
                case "NetGroup.Replication.Fetch.Failed": // e.info.index
                case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
                case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
                default:
                    break;
                }
            }

            private function DoConnect():void
            {
                StatusMessage("Connecting to \"" + SERVER + "\" ...\n");
                netConnection = new NetConnection();
                netConnection.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);
                netConnection.connect(SERVER);
            }

            private function OnConnect():void
            {
                var groupSpecifier:GroupSpecifier;

                StatusMessage("Connected\n");
                connected = true;

                groupSpecifier = new GroupSpecifier("max2009lab/" + groupName.text);
                groupSpecifier.multicastEnabled = true;
                groupSpecifier.postingEnabled = true;
                groupSpecifier.serverChannelEnabled = true;

                netStream = new NetStream(netConnection, groupSpecifier.groupspecWithAuthorizations());
                netStream.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

                netGroup = new NetGroup(netConnection, groupSpecifier.groupspecWithAuthorizations());
                netGroup.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

                StatusMessage("Join \"" + groupSpecifier.groupspecWithAuthorizations() + "\"\n");
            }

            private function OnNetStreamConnect():void
            {
                netStream.client = this;

                var mic:Microphone = Microphone.getMicrophone();
                if(mic)
                {
                    mic.codec = SoundCodec.SPEEX;
                    mic.setSilenceLevel(0);

                    netStream.attachAudio(mic);

                    StatusMessage("got microphone\n");
                }

                var camera:Camera = Camera.getCamera();
                if(camera)
                {
                    camera.setMode(320, 240, 10);
                    camera.setQuality(30000, 0);
                    camera.setKeyFrameInterval(15);

                    videoDisplay.attachCamera(camera);
                    videoDisplay.maintainAspectRatio = true;

                    netStream.attachCamera(camera);

                    StatusMessage("got camera\n");
                }

                netStream.publish("stream");
            }

            private function OnNetGroupConnect():void
            {
                joinedGroup = true;
            }

            private function DoDisconnect():void
            {
                if(netConnection)
                    netConnection.close();
                videoDisplay.attachCamera(null);
            }

            private function OnDisconnect():void
            {
                StatusMessage("Disconnected\n");
                netConnection = null;
                netStream = null;
                netGroup = null;
                connected = false;
                joinedGroup = false;
            }

            private function ClearChatText():void
            {
                chatText.text = "";
            }

            private function DoPost():void
            {
                var message:Object = new Object;

                message.user = userName.text;
                message.text = chatText.text;
                message.sequence = sequenceNumber++;
                message.sender = netConnection.nearID;

                netGroup.post(message);

                StatusMessage("==> " + chatText.text + "\n");

                chatText.callLater(ClearChatText);
            }

            private function OnPosting(message:Object):void
            {
                StatusMessage("<" + message.user + "> " + message.text + "\n");
            }

            private function DoResizeVideo(ignored:* = null):void
            {
                if(video)
                {
                    if( (0 == video.videoHeight)
                     || (0 == video.videoWidth)
                    )
                    {
                        video.height = videoDisplay.height;
                        video.width = videoDisplay.width;
                        video.x = 0;
                        video.y = 0;
                    }
                    else
                    {
                        var videoAspect:Number = Number(video.videoWidth) / Number(video.videoHeight);
                        var displayAspect:Number = Number(videoDisplay.width) / Number(videoDisplay.height);
                        var adjustFactor:Number;

                        if(videoAspect >= displayAspect) // video is wider than display
                        {
                            adjustFactor = Number(video.videoWidth) / Number(videoDisplay.width);
                            video.width = videoDisplay.width;
                            video.height = int(Number(video.videoHeight) / adjustFactor);
                            video.x = 0;
                            video.y = int((videoDisplay.height - video.height) / 2);
                        }
                        else
                        {
                            adjustFactor = Number(video.videoHeight) / Number(videoDisplay.height);
                            video.height = videoDisplay.height;
                            video.width = int(Number(video.videoWidth) / adjustFactor);
                            video.x = int((videoDisplay.width - video.width) / 2);
                            video.y = 0;
                        }
                    }
                }
            }

            public function onPlayStatus(info:Object):void {}
            public function onMetaData(info:Object):void {}
            public function onCuePoint(info:Object):void {}
            public function onTextData(info:Object):void {}

            public function ValidateConnectAllowed(isConnected:Boolean, groupNameText:String):Boolean
            {
                return (!isConnected) && (groupNameText.length > 0);
            }
        ]]>
    </mx:Script>

    <mx:VBox top="10" right="10" left="10" bottom="10" verticalGap="6">
        <mx:HBox width="100%">
            <mx:Text text="Group:"/>
            <mx:TextInput id="groupName" width="100%" text="default" enabled="{!connected}"/>
            <mx:Button label="Connect" click="DoConnect()" enabled="{ValidateConnectAllowed(connected, groupName.text)}" />
            <mx:Button label="Disconnect" click="DoDisconnect()" enabled="{connected}" />
        </mx:HBox>
        <mx:VideoDisplay id="videoDisplay" width="320" height="240" resize="DoResizeVideo()"/>
        <mx:TextArea id="statusLog" width="100%" height="100%"/>
        <mx:HBox width="100%">
            <mx:TextInput id="userName" width="160" />
            <mx:TextInput id="chatText" width="100%" enabled="{joinedGroup}" enter="DoPost()"/>
        </mx:HBox>
    </mx:VBox>

</mx:Application>