FocusEvent  - AS3

Specifica la direzione di attivazione di un evento focusIn.

Elementi API correlati

Se è true, la proprietà relatedObject viene impostata su null per motivi riconducibili alle sandbox. Se il valore nominale di relatedObject è un riferimento a DisplayObject in un'altra sandbox, relatedObject viene impostato su null a meno che non vi sia autorizzazione in entrambe le direzioni attraverso questa sandbox. L'autorizzazione si stabilisce chiamando Security.allowDomain() da un file SWF o fornendo un file di criteri dal server di un file di immagine e impostando la proprietà LoaderContext.checkPolicyFile quando si carica l'immagine.

Elementi API correlati

Il valore del codice tasto del tasto premuto per attivare un evento keyFocusChange.

Un riferimento all'istanza complementare di InteractiveObject che è interessata dal cambiamento di attivazione. Ad esempio, quando si verifica un evento focusOut, la proprietà relatedObject rappresenta l'istanza InteractiveObject che è stata attivata.

Il valore di questa proprietà può essere null in due casi: se non vi è un oggetto correlato oppure se esiste un oggetto correlato ma si trova in una sandbox a cui non si può accedere. Per individuare il motivo, utilizzate la proprietà isRelatedObjectInaccessible().

Elementi API correlati

Indica se il modificatore del tasto Maiusc è attivato; in questo caso il valore è true. In caso contrario, il valore è false. Questa proprietà è utilizzata solo se FocusEvent è di tipo keyFocusChange.

Crea un oggetto Event con informazioni specifiche relative agli eventi di attivazione. Gli oggetti evento vengono passati ai listener di eventi come parametri.

Elementi API correlati

Crea una copia dell'oggetto FocusEvent e imposta il valore di ogni proprietà in modo che corrisponda a quello dell'originale.

Restituisce una stringa che contiene tutte le proprietà dell'oggetto FocusEvent. La stringa ha il seguente formato:

[FocusEvent type=valore bubbles=valore cancelable=valore relatedObject=valore shiftKey=valore] keyCode=valore]

Definisce il valore della proprietà type di un oggetto evento focusIn.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento focusOut.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento keyFocusChange.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento mouseFocusChange.

Questo evento ha le seguenti proprietà:

Elementi API correlati

1. Dichiara le proprietà child (di tipo Sprite) e childCount (di tipo uint).
2. Un ciclo for crea cinque quadrati blu chiaro in corrispondenza delle coordinate (0,0). Inizia dall'assegnazione di child a una nuova istanza CustomSprite. Ogni volta che viene creato un oggetto CustomSprite, vengono eseguite le seguenti operazioni:
   • La proprietà size di tipo uint viene impostata su 50 pixel e bgColor su blu chiaro.
   • Le proprietà buttonMode e useHandCursor della classe Sprite vengono impostate su true all'interno della funzione di costruzione.
   • Viene istanziato un listener di eventi di tipo click unitamente al sottoscrittore clickHandler() associato. Il metodo subscriber crea una variabile locale target di tipo Sprite e la assegna a qualsiasi casella su cui si è fatto clic. Lo stato attivo dello stage viene quindi assegnato a target.
   • Viene chiamato il metodo draw(), che crea un quadrato di 50 x 50 pixel mediante una chiamata ai metodi beginFill(), drawRect() e endFill() della classe Graphics e alle proprietà dell'istanza.
3. Nel ciclo for viene chiamato il metodo configureListeners(), che crea un'istanza di tre listener/subscriber di eventi:
   • focusIn/focusInHandler() viene inviato dopo l'evento click per qualsiasi oggetto elenco di visualizzazione (casella) su cui viene fatto clic.
   • focusOut/focusOutHandler() viene inviato quando viene fatto clic su un'altra casella o quando lo stato attivo esce dallo stage (ad esempio, facendo clic all'esterno di Flash Player).
   • keyFocusChange/keyFocusChangeHandler() viene inviato se si utilizza il tasto Tab o il tasto Freccia destra o Freccia sinistra per selezionare un oggetto elenco di visualizzazione. Il metodo keyFocusChangeHandler(), tuttavia, intercetta i tasti Freccia sinistra e Freccia destra e chiama il metodo preventDefault() per disattivarli.
4. Nel ciclo for ogni quadrato viene aggiunto all'elenco di visualizzazione e visualizzato (tutti nella stesa area) mediante addChild().
5. La funzione di costruzione chiama quindi refreshLayout(), che distribuisce i quadrati arancione nella parte superiore (y = 0) del display, ciascuno separato da 5 pixel.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}