ElementFormat  - AS3

指定包含元素中的基线类型，具有此格式的元素的主要基线将与此基线对齐。对此属性使用 TextBaseline 常量。

行中的最大垂直元素确定基线的对齐方式，除非将 TextBlock.baselineFontDescription 和 TextBlock.baselineFontSize 设置为覆盖该逻辑。

默认值为 TextBaseline.USE_DOMINANT_BASELINE。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

指定受此对象影响的行元素的透明效果。有效值范围介于 0（完全透明）到 1（完全不透明）之间。alpha 设置为 0 的显示对象是活动的，即使它们不可见。

默认值为 1。

相关 API 元素

表示元素的基线偏移，以像素为单位。

元素将按照这个量偏离 dominantBaseline。此偏移量将加到元素成员的 y 位置中，因此在非旋转的文本中，正基线偏移会向下移动元素，负基线偏移会向上移动元素。

默认值为 0.0，表示不偏移。

应用于此文本的换行。此属性确定在将换行文本分为多行时可用于断行的字符。将 BreakOpportunity 常量用于此属性。

默认值为 BreakOpportunity.AUTO。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

表示文本的颜色。一个包含三个 8 位 RGB 分量的整数；例如，0xFF0000 为红色，0x00FF00 为绿色。

默认值为 0x000000，黑色。

用于此文本的数字大小写。数字大小写会影响数字字符组的样式和位置。将 DigitCase 常量用于此属性。

默认值为 DigitCase.DEFAULT。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

用于此文本的数字宽度。将 DigitWidth 常量用于此属性。

默认值为 DigitWidth.DEFAULT。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

指定用作主要基线的基线类型。将主要基线与对齐基线对齐以确定元素在行中的垂直位置。对此属性使用 TextBaseline 常量。

元素的内容将确定基线。对于 TextElement，字体和点值将确定基线。对于 GraphicElement，元素的高度将确定基线。

默认值为 TextBaseline.ROMAN。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

其属性说明字体的对象。

默认值为默认构造的 FontDescription 对象。

如果设置了 fontDescription 属性，提供的 FontDescription 对象已锁定，则 locked 属性将设置为 true。无法修改已锁定 FontDescription。

相关 API 元素

文本的大小，以像素为单位。

默认值为 12.0。

字距调整可调整某些字符对之间的像素以提高可读性。具有字距微调表的所有字体都支持字距调整。

默认值为 Kerning.ON。

要设置该属性的值，请使用 Kerning 类中的下列常量：

相关 API 元素

用于此文本的连字级别。由两个或两个以上的字母结合在一起形成单个字型时就是连字。连字通常用于替换一些共享公共部分的连续字符，例如字母对“fi”、“fl”或“ae”。在拉丁语字符集和非拉丁语字符集中均可使用连字。将 LigatureLevel 常量用于此属性。

默认值为 LigatureLevel.COMMON。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

文本的区域设置。控制大小写转换和形状。使用标准区域设置标识符。例如，"en"、"en_US" 和 "en-US" 均表示英语，"ja" 表示日语。有关区域设置代码列表的信息，请参阅 iso639-2 code list。

默认值为 "en"。

表示 ElementFormat 是否已锁定。如果为 true，将无法修改 ElementFormat。调用 ElementFormat.clone() 获取 ElementFormat 对象的没有锁定的副本。

设置应用于各个字型的旋转。将 TextRotation 类中定义的常量用于此属性。

默认值为 TextRotation.AUTO。

任何字型的最终旋转均为 ElementFormat.textRotation、ContentElement.textRotation 与 TextBlock.lineRotation 之和。

您通常将此属性用于亚洲文字，在其中必须旋转字符才能在垂直布局中正确显示。将 TextRotation.AUTO 与 TextBlock.lineRotation = TextRotation.ROTATE_90 结合使用以实现该目的。

对不包含垂直布局信息的字体设置此属性可能会产生不良结果。包含 vmtx 或 VORG 表的字体（例如，日文字体、“MS Mincho”）能够正常工作，因为这些表提供布局引擎显示正确布局所需的数据。而未包含必要信息的字体（例如 Verdana）则不能正常工作。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

应用到每个字型左侧的间距或手动字距调整（以像素为单位）。如果启用 kerning，则会将 trackingLeft 值与字体字距微调表中的值相加。如果禁用 kerning，则使用 trackingLeft 值作为手动字距调整值。同时支持正值和负值。

通常，在 trackingRight 与 trackingLeft 之间拆分所需的间距值。否则，在混合方向文本中，一个双向边界处间距加倍，而另一个双向边界处不存在间距。

默认值为 0.0。

示例：

          //positive tracking added to kerning
          var ef1:ElementFormat = new ElementFormat();
          ef1.kerning = flash.text.engine.Kerning.ON;
          ef1.trackingLeft = 0.5;
     
          //negative manual kerning
          var ef2:ElementFormat = new ElementFormat();
          ef2.kerning = flash.text.engine.Kerning.OFF;
          ef2.trackingLeft = -1.0;
     

应用到每个字型右侧的间距或手动字距调整（以像素为单位）。如果启用 kerning，则会将 trackingRight 值与字体字距微调表中的值相加。如果禁用 kerning，则使用 trackingRight 值作为手动字距调整值。同时支持正值和负值。

通常，在 trackingRight 与 trackingLeft 之间拆分所需的间距值。否则，在混合方向文本中，一个双向边界处间距加倍，而另一个双向边界处不存在间距。

默认值为 0.0。

示例：

          //positive tracking added to kerning
          var ef1:ElementFormat = new ElementFormat();
          ef1.kerning = flash.text.engine.Kerning.ON;
          ef1.trackingRight = 0.5;
     
          //negative manual kerning
          var ef2:ElementFormat = new ElementFormat();
          ef2.kerning = flash.text.engine.Kerning.OFF;
          ef2.trackingRight = -1.0;
     

用于此文本的印刷大小写。将 TypographicCase 类中定义的常量用于此属性。

默认值为 TypographicCase.DEFAULT。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

创建 ElementFormat 对象。

构造 ElementFormat 的没有锁定的克隆副本。

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormat_cloneExample extends Sprite {
        private var ef1:ElementFormat;
        private var ef2:ElementFormat;
        
        public function ElementFormat_cloneExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize=20;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            ef2 = (ef1.locked) ? ef1.clone() : ef1;    
            ef2.fontSize = 32;

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

返回一个 FontMetrics 对象，该对象的属性说明由 fontDescription 和 fontSize 指定的字体的全角字框、删除线位置、删除线粗细、下划线位置和下划线粗线。

相关 API 元素

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontMetricsExample extends Sprite {
        
        public function FontMetricsExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 24;            
            var fm1:FontMetrics = ef1.getFontMetrics();

            trace(fm1.emBox);
            trace(fm1.strikethroughOffset);
            trace(fm1.strikethroughThickness);
            trace(fm1.subscriptScale);
            trace(fm1.subscriptOffset);
            trace(fm1.superscriptScale);
            trace(fm1.superscriptOffset);
            trace(fm1.underlineOffset);
            trace(fm1.underlineThickness);
            
            
        }
    }    
}

此示例创建了两个 ElementFormat 对象并设置了它们的一些属性。然后，该示例将新的 ElementFormat 分配给 TextElement 对象，该对象已经被指定为 TextBlock 的内容。请注意，更改 TextElement 的 ElementFormat 不会影响父 TextBlock 以前创建的 TextLine。

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormatExample extends Sprite {
        
        public function ElementFormatExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            ef1.alpha = 100;
            ef1.kerning = flash.text.engine.Kerning.ON;
            ef1.trackingRight = 2;
            ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
            ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
            ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
            
            var ef2:ElementFormat = new ElementFormat(fd);
            ef2.fontSize = 30;
            ef2.color = 0xFF0000;
            ef2.alpha = 0.3;
            ef2.kerning = flash.text.engine.Kerning.OFF;
            ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
            ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
            ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            line1.x = 15;
            line1.y = 30;

            tb.content.elementFormat = ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            line2.x = 15;
            line2.y = 60;
            
        }
    }    
}