WorkerDomain  - AS3

L’occurrence de WorkerDomain dans laquelle le code est en cours d’exécution. Il s’agit de l’unique objet WorkerDomain dans l’application.

Indique si le contexte du moteur d’exécution actuel prend en charge les objets WorkerDomain et Worker pour l’exécution de code simultanée.

Si la fonction de simultanéité est disponible, la valeur de cette propriété est true.

Crée une nouvelle occurrence de Worker à partir des octets d’un fichier swf.

Chaque programme de travail est créé et s’exécute comme une application swf isolée. Pour créer une occurrence de Worker, vous obtenez les octets du fichier SWF comme une occurrence de ByteArray et les transmettez à cette méthode. Il existe trois méthodes standard pour accéder aux octets d’un fichier swf à ces fins :

• Utilisez la métabalise [Embed] pour intégrer le fichier .swf à l’application en tant qu’objet ByteArray :

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Chargez un fichier SWF externe à l’aide d’un objet URLLoader :

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Utilisez un fichier swf unique en tant que programme de travail primordial et programme de travail en arrière-plan :

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

La création d’un objet Worker à l’aide de la méthode createWorker() ne lance pas l’exécution du programme de travail. Pour lancer l’exécution du code d’un programme de travail, appelez la méthode start() de l’objet Worker.

Les programmes de travail sont utiles, car ils diminuent le risque d’une baisse de la cadence, qui peut se produire si le thread de rendu principal est bloqué par l’exécution d’un autre code. Les programmes de travail augmentent toutefois l’utilisation de la mémoire système et du processeur, ce qui peut avoir une incidence considérable sur les performances globales de l’application. Etant donné que chaque programme de travail utilise sa propre occurrence de la machine virtuelle du moteur d’exécution, le traitement d’un programme de travail, aussi simple soit-il, peut consommer de nombreuses ressources. Lorsque vous utilisez des programmes de travail, testez votre code sur toutes vos plates-formes cibles afin de vous assurer que les ressources requises ne sont pas trop importantes. Adobe vous recommande de ne pas utiliser plus de deux programmes de travail dans un scénario type.

Paramètres

Permet d’accéder à l’ensemble de programmes de travail en cours d’exécution dans l’objet WorkerDomain (la propriété state de l’occurrence de l’objet Worker est WorkerState.RUNNING).