| Package | flash.ui |
| Classe | public final class MouseCursorData |
| Héritage | MouseCursorData  Object |
| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | Flash Player 10.2, AIR 2.6 |
Pour afficher le curseur, utilisez la fonction Mouse.registerCursor(). Pour que le système d’exploitation reprenne le contrôle de l’image associée au curseur, appelez Mouse.unregisterCursor(). Appelez Mouse.supportsNativeCursor pour vérifier si les curseurs natifs sont pris en charge sur l’ordinateur actuel.
La taille maximale du curseur est de 32 x 32 pixels. La transparence est prise en charge sur la plupart des systèmes d’exploitation.
Un curseur de souris natif est implémenté directement via le mécanisme de curseur du système d’exploitation curseur et est un moyen plus efficace d’afficher une image de curseur personnalisé que d’utiliser un objet d’affichage. Il est possible d’animer le curseur en fournissant plus d’une image dans la propriété data et en définissant la cadence.
Le curseur est uniquement affiché à l’intérieur des limites de la scène. En dehors de la scène, le contrôle de l’image associée au curseur revient au système d’exploitation.
Informations complémentaires
Eléments de l’API associés
Masquer les propriétés publiques héritées
Afficher les propriétés publiques héritées| Propriété | Défini par | ||
|---|---|---|---|
 | constructor : Object
Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet. | Object | |
| data : Vector.<BitmapData>
Vecteur d’objets BitmapData contenant l’image ou les images associées au curseur. | MouseCursorData | ||
| frameRate : Number
Cadence pour animer le curseur. | MouseCursorData | ||
| hotSpot : Point
Zone sensible du curseur, en pixels. | MouseCursorData | ||
| Méthode | Défini par | ||
|---|---|---|---|
Crée un objet MouseCursorData. | MouseCursorData | ||
|
Indique si la propriété spécifiée d’un objet est définie. | Object | |
|
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre. | Object | |
|
Indique si la propriété spécifiée existe et est énumérable. | Object | |
|
Définit la disponibilité d’une propriété dynamique pour les opérations en boucle. | Object | |
|
Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur. | Object | |
|
Renvoie la représentation sous forme de chaîne de l’objet spécifié. | Object | |
|
Renvoie la valeur primitive de l’objet spécifié. | Object | |
data | propriété |
data:Vector.<BitmapData>| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | Flash Player 10.2, AIR 2.6 |
Vecteur d’objets BitmapData contenant l’image ou les images associées au curseur.
Fournissez plusieurs images et définissez la propriété framerate pour animer le curseur.
La taille maximale du curseur est de 32 x 32 pixels.
Implémentation
public function get data():Vector.<BitmapData> public function set data(value:Vector.<BitmapData>):voidframeRate | propriété |
frameRate:Number| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | Flash Player 10.2, AIR 2.6 |
Cadence pour animer le curseur.
Fournissez plusieurs images dans la propriété data et définissez la cadence sur une valeur supérieure à 0 pour animer le curseur. La cadence du curseur peut être différente de la cadence réelle du SWF.
Implémentation
public function get frameRate():Number public function set frameRate(value:Number):voidhotSpot | propriété |
hotSpot:Point| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | Flash Player 10.2, AIR 2.6 |
Zone sensible du curseur, en pixels.
La zone sensible est le point sur le curseur sous lequel les clics de souris sont enregistrés. Par défaut, la zone sensible correspond au coin supérieur gauche (0,0).
Implémentation
public function get hotSpot():Point public function set hotSpot(value:Point):voidMouseCursorData | () | Constructeur |
public function MouseCursorData()| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | Flash Player 10.2, AIR 2.6 |
Crée un objet MouseCursorData.
Pour afficher le curseur, appelez la fonction Mouse.registerCursor().
Eléments de l’API associés
L’exemple utilise les commandes de dessin disponibles via la classe Graphics pour créer huit images d’une flèche avec une rotation. Ces images sont placées dans un vecteur et affectées à la propriété data de l’objet MouseCursorData. (Notez que vous pouvez également utiliser des images bitmap pré-rendues pour vos curseurs.)
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.GraphicsPath;
import flash.ui.MouseCursorData;
import flash.ui.Mouse;
import flash.geom.Matrix;
public class MouseCursorDataExample extends Sprite {
//Graphics path data for an arrow
private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
public function MouseCursorDataExample() {
var mouseCursorData:MouseCursorData = new MouseCursorData();
mouseCursorData.data = makeCursorImages();
mouseCursorData.frameRate = 1;
Mouse.registerCursor( "spinningArrow", mouseCursorData );
Mouse.cursor = "spinningArrow";
}
//Returns a Vector containing 8 cursor images
private function makeCursorImages():Vector.<BitmapData>
{
var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
var cursorShape:Shape = new Shape();
cursorShape.graphics.beginFill( 0xff5555, .75 );
cursorShape.graphics.lineStyle( 1 );
cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
cursorShape.graphics.endFill();
var transformer:Matrix = new Matrix();
//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames
for( var i:int = 0; i < 8; i++ )
{
var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
cursorFrame.draw( cursorShape, transformer );
cursorData.push( cursorFrame );
transformer.translate(-15,-15);
transformer.rotate( 0.785398163 );
transformer.translate(15,15);
}
return cursorData;
}
}
}
Tue Jun 12 2018, 09:30 AM Z