QName  - AS3

Det lokala namnet på QName-objektet.

QName-objektets URI (Uniform Resource Identifier).

Skapar ett QName-objekt som är en kopia av ett annat QName-objekt. Om parametern som skickas till konstruktorn är ett QName-objekt skapas en kopia av QName-objektet. Om parametern inte är ett QName-objekt konverteras parametern till en sträng och tilldelas till egenskapen localName för den nya QName-instansen. Om parametern är undefined eller ospecificerad skapas ett nytt QName-objekt med egenskapen localName inställd på en tom sträng.

Obs! Klassen visar två konstruktorer eftersom varje form accepterar olika parametrar. Konstruktorn uppför sig på olika sätt beroende på vilken typ av och antal parametrar som skickas enligt detaljerna för varje post. ActionScript 3.0 tillåter inte metod- eller konstruktoröverinläsning.

Skapar ett QName-objekt med ett URI från ett Namespace-objekt och ett localName från ett QName-objekt. Om någon av parametrarna inte är av den förväntade datatypen konverteras den parametern till en sträng och tilldelas till motsvarande egenskap för det nya QName-objektet. Om båda parametrarna till exempel är strängar returneras ett nytt QName-objekt med egenskapen uri inställd på den första parametern och egenskapen localName inställd på den andra parametern. Följande permutationer tillsammans med många andra är alltså giltiga former på konstruktorn:

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

Om du skickar null för parametern uri ställs egenskapen uri för det nya QName-objektet in på null.

Obs! Klassen visar två konstruktorer eftersom varje form accepterar olika parametrar. Konstruktorn uppför sig på olika sätt beroende på vilken typ av och antal parametrar som skickas enligt detaljerna för varje post. ActionScript 3.0 tillåter inte metod- eller konstruktoröverinläsning.

Returnerar en sträng som består av URI och det lokala namnet på QName-objektet, avgränsade med "::".

Formatet beror på egenskapen uri för QName-objektet:

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

Returnerar QName-objektet

1. Skapa en Namespace-instans och därefter använda den som indata för QName-konstruktorn. Den här metoden passar bäst om du vill använda egenskapen Namespace.prefix i andra syften senare.
2. Skapa en QName-instans med ett enkelt strängvärde på parametern uri i QName-konstruktorn.

Denna kod fungerar på följande sätt:

1. Definierar en XML-variabel med namnet rssXML.
2. Skapar ett Namespace-objekt med prefixet dc.
3. Skapar ett nytt QName-objekt med Namespace-objektet och det lokala namnet creator.
4. Anropar metoden showDescendants() som använder metoden XML.descendants() för att få en XMLList-instans som innehåller alla underordnade element vars kvalificerade namn matchar den givna QName-instansen.
5. Visar det kvalificerade namnet och textvärdet för varje element i listan med hjälp av en for each-slinga.
6. Skapar ett till QName-objekt med strängvärdet för parametern uri och det lokala namnet date.
7. Anropar metoden showDescendants() igen för att visa namnet och textvärdet för de underordnade elementen.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}