MouseEvent  - AS3

Alt tuşunun etkin mi (true) yoksa devre dışı mı (false) olduğunu belirtir. Yalnızca Windows için desteklenir. Diğer işletim sistemlerinde bu özellik her zaman false olarak ayarlanmıştır.

Birincil fare düğmesinin basılı durumda olup (true) olmadığını (false) belirtir.

Mouse down olayının bir çok tıklatma sırasının parçası olup olmadığını gösterir. Bu parametre, MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown ve MouseEvent.rightMouseUp dışındaki tüm fare olayları için sıfır olacaktır. clickCount parametresiyle tek tıklatma, çift tıklatma veya herhangi bir çok tıklatma sırası dinlenebilir. Örneğin, ilk MouseEvent.mouseDown ile MouseEvent.mouseUp 1 clickCount ve çok tıklatma sırasındaki ikinci MouseEvent.mouseDown ile MouseEvent.mouseUp 2 clickCount içerir. Fare yeteri kadar hareket ettiğinde veya herhangi bir nedenle çok tıklatma sırası kesintiye uğradığında, MouseEvent.mouseDown 1 clickCount değerine sahip olur. Beklendiği gibi doubleClick olayı başlatılacaktır.

Command tuşunun etkin olup olmadığını gösterir (yalnızca Mac'te).

commandKey özelliğinin değeri, Mac'te ctrlKey özelliğiyle aynı değere sahip olacaktır. Windows veya Linux'ta her zaman false değerindedir.

Mac'te Control tuşunun etkin olup olmadığını, Windows veya Linux'ta Ctrl tuşunun etkin olup olmadığını belirtir.

Windows veya Linux'ta Ctrl tuşunun etkin olup (true) olmadığını (false) gösterir. Macintosh'ta, Ctrl tuşunun veya Command tuşunun etkin olup olmadığını belirtir.

Her birim için kullanıcının fare tekerleğini kaç satır kaydırması gerektiğini belirtir. Pozitif bir delta değeri, yukarı kaydırmayı; negatif bir değer ise aşağı kaydırmayı belirtir. Tipik değerler 1-3'tür, ancak daha hızlı dönüş daha büyük değerler oluşturabilir. Bu ayar, aygıta ve işletim sistemine bağlı olup genellikle kullanıcı tarafından konfigüre edilebilir. Bu özellik yalnızca MouseEvent.mouseWheel olayı için geçerlidir.

true olursa, relatedObject özelliği, güvenlik sanal alanlarıyla ilgili nedenlerden dolayı null değerine ayarlanır. relatedObject öğesinin nominal değeri, başka bir güvenlik sanal alanındaki DisplayObject öğesine başvuruysa, bu sanal alan sınırı içinde her iki yönde de izin olmadığı sürece relatedObject öğesi null değerine ayarlanır. Bir SWF dosyasından Security.allowDomain() öğesi çağrılarak veya bir görüntü dosyası sunucusundan ilke dosyası sağlanarak ve görüntü yüklenirken LoaderContext.checkPolicyFile özelliği ayarlanarak izin oluşturulur.

İlgili API Öğeleri

Fare kilidinin devre dışı olduğu zaman, olayın içerilen hareketli grafiğe göre meydana geldiği yatay koordinat. Stage.mouseLock öğesini false olarak ayarlayarak fare kilidini devre dışı bırakın.

Fare kilidinin etkin olduğu durumda localX ve localY öğeleri 0'dır. Fare kilidinin etkin olduğu durumda fare konumundaki değişiklikleri belirlemek için movementX ve movementY öğelerini kullanın.

İlgili API Öğeleri

Fare kilidinin devre dışı olduğu zaman, olayın içerilen hareketli grafiğe göre meydan geldiği dikey koordinat. Stage.mouseLock öğesini false olarak ayarlayarak fare kilidini devre dışı bırakın.

Fare kilidinin etkin olduğu durumda localX ve localY öğeleri 0'dır. Fare kilidinin etkin olduğu durumda fare konumundaki değişiklikleri belirlemek için movementX ve movementY öğelerini kullanın.

İlgili API Öğeleri

Fare kilidinin devre dışı olduğu zaman, son fare olayından itibaren X yönündeki fare konumunda meydana gelen değişiklikler. Stage.mouseLock öğesini true olarak ayarlayarak fare kilidini etkinleştirin.

Fare kilidi etkin olduğu zaman:

• localX ve localY öğesi 0 içerir.
• movementX ve movementY öğesi delta değerleri içerir.
• movementX ve movementY öğesi, sahne alanı aktarımına dayalı olarak hiçbir zaman aktarılmaz. Bu, bu öğelerin her zaman ekran koordinatlarında kaldıkları anlamına gelir.

Stage.mouseLock öğesi false olduğunda movementX ve movementY öğesi 0'dır.

İlgili API Öğeleri

Fare kilidinin devre dışı olduğu zaman, son fare olayından itibaren Y yönündeki fare konumunda meydana gelen değişiklikler. Stage.mouseLock öğesini true olarak ayarlayarak fare kilidini etkinleştirin.

Fare kilidi etkin olduğu zaman:

• localX ve localY öğesi 0 içerir.
• movementX ve movementY öğesi delta değerleri içerir.
• movementX ve movementY öğesi, sahne alanı aktarımına dayalı olarak hiçbir zaman aktarılmaz. Bu, bu öğelerin her zaman ekran koordinatlarında kaldıkları anlamına gelir.

Stage.mouseLock öğesi false olduğunda movementX ve movementY öğesi 0'dır.

İlgili API Öğeleri

Olay ile ilgili bir ekran listesi nesnesine bir başvuru. Örneğin bir mouseOut olayı oluştuğunda, relatedObject, işaretleme aygıtının şimdi işaret ettiği görüntüleme listesini temsil eder. Bu özellik, mouseOut, mouseOver, rollOut ve rollOver olayları için geçerlidir.

Bu özelliğin değeri, iki durumda null olabilir: ilgili bir nesne yoksa veya bir ilgili nesne varsa ancak bu sizin erişemediğiniz bir güvenlik sanal alanındaysa. Bu nedenlerden hangisinin geçerli olduğunu belirlemek için isRelatedObjectInaccessible() özelliğini kullanın.

İlgili API Öğeleri

Shift tuşunun etkin mi (true) yoksa devre dışı mı (false) olduğunu belirtir.

Olayın global Sahne Alanı koordinatlarında gerçekleştiği yatay koordinat. Bu özellik, localX özelliği ayarlandığında hesaplanır.

Olayın global Sahne Alanı koordinatlarında gerçekleştiği dikey koordinat. Bu özellik, localY özelliği ayarlandığında hesaplanır.

mouse olayları hakkındaki bilgileri içeren bir Event nesnesi oluşturur. Event nesneleri, olay dinleyicilerine parametre olarak iletilir.

MouseEvent nesnesinin bir kopyasını oluşturur ve her özelliğin değerini, orijinal ile aynı olacak şekilde ayarlar.

MouseEvent nesnesinin tüm özelliklerini içeren bir dize döndürür. Dize şu biçimdedir:

[MouseEvent type=value bubbles=value cancelable=value ... delta=value]

Flash Player veya Adobe AIR'i, bu olayın işlenmesi tamamlandıktan sonra ekran değişmişse ekranı oluşturmaya yönlendirir.

click olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

MouseEvent.CONTEXT_MENU sabiti, contextMenu olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

doubleClick olay nesnesinin type özelliği değerini tanımlar. Bir nesnenin doubleClick olayı oluşturması için doubleClickEnabled özelliğinin true olması gerekir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

middleClick olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

middleMouseDown olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

middleMouseUp olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

mouseDown olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

mouseMove olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Bir mouseOut olay nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Bir mouseOver olay nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

mouseUp olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

mouseWheel olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Bir releaseOutside olay nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

rightClick olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

rightMouseDown olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

rightMouseUp olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

rollOut olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Bir rollOver olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

1. Söz konusu örnek, ileride kare çiziminde kullanılmak üzere boyut (100 x 100 piksel) ve arka plan rengi (turuncu) özelliklerini bildirir.
2. Yapıcı yeni bir child ChildSprite nesnesi oluşturur. Bunun yapıcısı ilk olarak draw() çizim yöntemini çağırarak (0,0) koordinatlarında 100 x 100 piksel turuncu bir kare çizer ve yedi adet olay dinleyicisi/abonesi ekler.
   • click/clickHandler(): Kullanıcı karenin üzerini sol fare düğmesiyle bir kez tıklattığında gönderilir.
   • doubleClick/doubleClickHandler(): Kullanıcı karenin üzerini sol fare düğmesiyle çift tıklattığında gönderilir.
   • mouseDown/mouseDownHandler(): ChildSprite nesnesi (turuncu kare) tıklatıldığında, ekrana bir trace() mesajı yazdırılır ve sonra ChildSprite.draw() çağrılır, bu çağrı mouseOverHandler() öğesinde çizilmiş olan açık mavi kare yerine koyu sarı bir kare çizer. mouseDownHandler() yöntemi de bir mouseMove olay dinleyicisi ve fare hareketlerini işleyenmouseMoveHandler() abonesini (aşağıda açıklanmaktadır) ekler. Daha sonra startDrag() yöntemi çağrılır, bu çağrı Sprite nesnesinin sürüklenmesini sağlar.
   • mouseOut/mouseOutHandler(): İşaretçi kare alanından her çıktığında gönderilir. Kareyi normal boyut ve rengine dönüştürmek için draw() yöntemi çağrılır.
   • mouseOver/mouseOverHandler(): Fare işaretçisi karenin üzerinde olduğunda gönderilir. Bu yöntem, kareyi daha büyük ve arka plan rengi koyu sarı olacak şekilde yeniden çizer.
   • mouseUp/mouseUpHandler(): Kullanıcı fare düğmesini serbest bıraktığında, mouseMove olay dinleyicisi kaldırılır ve stopDrag çağrılır, bu çağrı kareyi yerinde dondurur.
   • mouseMove/mouseMoveHandler(): mouseDownHandler() işlevinin bir parçası olarak çağrılır ve kullanıcı sol fare düğmesine basıp kareyi sürüklerken gönderilir.
   • mouseWheel/mouseWheelHandler(): Kullanıcı fare tekerleğini karenin üzerinde döndürdüğünde gönderilir.
3. Daha sonra addChild() aracılığıyla child ChildSprite örneği görüntüleme listesine eklenir, bu da hemen turuncu kare çizer.

Notlar:

• MouseEventExample sınıfının belge kökü olması gerekir.
• Yukarıda listelenen olay yöntemlerinden bazıları, Sprite türüne event.target çevirisi atanan yerel bir sprite değişkenini bildirir.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}