ContextMenuEvent  - AS3

Menünün eklendiği görüntüleme listesi nesnesi. Bu, (mouseTarget) veya görüntüleme listesindeki alt öğelerinden biri olabilir.

mouseTarget özelliğinin güvenlik nedenleriyle null olarak ayarlanıp ayarlanmadığını gösterir. menuTarget nominal değeri, başka bir güvenlik sanal alanındaki DisplayObject nesnesine başvuruyorsa, bu sanal alan sınırı içinde her iki yönde de izin olmadığı sürece menuTarget, null olarak ayarlanır. Bir SWF dosyasından Security.allowDomain() öğesi çağrılarak veya bir görüntü dosyası sunucusundan ilke dosyası sağlanarak ve görüntü yüklenirken LoaderContext.checkPolicyFile bayrağı ayarlanarak izin oluşturulur.

İlgili API Öğeleri

Kullanıcının bağlam menüsünü görüntülemek için üzerinde sağ tıklattığı görüntüleme listesi nesnesi. Bu, menünün ekli olduğu görüntüleme listesi nesnesi (contextMenuOwner) veya görüntüleme listesi alt öğelerinden biri olabilir.

Bu özelliğin değeri, iki durumda null olabilir: bir fare hedefi yoksa, örneğin, arka plandaki bir şeyin üzerine fareyi getirdiğinizde veya bir fare hedefi varsa ancak bu erişiminiz olmayan bir güvenlik sanal alanında bulunuyorsa. Bu nedenlerden hangisinin geçerli olduğunu belirlemek için isMouseTargetInaccessible() özelliğini kullanın.

İlgili API Öğeleri

menu olayları hakkındaki belirli bilgileri içeren bir Event nesnesi oluşturur. Event nesneleri, olay dinleyicilerine parametre olarak iletilir.

İlgili API Öğeleri

ContextMenuEvent nesnesinin bir kopyasını oluşturur ve her özelliğin değerini, orijinal ile aynı olacak şekilde ayarlar.

ContextMenuEvent nesnesinin tüm özelliklerini içeren bir dize döndürür. Dize şu biçimdedir:

[ContextMenuEvent type=value bubbles=value cancelable=value ... contextMenuOwner=value]

Bir menuItemSelect olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

menuSelect olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

1. myContextMenu özelliği bildirilir, ardından yeni bir ContextMenu nesnesine atanır ve (Sprite türünde) redRectangle özelliği bildirilir.
2. removeDefaultItems() yöntemi çağrılır. Bu yöntem, Print dışındaki tüm yerleşik bağlam menüsü öğelerini kaldırır.
3. addCustomMenuItems() yöntemi çağrılır. Bu yöntem, push() Array yöntemini kullanarak defaultItems dizisine bir Reverse Colors menü öğesi ekler. ContextMenuItem nesnesine bir menuItemSelect olay dinleyicisi eklenir ve ilişkili yöntem menuItemSelectHandler() olarak adlandırılır. Kullanıcı bağlam menüsünden Reverse Colors seçeneğini her belirlediğinde, bu yöntem bazı trace() ifadelerini yazdırır. Kırmızı karenin siyah olmasının yanı sıra, siyah metin de kırmızı olur.
4. Yapıcıda ise, bağlam menüsünde her bir öğe seçildiğinde üç trace() ifadesi yazdıran ilişkili menuSelectHandler() yöntemiyle birlikte menuSelect olay dinleyicisi eklenir.
5. Yapıcı addChildren() çağırır, bu çağrı, kırmızı bir kare çizer ve bu kareyi hemen görüntüleneceği görüntüleme listesine ekler.
6. Son olarak, myContextMenu, redRectangle özelliğinin bağlam menüsüne atanır, böylece yalnızca fare işaretçisi karenin üzerindeyken özel bağlam menüsü görüntülenir.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}