SerialElement  - AS3 OSMF

包	org.osmf.elements
类	public class SerialElement
继承	SerialElement CompositeElement MediaElement EventDispatcher Object

语言版本:

ActionScript 3.0

产品版本:

OSMF 1.0

运行时版本:

Flash Player 10, AIR 1.5

SerialElement 是一个媒体组合，其元素连续显示（即按顺序显示）。

组成 SerialElement 的媒体元素被视为单个统一的媒体元素。例如，如果 SerialElement 封装一个视频序列，则 SerialElement 的行为将与单个 VideoElement 的行为类似，但后者按顺序播放多个视频。

通常，SerialElement 的特征是组合的“当前”子级的反映。SerialElement 按序列顺序播放其子级。当前子级执行完操作后，序列中的下一个子级将成为“当前”子级。将对类的客户端隐藏从当前子级到下一个子级的更改。这些更改只有在此类的特征更改时才能被注意到。

不包含子级的 SerialElement 没有“当前”子级的概念，因此它反映不出任何特征。添加到 SerialElement 的第一个子级将立即成为该组合的当前子级。如果删除当前子级，则序列中的下一个子级将成为新的当前子级（如果存在下一个子级）。如果没有下一个子级，则该序列中的第一个子级将成为当前子级。

要将“当前”状态从一个子级传递到另一个子级，唯一的方式是，当前子级的其中一种特征的状态以 SerialElement 了解的某种方式更改以便它需要更改其当前子级。例如，如果序列中的各个子级都具有 PlayTrait，则当子级完成播放且其 PlayTrait 的 PlayState 属性从 PLAYING 更改为 STOPPED 时，“当前”状态将从一个子级移到下一个子级。另一个示例：如果带有 SeekTrait 的 SerialElement 的客户端逐点搜索，“当前”状态很可能从一个子级落到另一个子级。

以下是按顺序排列时各个特征的表示方式：

• AudioTrait – 组合特征使所有子级的有声属性保持同步。更改子元素（或组合元素）的音量时，将同时更改所有有声子级（和组合特征）的音量。
• BufferTrait – 组合特征表示序列中当前子级的可缓冲特征。所有更改仅应用到当前子级。
• DisplayObjectTrait - 组合特征表示序列中当前子级的 DisplayObjectTrait。
• DRMTrait - 组合特征表示序列中当前子级的 DRMTrait。
• DVRTrait - 组合特征表示序列中当前子级的 DVRTrait。
• DynamicStreamTrait - 组合特征表示序列中当前子级的 DynamicStreamTrait。所有更改仅应用到当前子级。
• LoadTrait - 组合特征表示序列中当前子级的 LoadTrait。所有更改仅应用到当前子级。
• PlayTrait - 组合特征表示序列中当前子级的 PlayTrait。所有更改仅应用到当前子级。
• SeekTrait - 组合特征表示序列中当前子级的 SeekTrait。搜索操作可更改当前子级。
• TimeTrait - 报告的 SerialElement 的 TimeTrait 的持续时间仅是当前子级和任何已完成子级的总和。此报告值不反映所有子级的持续时间总和。

查看示例

---

package
{
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    
    import org.osmf.elements.LightweightVideoElement;
    import org.osmf.elements.SerialElement;
    import org.osmf.media.MediaPlayerSprite;
    import org.osmf.media.URLResource;
    
    public class SerialElementExample extends Sprite
    {
        public function SerialElementExample()
        {
            super();
            
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var mediaPlayerSprite:MediaPlayerSprite = new MediaPlayerSprite();
            var serialElement:SerialElement = new SerialElement();
            
            var videoElement:LightweightVideoElement = new LightweightVideoElement();
            videoElement.resource = new URLResource("http://mediapm.edgesuite.net/strobe/content/test/AFaerysTale_sylviaApostol_640_500_short.flv");
            
            var videoElement2:LightweightVideoElement = new LightweightVideoElement();
            videoElement2.resource = new URLResource("http://mediapm.edgesuite.net/strobe/content/test/elephants_dream_768x428_24_short.flv");
            
            serialElement.addChild(videoElement);
            serialElement.addChild(videoElement2);
            
            addChild(mediaPlayerSprite);
            mediaPlayerSprite.media = serialElement;    
            
        }
    }
}