XML

Paket	Översta nivån
Klass	public final dynamic class XML
Arv	XML Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Klassen XML innehåller metoder och egenskaper du använder när du arbetar med XML-objekt. Klassen XML (tillsammans med klasserna XMLList, Namespace och QName) implementerar kraftfulla XML-hanteringsstandarder som definieras i specifikationen ECMAScript för XML (E4X) (ECMA-357 utgåva 2).

Använd metoden toXMLString() om du vill returnera en strängbeteckning av XML-objektet, oavsett om XML-objektet har enkelt eller komplext innehåll.

Obs: Klassen XML (tillsammans med relaterade klasser) från ActionScript 2.0 har fått nytt namn, XMLDocument, och flyttats till paketet flash.xml. Klassen finns med i ActionScript 3.0 för bakåtkompatibilitet.

Visa exemplen

Lär dig mer

Specifikationen ECMAScript för XML (E4X) (ECMA-357 utgåva 2)

Relaterade API-element

Namespace
QName
XMLList
XML.toXMLString()

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object
		ignoreComments : Boolean [statisk] Avgör om XML-kommentarer ska ignoreras när XML-objekt tolkar XML-källdata.	XML
		ignoreProcessingInstructions : Boolean [statisk] Avgör om XML-behandlingsinstruktioner ska ignoreras när XML-objekt tolkar XML-källdata.	XML
		ignoreWhitespace : Boolean [statisk] Avgör om tomrum i början och slutet av textnoder ska ignoreras under tolkning.	XML
		prettyIndent : int [statisk] Avgör hur mycket indrag som ska användas av metoderna toString() och toXMLString() när egenskapen XML.prettyPrinting är inställd på true.	XML
		prettyPrinting : Boolean [statisk] Avgör om metoderna toString() och toXMLString() ska normalisera tomrum mellan vissa taggar.	XML

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		XML(value:Object) Skapar ett nytt XML-objekt.	XML
		addNamespace(ns:Object):XML Lägger till ett namnutrymme i uppsättningen med namnutrymmet i XML-objektets omfång.	XML
		appendChild(child:Object):XML Lägger till det angivna child i slutet av XML-objektets egenskaper.	XML
		attribute(attributeName:*):XMLList Returnerar XML-värdet för attributet som har ett namn som matchar parametern attributeName.	XML
		attributes():XMLList Returnerar en lista med attributvärden för det givna XML-objektet.	XML
		child(propertyName:Object):XMLList Listar underordnade objekt för ett XML-objekt.	XML
		childIndex():int Identifierar det här XML-objektets nollindexposition inom det överordnade objektet.	XML
		children():XMLList Listar XML-objektets underordnade objekt i den följd de visas.	XML
		comments():XMLList Listar de egenskaper i XML-objektet som innehåller XML-kommentarer.	XML
		contains(value:XML):Boolean Jämför XML-objektet med den givna value-parametern.	XML
		copy():XML Returnerar en kopia av det givna XML-objektet.	XML
		defaultSettings():Object [statisk] Returnerar ett objekt med följande egenskaper inställda på standardvärden: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent och prettyPrinting.	XML
		descendants(name:Object = *):XMLList Returnerar alla underordnade objekt (direkt underordnade och indirekt underordnade i ett eller flera steg) för XML-objektet med den givna name-parametern.	XML
		elements(name:Object = *):XMLList Listar elementen i ett XML-objekt.	XML
		hasComplexContent():Boolean Kontrollerar om XML-objektet innehåller komplext innehåll.	XML
		hasOwnProperty(p:String):Boolean Kontrollerar om objektet har egenskapen som anges av parametern p.	XML
		hasSimpleContent():Boolean Kontrollerar om XML-objektet innehåller enkelt innehåll.	XML
		inScopeNamespaces():Array Visar namnutrymmena för XML-objektet utifrån objektets överordnade.	XML
		insertChildAfter(child1:Object, child2:Object):* Infogar den givna parametern child2 efter parametern child1 i XML-objektet och returnerar det resulterande objektet.	XML
		insertChildBefore(child1:Object, child2:Object):* Infogar den givna parametern child2 före parametern child1 i XML-objektet och returnerar det resulterande objektet.	XML
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		length():int För XML-objekt returnerar den här metoden alltid heltalet 1.	XML
		localName():Object Ger den lokala namndelen av det kvalificerade namnet på XML-objektet.	XML
		name():Object Ger det kvalificerade namnet för XML-objektet.	XML
		namespace(prefix:String = null):* Om ingen parameter anges ges det namnutrymme som är associerat med det kvalificerade namnet på XML-objektet.	XML
		namespaceDeclarations():Array Listar namnutrymmesdeklarationer som är associerade med XML-objektet inom dess överordnade objekt.	XML
		nodeKind():String Anger typen av nod: text, kommentar, behandlingsinstruktion, attribut eller element.	XML
		normalize():XML För XML-objektet och alla underordnade XML-objekt sammanfogas intilliggande textnoder och tomma textnoder elimineras.	XML
		parent():* Returnerar XML-objektets överordnade objekt.	XML
		prependChild(value:Object):XML Infogar en kopia av det underordnade objektet i XML-elementet före eventuella befintliga XML-egenskaper för det elementet.	XML
		processingInstructions(name:String = "*"):XMLList Om en name-parameter har angetts listas alla underordnade objekt för XML-objektet som innehåller behandlingsinstruktioner med det namnet.	XML
		propertyIsEnumerable(p:String):Boolean Kontrollerar om egenskapen p finns i egenskapsuppsättningen som kan itereras i en for..in-programsats som tillämpas på XML-objektet.	XML
		removeNamespace(ns:Namespace):XML Tar bort det givna namnutrymmet för objektet och alla dess underordnade objekt på alla nivåer.	XML
		replace(propertyName:Object, value:XML):XML Ersätter egenskaperna som anges av parametern propertyName med den givna value-parametern.	XML
		setChildren(value:Object):XML Ersätter de underordnade egenskaperna för XML-objektet med den angivna uppsättningen XML-egenskaper, som anges i value-parametern.	XML
		setLocalName(name:String):void Ändrar XML-objektets lokala namn till den givna name-parametern.	XML
		setName(name:String):void Anger att XML-objektets namn ska vara det givna kvalificerade namnet eller attributnamnet.	XML
		setNamespace(ns:Namespace):void Anger namnutrymmet som är associerat med XML-objektet.	XML
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		setSettings(... rest):void [statisk] Anger värden för följande XML-egenskaper: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent och prettyPrinting.	XML
		settings():Object [statisk] Hämtar följande egenskaper: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent och prettyPrinting.	XML
		text():XMLList Returnerar ett XMLList-objekt för alla XML-egenskaper för XML-objektet som representerar XML-textnoder.	XML
		toJSON(k:String):* Erbjuder en åsidosättningsbar metod för att anpassa JSON-kodningen av värden i ett XML-objekt.	XML
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String Returnerar XML-objektets strängbeteckning.	XML
		toXMLString():String Returnerar XML-objektets strängbeteckning.	XML
		valueOf():XML Returnerar XML-objektet.	XML

Egenskapsdetaljer

ignoreComments

egenskap

ignoreComments:Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Avgör om XML-kommentarer ska ignoreras när XML-objekt tolkar XML-källdata. Som standard ignoreras kommentarerna (true). Om du vill ta med XML-kommentarerna ställer du in egenskapen på false. Egenskapen ignoreComments används endast vid tolkning av XML, inte under anrop till någon metod, till exempel myXMLObject.child(*).toXMLString(). Om käll-XML innehåller kommentarnoder, behålls eller tas de bort under tolkningen av XML-koden.

Implementering
public static function get ignoreComments():Boolean
public static function set ignoreComments(value:Boolean):void

Relaterade API-element

XML.child()
XML.toXMLString()

Exempel ( Så här använder du exemplet )

I det här exemplet visas effekterna av att ställa in XML.ignoreComments på false och på true:

XML.ignoreComments = false;
var xml1:XML = 
        <foo>
            <!-- comment -->
        </foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>

XML.ignoreComments = true;
var xml2:XML = 
        <foo>
            <!-- example -->
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreProcessingInstructions

egenskap

ignoreProcessingInstructions:Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Avgör om XML-behandlingsinstruktioner ska ignoreras när XML-objekt tolkar XML-källdata. Som standard ignoreras behandlingsinstruktionerna (true). Om du vill ta med XML-behandlingsinstruktionerna ställer du in egenskapen på false. Egenskapen ignoreProcessingInstructions används endast vid tolkning av XML, inte under anrop till någon metod, till exempel myXMLObject.child(*).toXMLString(). Om käll-XML innehåller behandlingsinstruktioner, behålls eller tas de bort under tolkningen av XML-koden.

Implementering
public static function get ignoreProcessingInstructions():Boolean
public static function set ignoreProcessingInstructions(value:Boolean):void

Relaterade API-element

XML.child()
XML.toXMLString()

Exempel ( Så här använder du exemplet )

I det här exemplet visas effekterna av att ställa in XML.ignoreProcessingInstructions på false och på true:

XML.ignoreProcessingInstructions = false;
var xml1:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>

XML.ignoreProcessingInstructions = true;
var xml2:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreWhitespace

egenskap

ignoreWhitespace:Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Avgör om tomrum i början och slutet av textnoder ska ignoreras under tolkning. Som standard ignoreras tomt utrymme (true). Om en textnod innehåller 100 % tomt utrymme och egenskapen ignoreWhitespace är inställd på true, skapas inte noden. Om du vill visa tomt utrymme i en textnod ställer du in egenskapen ignoreWhitespace på false.

När du skapar ett XML-objekt cachelagras det aktuella värdet på egenskapen ignoreWhitespace. Även om du ändrar ignoreWhitespace påverkar det inte beteendet för befintliga XML-objekt.

Implementering
public static function get ignoreWhitespace():Boolean
public static function set ignoreWhitespace(value:Boolean):void

Exempel ( Så här använder du exemplet )

I det här exemplet visas effekterna av att ställa in XML.ignoreWhitespace på false och på true:

XML.ignoreWhitespace = false;
var xml1:XML = <foo>    </foo>;
trace(xml1.children().length()); // 1

XML.ignoreWhitespace = true;
var xml2:XML = <foo>    </foo>;
trace(xml2.children().length()); // 0

prettyIndent

egenskap

prettyIndent:int

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Avgör hur mycket indrag som ska användas av metoderna toString() och toXMLString() när egenskapen XML.prettyPrinting är inställd på true. Indrag görs med blanksteg, inte med tabbtecken. Standardvärdet är 2.

Implementering
public static function get prettyIndent():int
public static function set prettyIndent(value:int):void

Relaterade API-element

prettyPrinting
toString()
toXMLString()

Exempel ( Så här använder du exemplet )

I det här exemplet visas effekten av att ställa in den statiska egenskapen XML.prettyIndent:

var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());

XML.prettyIndent = 1;
trace(xml.toXMLString());

XML.prettyIndent = 2;
trace(xml.toXMLString());

prettyPrinting

egenskap

prettyPrinting:Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Avgör om metoderna toString() och toXMLString() ska normalisera tomrum mellan vissa taggar. Standardvärdet är true.

Implementering
public static function get prettyPrinting():Boolean
public static function set prettyPrinting(value:Boolean):void

Relaterade API-element

prettyIndent
toString()
toXMLString()

Exempel ( Så här använder du exemplet )

I det här exemplet visas effekterna av att ställa in den statiska egenskapen XML.prettyPrinting:

var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());

XML.prettyPrinting = true;
trace(xml.toXMLString());

Konstruktordetaljer

()

Konstruktor

public function XML(value:Object)

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Skapar ett nytt XML-objekt. Du måste använda konstruktorn för att skapa ett XML-objekt innan du kan anropa metoderna i klassen XML.

Använd metoden toXMLString() om du vill returnera en strängbeteckning av XML-objektet, oavsett om XML-objektet har enkelt eller komplext innehåll.

Parametrar

value:Object — Alla objekt som kan konverteras till XML med toppnivåfunktionen XML().

Relaterade API-element

Den globala funktionen XML()
XML.toXMLString()

Exempel ( Så här använder du exemplet )

Exemplet nedan visar hur du kan läsa in ett XML fjärrdokument i ActionScript 3.0 med klassen URLLoader i Flash Professional. Exempel från ActionScriptExamples.com.

//
// Requires:
//   - TextArea control UI component in the Flash Professional Library.
//
import fl.controls.TextArea;
 
var xml:XML;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
 
var urlLoader:URLLoader = new URLLoader();
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
var textArea:TextArea = new TextArea();
textArea.move(5, 5);
textArea.setSize(stage.stageWidth - 10, stage.stageHeight - 10);
addChild(textArea);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.currentTarget.data);
    textArea.text = xml.toXMLString();
}

Här är en annan variant som bara använder ActionScript. Exempel från ActionScriptExamples.com.

var xml:XML;
var textArea:TextField = new TextField();
textArea.width = 300;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.target.data);
    textArea.text = xml.toXMLString();
    addChild(textArea);
}

Metoddetaljer

addNamespace

()

metod

AS3 function addNamespace(ns:Object):XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Lägger till ett namnutrymme i uppsättningen med namnutrymmet i XML-objektets omfång. Om namnutrymmet redan finns i namnutrymmesomfånget för XML-objektet (med ett prefix som matchar en angiven parameter), ställs prefixet för det befintliga namnutrymmet in på undefined. Om en indataparameter är ett Namespace-objekt används det direkt. Om indataparametern är ett QName-objekt används dess URI för att skapa ett nytt namnutrymme, annars konverteras den till ett String-objekt och därefter skapas ett namnutrymme från String-objektet.

Parametrar

ns:Object — Namnutrymmet som ska läggas till i XML-objektet.

Returnerar

XML — Det nya XML-objektet med namnutrymmet tillagt.

Exempel ( Så här använder du exemplet )

Exemplet använder ett namnutrymme som har definierats i ett XML-objekt och tillämpar det sedan på ett annat XML-objekt:

var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();

var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>

appendChild

()

metod

AS3 function appendChild(child:Object):XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Lägger till det angivna child i slutet av XML-objektets egenskaper. Metoden appendChild() tar ett XML-objekt, ett XMLList-objekt eller någon annan datatyp som konverteras till en String.

Använd (XML-) operatorn delete för att ta bort XML-noder.

Parametrar

child:Object — XML-objektet som ska läggas till.

Returnerar

XML — Det resulterande XML-objektet.

Relaterade API-element

(XML-) operatorn delete

Exempel ( Så här använder du exemplet )

I det här exemplet läggs ett nytt element till i slutet av XML-objektets lista med underordnade noder:

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.appendChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>

attribute

()

metod

AS3 function attribute(attributeName:*):XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar XML-värdet för attributet som har ett namn som matchar parametern attributeName. Attribut finns i XML-element. I följande exempel har elementet ett attribut med namnet " gender " med värdet " boy ": <first gender="boy">John</first>.

Parametern attributeName kan vara av valfri datatyp. String är dock den vanligaste datatypen som används. När du skickar ett objekt i stället för ett QName-objekt använder parametern attributeName metoden toString() för att konvertera parametern till en sträng.

Om du behöver en kvalificerad namnreferens kan du skicka ett QName-objekt. Ett QName-objekt definierar ett namnutrymme och det lokala namnet som du använder när du definierar det kvalificerade namnet på ett attribut. Därför är det inte samma sak att anropa attribute(qname) som att anropa attribute(qname.toString()).

Parametrar

attributeName:* — Attributnamnet.

Returnerar

XMLList — Ett XMLList-objekt eller ett tomt XMLList-objekt. Returnerar ett tomt XMLList-objekt när ett attributvärde inte har definierats.

Relaterade API-element

XML.attributes()
QName
Namespace
XML.elements()
attributidentifieraroperator (@)

Exempel ( Så här använder du exemplet )

Det hr exemplet visar ett QName-objekt som skickas till metoden attribute(). Egenskapen localName är attr och egenskapen namespace är ns.

 var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />       
 var qn:QName = new QName("http://uri", "attr");
 trace (xml.attribute(qn)); // 7

Om du vill returnera ett attribut med ett namn som matchar ett reserverat ord i ActionScript använder du metoden attribute() i stället för attributidentifieraroperatorn (@), som i följande exempel:

 var xml:XML = <example class="first" />
 trace(xml.attribute("class"));

attributes

()

metod

AS3 function attributes():XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar en lista med attributvärden för det givna XML-objektet. Använd metoden name() med metoden attributes() om du vill returnera namnet på ett attribut. Att använda xml.attributes() är ekvivalent med xml.@*.

Returnerar

XMLList — Listan med attributvärden.

Relaterade API-element

XML.attribute()
XML.name()
@-operator

Exempel ( Så här använder du exemplet )

I följande exempel returneras namnet på attributet:

var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color

I det här exemplet returneras namnen på alla attribut:

 
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;

trace (attNamesList is XMLList); // true
trace (attNamesList.length()); // 2

for (var i:int = 0; i < attNamesList.length(); i++)
{ 
    trace (typeof (attNamesList[i])); // xml
    trace (attNamesList[i].nodeKind()); // attribute
    trace (attNamesList[i].name()); // id and color
}

child

()

metod

AS3 function child(propertyName:Object):XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Listar underordnade objekt för ett XML-objekt. Ett underordnat XML-objekt är ett XML-element, en textnod, en kommentar eller en bearbetningsinstruktion.

Använd parametern propertyName om du vill visa innehållet i ett visst underordnat XML-objekt. Om du till exempel vill återställa innehållet för ett underordnat objekt med namnet <first>, ska du anropa child("first") i XML-objektet. Du får samma resultat om du använder det underordnade objektets indexvärde. Indexvärdet identifierar det underordnade objektets position i listan med andra underordnade XML-objekt. Till exempel returnerar child(0) det första underordnade objektet.

Använd en asterisk (*) om du vill hämta alla de underordnade objekten i ett XML-dokument. Exempel: doc.child("*").

Använd metoden length() med en asteriskparameter (*) för metoden child() om du vill hämta totalt antal underordnade objekt. Exempel: numChildren = doc.child("*").length().

Parametrar

propertyName:Object — Elementnamnet eller heltalet för det underordnade XML-elementet.

Returnerar

XMLList — Ett XMLList-objekt med underordnade noder som matchar indataparametern.

Relaterade API-element

XML.elements()
Klassen XMLList
XML.length()

Exempel ( Så här använder du exemplet )

Det här exemplet visar hur du använder metoden child() för att identifiera underordnade element med ett visst namn:

var xml:XML = 
        <foo>
            <bar>text1</bar>
            <bar>text2</bar>
        </foo>;
trace(xml.child("bar").length());  // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>

childIndex

()

metod

AS3 function childIndex():int

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Identifierar det här XML-objektets nollindexposition inom det överordnade objektet.

Returnerar

int — Objektets position. Returnerar -1 samt positiva heltal.

Exempel ( Så här använder du exemplet )

Det här exemplet visar hur du använder metoden childIndex():

var xml:XML = 
            <foo>
                <bar />
                text
                <bob />
            </foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2

children

()

metod

AS3 function children():XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Listar XML-objektets underordnade objekt i den följd de visas. Ett underordnat XML-objekt är ett XML-element, en textnod, en kommentar eller en bearbetningsinstruktion.

Returnerar

XMLList — Ett XMLList-objekt med de underordnade elementen i XML-objektet.

Exempel ( Så här använder du exemplet )

Det här exemplet visar hur du använder metoden children():

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML = 
        <foo id="22">
            <bar>44</bar>
            text
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>

comments

()

metod

AS3 function comments():XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Listar de egenskaper i XML-objektet som innehåller XML-kommentarer.

Returnerar

XMLList — Ett XMLList-objekt med egenskaperna som innehåller kommentarer.

Exempel ( Så här använder du exemplet )

Det här exemplet visar hur du använder metoden comments():

XML.ignoreComments = false;
var xml:XML = 
        <foo>
            <!-- example -->
            <!-- example2 -->
        </foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->

contains

()

metod

AS3 function contains(value:XML):Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Jämför XML-objektet med den givna value-parametern.

Parametrar

value:XML — Ett värde som jämförs med det aktuella XML-objektet.

Returnerar

Boolean — Om XML-objektet som matchar parametern value returneras true annars returneras false.

Exempel ( Så här använder du exemplet )

Det här exemplet visar hur du använder metoden contains():

var xml:XML = 
        <order>
            <item>Rice</item>
            <item>Kung Pao Shrimp</item>
        </order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false

copy

()

metod

AS3 function copy():XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar en kopia av det givna XML-objektet. Kopian är ett duplikat av hela trädet med noder. Det kopierade XML-objektet har inget överordnat objekt och returnerar null om du anropar metoden parent().

Returnerar

XML — Objektets kopia.

Exempel ( Så här använder du exemplet )

I det här exemplet visas att metoden copy() skapar en ny instans av ett XML-objekt. Originalet ändras inte när du ändrar kopian:

var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1

defaultSettings

()

metod

AS3 static function defaultSettings():Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar ett objekt med följande egenskaper inställda på standardvärden: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent och prettyPrinting. Standardvärdena är som följer:

ignoreComments = true
ignoreProcessingInstructions = true
ignoreWhitespace = true
prettyIndent = 2
prettyPrinting = true

Obs: Den här metoden ska inte användas på en instans av XML-klassen. Du använder den på XML, som i följande kod: var df:Object = XML.defaultSettings().

Returnerar

Object — Ett objekt med egenskaper inställda på standardvärden.

Relaterade API-element

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.setSettings()
XML.settings()

Exempel ( Så här använder du exemplet )

I följande exempel visas: hur du använder vissa anpassade inställningar (för att ta med kommentarer och behandlingsinstruktioner) innan du ställer in ett XML-objekt, hur du sedan går tillbaka till standardinställningarna innan du ställer in ett annat XML-objekt och hur du ställer in anpassade inställningar igen (för att ställa in fler XML-objekt):

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

descendants

()

metod

AS3 function descendants(name:Object = *):XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar alla underordnade objekt (direkt underordnade och indirekt underordnade i ett eller flera steg) för XML-objektet med den givna name-parametern. Parametern name är valfri. Parametern name kan vara ett QName-objekt, en String-datatyp eller någon annan datatyp som konverteras till en String-datatyp.

Om du vill returnera alla underordnade objekt använder du parametern "*". Om ingen parameter skickas, skickas strängen "*" och alla underordnade objekt till XML-objektet returneras.

Parametrar

name:Object (default = *) — Namnet på elementet som ska matchas.

Returnerar

XMLList — Ett XMLList-objekt med matchande underordnade objekt. Om det inte finns några underordnade objekt returneras ett tomt XMLList-objekt.

Relaterade API-element

descendant accessor (..) operator

Exempel ( Så här använder du exemplet )

Om du vill returnera underordnade objekt med namn som matchar reserverade ord i ActionScript använder du metoden descendants() i stället för den underordnade operatorn (..) , som i följande exempel:

var xml:XML = 
  <enrollees>
    <student id="239">
        <class name="Algebra" />
        <class name="Spanish 2"/>
    </student>
    <student id="206">
        <class name="Trigonometry" />
        <class name="Spanish 2" />
    </student>
  </enrollees>
trace(xml.descendants("class"));

I följande exempel visas att metoden descendants() returnerar ett XMLList-objekt som innehåller alla underordnade objekt, även direkt underordnade och indirekt underordnade i ett eller flera steg:

XML.ignoreComments = false;
var xml:XML = 
        <body>
            <!-- comment -->
            text1
            <a>
                <b>text2</b>
            </a>
        </body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>

elements

()

metod

AS3 function elements(name:Object = *):XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Listar elementen i ett XML-objekt. Ett element består av en start- och en sluttagg, till exempel <first></first>. Parametern name är valfri. Parametern name kan vara ett QName-objekt, en String-datatyp eller någon annan datatyp som konverteras till en String-datatyp. Använd parametern name om du vill visa ett visst element. Elementet " first " returnerar " John " i det här exemplet: <first>John</first>.

Om du vill visa alla element använder du asterisk (*) som parameter. Asterisk är även standardparameter.

Använd metoden length() med en asteriskparameter om du vill hämta det totala antalet element. Exempel: numElement = addressbook.elements("*").length().

Parametrar

name:Object (default = *) — Elementets namn. Ett elementnamn är omgivet av vinkelparenteser. "first" är till exempel name i det här exemplet: <first></first>.

Returnerar

XMLList — Ett XMLList-objekt med elementets innehåll. Elementets innehåll finns mellan start- och sluttaggarna. Om du anropar alla element med asterisken (*) returneras både elementets taggar och innehåll.

Relaterade API-element

XML.child()
Klassen XMLList
XML.length()
XML.attribute()
XML-punkt- (.) operator

Exempel ( Så här använder du exemplet )

I följande exempel visas att metoden elements() endast returnerar en elementlista – inga kommentarer, textegenskaper eller behandlingsinstruktioner:

var xml:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
            text
            <a>1</a>
            <b>2</b>
        </foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b>

Om du vill returnera element med namn som matchar reserverade ord i ActionScript använder du metoden elements() i stället för XML-punktoperatorn (.) , som i följande exempel:

var xml:XML =
 <student id="206">
    <class name="Trigonometry" />
    <class name="Spanish 2" />
 </student>
trace(xml.elements("class"));

hasComplexContent

()

metod

AS3 function hasComplexContent():Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Kontrollerar om XML-objektet innehåller komplext innehåll. Ett XML-objekt innehåller komplext innehåll om det har underordnade element. XML-objekt som representerar attribut, kommentarer, behandlingsinstruktioner och textnoder har inget komplext innehåll. Ett objekt som innehåller ovanstående objekt kan dock anses innehålla komplext innehåll (om objektet har underordnade element).

Returnerar

Boolean — Om XML-objektet innehåller komplext innehåll true; annars false.

Relaterade API-element

XML.hasSimpleContent()

Exempel ( Så här använder du exemplet )

I följande exempel visas ett XML-objekt med egenskapen a som har enkelt innehåll och en egenskap med namnet a som har komplext innehåll:

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

hasOwnProperty

()

metod

AS3 function hasOwnProperty(p:String):Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Kontrollerar om objektet har den egenskap som anges av parametern p.

Parametrar

p:String — Egenskapen som ska matchas.

Returnerar

Boolean — Om egenskapen existerar true; annars false.

Exempel ( Så här använder du exemplet )

I följande exempel använder du metoden hasOwnProperty() för att kontrollera att en egenskap (b) existerar innan ett uttryck utvärderas (b == "11"):

var xml:XML = 
        <foo>
            <a />
            <a>
                <b>10</b>
            </a>
            <a>
                <b>11</b>
            </a>
        </foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11"));

Om den sista raden i exemplet var följande, genereras ett undantag i Flash Player eftersom det första elementet med namnet a inte har en egenskap med namnet b:

trace(xml.a.(b == "11"));

I följande exempel använder du metoden hasOwnProperty() för att kontrollera att en egenskap (item) existerar innan ett uttryck utvärderas (item.contains("toothbrush")):

var xml:XML = 
        <orders>
            <order id='1'>
                <item>toothbrush</item>
                <item>toothpaste</item>
            </order>
            <order>
                <returnItem>shoe polish</returnItem>
            </order>
        </orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush")));

hasSimpleContent

()

metod

AS3 function hasSimpleContent():Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Kontrollerar om XML-objektet innehåller enkelt innehåll. Ett XML-objekt innehåller enkelt innehåll om det representerar en textnod, en attributnod eller ett XML-element som inte har några underordnade element. XML-objekt som representerar kommentarer och behandlingsinstruktioner innehåller inget enkelt innehåll.

Returnerar

Boolean — Om XML-objektet innehåller enkelt innehåll true; annars false.

Relaterade API-element

XML.hasComplexContent()

Exempel ( Så här använder du exemplet )

I följande exempel visas ett XML-objekt med egenskapen a som har enkelt innehåll och en egenskap med namnet a som har komplext innehåll:

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

inScopeNamespaces

()

metod

AS3 function inScopeNamespaces():Array

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Visar namnutrymmena för XML-objektet utifrån objektets överordnade.

Returnerar

Array — En array med Namespace-objekt.

insertChildAfter

()

metod

AS3 function insertChildAfter(child1:Object, child2:Object):*

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Infogar den givna parametern child2 efter parametern child1 i XML-objektet och returnerar det resulterande objektet. Om parametern child1 är null infogar metoden innehållet av child2 före alla underordnade objekt i XML-objektet (efter none). Om child1 anges men inte finns i XML-objektet ändras inte XML-objektet och undefined returneras.

Om du anropar den här metoden på ett underordnat XML-objekt som inte är ett element (text, attribut, kommentarer och så vidare) returneras undefined.

Använd (XML-) operatorn delete för att ta bort XML-noder.

Parametrar

	`child1:Object` — Objektet i källobjektet som du infogar före `child2`.

	`child2:Object` — Objektet som ska infogas.

Returnerar

* — Det resulterande XML-objektet eller undefined.

Relaterade API-element

XML.insertChildBefore()
(XML-) operatorn delete

Exempel ( Så här använder du exemplet )

I följande exempel läggs ett nytt element till i slutet av de underordnade elementen i ett XML-objekt:

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

Följande trace()-resultat visas:

 <menu>
     <item>burger</item>
     <saleItem>fries</saleItem>
     <item>soda</item>
 </menu>

insertChildBefore

()

metod

AS3 function insertChildBefore(child1:Object, child2:Object):*

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Infogar den givna parametern child2 före parametern child1 i XML-objektet och returnerar det resulterande objektet. Om parametern child1 är null infogar metoden innehållet av child2 efter alla underordnade objekt i XML-objektet (före none). Om child1 anges men inte finns i XML-objektet ändras inte XML-objektet och undefined returneras.

Om du anropar den här metoden på ett underordnat XML-objekt som inte är ett element (text, attribut, kommentarer och så vidare) returneras undefined.

Använd (XML-) operatorn delete för att ta bort XML-noder.

Parametrar

	`child1:Object` — Objektet i källobjektet som du infogar efter `child2`.

	`child2:Object` — Objektet som ska infogas.

Returnerar

* — Det resulterande XML-objektet eller undefined.

Relaterade API-element

XML.insertChildAfter()
(XML-) operatorn delete

Exempel ( Så här använder du exemplet )

I följande exempel läggs ett nytt element till i slutet av de underordnade elementen i ett XML-objekt:

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildBefore(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

Följande trace()-resultat visas:

 <menu>
     <saleItem>fries</saleItem>
     <item>burger</item>
     <item>soda</item>
 </menu>

length

()

metod

AS3 function length():int

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

För XML-objekt returnerar den här metoden alltid heltalet 1. Metoden length() i XMLList-klassen returnerar värdet 1 för ett XMLList-objekt som endast innehåller ett värde.

Returnerar

int — Returnerar alltid 1 för alla XML-objekt.

localName

()

metod

AS3 function localName():Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Ger den lokala namndelen av det kvalificerade namnet på XML-objektet.

Returnerar

Object — Det lokala namnet som antingen en String eller null.

Exempel ( Så här använder du exemplet )

I följande exempel visas hur metoden localName() används:

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.localName()); // Envelope

name

()

metod

AS3 function name():Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Ger det kvalificerade namnet för XML-objektet.

Returnerar

Object — Det kvalificerade namnet är antingen ett QName-objekt eller null.

Relaterade API-element

XML.attributes()
attributidentifierare

Exempel ( Så här använder du exemplet )

I följande exempel visas hur du använder metoden name() för att få det kvalificerade namnet för ett XML-objekt:

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope"

I följande exempel visas hur metoden name() anropar en XML-egenskap, på ett textelement och på ett attribut:

var xml:XML = 
        <foo x="15" y="22">
            text
        </foo>;
        
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x

namespace

()

metod

AS3 function namespace(prefix:String = null):*

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Om ingen parameter anges ges det namnutrymme som är associerat med det kvalificerade namnet på XML-objektet. Om en prefix-parameter anges returnerar metoden namnutrymmet som matchar prefix-parametern och som är i omfånget för XML-objektet. Om det inte finns ett sådant namnutrymme returnerar metoden undefined.

Parametrar

prefix:String (default = null) — Prefixet som du vill matcha.

Returnerar

* — Returnerar null, undefined eller ett namnutrymme.

Exempel ( Så här använder du exemplet )

I följande exempel använder du metoden namespace() för att få namnutrymmet för ett XML-objekt och tilldela det till ett Namespace-objekt med namnet soap som sedan används för att identifiera en egenskap i xml-objektet (xml.soap::Body[0]):

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope

var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather"

I följande exempel använder du metoden namespace() för att hämta standardnamnutrymmet för en nod samt namnutrymmet för ett visst prefix ("dc"):

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">
                <!-- ... -->
        </rdf:RDF>;
                    
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined

namespaceDeclarations

()

metod

AS3 function namespaceDeclarations():Array

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Listar namnutrymmesdeklarationer som är associerade med XML-objektet inom dess överordnade objekt.

Returnerar

Array — En array med Namespace-objekt.

Relaterade API-element

XML.namespace()

Exempel ( Så här använder du exemplet )

I följande exempel skrivs namnutrymmesdeklarationer ut för ett XML-objekt:

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">

            <!-- ... -->
            
        </rdf:RDF>;
                    
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
    var ns:Namespace = xml.namespaceDeclarations()[i]; 
    var prefix:String = ns.prefix;
    if (prefix == "") {
        prefix = "(default)";
    }
    trace(prefix + ":" , ns.uri);
}

Följande trace()-resultat visas:

rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
 dc: http://purl.org/dc/elements/1.1/
 (default): http://purl.org/rss/1.0/

nodeKind

()

metod

AS3 function nodeKind():String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Anger typen av nod: text, kommentar, behandlingsinstruktion, attribut eller element.

Returnerar

String — Nodtypen som används.

Relaterade API-element

attributidentifierare

Exempel ( Så här använder du exemplet )

I exemplet skrivs alla fem nodtyperna ut:

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;

var xml:XML = 
    <example id="10">
        <!-- this is a comment -->
        <?test this is a pi ?>
        and some text
    </example>;

trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute

normalize

()

metod

AS3 function normalize():XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

För XML-objektet och alla underordnade XML-objekt sammanfogas intilliggande textnoder och tomma textnoder elimineras.

Returnerar

XML — Det resulterande normaliserade XML-objektet.

Exempel ( Så här använder du exemplet )

I följande exempel visas effekten av att anropa metoden normalize():

var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1

parent

()

metod

AS3 function parent():*

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar XML-objektets överordnade objekt. Om XML-objektet inte har något överordnat objekt returnerar metoden undefined.

Returnerar

* — Antingen en XML-referens för den överordnade noden eller undefined om XML-objektet inte har något överordnat objekt.

Exempel ( Så här använder du exemplet )

I följande exempel använder du metoden parent() för att identifiera det överordnade elementet för ett angivet element i en XML-struktur:

var xml:XML = 
    <body>
        <p id="p1">Hello</p>
        <p id="p2">Test:
            <ul>
                <li>1</li>
                <li>2</li>
            </ul>
        </p>
    </body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2

prependChild

()

metod

AS3 function prependChild(value:Object):XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Infogar en kopia av child-objektet i XML-elementet före eventuella befintliga XML-egenskaper för det elementet.

Använd (XML-) operatorn delete för att ta bort XML-noder.

Parametrar

value:Object — Objektet som ska infogas.

Returnerar

XML — Det resulterande XML-objektet.

Relaterade API-element

(XML-) operatorn delete

Exempel ( Så här använder du exemplet )

I följande exempel använder du metoden prependChild() för att lägga till ett element i början av ett XML-objekts lista med underordnade objekt:

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.prependChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>

processingInstructions

()

metod

AS3 function processingInstructions(name:String = "*"):XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Om en name-parameter har angetts visas alla underordnade objekt för XML-objektet som innehåller behandlingsinstruktioner med name. Utan parametrar visar metoden alla underordnade objekt för XML-objektet som innehåller behandlingsinstruktioner.

Parametrar

name:String (default = "*") — Namnet på behandlingsinstruktionerna som ska matchas.

Returnerar

XMLList — En lista med matchande underordnade objekt.

Exempel ( Så här använder du exemplet )

I följande exempel använder du metoden processingInstructions() för att hämta en array med behandlingsinstruktioner för ett XML-objekt:

XML.ignoreProcessingInstructions = false;
var xml:XML =
    <body>
            foo
            <?xml-stylesheet href="headlines.css" type="text/css" ?>
            <?instructionX ?>
            
    </body>;

trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet

propertyIsEnumerable

()

metod

AS3 function propertyIsEnumerable(p:String):Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Kontrollerar om egenskapen p finns i egenskapsuppsättningen som kan itereras i en for..in-programsats som tillämpas på XML-objektet. Returnerar endast true om toString(p) == "0".

Parametrar

p:String — Egenskapen som du vill kontrollera.

Returnerar

Boolean — Om egenskapen kan itereras i en for..in-programsats true; annars false.

Exempel ( Så här använder du exemplet )

I följande exempel visas att metoden propertyNameIsEnumerable() för ett XML-objekt endast returnerar värdet true för värdet 0, medan det för ett XMLList-objekt returnerar värdet true för alla giltiga indexvärden för ett XMLList-objekt:

var xml:XML = 
        <body>
             <p>Hello</p>
               <p>World</p>
        </body>;

trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false

for (var propertyName:String in xml) {
    trace(xml[propertyName]);
}

var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false

for (var propertyName:String in list) { 
    trace(list[propertyName]);
}

removeNamespace

()

metod

AS3 function removeNamespace(ns:Namespace):XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Tar bort det givna namnutrymmet för objektet och alla dess underordnade objekt på alla nivåer. Du kan inte ta bort ett namnutrymme med metoden removeNamespaces() om objektets kvalificerade namn eller de kvalificerade namnen på objektets attribut refererar till namnutrymmet.

Parametrar

ns:Namespace — Namnutrymmet som ska tas bort.

Returnerar

XML — En kopia av det resulterande XML-objektet.

Exempel ( Så här använder du exemplet )

I följande exempel visas hur du tar bort en namnutrymmesdeklaration från ett XML-objekt:

var xml:XML = 
    <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
        xmlns:dc="http://purl.org/dc/elements/1.1/" 
        xmlns="http://purl.org/rss/1.0/">
    
        <!-- ... -->
        
    </rdf:RDF>;

trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); // 
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2

replace

()

metod

AS3 function replace(propertyName:Object, value:XML):XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Ersätter de egenskaper som anges av parametern propertyName med den givna value-parametern. Om inga egenskaper matchar propertyName ändras inte XML-objektet.

Parametrar

	`propertyName:Object` — Kan vara ett numeriskt värde, ett okvalificerat namn eller en uppsättning XML-element, ett kvalificerat namn för en uppsättning XML-element eller jokertecknet asterisk ("*"). Använd ett okvalificerat namn när du identifierar XML-element i standardnamnutrymmet.

	`value:XML` — Ersättningsvärdet. Detta kan vara ett XML-objekt, ett XMLList-objekt eller ett annat värde som kan konverteras med `toString()`.

Returnerar

XML — Det resulterande XML-objektet med den matchande egenskapen utbytt.

Exempel ( Så här använder du exemplet )

I följande exempel visas hur metoden replace() anropas med ett heltal som första parameter:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace(1, <p>Bob</p>);
trace(xml);

Detta ger följande trace()-utdata:


 <body>
     <p>Hello</p>
     <p>Bob</p>
     <hr/>
 </body>

I följande exempel anropas metoden replace() med en sträng som första parameter:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("p", <p>Hi</p>); 
trace(xml);

Detta ger följande trace()-utdata:


 <body>
     <p>Hi</p>
     <hr/>
 </body>;

I följande exempel visas hur metoden replace() anropas med ett QName som första parameter:

var xml:XML = 
    <ns:body xmlns:ns = "myNS">
        <ns:p>Hello</ns:p>
        <ns:p>World</ns:p>
        <hr/>
    </ns:body>;

var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);

Detta ger följande trace()-utdata:


 <ns:body xmlns:ns = "myNS">
     <p>Bob</p>
     <hr/>
 </ns:body>

I följande exempel visas hur metoden replace() anropas med strängen "*" som första parameter:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("*", <img src = "hello.jpg"/>);
trace(xml);

Detta ger följande trace()-utdata:


 <body>
     <img src="hello.jpg"/>
 </body>

setChildren

()

metod

AS3 function setChildren(value:Object):XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Ersätter de underordnade egenskaperna för XML-objektet med den angivna uppsättningen XML-egenskaper, som anges i value-parametern.

Parametrar

value:Object — XML-ersättningsegenskaperna. Kan vara ett XML-objekt eller ett XMLList-objekt.

Returnerar

XML — Det resulterande XML-objektet.

Exempel ( Så här använder du exemplet )

I följande exempel visas hur metoden setChildren() anropas, först med ett XML-objekt som parameter och sedan med ett XMLList-objekt som parameter:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
    </body>;

var list:XMLList = xml.p;

xml.setChildren(<p>hello</p>);
trace(xml);

//    <body>
//        <p>hello</p>
//    </body>

xml.setChildren(list);
trace(xml);

//    <body>
//        <p>Hello</p>
//        <p>World</p>
//    </body>

setLocalName

()

metod

AS3 function setLocalName(name:String):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Ändrar XML-objektets lokala namn till den givna name-parametern.

Parametrar

name:String — Ersättningsnamnet för det lokala namnet.

Exempel ( Så här använder du exemplet )

I följande exempel använder du metoden setLocalName() för att ändra det lokala namnet på ett XML-element:

var xml:XML = 
    <ns:item xmlns:ns="http://example.com">
        toothbrush
    </ns:item>;
    
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>

setName

()

metod

AS3 function setName(name:String):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Anger att XML-objektets namn ska vara det givna kvalificerade namnet eller attributnamnet.

Parametrar

name:String — Det nya namnet för objektet.

Exempel ( Så här använder du exemplet )

I följande exempel använder du metoden setName() för att ändra namnet för ett XML-element:

var xml:XML = 
    <item>
        toothbrush
    </item>;
    
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>

setNamespace

()

metod

AS3 function setNamespace(ns:Namespace):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Anger namnutrymmet som är associerat med XML-objektet.

Parametrar

ns:Namespace — Det nya namnutrymmet.

Exempel ( Så här använder du exemplet )

I följande exempel använder du namnutrymmet soap som har definierats i ett XML-objekt och tillämpar det sedan på ett namnutrymme för ett annat XML-objekt (xml2):

var xml1:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
            <!-- ... -->
        </soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");

var xml2:XML = 
    <Envelope>
        <Body/>
    </Envelope>;
    
xml2.setNamespace(ns);

trace(xml2);

setSettings

()

metod

AS3 static function setSettings(... rest):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Anger värden för följande XML-egenskaper: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent och prettyPrinting. Följande är standardinställningar som används om ingen setObj-parameter anges:

XML.ignoreComments = true
XML.ignoreProcessingInstructions = true
XML.ignoreWhitespace = true
XML.prettyIndent = 2
XML.prettyPrinting = true

Obs: Använd inte den här metoden på en instans av XML-klassen. Använd den på XML, som i följande kod: XML.setSettings().

Parametrar

... rest — Ett objekt med följande egenskaper:

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

Relaterade API-element

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting
defaultSettings()
settings()

Exempel ( Så här använder du exemplet )

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

settings

()

metod

AS3 static function settings():Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Hämtar följande egenskaper: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent och prettyPrinting.

Returnerar

Object — Ett objekt med följande XML-egenskaper:

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

Relaterade API-element

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.defaultSettings()
XML.setSettings()

Exempel ( Så här använder du exemplet )

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

text

()

metod

AS3 function text():XMLList

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar ett XMLList-objekt för alla XML-egenskaper för XML-objektet som representerar XML-textnoder.

Returnerar

XMLList — Listan med egenskaper.

Exempel ( Så här använder du exemplet )

I följande exempel använder du metoden text() för att få textnoderna för ett XML-objekt:

var xml:XML =
        <body>
            text1
            <hr/>
            text2
        </body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2

toJSON

()

metod

AS3 function toJSON(k:String):*

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

Flash Player 11, AIR 3, Flash Lite 4

Erbjuder en åsidosättningsbar metod för att anpassa JSON-kodningen av värden i ett XML-objekt.

I metoden JSON.stringify() eftersöks en toJSON()-metod för varje objekt som flyttas. Om metoden toJSON() hittas, anropar JSON.stringify() den för varje värde som upptäcks och anger nyckeln som är kopplad till värdet.

XML erbjuder en standardimplementering av toJSON() som endast returnerar namnet på klassen. Klienter som vill exportera XML-objekt till JSON måste erbjuda egna implementeringar. Du kan göra detta genom att omdefiniera metoden toJSON() på klassprototypen.

Metoden toJSON() kan returnera alla typer av värden. Om ett objekt returneras kommer stringify() att repeteras i objektet. Om toJSON() returnerar en sträng, kommer stringify() inte att repeteras och genomgången fortsätter.

Parametrar

k:String — Nyckeln i ett nyckel-/värdepar som upptäckts i JSON.stringify() vid genomgång av detta objekt.

Returnerar

* — Klassnamnssträngen.

Relaterade API-element

Object
Object.prototype

toString

()

metod

AS3 function toString():String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar XML-objektets strängbeteckning. Reglerna för denna konvertering beror på om XML-objektet har enkelt eller komplext innehåll:

Om XML-objektet har enkelt innehåll returnerar toString() String-innehållet för XML-objektet utan följande borttaget: starttaggen, attribut, namnutrymmesdeklarationer och sluttaggen.

Om XML-objektet har komplext innehåll returnerar toString() ett XML-kodat String-objekt som representerar hela XML-objektet, inklusive starttagg, attribut, namnutrymmesdeklarationer och sluttagg.

Om du vill att hela XML-objektet ska returneras varje gång använder du toXMLString().

Returnerar

String — XML-objektets strängbeteckning.

Relaterade API-element

XML.hasSimpleContent()
XML.hasComplexContent()
XML.toXMLString()

Exempel ( Så här använder du exemplet )

I följande exempel visas vad metoden toString() returnerar när XML-objektet har enkelt innehåll:

var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example

I följande exempel visas vad metoden toString() returnerar när XML-objektet har komplext innehåll:

var test:XML = 
<type name="Joe">
    <base name="Bob"></base>
    example
</type>;
trace(test.toString());
  // <type name="Joe">
  // <base name="Bob"/>
  // example
  // </type>

toXMLString

()

metod

AS3 function toXMLString():String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar XML-objektets strängbeteckning. Till skillnad från metoden toString() returnerar alltid metoden toXMLString() starttaggen, attribut och sluttaggen för XML-objektet, oavsett om XML-objektet har enkelt eller komplext innehåll. (Metoden toString() tar bort dessa objekt för XML-objekt som innehåller enkelt innehåll.)

Returnerar

String — XML-objektets strängbeteckning.

Relaterade API-element

XML.toString()

Exempel ( Så här använder du exemplet )

I följande exempel visas skillnaden mellan att använda metoden toString() (som används på alla parametrar i metoden trace() enligt standardinställningen) och att använda metoden toXMLString():

var xml:XML =
        <p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>

valueOf

()

metod

AS3 function valueOf():XML

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Returnerar XML-objektet.

Returnerar

XML — XML-instansens primitiva värde.

Exempel ( Så här använder du exemplet )

I följande exempel visas att värdet som returneras av metoden valueOf() är samma som XML-källobjektet:

var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true

Exempel Så här använder du exemplet

XMLExample.as

I följande exempel skapas först en XML-variabel och sedan läggs noder till i variabeln. Du använder XML-egenskaperna för att hitta och skriva ut XML-noder. Observera att symbolen "at" (@) används i flera av anropen till trace() för att hitta information efter attributnamn.

package {
    import flash.display.Sprite;

    public class XmlExample extends Sprite {        
        public function XmlExample() {
            var employees:XML =
                <employees>
                    <employee ssn="123-123-1234">
                        <name first="John" last="Doe"/>
                        <address>
                            <street>11 Main St.</street>
                            <city>San Francisco</city>
                            <state>CA</state>
                            <zip>98765</zip>
                        </address>
                    </employee>
                    <employee ssn="789-789-7890">
                        <name first="Mary" last="Roe"/>
                        <address>
                            <street>99 Broad St.</street>
                            <city>Newton</city>
                            <state>MA</state>
                            <zip>01234</zip>
                        </address>
                    </employee>
                </employees>;

            trace(employees.employee[0].address.zip);   // 98765

            trace(employees.employee[1].@ssn);          // 789-789-7890

            trace(employees.employee.name);             // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees..zip[0]);                   // 98765

            trace(employees..@ssn[1]);                  // 789-789-7890

            trace(employees..name);                     // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees.employee[0].address.*);     // <street>11 Main St.</street>    
                                                        // <city>San Francisco</city>
                                                        // <state>CA</state>
                                                        // <zip>98765</zip>
            var node:String = "zip";
            trace(employees.employee[0].address[node]); // 98765
            
            var attribute:String = "ssn";
            trace(employees.employee[1].@[attribute]);  // 789-789-7890
            
            for each (var num:XML in employees..@ssn) {
                trace(num);                             // 123-123-1234
            }                                           // 789-789-7890
            
            var ssnToFind:String = "789-789-7890";
            trace(employees.employee.(@ssn == ssnToFind).toXMLString());
                                                        // <employee ssn="789-789-7890">
                                                        // <name first="Mary" last="Roe"/>
                                                        // <address>
                                                        // <street>99 Broad St.</street>
                                                        // <city>Newton</city>
                                                        // <state>MA</state>
                                                        // <zip>01234</zip>
                                                        // </address>
                                                        // </employee>
        }
    }
}

Juridiska meddelanden | Onlinesekretesspolicy

XML - AS3

Paketx

Språkelement

Bilagor

Klasser x

ignoreComments

ignoreProcessingInstructions

ignoreWhitespace

prettyIndent

prettyPrinting

XML

addNamespace

appendChild

attribute

attributes

child

childIndex

children

comments

contains

copy

defaultSettings

descendants

elements

hasComplexContent

hasOwnProperty

hasSimpleContent

inScopeNamespaces

insertChildAfter

insertChildBefore

length

localName

name

namespace

namespaceDeclarations

nodeKind

normalize

parent

prependChild

processingInstructions

propertyIsEnumerable

removeNamespace

replace

setChildren

setLocalName

setName

setNamespace

setSettings

settings

text

toJSON

toString

toXMLString

valueOf