PrintJobOptions  - AS3

Spécifie la résolution à utiliser pour les images bitmap, en pixels par pouce. La valeur par défaut est Number.NaN, ce qui signifie que la résolution de l’imprimante native est utilisée.

Le paramètre de résolution s’applique à l’impression bitmap et à l’impression vectorielle. Pour l’impression bitmap, la résolution détermine la manière dont la totalité de la page est rastérisée. Pour l’impression vectorielle, la résolution détermine la manière dont le contenu spécifique, tels que les images bitmaps et les dégradés, est rastérisé.

Spécifie si le contenu de la tâche d’impression est imprimé sous forme de bitmap ou de vecteur. La valeur par défaut est false (impression vectorielle).

Si le contenu à imprimer comprend une image bitmap, réglez printAsBitmap sur true pour inclure tout effet de transparence alpha et de couleur. Si le contenu ne comprend pas d’images bitmap, imprimez le contenu au format vectoriel, qui est de qualité supérieure (option par défaut).

Par exemple, pour imprimer le contenu sous forme de bitmap, utilisez la syntaxe suivante :

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);
         

Remarque : Adobe AIR ne prend pas en charge l’impression vectorielle sous Mac OS.

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

Indique que le moteur d’exécution de Flash choisit la méthode d’impression appropriée, ou que l’auteur souhaite explicitement sélectionner l’impression vectorielle ou l’impression bitmap.

Définissez cette propriété sur l’une des valeurs suivantes dans la classe PrintMethod :

• PrintMethod.AUTO : indique que l’impression vectorielle ou l’impression bitmap est sélectionnée automatiquement en fonction du contenu à imprimer. L’impression vectorielle est utilisée chaque fois que le contenu peut être fidèlement reproduit par cette méthode. Si la transparence ou certains autres effets sont activés, l’impression bitmap est utilisée.
• PrintMethod.vector : spécifie l’impression vectorielle. Ce paramètre équivaut à définir printAsBitmap sur false.
• PrintMethod.bitmap : spécifie l’impression bitmap. Ce paramètre équivaut à définir printAsBitmap sur true.

Si la méthode printMethod est définie sur l’une de ces valeurs prises en charge, printAsBitmap est ignorée.

La valeur par défaut est null et la propriété printAsBitmap est utilisée.

Eléments de l’API associés

Crée un objet PrintJobOptions. Transmettez cet objet au paramètre options de la méthode PrintJob.addPage().

Eléments de l’API associés