| Pakiet | flashx.textLayout.elements |
| Klasa | public final class ParagraphElement |
| Dziedziczenie | ParagraphElement  ParagraphFormattedElement FlowGroupElement FlowElement Object |
| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10, AIR 1.5 |
Domyślna właściwość MXMLmxmlChildren
Powiązane elementy interfejsu API
Właściwości publiczne
Ukryj dziedziczone właściwości publiczne
Pokaż dziedziczone właściwości publiczneMetody publiczne
| Metoda | Zdefiniowane przez | ||
|---|---|---|---|
Konstruktor - reprezentuje akapit w przepływie tekstu. | ParagraphElement | ||
 |
Dołącza podrzędny element FlowElement. | FlowGroupElement | |
|
Dodaje podrzędny obiekt FlowElement w określonym indeksie. | FlowGroupElement | |
| Usuwa styl określony przez parametr styleProp z danego obiektu FlowElement. | FlowElement | |
|
Tworzy głęboką kopię tego obiektu FlowElement wraz z wszelkimi elementami podrzędnymi, kopiując treść między dwoma określonymi położeniami znaków oraz zwracając kopię jako obiekt FlowElement. | FlowElement | |
| Porównanie stylów userStyle danej kopii ze stylami userStyle innego elementu otherElement. | FlowElement | |
|
Na podstawie względnego położenia tekstu znajdowany jest pierwszy podrzędny element FlowElement, który zawiera położenie względne. | FlowGroupElement | |
|
Na podstawie względnego położenia tekstu znajduje element liścia zawierający to położenie. | FlowGroupElement | |
Przeszukuje do przodu od określonego położenia w celu znalezienia w tekście miejsca następnego atomu, a następnie zwraca indeks. | ParagraphElement | ||
Zwraca indeks granicy następnego słowa w tekście. | ParagraphElement | ||
Przeszukuje do tyłu od określonego położenia w celu znalezienia w tekście miejsca poprzedniego atomu, a następnie zwraca indeks. | ParagraphElement | ||
Zwraca indeks granicy poprzedniego wyrazu w tekście. | ParagraphElement | ||
|
Zwraca położenie początkowe elementu w przepływie tekstu w postaci indeksu bezwzględnego. | FlowElement | |
|
Zwraca znak w określonym położeniu względem danego obiektu FlowElement. | FlowElement | |
| Zwraca kod znaku w określonym położeniu względem danego obiektu FlowElement. | FlowElement | |
|
Zwraca obiekt potomny FlowElement w określonym indeksie. | FlowGroupElement | |
|
Wyszukuje elementy potomne określonego obiektu FlowElement i zwraca ich indeksy. | FlowGroupElement | |
|
Zwraca początek tego elementu względem elementu przodka. | FlowElement | |
|
Zwraca pierwszy element potomny FlowLeafElement danej grupy. | FlowGroupElement | |
|
Zwraca ostatni element potomny FlowLeafElement danej grupy. | FlowGroupElement | |
Zwraca akapit, który występuje po konkretnym akapicie, lub wartość null, jeśli nie ma więcej akapitów. | ParagraphElement | ||
| Zwraca następny siostrzany obiekt FlowElement z hierarchii przepływu tekstu. | FlowElement | |
|
Zwraca obiekt ParagraphElement skojarzony z danym elementem. | FlowElement | |
Zwraca akapit poprzedzający określony akapit lub wartość null, jeśli dany akapit jest pierwszy w przepływie TextFlow. | ParagraphElement | ||
| Zwraca poprzedni obiekt równorzędny FlowElement z hierarchii przepływu tekstu. | FlowElement | |
| Zwraca wartość stylu określonego przez parametr styleProp, który określa nazwę stylu oraz może zawierać dowolną nazwę stylu użytkownika. | FlowElement | |
| [przesłanianie] | FlowGroupElement | |
|
Przechodzi do coraz wyższych poziomów w hierarchii przepływu tekstu w celu zwrócenia głównego obiektu TextFlow dla elementu. | FlowElement | |
|
Wskazuje, czy dla obiektu zdefiniowano określoną właściwość. | Object | |
| Wywoływany dla obiektów MXML po utworzeniu obiektu implementującego i jeśli zainicjalizowano wszystkie właściwości składnika określonego w znaczniku MXML. | FlowElement | |
|
Wskazuje, czy instancja klasy Object należy do łańcucha prototypów obiektu określonego jako parametr. | Object | |
|
Wskazuje, czy określona właściwość istnieje i jest przeliczalna. | Object | |
|
Usuwa określony obiekt podrzędny FlowElement z grupy. | FlowGroupElement | |
|
Usuwa potomny obiekt FlowElement o określonym indeksie. | FlowGroupElement | |
|
Zastępuje elementy podrzędne w grupie nowymi określonymi elementami. | FlowGroupElement | |
|
Ustawia dostępność właściwości dynamicznej używanej w pętlach. | Object | |
| Ustawia styl określony przez parametr styleProp na wartość określoną przez parametr newValue. | FlowElement | |
|
Tworzy kopię danego obiektu FlowElement, kopiując treść między dwoma określonymi położeniami znaków. | FlowElement | |
|
Dzieli dany obiekt w położeniu określonym przez parametr childIndex. | FlowGroupElement | |
|
Dzieli obiekt FlowElement w miejscu określonym przez parametr relativePosition, co stanowi względne położenie tego elementu w tekście. | FlowElement | |
|
Zwraca ciąg reprezentujący obiekt — sformatowany zgodnie z konwencjami właściwymi dla ustawień regionalnych. | Object | |
|
Zwraca ciąg reprezentujący określony obiekt. | Object | |
|
Zwraca pierwotną wartość dla określonego obiektu. | Object | |
Konstruktor Szczegół
ParagraphElement | () | Konstruktor |
public function ParagraphElement()| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10, AIR 1.5 |
Konstruktor — reprezentuje akapit w przepływie tekstu.
Szczegół metody
findNextAtomBoundary | () | metoda |
public function findNextAtomBoundary(relativePosition:int):int| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10, AIR 1.5 |
Przeszukuje do przodu od określonego położenia w celu znalezienia w tekście miejsca następnego atomu, a następnie zwraca indeks. Określenie atom odnosi się do elementów graficznych i znaków (w tym grup połączonych znaków), niepodzielnych elementów tworzących wiersz tekstu.
Parametry
relativePosition:int — Położenie w tekście dla rozpoczęcia, licząc od 0.
|
int — indeks następującego atomu w tekście
|
Powiązane elementy interfejsu API
Przykład ( Sposób korzystania z tego przykładu )
W tym przykładzie przedstawiono wyszukiwanie granic następnego atomu od określonego przesunięcia w akapicie.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextAtomBoundary extends Sprite
{
public function ParagraphElement_findNextAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next atom boundaries from offsets 5 and 10
var atomBoundary:int = paragraph.findNextAtomBoundary(4);
trace(atomBoundary); // 5
atomBoundary = paragraph.findNextAtomBoundary(10);
trace(atomBoundary); // 11
}
}
}
findNextWordBoundary | () | metoda |
public function findNextWordBoundary(relativePosition:int):int| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10, AIR 1.5 |
Zwraca indeks granicy następnego wyrazu w tekście.
Przeszukuje do przodu od określonego położenia w celu znalezienia następnego położenia w tekście, które zaczyna lub kończy słowo.
Parametry
relativePosition:int — położenie w tekście dla rozpoczęcia, licząc od 0
|
int — indeks (w tekście) granicy następnego słowa
|
Przykład ( Sposób korzystania z tego przykładu )
W tym przykładzie przedstawiono wyszukiwanie granic następnego słowa w akapicie od określonego przesunięcia.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextWordBoundary extends Sprite
{
public function ParagraphElement_findNextWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findNextWordBoundary(0);
trace(wordBoundary); // 5
wordBoundary = paragraph.findNextWordBoundary(12);
trace(wordBoundary); // 13
}
}
}
findPreviousAtomBoundary | () | metoda |
public function findPreviousAtomBoundary(relativePosition:int):int| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10, AIR 1.5 |
Przeszukuje do tyłu od określonego położenia w celu znalezienia w tekście miejsca poprzedniego atomu, a następnie zwraca indeks. Określenie atom odnosi się do elementów graficznych i znaków (w tym grup połączonych znaków), niepodzielnych elementów tworzących wiersz tekstu.
Parametry
relativePosition:int — Położenie w tekście dla rozpoczęcia, licząc od 0.
|
int — indeks poprzedniego klastra w tekście
|
Powiązane elementy interfejsu API
Przykład ( Sposób korzystania z tego przykładu )
W tym przykładzie przedstawiono wyszukiwanie granic poprzedniego atomu od określonego przesunięcia w akapicie.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousAtomBoundary extends Sprite
{
public function ParagraphElement_findPreviousAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous atom boundaries from offsets 6 and 13
var atomBoundary:int = paragraph.findPreviousAtomBoundary(6);
trace(atomBoundary); // 5
atomBoundary = paragraph.findPreviousAtomBoundary(13);
trace(atomBoundary); // 12
}
}
}
findPreviousWordBoundary | () | metoda |
public function findPreviousWordBoundary(relativePosition:int):int| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10, AIR 1.5 |
Zwraca indeks granicy poprzedniego słowa w tekście.
Przeszukuje do tyłu od określonego położenia w celu znalezienia poprzedniego położenia w tekście, które zaczyna lub kończy słowo.
Parametry
relativePosition:int — Położenie w tekście dla rozpoczęcia, licząc od 0.
|
int — indeks (w tekście) granicy poprzedniego słowa
|
Przykład ( Sposób korzystania z tego przykładu )
W tym przykładzie przedstawiono wyszukiwanie granic poprzedniego słowa w akapicie od określonego przesunięcia.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousWordBoundary extends Sprite
{
public function ParagraphElement_findPreviousWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findPreviousWordBoundary(22);
trace(wordBoundary); // 17
wordBoundary = paragraph.findPreviousWordBoundary(11);
trace(wordBoundary); // 6
}
}
}
getNextParagraph | () | metoda |
public function getNextParagraph():ParagraphElement| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10, AIR 1.5 |
Zwraca akapit, który występuje po konkretnym akapicie, lub wartość null, jeśli nie ma więcej akapitów.
ZwracaParagraphElement — następny akapit lub null, jeśli nie ma więcej akapitów.
|
Powiązane elementy interfejsu API
Przykład ( Sposób korzystania z tego przykładu )
W tym przykładzie przedstawiono importowanie trzech akapitów tekstu ze znaczników xml, dostęp do pierwszego akapitu za pomocą metody getChildAtIndex(0), a także użycie metody getNextParagraph() w celu uzyskania dostępu do drugiego akapitu.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getNextParagraph extends Sprite
{
public function ParagraphElement_getNextParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get first paragraph
var p:ParagraphElement = textFlow.getChildAt(0) as ParagraphElement;
// get next paragraph and display its content
var nextParagraph:ParagraphElement = p.getNextParagraph();
trace("nextParagraph.text is: " + nextParagraph.getText());
}
}
}
getPreviousParagraph | () | metoda |
public function getPreviousParagraph():ParagraphElement| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10, AIR 1.5 |
Zwraca akapit poprzedzający określony akapit lub wartość null, jeśli dany akapit jest pierwszy w przepływie TextFlow.
ZwracaParagraphElement |
Powiązane elementy interfejsu API
Przykład ( Sposób korzystania z tego przykładu )
W tym przykładzie przedstawiono importowanie trzech akapitów tekstu ze znaczników xml, dostęp do drugiego akapitu za pomocą metody getChildAtIndex(1), a także użycie metody getPreviousParagraph() w celu uzyskania dostępu do pierwszego akapitu.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getPreviousParagraph extends Sprite
{
public function ParagraphElement_getPreviousParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get second paragraph (first = 0)
var p:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
// get previous paragraph and display its content
var prevParagraph:ParagraphElement = p.getPreviousParagraph();
trace("prevParagraph.text is: " + prevParagraph.getText());
}
}
}
Przykłady Sposób korzystania z tego przykładu
ParagraphElementExample.as
Niniejszy przykład przedstawia tworzenie i formatowanie trzech akapitów tekstu.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flash.text.engine.FontPosture;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.formats.TextLayoutFormat;
public class ParagraphElementExample extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// Create Strings of text for the paragraphs
private var para1String:String = "In the first paragraph of a "
private var para1String2:String = "cheap"
private var para1String3:String ="Western novel, a cowboy meets a saloon girl.";
private var para2String:String = "In the middle of the cheap novel a really bad guy, "+
"who is having a relationship with the saloon girl, sees the cowboy help "+
"her onto her horse as she smiles at him warmly."
private var para3String:String = "In the last paragraph of the cheap novel, the cowboy kills "+
"the really bad guy in a shootout in the middle of main street and "+
"then rides into the sunset with the saloon girl on the back of his horse.";
public function ParagraphElementExample()
{
// create a TextLayoutFormat object to use in formatting the paragraphs
var textLayoutFormat:TextLayoutFormat = new TextLayoutFormat();
var paragraph1:ParagraphElement = new ParagraphElement();
// create the ParagraphElement objects
var paragraph2:ParagraphElement = new ParagraphElement();
var paragraph3:ParagraphElement = new ParagraphElement();
// create the SpanElement objects to hold the content of the paragraphs
var p1Span1:SpanElement = new SpanElement();
var p1Span2:SpanElement = new SpanElement();
var p1Span3:SpanElement = new SpanElement();
var p2Span:SpanElement = new SpanElement();
var p3Span:SpanElement = new SpanElement();
// assign the strings of text for the 1st paragraph to spans
p1Span1.text = para1String;
p1Span2.text = para1String2;
p1Span2.fontStyle = FontPosture.ITALIC; // italicize 'cheap'
p1Span3.text = para1String3;
// add spans to first paragraph
paragraph1.addChild(p1Span1);
paragraph1.addChild(p1Span2);
paragraph1.addChild(p1Span3);
// assign the string of text for the 2nd paragraph to a span
// and add the span to the second paragraph
p2Span.text = para2String;
paragraph2.addChild(p2Span);
// assign the string of text for the 3rd paragraph to a span
// and add the span to the third paragraph
p3Span.text = para3String;
paragraph3.addChild(p3Span);
// add the paragraphs to the TextFlow
textFlow.addChild(paragraph1);
textFlow.addChild(paragraph2);
textFlow.addChild(paragraph3);
// set the text formatting properties
textLayoutFormat.fontSize = 14;
textLayoutFormat.textIndent = 15;
textLayoutFormat.paragraphSpaceAfter = 15;
textLayoutFormat.paddingTop = 4;
textLayoutFormat.paddingLeft = 4;
// assign the format object to the TextFlow
textFlow.hostFormat = textLayoutFormat;
// assign a controller to the stage and update it to compose and
// display the text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
ParagraphElementExample2.as
W tym przykładzie przedstawiono importowanie znaczników xml do obiektu TextFlow. Znaczniki xml definiują te same trzy akapity tekstu oraz takie samo formatowanie, jak w poprzednim przykładzie.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
public class ParagraphElementExample2 extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// xml markup that defines the attributes and contents of a text flow
private var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>In the first paragraph of a </flow:span>"+
"<flow:span fontStyle=\"italic\">cheap</flow:span>"+
"<flow:span> Western novel, a cowboy meets a saloon girl.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the middle of the cheap novel a really bad guy, </flow:span>"+
"<flow:span>who is having a relationship with the saloon girl, sees the cowboy help </flow:span>"+
"<flow:span>her onto her horse as she smiles at him warmly.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the last paragraph of the cheap novel, the cowboy kills the really </flow:span>"+
"<flow:span> bad guy in a shootout in the middle of main street and then rides into the sunset with </flow:span>"+
"<flow:span>the saloon girl on the back of his horse.</flow:span>" +
"</flow:p>"+
"</flow:TextFlow>";
public function ParagraphElementExample2()
{
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
Tue Jun 12 2018, 12:06 PM Z