GradientGlowFilter  - AS3

Conjunto de valores de transparencia alfa para los colores correspondientes del conjunto colors. Los valores válidos para cada elemento del conjunto van de 0 a 1. Por ejemplo, 0,25 establece un valor de transparencia alfa del 25%.

La propiedad alphas no puede cambiarse directamente mediante la modificación de estos valores. Debe obtener una referencia a alphas, realizar el cambio en la referencia y definir alphas como la referencia.

Las propiedades colors, alphas y ratios están relacionadas. El primer elemento del conjunto colors corresponde al primer elemento del conjunto alphas en el conjunto ratios y así sucesivamente.

Elementos de API relacionados

Ángulo, expresado en grados. Los valores válidos van de 0 a 360. El valor por defecto es 45.

El valor de angle representa el ángulo de la fuente de luz teórica que ilumina el objeto y determina la posición del efecto con respecto al objeto Si se define distance como 0, el efecto no se desplaza del objeto, por lo que la propiedad angle no tiene ningún efecto.

Cantidad de desenfoque horizontal. Los valores válidos van de 0 a 255. Un desenfoque de 1 o menos indica que la imagen original se copiará tal cual. El valor predeterminado es 4. Los valores que son potencia de 2 (como 2, 4, 8, 16 y 32) se optimizan para representarse más rápidamente que otros valores.

Cantidad de desenfoque vertical. Los valores válidos van de 0 a 255. Un desenfoque de 1 o menos indica que la imagen original se copiará tal cual. El valor predeterminado es 4. Los valores que son potencia de 2 (como 2, 4, 8, 16 y 32) se optimizan para representarse más rápidamente que otros valores.

Conjunto de colores que define un degradado. Por ejemplo, rojo es 0xFF0000, azul es 0x0000FF, y así sucesivamente.

La propiedad colors no puede cambiarse directamente mediante la modificación de estos valores. Debe obtener una referencia a colors, realizar el cambio en la referencia y definir colors como la referencia.

Las propiedades colors, alphas y ratios están relacionadas. El primer elemento del conjunto colors corresponde al primer elemento del conjunto alphas en el conjunto ratios y así sucesivamente.

Elementos de API relacionados

Distancia de desplazamiento del iluminado. El valor predeterminado es 4.

Especifica si el objeto tiene un efecto extractor. El efecto extractor hace que el relleno del objeto sea transparente y el color de fondo del documento quede visible. El valor true especifica un efecto extractor; el valor predeterminado es false (sin efecto recorte).

Número de veces que debe aplicarse el filtro. El valor predeterminado es BitmapFilterQuality.LOW, lo que equivale a aplicar el filtro una vez. El valor BitmapFilterQuality.MEDIUM aplica el filtro dos veces; BitmapFilterQuality.HIGH lo aplica tres veces. Los filtros con valores más bajos se representan con mayor rapidez.

Para la mayoría de las aplicaciones, es suficiente un valor quality de calidad baja, media o alta. Aunque puede utilizar valores numéricos hasta 15 para conseguir efectos distintos, los valores más altos se representan más lentamente. En lugar de aumentar el valor de quality, se suele conseguir un efecto similar, con una representación más rápida, simplemente aumentando los valores de las propiedades blurX y blurY.

Elementos de API relacionados

Conjunto de proporciones de distribución de color para los colores correspondientes del conjunto colors. Los valores válidos van de 0 a 255.

La propiedad ratios no puede cambiarse directamente mediante la modificación de estos valores. Debe obtener una referencia a ratios, realizar el cambio en la referencia y definir ratios como la referencia.

Las propiedades colors, alphas y ratios están relacionadas. El primer elemento del conjunto colors corresponde al primer elemento del conjunto alphas en el conjunto ratios y así sucesivamente.

El filtro de iluminado degradado se puede considerar como un iluminado que surge del centro del objeto (si se ha definido el valor distance como 0), con degradados que son franjas de colores combinadas. El primer color del conjunto colors es el color exterior del iluminado. El último es el color interior del iluminado.

Cada valor del conjunto ratios define la posición del color en el radio del degradado, donde 0 representa el punto exterior del degradado y 255 representa el punto interior. Los valores de proporciones van de 0 a 255 píxeles, de forma ascendente; por ejemplo [0, 64, 128, 200, 255]. Los valores de 0 a 128 aparecen en los bordes exteriores del iluminado. Los valores del 129 al 255 aparecen en la zona interior del iluminado. Según los valores de proporciones de los colores y el valor type del filtro, el objeto al que se aplica el filtro puede ocultar sus colores.

En el código y la imagen siguientes, se aplica un filtro a un clip de película circular negro, con el tipo definido como "full". Para que este ejemplo resulte gráfico, el primer color del conjunto colors, rosa, tiene un valor de alpha 1, por lo que resalta con el fondo blanco del documento. (En la práctica, probablemente no elegiría el primer color con este valor). El último color del conjunto, amarillo, oculta el círculo negro al que se aplica el filtro:

	var colors:Array = [0xFFCCFF, 0x0000FF, 0x9900FF, 0xFF0000, 0xFFFF00];
	var alphas:Array = [1, 1, 1, 1, 1];
	var ratios:Array = [0, 32, 64, 128, 225];
	var myGGF:GradientGlowFilter = new GradientGlowFilter(0, 0, colors, alphas, ratios, 50, 50, 1, 2, "full", false);
	

Para conseguir un efecto uniforme con el fondo del documento, cuando defina el valor de type como "outer" o "full", defina el primer color del conjunto con el mismo color que el fondo del documento, o bien, defina el valor alfa del primer color como 0. Con cualquiera de estas técnicas el filtro se mezcla con el fondo.

Si realiza dos pequeños cambios en el código, el efecto del iluminado puede ser muy distinto, incluso con los mismos conjuntos ratios y colors. Defina el valor de alfa del primer color del conjunto como 0, para que el filtro se mezcle con el fondo blanco del documento y la propiedad type como "outer" o "inner". Observe el resultado, como muestran las siguientes imágenes.

Tenga en cuenta que la extensión de los colores del degradado varía en función de los valores de las propiedades blurX, blurY, strength y quality, así como de los valores de ratios.

Elementos de API relacionados

Intensidad de la impresión o extensión. Cuanto más alto sea el valor, más color se imprimirá y mayor será el contraste entre el iluminado y el fondo. Los valores válidos van de 0 a 255. Un valor de 0 significa que el filtro no se aplica. El valor predeterminado es 1.

Colocación del efecto de filtro. Los valores posibles son las constantes flash.filters.BitmapFilterType:

• BitmapFilterType.OUTER: iluminado en lado exterior del objeto.
• BitmapFilterType.INNER: iluminado en lado interior del objeto; es el valor predeterminado.
• BitmapFilterType.FULL: iluminado en la parte superior del objeto

Inicializa el filtro con los parámetros especificados.

Devuelve una copia de este objeto de filtro.

1. Importe las clases necesarias.
2. Declare variables globales utilizadas para definir el cuadrado y el filtro.
3. Cree la función constructora, que realiza lo siguiente:
   • Llama al método draw(), que utiliza métodos de la clase Graphics a los que accede mediante la propiedad graphics de Sprite para dibujar un cuadrado.
   • Crea un objeto BitmapFilter llamado filter y le asigna el valor devuelto de la llamada a getBitmapFilter(), que crea el filtro.
   • Crea una nueva matriz denominada myFilters y le añade la propiedad filter.
   • Asigna myFilters a la propiedad filters del objeto GradientGlowFilterExample. Esto se aplicará a todos los filtros de myFilters que, en este caso, sólo es filter.

package {
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;
    import flash.filters.GradientGlowFilter;
    import flash.display.Sprite;

    public class GradientGlowFilterExample extends Sprite {
        private var bgColor:uint = 0xCCCCCC;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        private var distance:Number  = 0;
        private var angleInDegrees:Number = 45;
        private var colors:Array     = [0xFFFFFF, 0xFF0000, 0xFFFF00, 0x00CCFF];
        private var alphas:Array     = [0, 1, 1, 1];
        private var ratios:Array     = [0, 63, 126, 255];
        private var blurX:Number     = 50;
        private var blurY:Number     = 50;
        private var strength:Number  = 2.5;
        private var quality:Number   = BitmapFilterQuality.HIGH;
        private var type:String      = BitmapFilterType.OUTER;
        private var knockout:Boolean = false;

        public function GradientGlowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            return new GradientGlowFilter(distance,
                                          angleInDegrees,
                                          colors,
                                          alphas,
                                          ratios,
                                          blurX,
                                          blurY,
                                          strength,
                                          quality,
                                          type,
                                          knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}