FontDescription  - AS3

用于此文本的 CFF 提示的类型。对此属性使用 CFFHinting 常量。仅在文本的 RenderingMode 属性设置为 RenderingMode.CFF 时才应用此属性。

使用的 CFF（压缩字体格式）提示的类型决定 Flash 运行时强制粗水平线是否适合子像素网格。

仅适用于嵌入字体。

默认值为 CFFHinting.HORIZONTAL_STEM。

对于 CFFHinting 属性，您可以使用 CFFHinting 类中的下列常量：

相关 API 元素

指定应该如何查找字体。

默认值为 FontLookup.DEVICE。

要设置此属性的值，请使用下列字符串值：

相关 API 元素

要使用的字体的名称或用逗号分隔的字体名称列表。运行时使用列表中的第一个可用字体呈现元素。例如“Arial, Helvetica, _sans”使播放器搜索 Arial，如果找不到 Arial，则搜索 Helvetica，如果这两种字体都找不到，则最后搜索 _sans。

Flash 运行时支持三种通用设备字体名称：sans（对于 sans serif 字体）、_serif（对于 serif 字体）和 _typewriter（对于 mono-space 字体）。这些字体将映射到特定的设备字体，具体取决于平台。

默认值为 "_serif"。

Flash 运行时为所选字体中没有的字形提供字体回退。无论是正在使用的已嵌入字体还是设备，如果字体中没有字形，则运行时将很有可能尝试使用其他设备呈现以包含此字形。

相关 API 元素

指定字体形态。

默认值为 FontPosture.NORMAL。

要设置此属性的值，请使用 FontPosture 类中的下列常量：

相关 API 元素

指定字体粗细。

默认值为 FontWeight.NORMAL。

要设置此属性的值，请使用 FontWeight 类中的下列常量：

相关 API 元素

表示 FontDescription 是否已经锁定。如果为 true，将无法修改 FontDescription。调用 FontDescription.clone() 以获取 FontDescription 对象的没有锁定的副本。

用于此文本的呈现模式。对此属性使用 RenderingMode 常量。

仅适用于嵌入字体。

默认值为 RenderingMode.CFF。

要设置此属性的值，请使用 RenderingMode 类中的下列常量：

相关 API 元素

创建一个 FontDescription 对象。

构造 FontDescription 的没有锁定的克隆副本。

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontDescription_cloneExample extends Sprite {
        private var fd:FontDescription;
        private var fd2:FontDescription;
        
        public function FontDescription_cloneExample():void {
            fd = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;
            fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

            var ef1:ElementFormat = new ElementFormat(fd);
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            fd2 = (fd.locked) ? fd.clone() : fd;    
            fd2.fontWeight = flash.text.engine.FontWeight.NORMAL;
            var ef2:ElementFormat = new ElementFormat(fd2);

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

如果可用的设备字体可与指定的 fontName、fontWeight 和 fontPosture 配合使用，则返回 true。

flash.text.engine 类只能使用 OpenType 和 TrueType 设备字体。如果使用基于早期字体技术的字体，则运行时将回退到基于字形的已知设备字体以呈现文本

参数

相关 API 元素

如果使用指定的 fontName、fontWeight 和 fontPosture（其中 Font.fontType 为 flash.text.FontType.EMBEDDED_CFF）的嵌入字体可用，则将返回 true。从 Flash Player 10 开始，两种嵌入字体可显示在应用程序内容中。标准的嵌入字体只能由 TextField 使用。CFF 嵌入字体只能由 flash.text.engine 类使用。两种类型由 enumerateFonts() 函数返回的 Font 类的 fontType 属性加以区分。

flash.text.engine 类不能使用 EMBEDDED 类型的字体。如果 fontLookup 设置为 FontLookup.EMBEDDED_CFF 并且运行时唯一可用的具有指定名称、粗细和形态的字体的类型为 EMBEDDED，则运行时将回退到基于字形的设备字体以呈现文本，就如同没有任何可用的具有指定名称和样式的嵌入字体。

如果具有相同名称、粗细和形态的 EMBEDDED 和 EMBEDDED_CFF 字体均可用，则将选择 EMBEDDED_CFF 字体并使用 EMBEDDED_CFF 字体呈现文本。

参数

相关 API 元素

此示例将创建一个 FontDescription 对象、将设备字体分配给该对象、设置各种字体属性并将新对象分配给 ElementFormat 对象。附加字体格式设置是在 ElementFormat 中完成的。使用 ElementFormat 创建新的 TextElement，并将 TextElement 用作 TextBlock 的内容。从 TextBlock 创建的文本行。

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontDescriptionExample extends Sprite {
        
        public function FontDescriptionExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;
            fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
        }
    }    
}