RadioButtonGroup

Pacote	fl.controls
Classe	public class RadioButtonGroup
Herança	RadioButtonGroup EventDispatcher Object

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

A classe RadioButtonGroup define um grupo de componentes RadioButton de forma a atuar com um componente simples. Quando um botão de rádio é selecionado, nenhum outro botão de rádio do mesmo grupo pode ser selecionado.

Veja os exemplos

Elementos da API relacionados

RadioButton
RadioButton.group

Propriedades públicas

Ocultar propriedades públicas herdadas

Mostrar propriedades públicas herdadas

	Propriedade		Definido por
		constructor : Object Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto.	Object
		name : String [somente leitura] Obtém o nome de ocorrência do botão de rádio.	RadioButtonGroup
		numRadioButtons : int [somente leitura] Obtém o número de botões de rádio neste grupo de botões de rádio.	RadioButtonGroup
		selectedData : Object Obtém ou define a propriedade de valor do botão de rádio selecionado.	RadioButtonGroup
		selection : RadioButton Obtém ou define uma referência ao botão de rádio que está atualmente selecionado no grupo de botões de rádio.	RadioButtonGroup

Métodos públicos

Ocultar métodos públicos herdados

Mostrar métodos públicos herdados

	Método		Definido por
		RadioButtonGroup(name:String) Cria uma nova ocorrência de RadioButtonGroup.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registra um objeto de ouvinte de evento em um objeto EventDispatcher, de forma que o ouvinte receba a notificação de um evento.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Adiciona um botão de rádio à matriz interna de botões de rádio para uso com a indexação de grupo de botões de rádio, que possibilita a seleção de um único botão de rádio em um grupo de botões de rádio.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Envia um evento para o fluxo de eventos.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [estático] Recupera uma referência ao grupo de botões de rádio especificado.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Recupera o componente RadioButton na localização de índice especificada.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Retorna o índice da ocorrência de RadioButton especificada.	RadioButtonGroup
		hasEventListener(type:String):Boolean Verifica se o objeto EventDispatcher tem ouvintes registrados para um tipo específico de evento.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indica se um objeto tem uma propriedade especificada definida.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se a propriedade especificada existe e é enumerável.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Remove um ouvinte do objeto EventDispatcher.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Limpa a ocorrência de RadioButton da lista interna de botões de rádio.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Define a disponibilidade de uma propriedade dinâmica para operações de repetição.	Object
		toLocaleString():String Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade.	Object
		toString():String Retorna a representação de string do objeto especificado.	Object
		valueOf():Object Retorna o valor primitivo do objeto especificado.	Object
		willTrigger(type:String):Boolean Verifica se um ouvinte de evento está registrado nesse objeto EventDispatcher ou em qualquer um de seus ancestrais para o tipo de evento especificado.	EventDispatcher

Eventos

Clique para obter mais informações sobre eventos

Ocultar eventos herdados

Mostrar eventos herdados

	Resumo	Definido por
activate	[transmissão de evento] Despachado quando o Flash Player ou o aplicativo do AIR ganha o foco do sistema operacional e está se tornando inativo.	EventDispatcher
change	Despachado quando a ocorrência de RadioButton selecionada em um grupo é alterada.	RadioButtonGroup
click	Despachado quando uma ocorrência de RadioButton é clicada.	RadioButtonGroup
deactivate	[transmissão de evento] Despachado quando o Flash Player ou o aplicativo do AIR perde o foco do sistema operacional e está se tornando inativo.	EventDispatcher

Detalhes da propriedade

name	propriedade

name:String [somente leitura]

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Obtém o nome de ocorrência do botão de rádio.

O valor padrão é "RadioButtonGroup".

Implementação
public function get name():String

numRadioButtons

propriedade

numRadioButtons:int [somente leitura]

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Obtém o número de botões de rádio neste grupo de botões de rádio.

O valor padrão é 0.

Implementação
public function get numRadioButtons():int

selectedData

propriedade

selectedData:Object

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Obtém ou define a propriedade value do botão de rádio selecionado. Se nenhum botão de rádio estiver selecionado atualmente, esse propriedade é null.

Implementação
public function get selectedData():Object
public function set selectedData(value:Object):void

Exemplo ( Como usar este exemplo )

O exemplo a seguir cria um novo RadioButtonGroup e ouve seu evento change:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

propriedade

selection:RadioButton

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Obtém ou define uma referência ao botão de rádio que está atualmente selecionado no grupo de botões de rádio.

Implementação
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Exemplo ( Como usar este exemplo )

O exemplo a seguir cria um novo grupo de botões de rádio que contém dois botões de rádio. Quando o botão de rádio selecionado atualmente é alterado, o rótulo e o valor do botão selecionado são rastreados:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Detalhes do construtor

()

Construtor

public function RadioButtonGroup(name:String)

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Cria uma nova ocorrência de RadioButtonGroup. Geralmente, isso é feito automaticamente quando um botão de rádio é instanciado.

Parâmetros

name:String — O nome do grupo de botões de rádio.

Detalhes do método

addRadioButton

()

método

public function addRadioButton(radioButton:RadioButton):void

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Adiciona um botão de rádio à matriz interna de botões de rádio para uso com a indexação de grupo de botões de rádio, que possibilita a seleção de um único botão de rádio em um grupo de botões de rádio. Esse método é usado automaticamente pelos botões de rádio, mas também podem ser usados manualmente para adicionar explicitamente um botão de rádio a um grupo.

Parâmetros

radioButton:RadioButton — A ocorrência de RadioButton a ser adicionada ao grupo atual de botões de rádio.

getGroup

()

método

public static function getGroup(name:String):RadioButtonGroup

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Recupera uma referência ao grupo de botões de rádio especificado.

Parâmetros

name:String — O nome do grupo para o qual recuperar uma referência.

Retorna

RadioButtonGroup — Uma referência ao RadioButtonGroup especificado.

Exemplo ( Como usar este exemplo )

O exemplo a seguir demonstra como determinar o botão de rádio selecionado em um grupo:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

método

public function getRadioButtonAt(index:int):RadioButton

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Recupera o componente RadioButton na localização de índice especificada.

Parâmetros

index:int — O índice do componente RadioButton no componente RadioButtonGroup, no qual o índice do primeiro componente é 0.

Retorna

RadioButton — O componente RadioButton especificado.

Lança

RangeError — O índice especificado é menor do que 0 ou maior ou igual ao comprimento do provedor de dados.

getRadioButtonIndex

()

método

public function getRadioButtonIndex(radioButton:RadioButton):int

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Retorna o índice da ocorrência de RadioButton especificada.

Parâmetros

radioButton:RadioButton — A ocorrência de RadioButton a ser localizada no RadioButtonGroup atual.

Retorna

int — O índice do componente RadioButton especificado, ou -1, se o RadioButton especificado não foi encontrado.

removeRadioButton

()

método

public function removeRadioButton(radioButton:RadioButton):void

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Limpa a ocorrência de RadioButton da lista interna de botões de rádio.

Parâmetros

radioButton:RadioButton — A ocorrência de RadioButton a ser removida.

Detalhe do evento

change

Evento

Tipo do objeto de evento: flash.events.Event
propriedade Event.type = flash.events.Event.CHANGE

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Despachado quando a ocorrência de RadioButton selecionada em um grupo é alterada.

A constante Event.CHANGE define o valor da propriedade type de um objeto de evento change.

Esse evento tem as seguintes propriedades:

Propriedade	Valor
`bubbles`	`true`
`cancelable`	`false`; não há comportamento padrão a ser cancelado.
`currentTarget`	O objeto que está processando ativamente o objeto Event com um ouvinte de evento.
`target`	O objeto que tem seus respectivos valores modificados. `target` não é sempre o objeto na lista de exibição que registrou o ouvinte de evento. Use a propriedade `currentTarget` para acessar o objeto na lista de exibição que está processando o evento no momento.

Exemplo ( Como usar este exemplo )

O exemplo a seguir cria três botões de rádio e adiciona um ouvinte de evento para um evento change de um grupo de botões de rádio:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Evento

Tipo do objeto de evento: flash.events.MouseEvent
propriedade MouseEvent.type = flash.events.MouseEvent.CLICK

Versão da linguagem:

ActionScript 3.0

Versão de produto:

Flash CS3

Versões de runtime:

Flash Player 9.0.28.0, AIR 1.0

Despachado quando uma ocorrência de RadioButton é clicada.

Define o valor da propriedade type de um objeto de evento click.

Esse evento tem as seguintes propriedades:

Propriedade	Valor
`altKey`	`true` caso a tecla Alt esteja ativa (Windows).
`bubbles`	`true`
`buttonDown`	Para eventos de clique, este valor é sempre `false`.
`cancelable`	`false`; não há comportamento padrão a ser cancelado.
`commandKey`	`true` no Mac se a tecla Command estiver ativa; `false` se estiver inativa. Sempre `false` no Windows.
`controlKey`	`true` se a tecla Ctrl ou Control estiver ativa; `false` se estiver inativa.
`ctrlKey`	`true` no Windows ou no Linux caso a tecla Ctrl esteja ativa. `true` no Mac se a tecla Ctrl ou Command estiver ativa. Caso contrário, `false`.
`currentTarget`	O objeto que está processando ativamente o objeto Event com um ouvinte de evento.
`localX`	A coordenada horizontal na qual o evento ocorreu relacionada à entidade gráfica que contém, se o travamento de mouse estiver desativado.
`localY`	A coordenada vertical na qual o evento ocorreu relacionada à entidade gráfica que contém, se o travamento de mouse estiver desativado.
`movementX`	A modificação das coordenadas horizontais da posição de mouse desde o último evento de mouse, se o travamento de mouse estiver ativado.
`movementY`	A modificação das coordenadas verticais da posição de mouse desde o último evento de mouse, se o travamento de mouse estiver ativado.
`shiftKey`	`true` se a tecla Shift estiver ativa; `false` se estiver inativa.
`stageX`	A coordenada horizontal na qual o evento ocorreu em coordenadas globais de palco.
`stageY`	A coordenada vertical na qual o evento ocorreu em coordenadas globais de palco.
`target`	A ocorrência InteractiveObject sob o dispositivo apontador. `target` não é sempre o objeto na lista de exibição que registrou o ouvinte de evento. Use a propriedade `currentTarget` para acessar o objeto na lista de exibição que está processando o evento no momento.

Exemplos Como usar este exemplo

RadioButtonGroupExample.as

Este exemplo demonstra como gerenciar muitos objetos RadioButton em vários grupos

Adicione os componentes RadioButton e Label à biblioteca.
Salve esse código como RadioButtonGroupExample.as no mesmo diretório de FLA.
Defina DocumentClass em FLA como RadioButtonGroupExample.

package
{
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import fl.controls.Label;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Aspectos jurídicos | Política de privacidade on-line

RadioButtonGroup - AS3 Flash

Classes x

name

numRadioButtons

selectedData

selection