GlowFilter  - AS3

Valor de transparencia alfa del color. Los valores válidos van de 0 a 1. Por ejemplo, 0,25 establece un valor de transparencia del 25%. El valor predeterminado es 1.

Cantidad de desenfoque horizontal. Los valores válidos van de 0 a 255 (coma flotante). El valor predeterminado es 6. Los valores que son potencia de 2 (como 2, 4, 8, 16 y 32) se optimizan para representarse más rápidamente que otros valores.

Cantidad de desenfoque vertical. Los valores válidos van de 0 a 255 (coma flotante). El valor predeterminado es 6. Los valores que son potencia de 2 (como 2, 4, 8, 16 y 32) se optimizan para representarse más rápidamente que otros valores.

Color del iluminado. Los valores válidos tienen formato hexadecimal 0xRRGGBB. El valor predeterminado es 0xFF0000.

Especifica si el iluminado es interior. El valor true indica un iluminado interior. El valor predeterminado es false, un iluminado exterior (un iluminado alrededor de los bordes exteriores del objeto).

Especifica si el objeto tiene un efecto extractor. Con el valor true el relleno del objeto es transparente y el color de fondo del documento queda visible. El valor predeterminado es false (sin efecto extractor).

Número de veces que debe aplicarse el filtro. El valor predeterminado es BitmapFilterQuality.LOW, lo que equivale a aplicar el filtro una vez. El valor BitmapFilterQuality.MEDIUM aplica el filtro dos veces; BitmapFilterQuality.HIGH lo aplica tres veces. Los filtros con valores más bajos se representan con mayor rapidez.

Para la mayoría de las aplicaciones, es suficiente un valor quality de calidad baja, media o alta. Aunque puede utilizar valores numéricos hasta 15 para conseguir efectos distintos, los valores más altos se representan más lentamente. En lugar de aumentar el valor de quality, se suele conseguir un efecto similar, con una representación más rápida, simplemente aumentando los valores de las propiedades blurX y blurY.

Elementos de API relacionados

Intensidad de la impresión o extensión. Cuanto más alto sea el valor, más color se imprimirá y mayor será el contraste entre el iluminado y el fondo. Los valores válidos van de 0 a 255. El valor por defecto es 2.

Inicializa una instancia GlowFilter nueva con los parámetros especificados.

Elementos de API relacionados

Devuelve una copia de este objeto de filtro.

1. Importe las clases necesarias.
2. Declare tres propiedades utilizadas en el método draw, que usa métodos de la clase Graphics a los que accede mediante la propiedad graphics de Sprite para dibujar un cuadrado naranja.
3. Cree la función constructora, que realiza lo siguiente:
   • Llama a la función draw para crear un rectángulo.
   • Crea un objeto BitmapFilter glowFilter y le asigna el valores devueltos por la función método getBitmapFilter().
   • Asigna el conjunto de valores del objeto glowFilter a la propiedad filters del objeto de visualización raíz. En este caso, todos elementos secundarios de objetos de visualización del objeto de visualización raíz heredan las propiedades de un filtro de resplandor. Por lo tanto, el rectángulo creado en la función draw() muestra las propiedades de filtro de resplandor.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.GlowFilter;

    public class GlowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function GlowFilterExample() {
        //draw the rectangle using the draw() function below
            draw();
            
        //assign the values from getBitmapFilter function below
        //to a BitmapFilter object "glowFilter"
            var glowFilter:BitmapFilter = getBitmapFilter();
            
        //populate the filters property of the root display object with the array of values
        //from the glowFilter object.
            filters = [ glowFilter ];
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x33CCFF;
            var alpha:Number = 0.8;
            var blurX:Number = 35;
            var blurY:Number = 35;
            var strength:Number = 2;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;

            return new GlowFilter(color,
                                  alpha,
                                  blurX,
                                  blurY,
                                  strength,
                                  quality,
                                  inner,
                                  knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}