XMLDocument

Pacote	flash.xml
Classe	public class XMLDocument
Herança	XMLDocument XMLNode Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

A classe XMLDocument representa o objeto XML preexistente que estava presente no ActionScript 2.0. Ela foi renomeada no ActionScript 3.0 para XMLDocument, para evitar conflitos de nome com a nova classe XML no ActionScript 3.0. No ActionScript 3.0, é recomendado que você use a nova classe de nível superior XML e as classes relacionadas, que suportam E4X (ECMAScript for XML).

A classe XMLDocument, bem como as XMLNode e XMLNodeType, estão presentes para a compatibilidade para trás. A funcionalidade para o carregamento de documentos XML pode agora ser encontrada na classe URLLoader.

Veja os exemplos

Elementos da API relacionados

flash.net.URLLoader
Classe XML

Propriedades públicas

Ocultar propriedades públicas herdadas

Mostrar propriedades públicas herdadas

	Propriedade		Definido por
		attributes : Object Um objeto contendo todos os atributos da ocorrência de XMLNode especificado.	XMLNode
		childNodes : Array [somente leitura] Uma matriz dos filhos do objeto XMLNode especificado.	XMLNode
		constructor : Object Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto.	Object
		docTypeDecl : Object = null Especifica as informações sobre a declaração DOCTYPE do documento XML.	XMLDocument
		firstChild : XMLNode Avalia o objeto XMLDocument especificado e faz referência ao primeiro filho na lista de filhos do nó pai.	XMLNode
		idMap : Object Um Objeto contendo os nós do XML que possuem um atributo de id designado.	XMLDocument
		ignoreWhite : Boolean = false Quando definidos como verdadeiros, os nós de texto que contêm apenas espaço em branco são descartados durante o processo de análise.	XMLDocument
		lastChild : XMLNode Um valor XMLNode que faz referência ao último filho na lista de filhos do nó.	XMLNode
		localName : String [somente leitura] A parte do nome local do nome do nó XML.	XMLNode
		namespaceURI : String [somente leitura] Se o nó XML tiver um prefixo, namespaceURI será o valor da declaração xmlns desse prefixo (o URI), que é normalmente chamado de URI de namespace.	XMLNode
		nextSibling : XMLNode Um valor XMLNode que faz referência ao próximo irmão na lista de filhos do nó pai.	XMLNode
		nodeName : String Uma string que representa o nome do nó do objeto XMLNode.	XMLNode
		nodeType : uint Um valor de constante nodeType, seja XMLNodeType.ELEMENT_NODE para um elemento XML ou XMLNodeType.TEXT_NODE para um nó de texto.	XMLNode
		nodeValue : String O valor do nó do objeto XMLDocument.	XMLNode
		parentNode : XMLNode Um valor XMLNode que faz referência ao nó pai do objeto XML especificado ou que retornará null se o nó não tiver um pai.	XMLNode
		prefix : String [somente leitura] A parte do prefixo do nome do nó XML.	XMLNode
		previousSibling : XMLNode Um valor XMLNode que faz referência ao irmão anterior na lista de filhos do nó pai.	XMLNode
		xmlDecl : Object = null Uma string que especifica informações sobre a declaração XML do documento.	XMLDocument

Métodos públicos

Ocultar métodos públicos herdados

Mostrar métodos públicos herdados

	Método		Definido por
		XMLDocument(source:String = null) Cria um novo objeto XMLDocument.	XMLDocument
		appendChild(node:XMLNode):void Acrescenta o nó especificado à lista de filhos do objeto XML.	XMLNode
		cloneNode(deep:Boolean):XMLNode Constrói e retorna um novo nó XML do mesmo tipo, nome, valor e atributos que o objeto XML especificado.	XMLNode
		createElement(name:String):XMLNode Cria um novo objeto XMLNode com o nome especificado no parâmetro.	XMLDocument
		createTextNode(text:String):XMLNode Cria um novo nó de texto XML com o texto especificado.	XMLDocument
		getNamespaceForPrefix(prefix:String):String Retorna o URI de namespace associado ao prefixo especificado para o nó.	XMLNode
		getPrefixForNamespace(ns:String):String Retorna o prefixo associado ao URI de namespace especificado para o nó.	XMLNode
		hasChildNodes():Boolean Indica se o objeto XMLNode especificado tem nós filhos.	XMLNode
		hasOwnProperty(name:String):Boolean Indica se um objeto tem uma propriedade especificada definida.	Object
		insertBefore(node:XMLNode, before:XMLNode):void Insere um novo nó filho na lista de filhos do objeto XML, antes do nó beforeNode.	XMLNode
		isPrototypeOf(theClass:Object):Boolean Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro.	Object
		parseXML(source:String):void Analisa o texto XML especificado no parâmetro de valor e preenche o objeto XMLDocument especificado com a árvore XML resultante.	XMLDocument
		propertyIsEnumerable(name:String):Boolean Indica se a propriedade especificada existe e é enumerável.	Object
		removeNode():void Remove o objeto XML especificado do seu pai.	XMLNode
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Define a disponibilidade de uma propriedade dinâmica para operações de repetição.	Object
		toLocaleString():String Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade.	Object
		toString():String [substituir] Retorna uma representação de string do objeto XML.	XMLDocument
		valueOf():Object Retorna o valor primitivo do objeto especificado.	Object

Detalhes da propriedade

docTypeDecl

propriedade

public var docTypeDecl:Object = null

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Especifica as informações sobre a declaração DOCTYPE do documento XML. Após a análise do texto XML no objeto XMLDocument, a propriedade XMLDocument.docTypeDecl do objeto XMLDocument é configurada para o texto da declaração DOCTYPE do documento XML (por exemplo, <!DOCTYPE greeting SYSTEM "hello.dtd">). Esta propriedade é configurada com o uso da representação de string da declaração DOCTYPE e não um objeto XMLNode.

O analisador preexistente do ActionScript não é de validação. A declaração DOCTYPE é lida pelo analisador e armazenada na propriedade XMLDocument.docTypeDecl, mas não é executada a validação do DTD.

Se não for encontrada nenhuma declaração DOCTYPE durante a operação de análise, a propriedade XMLDocument.docTypeDecl é configurada como null. O método XML.toString() dá saída aos conteúdos da XML.docTypeDecl iimediatamente após a declaração XML armazenada no XML.xmlDecl e antes de qualquer outro texto no objeto XML. Se a XMLDocument.docTypeDecl for nula, nenhuma declaração DOCTYPE tem saída.

idMap

propriedade

public var idMap:Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Um Objeto contendo os nós do XML que possuem um atributo de id designado. Os nomes das propriedades do objeto (cada um contendo um nó) são compatíveis com os valores dos atributos de id.

Considere o objeto XMLDocument a seguir:

     <employee id='41'>
         <name>
             John Doe
         </name>
         <address>
             601 Townsend St.
         </address>
     </employee>
     
     <employee id='42'>
         <name>
             Jane Q. Public
         </name>
     </employee>
     <department id="IT">
         Information Technology
     </department>

Neste exemplo, a propriedade idMap para este objeto XMLDocument é um Objeto com três propriedades: 41, 42 e IT. Cada uma dessas propriedades é um XMLNode com valor id compatível. Por exemplo, a propriedade IT do objeto idMap neste nó:

     <department id="IT">
         Information Technology
     </department>

Você precisa usar o método parseXML() no objeto XMLDocument para a propriedade idMap ser exemplificada.

Se houver mais de um XMLNode com o mesmo valor id, a propriedade compatível do objeto idNode é a do último nó analisado. Por exemplo:

     var x1:XML = new XMLDocument("<a id='1'><b id='2' /><c id='1' /></a>");
     x2 = new XMLDocument();
     x2.parseXML(x1);
     trace(x2.idMap['1']);

Isso dará saída ao nó <c>:

     <c id='1' />

ignoreWhite

propriedade

public var ignoreWhite:Boolean = false

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Se definidos como true, os nós de texto que contêm apenas espaço em branco são descartados durante o processo de análise. Os nós de texto com espaço em branco principal ou posterior não são afetados. A configuração padrão é false.

Você pode configurar a propriedade ignoreWhite para objetos XMLDocument individuais, como mostra o código a seguir:

     my_xml.ignoreWhite = true;

xmlDecl

propriedade

public var xmlDecl:Object = null

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Uma string que especifica informações sobre a declaração XML do documento. Após a análise o documento XML no objeto XMLDocument, esta propriedade é configurada no texto da declaração XML do documento. Esta propriedade é configurada com o uso da representação da string da declaração XML e não um objeto XMLNode. Se não for encontrada nenhuma declaração XML durante a operação de análise, a propriedade é configurada como null. O método XMLDocument.toString() dá saída aos conteúdos da propriedade XML.xmlDecl antes de qualquer outro texto do objeto XML. Se a propriedade XML.xmlDecl contiver null, não há saída de declaração XML.

Detalhes do construtor

()

Construtor

public function XMLDocument(source:String = null)

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Cria um novo objeto XMLDocument. Você precisa usar o construtor para criar um objeto XMLDocument, antes de chamar qualquer dos métodos da classe XMLDocument.

Observação: Use os métodos createElement() e createTextNode() para acrescentar elementos e nós de texto a uma árvore de documento XML.

Parâmetros

source:String (default = null) — O texto XML analisado para criar o novo objeto XMLDocument.

Elementos da API relacionados

XMLDocument.createElement()
XMLDocument.createTextNode()

Detalhes do método

createElement

()

método

public function createElement(name:String):XMLNode

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Cria um novo objeto XMLNode com o nome especificado no parâmetro. O novo nó inicialmente não tem pai, filhos e irmãos. O método retorna uma referência ao objeto XMLNode recém-criado que representa o elemento. Este método e o método XMLDocument.createTextNode() são os métodos do construtor para a criação de nós para um objeto XMLDocument.

Parâmetros

name:String — O nome da marca do elemento XMLDocument sendo criado.

Retorna

XMLNode — Um objeto XMLNode.

Elementos da API relacionados

XMLDocument.createTextNode()

createTextNode

()

método

public function createTextNode(text:String):XMLNode

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Cria um novo nó de texto XML com o texto especificado. O novo nó inicialmente não tem pai e os nós de texto não podem ter filhos ou irmãos. Este método retorna uma referência para o objeto XMLDocument que representa o novo nó de texto. Este método e o método XMLDocument.createTextNode() são os métodos do construtor para a criação de nós para um objeto XMLDocument.

Parâmetros

text:String — O texto usado para criar o novo nó de texto.

Retorna

XMLNode — Um objeto XMLNode.

Elementos da API relacionados

XMLDocument.createElement()

parseXML

()

método

public function parseXML(source:String):void

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Analisa o texto XML especificado no parâmetro value e preenche o objeto XMLDocument especificado com a árvore XML resultante Quaisquer árvores existentes no objeto XMLDocument são descartadas.

Parâmetros

source:String — O texto XML pode ser analisado e transmitido para o objeto XMLDocument especificado.

toString

()

método

override public function toString():String

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Retorna uma representação de string do objeto XML.

Retorna

String — Uma representação de string do objeto XML.

Exemplos Como usar este exemplo

XMLDocumentExample.as

O exemplo a seguir usa as classes XMLDocument e XMLNode para analisar e formatar um documento XML. Em vez de carregar um arquivo XML externo, o exemplo usa a classe XML de nível superior para criar um documento XML e depois analisá-lo.

package {
    import flash.display.Sprite;
    import flash.xml.XMLDocument;
    import flash.xml.XMLNode;
    import flash.xml.XMLNodeType;

    public class XMLDocumentExample extends Sprite {
        public function XMLDocumentExample() {
            var result:XMLDocument = new XMLDocument();
            result.ignoreWhite = true;
            result.parseXML(getXMLString());

            var books:Array = parseBooks(result.firstChild);
            trace("books: \n" + books);
        }

        private function parseBooks(node:XMLNode):Array {
            var books:Array = new Array();

            var kids:Array = node.childNodes;
            for each(var item:XMLNode in kids) {
                parseBook(item, books);
            }

            return books;
        }

        private function parseBook(node:XMLNode, books:Array):void {
            var item:Book = new Book();
            item.setPublisher(node.attributes.publisher);
            item.setName(node.attributes.name);
            books.push(item);
        }

        private function getXMLString():String {
            var list:XML = <books>
                                <book publisher="Addison-Wesley" name="Design Patterns" />
                                <book publisher="Addison-Wesley" name="The Pragmatic Programmer" />
                                <book publisher="Addison-Wesley" name="Test Driven Development" />
                                <book publisher="Addison-Wesley" name="Refactoring to Patterns" />
                                <book publisher="O'Reilly Media" name="The Cathedral & the Bazaar" />
                                <book publisher="O'Reilly Media" name="Unit Test Frameworks" />
                            </books>;
            return list.toXMLString();
        }
    }

}
class Book {
    private var publisher:String;
    private var name:String;

    public function setPublisher(publisher:String):void {
        this.publisher = publisher;
    }

    public function setName(name:String):void {
        this.name = name;
    }

    public function toString():String {
        return "[Book name: " + name + " publisher: " + publisher + "]\n";
    }
}

Aspectos jurídicos | Política de privacidade on-line

XMLDocument - AS3

Pacotesx

Elementos de linguagem

Apêndices

Pacote flash.xml

docTypeDecl

idMap

ignoreWhite

xmlDecl

XMLDocument

createElement

createTextNode

parseXML

toString