SQLStatement  - AS3

Indica se l'istruzione è attualmente in esecuzione.

Questa proprietà è true se è stata effettuata una chiamata a execute() e non tutti i risultati sono stati restituiti dal database.

Elementi API correlati

Indica una classe (tipo di dati) che viene utilizzata da ciascuna riga restituita come risultato dell'esecuzione dell'istruzione.

Per impostazione predefinita, ogni riga restituita da un'istruzione SELECT viene creata sotto forma di istanza Object, con i nomi della colonna del set di risultati utilizzati come nomi delle proprietà dell'oggetto e il valore di ogni colonna come valore della proprietà associata.

Se si specifica una classe per la proprietà itemClass, ogni riga restituita da un'istruzione SELECT eseguita da questa istanza SQLStatement viene creata sotto forma di istanza della classe definita. A ogni proprietà dell'istanza itemClass viene assegnato il valore della colonna che ha lo stesso nome della proprietà.

Ogni classe assegnata a questa proprietà deve avere una funzione di costruzione che non richieda alcun parametro. Inoltre, per ogni colonna della classe restituita dall'istruzione SELECT deve essere presente una sola proprietà. Viene considerato un errore il caso in cui a una colonna dell'elenco SELECT non corrisponda un nome di proprietà nella classe itemClass.

Altri esempi

Elementi API correlati

// Employee class definition
package
{
    public class Employee
    {
        public var name:String;
        public var ssn:String;
        public var id:uint;
        public override function toString():String
        {
            return "id: "+ id.toString() + " name: " + name + " ssn: " + ssn;
        }
    }
}


// using the Employee class as SQLStatement.itemClass
var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    dbStatement.itemClass = Employee;
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.execute();
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var emp:Employee;
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            emp = result.data[i];
            trace(emp.toString());
        }
    }
}

Funge da array associativo al quale potete aggiungere valori per i parametri specificati nella proprietà text dell'istruzione SQL. Le chiavi dell'array sono i nomi dei parametri. Se nel testo dell'istruzione viene specificato un parametro senza nome, la relativa chiave è l'indice del parametro.

Nel testo di un'istruzione SQL, un parametro viene indicato con uno dei caratteri seguenti: "?", ":" o "@".

I token ":" e "@" indicano un parametro con nome; i caratteri che seguono il token definiscono il nome del parametro.

Ad esempio, nell'istruzione SQL seguente, viene specificato un parametro di nome firstName mediante il carattere ":":

SELECT FROM employees WHERE firstName = :firstName

Il token "?" indica un parametro indicizzato (numerato); a ogni parametro viene automaticamente assegnato un indice in base alla sequenza di parametri nel testo dell'istruzione. I valori di indice del parametro hanno base zero. In altre parole, il primo indice del parametro è 0.

I parametri vengono utilizzati per consentire la sostituzione con tipo di valori che sono sconosciuti al momento della costruzione dell'istruzione SQL. L'utilizzo dei parametri è l'unico modo per garantire la classe di archiviazione per un valore passato al database. Quando non vengono utilizzati i parametri, tutti i valori vengono convertiti dalla relativa rappresentazione sotto forma di testo a una classe di archiviazione basata sull'affinità di tipo della colonna associata. Per maggiori informazioni sulle classi di archiviazione e l'affinità delle colonne, vedete la sezione Supporto per i tipi di dati nell'appendice Supporto SQL nei database locali.

I parametri vengono utilizzati anche come misura di sicurezza, per impedire un attacco dannoso noto come iniezione SQL. In un attacco iniezione SQL, un utente immette del codice SQL in una posizione a cui l'utente ha accesso (ad esempio, un campo di immissione dati). Se il codice dell'applicazione costruisce un'istruzione SQL concatenando direttamente l'input da parte dell'utente nel testo SQL, il codice SQL immesso dall'utente viene eseguito sul database. L'elenco seguente mostra un esempio di concatenazione dell'input da parte dell'utente nel testo SQL. Non utilizzate questa tecnica:

     // assume the variables "username" and "password"
     // contain user-entered data
     var sql:String =
         "SELECT userId " +
         "FROM users " +
         "WHERE username = '" + username + "' " +
         "    AND password = '" + password + "'";
     var statement:SQLStatement = new SQLStatement();
     statement.text = sql;
     

L'utilizzo dei parametri di istruzione anziché la concatenazione di valori immessi dall'utente nel testo di un'istruzione impedisce un attacco di iniezione SQL, poiché i valori dei parametri vengono trattati esplicitamente come valori sostituiti anziché diventare parte del testo dell'istruzione letterale. Di seguito è riportata l'alternativa consigliata all'elenco precedente:

     // assume the variables "username" and "password"
     // contain user-entered data
     var sql:String =
         "SELECT userId " +
         "FROM users " +
         "WHERE username = :username " +
         "    AND password = :password";
     var statement:SQLStatement = new SQLStatement();
     statement.text = sql;
     // set parameter values
     statement.parameters[":username"] = username;
     statement.parameters[":password"] = password;
     

Tutti i valori di parametro devono essere impostati prima che venga eseguita l'istruzione. I valori di parametro specificati nell'array parameters vengono associati (cioè combinati con il testo dell'istruzione) quando viene chiamato il metodo execute(). Una volta effettuata la chiamata a execute(), tutte le successive modifiche apportate ai valori non vengono applicate all'istruzione in esecuzione. Tuttavia, alla successiva chiamata a execute() vengono utilizzati i valori modificati. Se il testo dell'istruzione include un parametro per cui non è specificato un valore nella proprietà parameters, viene generato un errore.

Per cancellare tutti i valori di parametro dalla proprietà parameters, utilizzate il metodo clearParameters().

Altri esempi

Elementi API correlati

// employees is a SQLStatement instance
employees.text = "SELECT FROM employees WHERE first = :firstName";
employees.parameters[":firstName"] = "Sam";
employees.execute();

// employees is a SQLStatement instance
employees.text = "SELECT FROM employees WHERE first = ?";
employees.parameters[0] = "Sam";
employees.execute();

L'oggetto SQLConnection che gestisce la connessione a uno o più database su cui l'istruzione viene eseguita.

Il testo SQL effettivo dell'istruzione.

Il testo può essere costituito da qualunque SQL supportato. Per una descrizione completa del dialetto SQL supportato nei database SQL locali, vedete l'appendice Supporto SQL nei database locali.

Crea un'istanza SQLStatement.

Annulla l'esecuzione di questa istruzione. Come per SQLConnection.cancel(), questo metodo viene utilizzato per interrompere una query dall'esecuzione lunga o per annullare una query che non è ancora stata completata. Tuttavia, a differenza di SQLConnection.cancel(), questo metodo annulla solo la singola istruzione. Se l'istruzione non è al momento in esecuzione, la chiamata a questo metodo non esegue alcuna operazione.

Non viene inviato alcun evento in risposta al completamento dell'operazione cancel(). Tuttavia, una volta completata l'operazione cancel() e annullata l'esecuzione dell'istruzione, l'istanza SQLStatement invia un evento error che indica che l'esecuzione dell'istruzione (la chiamata a execute() o next()) non è stata completata. In alternativa, se è stato specificato un valore per il parametro responder della chiamata a execute() o next(), viene chiamato il metodo del gestore errori specificato. In entrambi i casi, l'istanza SQLError che viene passata ai listener ha una proprietà errorID con valore 3118 (Operazione annullata).

Cancella tutte le impostazioni di parametro correnti.

Elementi API correlati

Esegue il codice SQL nella proprietà text sul database connesso all'oggetto SQLConnection nella proprietà sqlConnection.

Se l'argomento responder non è null, l'oggetto Responder specificato designa i metodi che vengono chiamati per gestire i risultati dell'operazione. Se l'argomento responder è null, in modalità di esecuzione asincrona viene inviato un evento result, se l'operazione ha avuto esito positivo, oppure un evento error, se l'operazione ha avuto esito negativo.

Per accedere ai risultati di un'istruzione, ad esempio le righe dei risultati di un'istruzione SELECT o la chiave primaria di un'istruzione INSERT generata dal database, chiamate il metodo getResult(). I risultati sono disponibili immediatamente dopo l'esecuzione dell'istruzione in modalità sincrona e quando viene inviato l'evento result in modalità asincrona.

Ogni istruzione deve essere preparata (compilata) prima di essere eseguita. La prima volta che viene chiamato il metodo execute() di un'istruzione SQLStatement, l'istruzione viene preparata dal runtime. Una volta preparata, l'istruzione non deve essere preparata di nuovo a meno che non venga modificata la proprietà text. L'impostazione di uno o più valori di parametro non richiede una nuova preparazione dell'istruzione.

Parametri

Altri esempi

Elementi API correlati

var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.addEventListener(SQLErrorEvent.ERROR, errorHandler);
    dbStatement.execute();
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
    }
}

function errorHandler(event:SQLErrorEvent):void
{
    trace("An error occured while executing the statement.");
}

var conn:SQLConnection;
var dbStatement:SQLStatement;
var employeeResponder:Responder;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    employeeResponder = new Responder(resultHandler, errorHandler);
    dbStatement.execute(-1, employeeResponder);
}

function resultHandler(result:SQLResult):void
{
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
    }
}

function errorHandler(error:SQLError):void
{
    trace("An error occured while executing the statement.");
}

Fornisce accesso a un oggetto SQLResult contenente i risultati dell'esecuzione di un'istruzione, comprese le righe dei risultati di un'istruzione SELECT e altre informazioni sull'esecuzione per tutte le istruzioni eseguite. In modalità di esecuzione asincrona, le informazioni sui risultati non sono disponibili fino a quando non viene inviato l'evento result.

Quando viene eseguita un'istruzione SELECT, se il metodo execute() viene chiamato con l'argomento prefetch predefinito -1, l'oggetto SQLResult restituito contiene l'intero set di risultati della query.

Quando specificate un argomento prefetch per una chiamata a un metodo execute() o next(), il metodo getResult() si comporta come una coda di risultati in cui il primo elemento in entrata è il primo in uscita. Ogni volta che viene inviato l'evento result, un nuovo oggetto SQLResult viene aggiunto alla coda. Ogni volta che viene chiamato il metodo getResult(), il primo oggetto SQLResult (cioè quello aggiunto per primo alla coda) viene restituito e rimosso dalla coda. Quando nella coda non rimane più alcun oggetto SQLResult, getResult() restituisce null.

A meno che non vengano rimossi chiamando getResult(), gli oggetti SQLResult rimangono nella coda. Ad esempio, se chiamate più volte il metodo execute() senza chiamare getResult(), gli oggetti SQLResult associati a ogni chiamata execute() rimangono nella coda.

Altri esempi

Elementi API correlati

Recupera la porzione successiva di un set di risultati dell'istruzione SELECT. Se nel set di risultati non sono presenti altre righe, viene inviato un evento result ma non viene aggiunto alcun oggetto SQLResult supplementare alla coda getResult().

In modalità di esecuzione asincrona, se l'argomento responder non è null l'oggetto Responder specificato indica i metodi che vengono chiamati per gestire i risultati dell'operazione. Se l'argomento responder è null, viene inviato un evento result se l'operazione ha avuto esito positivo oppure un evento error se l'operazione ha avuto esito negativo.

Questo metodo può essere chiamato solo quando l'istruzione è ancora in fase di esecuzione. Quando l'istruzione è una query SELECT e viene specificato un argomento prefetch maggiore di zero, l'istruzione viene considerata in esecuzione fino a quando non viene restituito l'intero set di risultati o non viene chiamato il metodo SQLStatement.cancel() o SQLConnection.cancel().

Parametri

Altri esempi

Elementi API correlati

var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.addEventListener(SQLErrorEvent.ERROR, errorHandler);
    dbStatement.execute(10);
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
        if (!result.complete)
        {
            dbStatement.next(10);
        }
    }
}

function errorHandler(event:SQLErrorEvent):void
{
    trace("An error occured while executing the statement.");
}

Inviato quando si verifica un errore durante un'operazione.

Elementi API correlati

Inviato quando un'operazione di una chiamata al metodo execute() o next() ha esito positivo. Quando l'evento result viene inviato, è possibile chiamare il metodo getResult() per recuperare i risultati dell'istruzione.

Elementi API correlati