ContextMenu  - AS3

Şu özelliklere sahip bir ContextMenuBuiltInItems sınıfı örneği: forwardAndBack, loop, play, print, quality, rewind, save ve zoom. Bu özellikler false olarak ayarlandığında karşılık gelen menü öğeleri belirtilen ContextMenu nesnesinden kaldırılır. Bu özellikler adımlanabilirdir ve varsayılan olarak true değerine ayarlanmıştır.

Not: AIR'da, bağlam menüleri yerleşik öğeler içermez.

İlgili API Öğeleri

Şu özelliklere sahip bir ContextMenuClipboardItems sınıfı örneği: cut, copy, paste, delete, selectAll. Bu özelliklerin herhangi birinin false olarak ayarlanması, pano menüsünde karşılık gelen öğeyi devre dışı bırakır.

İlgili API Öğeleri

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Pano menüsünün kullanılıp kullanılmayacağını belirtir. Bu değer true olduğunda, clipboardItems özelliği pano menüsünde hangi öğelerin etkinleştirileceğini veya etkinliğinin kaldırılacağını belirler.

link özelliği null dışında bir değere sahipse, clipBoardMenu özelliği yok sayılır.

ContextMenuItem nesneleri dizisi. Dizideki her nesne, tanımladığınız bir bağlam menüsü öğesini temsil eder. Bu özel menü öğelerini eklemek, kaldırmak veya değiştirmek için bu özelliği kullanın.

Yeni menü öğeleri eklemek için, bir ContextMenuItem nesnesi oluşturun ve ardından bu nesneyi customItems dizisine ekleyin (örneğin, Array.push() öğesini kullanarak). Menü öğeleri oluşturma hakkında daha fazla bilgi için ContextMenuItem sınıfı girişine bakın.

İlgili API Öğeleri

ContextMenu sınıfı geçerli platformda destekleniyorsa, isSupported özelliğitrue olarak, aksi halde false olarak ayarlanır.

Bu menüdeki özel öğe dizisi.

Bu özelliği kullanmak, customItems özelliğini kullanmakla eşdeğerdir. Dizi, görüntüleme düzeninde sıralanır.

Bağa ait URLRequest. Bu özellik null değerinde olduğunda, normal bir bağlam menüsü görüntülenir. Bu özellik null değerinde değilse, bağın bağlam menüsü görüntülenir ve belirtilen URL üzerinde çalışır.

Bir link belirtilirse, clipboardMenu özelliği yok sayılır.

Varsayılan değer null şeklindedir.

Bu menüdeki öğe sayısı.

Bir ContextMenu nesnesi oluşturur.

İlgili API Öğeleri

Menünün altına bir menü öğesi ekler.

Bir bağlam menüsü oluştururken, NativeMenuItem veya ContextMenuItem nesnelerini ekleyebilirsiniz. Ancak, menüdeki tüm öğelerin aynı özelliklere sahip olması için, bir bağlam menüsünde yalnızca bir tür nesne kullanmanız önerilir.

Parametreler

Belirtilen ContextMenu nesnesinin bir kopyasını oluşturur. Kopya, orijinal menü nesnesinin tüm özelliklerini devralır.

Bu menünün belirtilen menü öğesini içerip içermediğini bildirir.

Parametreler

Belirtilen konumda bu menüyü açar.

Not: Flash Player'da bu yöntem desteklenmez.

Parametreler

Belirtilen dizindeki menü öğesini alır.

Parametreler

Belirtilen öğenin konumunu alır.

Parametreler

ContextMenu nesnesindeki tüm yerleşik menü öğelerini (Ayarlar hariç) gizler. Flash Player'ın hata ayıklama sürümü çalışıyorsa, uzaktan hata ayıklamanın etkin olmadığı SWF dosyaları için silik görünse de Hata Ayıklama menü öğesi görünür.

Bu yöntem, yalnızca standart bağlam menüsünde görünen menü öğelerini gizler; düzen ve hata menülerinde görünen öğeler üzerinde bir etkisi yoktur.

Bu yöntem, my_cm.builtInItems öğesinin Boolean üyelerini false olarak ayarlayarak çalışır. Yerleşik bir öğeyi, my_cm.builtInItems öğesindeki karşılık gelen öğesini true olarak ayarlayarak görünür yapabilirsiniz.

Not: AIR'da, bağlam menüleri yerleşik öğeler içermez. Bu yöntemin çağrılmasının herhangi bir etkisi yoktur.

İlgili API Öğeleri

Menüden tüm öğeleri kaldırır.

Belirtilen dizindeki menü öğesini kaldırır ve döndürür.

Parametreler

Bir kullanıcı ilk olarak bir bağlam menüsü oluşturduğunda ancak bağlam menüsünün içeriği görüntülenmeden önce gönderilir. Bu işlem, programınızın menü görüntülenmeden önce bağlam menüsü öğeleri kümesini değiştirmesini sağlar. Kullanıcı, bağlam menüsü öğesini, işaretçi aygıtını sağ tıklatarak oluşturur.

Bu olay şu özelliklere sahiptir:

1. Bir myContextMenu özelliği bildirilir ve ardından yeni ContextMenu nesnesine atanır ve sonuç olarak Sprite türünün bir redRectangle özelliği bildirilir.
2. removeDefaultItems() yöntemi çağrılır ve böylece Yazdır dışındaki tüm yerleşik bağlam menüsü öğeleri kaldırılır.
3. addCustomMenuItems() yöntemi çağrılır ve böylece Dizinin push() yöntemi kullanılarak defaultItems dizisine Red to Black adı verilen bir menü öğesi yerleştirilir. ContextMenuItem nesnesine bir menuItemSelect olay dinleyicisi eklenir ve ilişkili yöntem menuItemSelectHandler() olarak adlandırılır. Bu yöntem, bağlam menüsüne her erişildiğinde ve Red to Black her seçildiğinde trace() öğesini kullanarak bazı ifadeler yazdırır. Ayrıca, kırmızı kare kaldırılır ve yerine siyah bir kare yerleştirilir.
4. İlişkili menuSelectHandler yöntemiyle birlikte menuSelect türünde bir olay dinleyicisi eklenir ve bu da bağlam menüsündeki öğelerden biri her açıldığında trace() öğesini kullanarak üç farklı ifade yazdırır.
5. Ardından, addChildren() kırmızı bir kare çizer ve bunu görüntü listesine ekler. Kare burada hemen görüntülenir.
6. Son olarak, myContextMenu, redRectangle hareketli grafiğinin bağlam menüsüne atanır ve böylece özel bağlam menüsünü yalnızca fare işaretçisi karenin üzerine geldiğinde görüntülenir.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}