TextConverter - Referência da API Adobe ActionScript® 3 (AS3 )

Pacote	flashx.textLayout.conversion
Classe	public class TextConverter
Herança	TextConverter Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Esta é a classe de gateway para controle de importações e exportações. Isto serve como ponto central de acesso para a função de conversão no Text Layout Framework. Contém um registro de conversores de produção e/ou entrada predefinidos bem como definidos pelo usuário, além do conjunto de métodos de conversão.

O formato dos dados convertidos não é predefinido; o usuário que gravou conversores é livre para aceitar e retornar qualquer formato da sua escolha. Os formatos comuns são sequências de caracteres, XML, e exemplos ByteArray. Os autores de conversores devem documentar que formatos são compatíveis.

Veja os exemplos

Mais exemplos

Creating a TextFlow object with the TextConverter class

Propriedades públicas

Ocultar propriedades públicas herdadas

Mostrar propriedades públicas herdadas

	Propriedade		Definido por
		constructor : Object Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto.	Object
		numFormats : int [estático] [somente leitura] Número de formatos.	TextConverter

Métodos públicos

Ocultar métodos públicos herdados

Mostrar métodos públicos herdados

	Método		Definido por
		addFormat(format:String, importerClass:Class, exporterClass:Class, clipboardFormat:String):void [estático] Registre um novo formato para importação/exportação.	TextConverter
		addFormatAt(index:int, format:String, importerClass:Class, exporterClass:Class = null, clipboardFormat:String = null):void [estático] Registre um novo formato para importar/exportar no local especificado.	TextConverter
		export(source:flashx.textLayout.elements:TextFlow, format:String, conversionType:String):Object [estático] Exporta um TextFlow em um formato específico.	TextConverter
		getExporter(format:String):flashx.textLayout.conversion:ITextExporter [estático] Cria e retorna um conversor de exportação que pode ser usado para exportar de um TextFlow para uma sequência de caracteres de origem ou um objeto XML.	TextConverter
		getFormatAt(index:int):String [estático] Retorna o nome de formato para o formato em índice.	TextConverter
		getFormatDescriptorAt(index:int):FormatDescriptor [estático] Retorna o FormatDescriptor para o formato em índice.	TextConverter
		getImporter(format:String, config:IConfiguration = null):flashx.textLayout.conversion:ITextImporter [estático] Cria e retorna um conversor de importação, que pode ser usado para importar de uma sequência de caracteres de origem, um objeto de XML, ou qualquer formato de dados definido pelo usuário para um TextFlow.	TextConverter
		hasOwnProperty(name:String):Boolean Indica se um objeto tem uma propriedade especificada definida.	Object
		importToFlow(source:Object, format:String, config:IConfiguration = null):flashx.textLayout.elements:TextFlow [estático] Cria um TextFlow do conteúdo de origem em um formato especificado.	TextConverter
		isPrototypeOf(theClass:Object):Boolean Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se a propriedade especificada existe e é enumerável.	Object
		removeFormat(format:String):void [estático] Remova o formato.	TextConverter
		removeFormatAt(index:int):void [estático] Remova o formato no local de índice.	TextConverter
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Define a disponibilidade de uma propriedade dinâmica para operações de repetição.	Object
		toLocaleString():String Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade.	Object
		toString():String Retorna a representação de string do objeto especificado.	Object
		valueOf():Object Retorna o valor primitivo do objeto especificado.	Object

Constantes públicas

	Constante		Definido por
		PLAIN_TEXT_FORMAT : String = "plainTextFormat" [estático] Formato de texto simples.	TextConverter
		TEXT_FIELD_HTML_FORMAT : String = "textFieldHTMLFormat" [estático] Formato HTML.	TextConverter
		TEXT_LAYOUT_FORMAT : String = "textLayoutFormat" [estático] Formato TextLayout.	TextConverter

Detalhes da propriedade

numFormats

propriedade

numFormats:int [somente leitura]

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Número de formatos.

Implementação
public static function get numFormats():int

Detalhes do método

addFormat

()

método

public static function addFormat(format:String, importerClass:Class, exporterClass:Class, clipboardFormat:String):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Registre um novo formato para importação/exportação. O novo formato será adicionado no fim, como a menor prioridade. O local pode ser significativo para clientes que têm várias escolhas para qual formato usar, como ao importar da área de transferência externa. O novo formato pode ser compatível com importação e/ou exportação. O formato estará presente em vários locais se já tiver sido adicionado. O primeiro localizado será usado.

Parâmetros

	`format:String` — A classe de conversor de importação a ser registrada ou null

	`importerClass:Class` — A classe de conversor de exportação a ser registrada ou null

	`exporterClass:Class` — A sequência de caracteres de formato que marca as classes de conversores. Os formatos podem ser qualquer nome, mas devem ser exclusivos.

	`clipboardFormat:String` — A sequência de caracteres usada como o formato de área de transferência ao converter para/da área de transferência. Torne isto null se o formato não for compatível com o acesso à área de transferência.

addFormatAt

()

método

 public static function addFormatAt(index:int, format:String, importerClass:Class, exporterClass:Class = null, clipboardFormat:String = null):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Registre um novo formato para importar/exportar no local especificado. O local pode ser significativo para clientes que têm várias escolhas para qual formato usar, como ao importar da área de transferência externa. Números menores indicam maior prioridade; esses conversores serão tentados primeiro. O novo formato pode ser compatível com importação e/ou exportação. O formato estará presente em vários locais se já tiver sido adicionado. O primeiro localizado será usado.

Parâmetros

	`index:int` — A classe de conversor de importação a ser registrada ou null

	`format:String` — A classe de conversor de exportação a ser registrada ou null

	`importerClass:Class` — A sequência de caracteres de formato que marca as classes de conversores

	`exporterClass:Class` (default = `null`) — A sequência de caracteres usada como o formato de área de transferência ao converter para/da área de transferência. Torne isto null se o formato não for compatível com o acesso à área de transferência.

	`clipboardFormat:String` (default = `null`)

export

()

método

public static function export(source:flashx.textLayout.elements:TextFlow, format:String, conversionType:String):Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Exporta um TextFlow em um formato específico.

Use uma das constantes estáticas fornecidas com esta classe, um tipo de MIME, ou um formato definido pelo usuário de exportadores definidos pelo usuário para especificar o parâmetro format:

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

Especifique o tipo dos dados exportados no parâmetro conversionType com uma das constantes estáticas fornecidas pela classe ConversionType, ou pelo tipo de dados definido pelo usuário de exportadores definidos pelo usuário:

ConversionType.STRING_TYPE
ConversionType.XML_TYPE

Retorna uma representação do TextFlow no formato especificado, ou null em erros.

Parâmetros

	`source:flashx.textLayout.elements:TextFlow` — Conteúdo de origem

	`format:String` — Formato de saída

	`conversionType:String` — Tipo de dados exportados

Retorna

Object — Formulário Objeto Exportado do TextFlow, ou null em erros

Elementos da API relacionados

TEXT_FIELD_HTML_FORMAT
PLAIN_TEXT_FORMAT
TEXT_LAYOUT_FORMAT
flashx.textLayout.conversion.ConversionType

getExporter

()

método

public static function getExporter(format:String):flashx.textLayout.conversion:ITextExporter

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Cria e retorna um conversor de exportação que pode ser usado para exportar de um TextFlow para uma sequência de caracteres de origem ou um objeto XML. Use esta função se precisar realizar várias exportações separadas. Equivale a chamar flashx.textLayout.conversion.TextConverter.export().

Use uma das constantes estáticas fornecidas com esta classe para especificar o parâmetro format:

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

Se o formato tiver sido adicionado várias vezes, o primeiro localizado será usado.

Parâmetros

format:String — Formato de destino para dados exportados

Retorna

flashx.textLayout.conversion:ITextExporter — Exportador de texto ITextExporter que pode exportar no formato especificado

Elementos da API relacionados

TEXT_FIELD_HTML_FORMAT
PLAIN_TEXT_FORMAT
TEXT_LAYOUT_FORMAT

Exemplo ( Como usar este exemplo )

Este snippet de código mostra uma utilização do método getExporter para realizar exportações repetidas do texto formatado.


package flashx.textLayout.conversion.examples
{
    import flashx.textLayout.conversion.ConversionType;
    import flashx.textLayout.conversion.ITextExporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;
    
    public class getExporter_example 
    {
        // Serialize the TextFlow into a String
        public function export(textFlow:TextFlow):String
        {
            var exporter:ITextExporter = TextConverter.getExporter(TextConverter.TEXT_LAYOUT_FORMAT);
            return exporter.export(textFlow, ConversionType.STRING_TYPE) as String;
        }
    }
}

getFormatAt

()

método

public static function getFormatAt(index:int):String

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Retorna o nome de formato para o formato em índice.

Parâmetros

index:int

Retorna

String

getFormatDescriptorAt

()

método

public static function getFormatDescriptorAt(index:int):FormatDescriptor

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Retorna o FormatDescriptor para o formato em índice.

Parâmetros

index:int

Retorna

FormatDescriptor

getImporter

()

método

 public static function getImporter(format:String, config:IConfiguration = null):flashx.textLayout.conversion:ITextImporter

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Cria e retorna um conversor de importação, que pode ser usado para importar de uma sequência de caracteres de origem, um objeto de XML, ou qualquer formato de dados definido pelo usuário para um TextFlow. Use este método caso seja necessário realizar muitas importações separadas, ou se quiser corrigir erros durante a importação. Equivale a chamar flashx.textLayout.conversion.TextConverter.importToFlow().

Use uma das constantes estáticas fornecidas com esta classe para especificar o parâmetro format, um tipo de MIME, ou um formato de dados definido pelo usuário.

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

Se o formato tiver sido adicionado várias vezes, o primeiro localizado será usado.

Parâmetros

	`format:String` — Formato do conteúdo de origem. Use constantes de flashx.textLayout.conversion.TextConverter.TEXT_LAYOUT_FORMAT, PLAIN_TEXT_FORMAT, TEXT_FIELD_HTML_FORMAT etc., um tipo de MIME ou um formato definido pelo usuário.

	`config:IConfiguration` (default = `null`) — configuração a ser usada durante esta importação. null significa usar o padrão atual. Você também pode definir a configuração através da propriedade `ITextImporter.configuration`.

Retorna

flashx.textLayout.conversion:ITextImporter — Importador de texto ITextImporter que pode importar os dados de origem

Elementos da API relacionados

TEXT_FIELD_HTML_FORMAT
PLAIN_TEXT_FORMAT
TEXT_LAYOUT_FORMAT

Exemplo ( Como usar este exemplo )

Este snippet de código mostra uma utilização do método getImporter para realizar importações repetidas do texto formatado. Observe que os erros são zerados no início de cada chamada de importToFlow.


package flashx.textLayout.conversion.examples
{
    import flashx.textLayout.conversion.ITextImporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;
    
    public class getImporter_example 
    {
        public function importAndCheckErrors():TextFlow
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'><p><span>Hello, World</span></p></TextFlow>";
            var importer:ITextImporter = TextConverter.getImporter(TextConverter.TEXT_LAYOUT_FORMAT);
            importer.throwOnError = false;
            var textFlow:TextFlow = importer.importToFlow(markup);
            if (!textFlow)
            {
                var errors:Vector.<String> = importer.errors;
                //deal with import errors
            }
            return textFlow;
        }
    }
}

importToFlow

()

método

 public static function importToFlow(source:Object, format:String, config:IConfiguration = null):flashx.textLayout.elements:TextFlow

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Cria um TextFlow do conteúdo de origem em um formato especificado.

Use uma das constantes estáticas fornecidas com esta classe, um tipo de MIME, para especificar o parâmetro format, ou use um valor definido pelo usuário para importadores registrados pelo usuário:

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

Parâmetros

	`source:Object` — Conteúdo de origem

	`format:String` — Formato do conteúdo de origem

	`config:IConfiguration` (default = `null`) — IConfiguration a utilizar na criação de novos TextFlows

Retorna

flashx.textLayout.elements:TextFlow — TextFlow que foi criado da origem, ou null em erros.

Elementos da API relacionados

TEXT_FIELD_HTML_FORMAT
PLAIN_TEXT_FORMAT
TEXT_LAYOUT_FORMAT

removeFormat

()

método

public static function removeFormat(format:String):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Remova o formato. Se um formato foi adicionado várias vezes, só o primeiro localizado é removido.

Parâmetros

format:String — A sequência de caracteres do formato de conversor a ser removido

removeFormatAt

()

método

public static function removeFormatAt(index:int):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Remova o formato no local de índice.

Parâmetros

index:int — O formato a ser removido

Detalhes da constante

PLAIN_TEXT_FORMAT

Constante

public static const PLAIN_TEXT_FORMAT:String = "plainTextFormat"

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Formato de texto simples. Utilize-o para criar um TextFlow a partir de uma string simples sem formatação, ou para criar uma string simples sem formatação a partir de um TextFlow.

TEXT_FIELD_HTML_FORMAT

Constante

public static const TEXT_FIELD_HTML_FORMAT:String = "textFieldHTMLFormat"

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Formato HTML. Utilize-o para importar de ou exportar para um TextFlow usando o formato HTML. O HTML de Estrutura de Layout de texto suporta um subconjunto de marcas e atributos suportados pela classe TextField no pacote flash.text.

A seguinte tabela enumera as marcas de HTML e atributos suportados para o processo de importação e exportação (marcas e atributos suportados por TextField, mas não suportados pela Estrutura de Layout de texto são especificamente descritos como não suportados):

Marca	Descrição
Marca de âncora	A marca `<a>` cria um link de hipertexto e oferece suporte aos seguintes atributos: `target`: especifica o nome da janela de destino em que você carrega a página. As opções incluem `_self`, `_blank`, `_parent` e `_top`. A opção `_self` especifica o quadro atual na janela atual, `_blank` especifica uma nova janela, `_parent` especifica o pai do quadro atual e `_top` especifica o quadro de nível superior na janela atual. `href`: especifica um URL. A URL pode ser absoluta ou relativa ao local do arquivo SWF que está carregando a página. Um exemplo de uma referência absoluta a um URL é `http://www.adobe.com`; um exemplo de uma referência relativa é `/index.html`. URLs absolutos devem ser iniciados com http://; do contrário, o Flash os tratará como URLs relativos. Nota: diferentemente da classe TextField, eventos ActionScript `link` não são suportados. Não são estilos `a:link`, `a:hover` e `a:active`.
Marca de negrito	A marca `<b>` renderiza o texto como negrito. Uma face de tipo negrito deve estar disponível para a fonte utilizada.
Marca de quebra	A marca `<br>` cria uma quebra de linha no de texto.
Marca de fonte	A marca `<font>` especifica uma fonte ou uma lista de fontes para exibir o texto. A marca de fonte oferece suporte aos seguintes atributos: `color`: apenas valores de cor hexadecimais (`#FFFFFF`) são suportados. `face`: especifica o nome da fonte a ser utilizada. Como mostrado no seguinte exemplo, você pode especificar uma lista de nomes de fonte delimitados por vírgula, caso em que o Flash Player seleciona a primeira fonte disponível. Se a fonte especificada não estiver instalada no sistema do computador local ou não estiver incorporada no arquivo SWF, o Flash Player selecionará uma fonte substituta. `size`: especifica o tamanho da fonte. Você pode utilizar tamanhos de pixel absolutos, como 16 ou 18, ou tamanhos de ponto relativos, como +2 ou -4. `letterspacing`: especifica o rastreamento (ajuste de espaço manual) em pixels a ser aplicado à direita de cada caractere. `kerning`: especifica se o ajuste de espaço é ativado ou desativado. Um valor diferente de zero ativa o ajuste de espaço, enquanto o zero o desativa.
Marca de imagem	A marca `<img>` permite que você incorpore arquivos de imagem externa (JPEG, GIF, PNG), arquivos SWF e clipes de vídeo dentro do texto. A marca `<img>` oferece suporte aos seguintes atributos: `src`: especifica o URL para um arquivo de imagem ou SWF, ou o identificador de ligação para um símbolo de clipe de vídeo na biblioteca. Esse atributo é obrigatório; todos os outros atributos são opcionais. Arquivos externos (JPEG, GIF, PNG e SWF) não serão exibidos até que sejam completamente baixados. `width`: a largura da imagem, do arquivo SWF ou do clipe de vídeo sendo inserido, em pixels. `height`: a altura da imagem, do arquivo SWF ou do clipe de vídeo sendo inserido, em pixels. Nota: diferentemente da classe TextField, os seguintes atributos não são suportados: `align`, `hspace`, `vspace`, `id` e `checkPolicyFile`.
Marca de itálico	A marca `<i>` exibe o texto selecionado em itálico. Uma face de tipo itálico deve estar disponível para a fonte utilizada.
Marca de item da lista	Nota: diferentemente da classe TextField, a marca do Item de lista não é suportada.
Marca de parágrafo	A marca `<p>` cria um novo parágrafo. A marca `<p>` oferece suporte aos seguintes atributos: align: especifica o alinhamento do texto dentro do parágrafo; os valores válidos são `left`, `right`, `justify` e `center`. classe: especifica um nome da classe que pode ser usado para a estilização
Marca span	A marca `<span>` oferece suporte aos seguintes atributos: classe: especifica um nome da classe que pode ser usado para a estilização. Enquanto as marcas de span muitas vezes são usadas para estabelecer um estilo definido em uma folha de estilos, as instâncias de TLFTextField não suportam folhas de estilos. A marca de span está disponível para instâncias TLFTextField para referir-se a uma classe com propriedades de estilo. Você também pode inserir propriedades diretamente na marca de span: `<span fontFamily = "Arial"> Olá </span>` . Contudo, as marcas de span aninhadas não são suportados.
Marca de formato de texto	A marca `<textformat>` permite utilizar um subconjunto de propriedades de formatação de parágrafo da classe TextFormat dentro de campos de texto, incluindo entrelinha, recuo, margens e paradas de tabulação. Você pode combinar as marcas `<textformat>` com as marcas HTML embutidas. A marca `<textformat>` tem os seguintes atributos: `indent`: especifica o recuo da margem esquerda para o primeiro caractere no parágrafo; corresponde ao `TextFormat.indent`. Números positivos e negativos são aceitáveis. `blockindent`: especifica que o recuo foi aplicado a todas as linhas do parágrafo. `leftmargin`: especifica a margem esquerda do parágrafo em pontos; corresponde ao `TextFormat.leftMargin`. `rightmargin`: especifica a margem direita do parágrafo em pontos; corresponde ao `TextFormat.rightMargin`. `leading`: especifica a entrelinha (altura de linha) medida em pixels entre a parte superior de uma linha e a parte inferior da linha `tabstops`: especifica uma lista separada por vírgula de posições de parada de tabulação do parágrafo.
Marca de sublinhado	A marca `<u>` sublinha o texto selecionado.

Quando uma marca desconhecida é importada, o importador textFieldHTMLFormat definirá a propriedade typeName de um FlowElement único naquele nome da marca ou criará um DivElement ou um SubParagraphGroupElement com seu conjunto de propriedades typeName ao nome da marca.

O exportador textFieldHTMLFormat exportará typeName como a marca XML quando for diferente do padrão.

Elementos da API relacionados

flashx.textLayout.elements.FlowElement.typeName

TEXT_LAYOUT_FORMAT

Constante

public static const TEXT_LAYOUT_FORMAT:String = "textLayoutFormat"

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

Flash Player 10, AIR 1.5

Formato TextLayout. Utilize-o para importar de ou exportar para um TextFlow usando o formato de marcação TextLayout. O formato Text Layout detecta os seguintes erros:

Namespace inesperado
Elemento desconhecido
Atributo desconhecido

Exemplos Como usar este exemplo

TextConverter_example.as

Este exemplo mostra uma utilização da classe de conversão TextConverter. O texto em um formato padrão de marcação é importado para um objeto TextFlow e, depois, exibido. Então, o texto é exportado no formato XML.

package flashx.textLayout.conversion.examples 
{
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.conversion.ConversionType;

    public class TextConverter_example extends Sprite
    {
        public function TextConverter_example()
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'><p><span>Hello, World</span></p></TextFlow>";
            var textFlow:TextFlow = TextConverter.importToFlow(markup, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this, 200, 50));
            textFlow.flowComposer.updateAllControllers();
            //export to XML
            var xmlOut:XML = TextConverter.export(textFlow,TextConverter.TEXT_LAYOUT_FORMAT, ConversionType.XML_TYPE) as XML;
        }
    }
}

Aspectos jurídicos | Política de privacidade on-line

TextConverter - AS3

Classes x

numFormats

addFormat

addFormatAt

export

getExporter

getFormatAt

getFormatDescriptorAt

getImporter

importToFlow

removeFormat

removeFormatAt

PLAIN_TEXT_FORMAT

TEXT_FIELD_HTML_FORMAT

TEXT_LAYOUT_FORMAT