Mouse  - AS3

O nome do cursor nativo.

Indica se o computador ou o dispositivo exibe um cursor persistente.

A propriedade supportsCursor é true na maior parte de computadores desktops e false na maior parte de dispositivos móveis.

Observação: Os eventos de mouse podem ser despachados se esta propriedade for true. Contudo, eventos de mouse podem comportar-se diferentemente dependendo das características físicas do dispositivo apontador.

Elementos da API relacionados

import flash.events.*;
import flash.display.*;
import flash.ui.Mouse;
import flash.text.TextField;

var supportsCursorTxt:TextField = new TextField();
supportsCursorTxt.width = 200;
supportsCursorTxt.border = true;
addChild(supportsCursorTxt);

addEventListener (MouseEvent.CLICK, getScreenKeyboardType);

function getScreenKeyboardType(e:MouseEvent):void{
    supportsCursorTxt.text= "Supports Cursor is : " + String(flash.ui.Mouse.supportsCursor);

}

if(Mouse.supportsCursor) {
    //Game acts as before
} else {
    if(Capabilities.touchscreenType == TouchscreenType.STYLUS ){
        //The Game has to change so that the character is chasing the location of the stylus as 
        //it's dragged around. Some of the animations will have to change
    }else if(Capabilities.touchscreenType = TouchscreenType.FINGER){
        //Same as above, except that the hit-area is larger for a finger.
    }else{
        //There's no pointing device at all. The developer designs some sort of custom cursor to 
        //be controlled with key presses or similar input
    }
}

Indica se a configuração atual oferece suporte a cursores nativos.

Oculta o ponteiro. O ponteiro é visível por padrão.

Observação: É necessário chamar Mouse.hide() somente uma vez, independentemente do número de chamadas anteriores para Mouse.show().

Elementos da API relacionados

Registra um cursor nativo com o nome fornecido, com os dados fornecidos.

Parâmetros

Exibe o ponteiro. O ponteiro é visível por padrão.

Observação: É necessário chamar Mouse.show() somente uma vez, independente do número de chamadas anteriores Mouse.hide().

Elementos da API relacionados

Cancela o registro do cursor nativo com o nome fornecido.

Parâmetros

1. Explique as seguintes propriedades das ocorrências: cursor do tipo CustomCursor, filho do tipo CustomButton e medianiz do tipo uint.
2. Atribua o filho à nova ocorrência CustomButton, defina suas coordenadas x e y para 10 pixels cada e, depois, insira a ocorrência na lista de exibição. A classe CustomButton substitui as propriedades downState, upState, overState e hitTestState no SimpleButton. Cada uma dessas propriedades exemplifica um objeto ButtonDisplayState, que desenha um quadrado diferente, dependendo do estado da ocorrência filho.
3. A ocorrência filho é usada em seguida para incluir o listener de evento ao MOUSE_OVER e o método de listener ao mouseOverHandler(), juntamente com o listener de evento MOUSE_OUT e o método associado mouseOutHandler().
4. Os listeners de evento funcionam como se segue:
   • mouseOverHandler: Oculta o ponteiro "normal" e inclui um listener MOUSE_MOVE, que processa os movimentos do mouse com o uso do mouseMoveHandler(), descrito a seguir.
   • mouseOutHandler: Quando o mouse se move fora do botão personalizado, o ponteiro "normal" é exibido, o listener de evento MOUSE_MOVE é removido e a visibilidade do cursor personalizado é configurada para false.
   • mouseMoveHandler: Move o cursor personalizado nas proximidades sempre que o ponteiro é movimentado e configura a visibilidade do cursor personalizado para true.
5. De volta ao construtor MouseExample, a propriedade do cursor é atribuída ao novo objeto CustomCursor e depois incluída na lista de exibição com o uso do addChild(). A classe CustomCursor desenha um quadrado pequeno quase preto no lugar do ponteiro "normal", sempre que o mouse está sobre filho.
6. Um quarto listener de evento do tipo MOUSE_LEAVE é incluído, com o método mouseLeaveHandler() associado. Nesse método (chamado quando o mouse deixa o Palco), o mouseOutHandler() é passado para um novo objeto listener mouseMove, que essencialmente remove o ponteiro de modo a não ser deixado no Palco.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.ui.Mouse;
    import flash.events.*;

    public class MouseExample extends Sprite {
         private var cursor:CustomCursor;
         private var child:CustomButton;
         private var gutter:uint = 10;

        public function MouseExample() {
            child = new CustomButton();
            child.x = gutter;
            child.y = gutter;
            addChild(child);

            child.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            child.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);

            cursor = new CustomCursor();
            addChild(cursor);

            stage.addEventListener(Event.MOUSE_LEAVE, mouseLeaveHandler);
        }

        private function mouseOverHandler(event:MouseEvent):void {
            trace("mouseOverHandler");
            Mouse.hide();
            child.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseOutHandler(event:MouseEvent):void {
            trace("mouseOutHandler");
            Mouse.show();
            child.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            cursor.visible = false;
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            cursor.x = event.localX;
            cursor.y = event.localY;
            event.updateAfterEvent();
            cursor.visible = true;
        }

        private function mouseLeaveHandler(event:Event):void {
            trace("mouseLeaveHandler");
            mouseOutHandler(new MouseEvent(MouseEvent.MOUSE_MOVE));
        }
    }
}

import flash.display.Shape;
import flash.display.SimpleButton;
    
class CustomButton extends SimpleButton {
    var upColor:uint = 0xFFCC00;
    var overColor:uint = 0xCCFF00;
    var downColor:uint = 0x00CCFF;
    var size:uint = 80;
    
    public function CustomButton() {
        downState = new ButtonDisplayState(downColor, size+10);
        overState = new ButtonDisplayState(overColor, size);
        upState = new ButtonDisplayState(upColor, size);
        hitTestState = new ButtonDisplayState(upColor, size);
    }
}

class ButtonDisplayState extends Shape {
    var bgColor:uint;
    var size:uint;
    
    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size = size;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}
    
class CustomCursor extends Shape {
    var bgColor:uint = 0x333333;
    var size:uint = 10;
    
    public function CustomCursor() {
        visible = false;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}