PrintJob  - AS3

Indica se um trabalho de impressão está ativo atualmente. Um trabalho de impressão é ativo (o valor de propriedade é verdadeiro ) em qualquer de duas condições:

• Uma caixa de diálogo Configurar Página ou Imprimir está sendo exibida.
• O start() ou start2() o método foi invocado com um verdadeiro valor de retorno, e o enviam() ou finito() o método não foi invocado.

Se esta propriedade é verdadeiro e você chamam o showPageSetupDialog(), start(), ou start2() método, o tempo de execução lança-se uma exceção.

Elementos da API relacionados

O número de cópias que o sistema de impressão imprime de quaisquer páginas subsequentes adicionadas ao trabalho de impressão. Esta valor é o número de cópias introduzido pelo usuário na caixa de diálogo Imprimir do sistema operacional. Se o número de cópias não foi exibido na caixa de diálogo Imprimir ou sea caixa de diálogo não foi apresentada ao usuário, o valor será 1 (a menos que tenha sido modificado pelo código do aplicativo).

O número de página da primeira página do intervalo inserida pelo usuário na caixa de diálogo Imprimir do sistema operacional. Esta propriedade será zero se o usuário solicitar que todas as páginas sejam impressas ou se o intervalo de páginas não for exibido no diálogo Imprimirnou se o diálogo Imprimir não foi exibido para o usuário.

Indica se a impressora atualmente selecionada nas impressões de configurações de impressão atuais que usam cor ( verdadeiro ) ou tons de cinza ( falso ).

Se um valor de cor-ou-tons-de-cinza não puder ser determinado, o valor é verdadeiro .

Indica se a classe PrintJob é suportada na plataforma atual ( verdadeiro ) ou não ( falso ).

O nome ou o título do trabalho de impressão. O nome de trabalho é normalmente usado pelo SO como o título do trabalho na fila de impressão ou como o nome padrão de um trabalho que é impresso para arquivo.

Se você não invocou start() ou start2() e você não estabeleceram um valor da propriedade, o valor desta propriedade é nulidade .

Para cada trabalho de impressão você realiza com um exemplo PrintJob, estabelece esta propriedade antes de chamar o método start() ou start2().

O valor padrão é null.

O número de página da última página do intervalo inserido pelo usuário na caixa de diálogo Imprimir do sistema operacional. Esta propriedade será zero se o usuário solicitar que todas as páginas sejam impressas ou se o intervalo de páginas não for exibido no diálogo Imprimirnou se o diálogo Imprimir não foi exibido para o usuário.

A resolução física da impressora selecionada, em pixels por polegada. O valor é calculado segundo as configurações de impressão atuais como informado pelo sistema operacional.

Se a resolução não puder ser determinada, o valor será um valor padrão. O valor padrão é 600 ppi no Linux e 360 ppi no Mac. No Windows, a resolução da impressora está sempre disponível, portanto nenhum valor padrão será necessário.

A orientação da imagem para impressão. Os valores aceitáveis são definidos como constantes na classe PrintJobOrientation.

Observação: de AIR 2 ou depois, fazem que esta propriedade antes de iniciar um trabalho de impressão estabeleça a orientação de padrão na Organização de Página e Caixas de diálogo Imprimir. Estabeleça a propriedade enquanto um trabalho de impressão está no progresso (depois que chamando start() ou start2() para estabelecer a orientação de um intervalo de páginas dentro do trabalho.

Elementos da API relacionados

A altura da maior área que pode ser centrada na área para impressão real na página, em pontos. Todas as margens definidas pelo usuário são ignoradas. Esta propriedade só ficará disponível após ter sido feita a chamada do método PrintJob.start().

Observação: Para o AIR 2 ou superior, esta propriedade é deprecada. Use printableArea, que mede a área imprimível em pontos fracionários e descreve com precisão áreas imprimíveis que estão fora do centro.

Elementos da API relacionados

A largura da maior área que pode ser centrada na área pronta para impressão real na página, em pontos. Todas as margens definidas pelo usuário são ignoradas. Esta propriedade só ficará disponível após ter sido feita a chamada do método PrintJob.start().

Observação: Para o AIR 2 ou superior, esta propriedade é deprecada. Use printableArea, que mede a área imprimível em pontos fracionários e descreve com precisão áreas imprimíveis que estão fora do centro.

Elementos da API relacionados

Os limites da mídia da impressora em pontos. Este valor usa o mesmo sistema de coordenadas que é usado para chamadas addPage() subsequentes.

A altura geral do papel, em pontos. Esta propriedade só ficará disponível após ter sido feita a chamada do método PrintJob.start().

Observação: Para o AIR 2 ou superior, esta propriedade é deprecada. Em vez disso, use paperArea, que mede as dimensões do papel em pontos fracionários.

Elementos da API relacionados

A largura geral do papel, em pontos. Esta propriedade só ficará disponível após ter sido feita a chamada do método PrintJob.start().

Observação: Para o AIR 2 ou superior, esta propriedade é deprecada. Em vez disso, use paperArea, que mede as dimensões do papel em pontos fracionários.

Elementos da API relacionados

Os limites da área pronta para impressão das mídias de impressora em pontos. Este valor usa o mesmo sistema de coordenadas que é usado para chamadas addPage() subsequentes.

Atribui ou define a impressora que será usada para o trabalho de impressão atual. A String passada para o setter e a retornada pelo getter devem corresponder a uma das strings na Matriz retornada pelo método printers(). Para indicar que a impressora por defeito deve ser usada, estabelecem o valor em nulidade . Em sistemas operacionais onde a impressora padrão não pode ser determinada, o valor desta propriedade é null .

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.printer = "HP_LaserJet_1";
     myPrintJob.start();
     

Estabelecendo o valor destas tentativas de propriedade para selecionar a impressora imediatamente. Se a selecção de impressora falhar, o valor desta propriedade será redefinido com o valor anterior. Você pode determinar se a configuração do valor da impressora será bem-sucedido ao ler o valor depois de tentar defini-lo e confirmar se esse valor corresponde ao que foi definido.

A propriedade printer de um trabalho de impressão ativo não pode ser modificada. Tentar alterar isso depois de o chamar o método start() ou start2() com sucesso e antes de chamar send() ou terminate() gera uma falha.

Fornece uma lista das impressoras disponíveis como valores de nomes de String. A lista não é pré-calculada; ela é gerada quando a função é chamada. Se nenhuma impressora estiver disponível ou se o sistema não suportar a impressão, o valor seránull. Se o sistema suportar impressão, mas não for capazes de retornar uma lista de impressoras, o valor será um Vetor com um elemento simples (sua propriedade length será 1). Neste caso, o elemento simples na matriz terá o nome da impressora real ou um nome padrão se o nome da impressora atual não puder ser determinado.

Indica se o ambiente de tempo de execução Flash suporta uma caixa de diálogo Configurar Página separada. Se esta propriedade for true, você poderá chamar o método showPageSetupDialog() para exibir a caixa de diálogo de configuração de página do sistema operacional.

Elementos da API relacionados

Cria um objeto PrintJob que você pode usar para imprimir uma ou mais páginas. Após criar o objeto PrintJob, você precisa usar (na seguinte sequência) os métodos PrintJob.start(), PrintJob.addPage() e depois o PrintJob.send() para enviar o trabalho de impressão para a impressora.

Por exemplo, você pode substituir o texto do espaço reservado [params] para as chamadas do método my_pj.addPage() por parâmetros personalizados, conforme exibido no código a seguir:

 // create PrintJob object
 var myPrintJob:PrintJob = new PrintJob();
  
 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (myPrintJob.start()) {
  
    // add specified page to print job
    // repeat once for each page to be printed
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
 
    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful 
    // calls to start() and addPage() before calling send().
    myPrintJob.send();
 }
 

No AIR 2 ou superior, você pode criar e usar múltiplas instâncias de PrintJob. As propriedades definidas na instâcia PrintJob são conservadas após o término da impressão. Isto permite reutilizar uma instância de PrintJob e manter as preferências de impressão selecionadas do usuário, oferecendo simultaneamente diferentes preferências de impressão para outro conteúdo no seu aplicativo. Para o conteúdo em Flash Player e em AIR anterior à versão 2, você não poderá criar um segundo objeto PrintJob enquanto o primeiro ainda estiver ativo. Se você criar um segundo objeto PrintJob (chamando new PrintJob()), enquanto o primeiro objeto PrintJob ainda está ativo, o segundo objeto PrintJob não será criado. Portanto, você deve verificar o valor de myPrintJob antes de criar um segundo PrintJob.

Elementos da API relacionados

Envia o objeto Sprite especificado como página única ao spooler de impressão. Antes de usar este método, você precisa criar o objeto PrintJob e depois usar start() ou start2(). Em seguida, depois de chamar addPage() uma ou mais vezes para um trabalho de impressão, use send() para enviar as páginas para o spool de impressão. Em outras palavras, após criar o objeto PrintJob, use (na seguinte sequência) os métodos start(), start2(), addPage() e, depois, send() para enviar o trabalho de impressão para a impressora. Você pode invocar addPage() várias vezes depois de uma chamada única para iniciar ( start()) a impressão de várias páginas em um trabalho de impressão.

Se addPage() fizer com que o Flash Player lance uma exceção (por exemplo, se você não tiver chamado start() ou se o usuário tiver cancelado o trabalho de impressão), todas as chamadas subsequentes de addPage() falharão. Entretanto, se as chamadas anteriores de addPage() tiverem êxito, o comando final send() enviará as páginas em spool bem-sucedidas para a impressora.

Se o trabalho de impressão levar mais de 15 segundos para concluir uma operação addPage(), o Flash Player lançará uma exceção na chamada addPage() seguinte.

Se você transmitir um valor para o parâmetro printArea, as coordenadas x e y do objeto printArea se organizarão no canto superior esquerdo (coordenadas 0,0) da área pronta para impressão da página. As propriedades read-only pageHeight e pageWidth descrevem a área pronta para impressão definida por start(). Como a listagem se alinha com o canto superior esquerdo da área imprimível da página, quando a área definida no printArea é maior do que a área imprimível da página, a listagem é recortada no lado direito ou inferior (ou ambos) da área definida pelo printArea. Se você não transmitir um valor para printArea e Palco for maior do que a área pronta para impressão, ocorrerá o mesmo tipo de corte. No Flex ou no Flash Builder, se você não transmitir um valor para printArea e a tela for maior do que a área pronta para impressão, ocorrerá o mesmo tipo de corte.

Se você deseja dimensionar um objeto Sprite antes de imprimi-lo, defina as propriedades da escala (consulte flash.display.DisplayObject.scaleX e flash.display.DisplayObject.scaleY), antes de chamar esse método e reconfigure-as nos valores originais antes de imprimir. A escala de um objeto Sprite não tem relação com o printArea. Ou seja, se você especificar a área de impressão de 50 x 50 pixels, serão impressos 2500 pixels. Se você dimensionar o objeto Sprite, serão impressos os mesmos 2500 pixels, mas o objeto Sprite será impresso no tamanho dimensionado.

O recurso de impressão do Flash Player suporta impressoras PostScript e não PostScript. As impressoras não PostScript convertem vetores em bitmaps.

Parâmetros

Elementos da API relacionados

Defina o tamanho do papel. Os valores aceitáveis para o parâmetro paperSize são constantes na classe PaperSize. A chamada deste método afeta as configurações de impressão como se o usuário tivesse escolhido um tamanho de papel no diálogo Configurar Página ou Imprimir.

Você pode invocar este método em qualquer momento. Este método deve ser chamado antes de iniciar um trabalho de impressão para definir o tamanho do papel padrão nas caixas de diálogo Configurar Página e Imprimir. Chame este método enquanto um trabalho de impressão estiver em andamento para definir o tamanho do papel de um intervalo de páginas no trabalho.

     import flash.printing.PrintJob;
     import flash.printing.PaperSize;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.selectPaperSize(PaperSize.ENV_10);
     

Parâmetros

Elementos da API relacionados

Envia páginas em spool para a impressora depois de chamadas bem-sucedidas de start () ou start2() e dos métodos addPage().

Este método não terá êxito se a chamada do método start() ou start2()falhar ou se uma chamada do método addPage() lançar uma exceção. Para evitar um erro, verifique que se o método start() ou start2() o método retorna verdadeiro e proveito algum addPage() exceções antes de invocar este método. O exemplo a seguir demonstra como verificar erros adequadamente antes de chamar este método:

     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.start()) {
       try {
         myPrintJob.addPage([params]);
       }
       catch(e:Error) {
          // handle error 
       }
     
       myPrintJob.send();
     }
     

Elementos da API relacionados

Exibe a caixa de diálogo Configurar Página do sistema operacional se o ambiente atual suportar. Use a propriedade supportsPageSetupDialog para determinar se a configuração de página é suportada.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.supportsPageSetupDialog)
     {
         myPrintJob.showPageSetupDialog();
     }
     

Elementos da API relacionados

Exibe a caixa de diálogo Imprimir do sistema operacional e inicia o spool de impressão. A caixa de diálogo Imprimir permite que o usuário mude as configurações de impressão. Quando o método PrintJob.start() retorna com êxito (o usuário clica em OK na caixa de diálogo Imprimir), as propriedades a seguir são preenchidas, representando as configurações de impressão do usuário:

Observação: Se o usuário cancelar a caixa de diálogo Imprimir, as propriedades não são preenchidas.

Depois do usuário clicar em OK na caixa de diálogo Imprimir, o player inicia um trabalho de impressão em spool para o sistema operacional. Como, em seguida, o sistema operacional começa a exibir informações para o usuário sobre o progresso da impressão, você deve chamar PrintJob.addPage() e PrintJob.send() o mais breve possível para enviar as páginas para o spooler. Você pode usar as propriedades somente leitura de altura, largura e orientação que esse método preenche para formatar a listagem.

Teste para ver se esse método retorna true (quando o usuário clica em OK na caixa de diálogo Imprimir do sistema operacional), antes das chamadas subsequentes para PrintJob.addPage() e PrintJob.send():

     var myPrintJob:PrintJob = new PrintJob();
        if(myPrintJob.start()) {
          // addPage() and send() statements here
        }
     

Para a ocorrência dada de trabalho de impressão, se qualquer dos intervalos a seguir durar mais de 15 segundos, a próxima chamada para PrintJob.start() retornará false:

• O PrintJob.start() e o primeiro PrintJob.addPage()
• Um PrintJob.addPage() e o seguinte PrintJob.addPage()
• O último PrintJob.addPage() e o PrintJob.send()

Elementos da API relacionados

Opcionalmente exibe a caixa de diálogo Imprimir do sistema operacional, inicia o spooling e possivelmente modifica os valores de propriedade somente leitura PrintJob.

O parâmetro uiOptions permite ao chamador controlar quais opções são exibidas na Caixa de diálogo Imprimir. Consulte a classe PrintUIOptions. Este parâmetro não é ignorado se showPrintDialog for falso.

Mesmo quando showPrintDialog é true , o comportamento deste método pode diferir do método start(). Em alguns sistemas operacionais, start() mostra a caixa de diálogo Configurar Página seguida pela caixa de diálogo Imprimir. Por outro lado, start2() nunca mostra a caixa de diálogo Configurar Página.

No exemplo seguir, as configurações mínimas e máximas da página, na caixa de diálogo Imprimir, são definidas antes que a caixa de diálogo seja exibida para o usuário:

     import flash.printing.PrintJob;
     import flash.printing.PrintUIOptions;
     
     var myPrintJob:PrintJob = new PrintJob();
     var uiOpt:PrintUIOptions = new PrintUIOptions();
     uiOpt.minPage = 1;
     uiOpt.maxPage = 3;
     var accepted:Boolean = myPrintJob.start2(uiOpt);
     

Parâmetros

Elementos da API relacionados

Mostra que o trabalho de impressão deve ser terminado sem envio. Este método deve ser usado quando um trabalho de impressão já foi iniciado por uma chamada a start() ou start2(), mas não for conveniente enviar qualquer página à impressora. Normalmente, terminate() só será usado para recuperar erros.

Depois de invocar este método, a instância PrintJob pode ser reutilizada. Sempre que possível, as configurações de impressão do trabalho serão conservadas para o uso subsequente.

1. Explique as duas variáveis do tipo Sprite denominadas sheet1 e sheet2.
2. Chame init(), que atribui uma nova ocorrência Sprite a sheet1 e sheet2 e depois chame createSheet(), com o uso de argumentos diferentes.
3. O createSheet() faz o seguinte:
   1. O objeto Sprite transmitido é usado para desenhar um retângulo com fundo em cinza claro, borda preta de um pixel e com 100 pixels de largura por 200 de altura e x = 0, y = 0.
   2. É criado um novo objeto TextField denominado txt com as mesmas dimensões do Sprite, a propriedade wordWrap definida para true e a propriedade do texto configurada para a String transmitida como um argumento para createSheet().
   3. Se o argumento Objeto transmitido não for nulo, crie uma nova ocorrência Sprite denominada img, usada para desenhar um retângulo branco, com o uso da coordenada e das propriedades de dimensão do Objeto transmitido. O retângulo branco é incluído na lista de exibição do objeto Sprite usando addChild().
   4. O TextField txt é incluído na lista de exibição do objeto Sprite usando addChild().
4. De volta ao construtor, é chamado o método de impressão ativado (sem marcas de comentário). Como os métodos são muito semelhantes, o printOnePerPage() está descrito abaixo.
5. O printOnePerPage() faz o seguinte:
   1. Explica o novo objeto PrintJob denominado pj e o pagesToPrint com um uint.
   2. Abra a caixa de diálogo de impressão nativa do sistema operacional e espere que o usuário clique no OK.
   3. Verifique a orientação e se foi selecionado Paisagem, lance um erro e saia.
   4. Defina a altura e a largura da página para sheet1 e sheet2.
   5. Envie sheet1 e sheet2 para o spooler da impressora, usando addPage().
   6. Se o número de páginas para imprimir for > 0, imprima todas as páginas em spool.
6. É chamado o método draw(), que redimensiona as duas propriedades Sprite para se encaixarem no palco e reposiciona a sheet2 de modo que fique bem à direita da sheet1.

Observação: o construtor é configurado de modo que um dos três métodos de impressão (uma folha por página, duas folhas por página ou imprimir na metade superior da página) pode ser selecionado, com base na preferência. Esse exemplo não funcionará adequadamente a menos que exatamente dois dos métodos de impressão estejam desativados com o uso dos comentários de código. O exemplo é definido de modo que printOnePerPage() será chamado.

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;
       
    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;
           
        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }
        
        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }
        
        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();
            
            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;
            
            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }
        
        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {    
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }
        
        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;
            
            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;
            
            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }        
    }
}