TextBlock  - AS3

Określa, czy poprawić wygląd ekranu kosztem dokładności drukowania w trybie WYSIWYG (To co widzisz jest tym, co otrzymasz). W przypadku platform i czcionek, które podczas renderowania czcionek urządzenia nie obsługują ustawiania pozycji glifów subpikseli, ale obsługują skalowanie nieliniowe, ustawienie dla tej właściwości wartości true umożliwia korzystanie z tych pomiarów w zamian za nieznaczne pogorszenie jakości wydruku WYSIWYG, szczególnie w przypadku małych czcionek. Nieliniowe skalowanie czcionek działa przez selektywne skalowanie szerokości poszczególnych glifów w celu ukrycia nieatrakcyjnych przerw spowodowanych przyciąganiem pikseli.

Na platformach obsługujących ustawianie pozycji glifów subpikseli ta flaga jest ignorowana.

Ta flaga nie ma żadnego wpływu na renderowanie czcionek osadzonych.

Wartością domyślną jest true.

Czcionka użyta do określenia linii bazowej dla wszystkich wierszy utworzonych z bloku niezależnie od swojej treści. Linie bazowe uzależnione są od czcionki i jej rozmiaru.

Wartością domyślną jest null. Jeśli czcionka linii bazowej ma wartość null, wielkość czcionki linii bazowej jest ignorowana, a linia bazowa dla danego wiersza opierać się będzie na czcionce i wielkości czcionki największego tekstu w wierszu. Po określeniu właściwości baselineFontDescription i baselineFontSize będą one decydowały o liniach bazowych w bloku tekstu, niezależnie od swojej zawartości. To połączenie jest najbardziej użyteczne w typografii języków azjatyckich.

Powiązane elementy interfejsu API

Wielkość czcionki użytej do obliczania linii bazowej dla wierszy utworzonych z bloku. Linie bazowe uzależnione są od czcionki i jej rozmiaru.

Wartość domyślna to 12. Jeśli czcionka linii bazowej ma wartość null, wielkość czcionki linii bazowej jest ignorowana, a linia bazowa dla danego wiersza opierać się będzie na czcionce i wielkości czcionki największego tekstu w wierszu.

Powiązane elementy interfejsu API

Określa, która linia bazowa znajduje się w położeniu y=0 dla wierszy utworzonych z tego bloku. Poprawne wartości dla tej właściwości znajdują się w elementach należących do klasy TextBaseline.

Wartością domyślną jest TextBaseline.ROMAN.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Określa dwukierunkowy poziom osadzenia tekstu w bloku tekstu. Zazwyczaj należy używać wartości 0 dla akapitów czytanych od lewej do prawej (dla języków angielskiego, japońskiego itd.) i wartości 1 dla akapitów czytanych od prawej do lewej (dla języków (arabskiego, hebrajskiego itd.). Korzystanie z wartości innych niż 0 i 1 jest zarezerwowane dla przypadków szczególnych. Informacje na ten temat zawiera dokument UAX#9, Unicode Bidirectional Algorithm (Algorytm dwukierunkowy Unicode, http://www.unicode.org/reports/tr9/).

Wartością domyślną jest 0.

Modyfikacja właściwości bidiLevel powoduje zmianę właściwości validity wszystkich wcześniej podzielonych wierszy na TextLineValidity.INVALID. Po zmianie właściwości bidiLevel właściwość firstInvalidLine jest taka sama jak właściwość firstLine i należy ponownie podzielić wszystkie wiersze w obiekcie TextBlock.

Powiązane elementy interfejsu API

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Utrzymuje treść bloku tekstowego. Ponieważ ContentElement to klasa podstawowa, należy przypisać właściwości content instancję podklasy ContentElement: TextElement, GraphicElement lub GroupElement. Obiekt TextElement zawiera ciąg znaków, obiekt GraphicElement zawiera DisplayObject, a GroupElement zawiera obiekt Vector obejmujący obiekt TextElement, GraphicElement oraz inne obiekty GroupElement. Obiekt TextElement należy używać w przypadku akapitów tekstu jednorodnego, GraphicElement dla elementów graficznych, a GroupElement dla połączenia elementów tekstowych i graficznych lub wielu instancji tych elementów oraz innych obiektów GroupElement.

Wartością domyślną jest null.

Modyfikacja właściwości content powoduje zmianę właściwości validity wszystkich wcześniej utworzonych wierszy na TextLineValidity.INVALID. Po zmianie właściwości content właściwość firstInvalidLine jest taka sama jak właściwość firstLine i należy ponownie podzielić wszystkie wiersze w obiekcie TextBlock.

Powiązane elementy interfejsu API

Wskazuje pierwszy wiersz w bloku tekstu, w którym TextLine.validity nie jest równe TextLineValidity.VALID.

Wartością domyślną jest null.

Powiązane elementy interfejsu API

Pierwszy obiekt TextLine w TextBlock (jeśli występuje).

Wartością domyślną jest null.

Powiązane elementy interfejsu API

Ostatni obiekt TextLine w TextBlock (jeśli występuje).

Wartością domyślną jest null.

Powiązane elementy interfejsu API

Obraca wiersze tekstu w bloku tekstu jako jednostkę. Należy wywołać metodę createTextLine() po ustawieniu lineRotation, tak aby uzyskać żądane rezultaty. Wartością domyślną jest TextRotation.ROTATE_0.

Końcowy obrót dowolnego glifu zależy od właściwości ElementFormat.textRotation, ContentElement.textRotation oraz TextBlock.lineRotation.

Właściwość TextBlock.lineRotation jest zazwyczaj stosowana dla tekstów w językach azjatyckich. W celu utworzenia akapitu pionowego tekstu w języku japońskim należy wykonać następujące czynności:

1. Ustawić dla właściwości TextBlock.lineRotation wartość TextRotation.ROTATE_90
2. Pozostawić właściwość treści ElementFormat.textRotation jako wartość domyślną TextRotation.AUTO.

Za pomocą następujących stałych zdefiniowanych w klasie TextRotation ustawić wartość dla tej właściwości:

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Określa punkty tabulacji dla tekstu w bloku tekstu w formie instancji klasy Vector zawierającej obiekty TabStop.

Wartość domyślna null oznacza, że nie określono żadnych punktów tabulacji. Jeśli nie określono żadnych punktów tabulacji (lub punkt wstawiania znajduje się poza ostatnim określonym punktem tabulacji) środowisko wykonawcze utworzy domyślnie punkty tabulacji w odstępach równych pół cala.

Po ustawieniu właściwości tabStops obiekt TextBlock tworzy kopię obiektu Vector na użytek wewnętrzny. Zmodyfikowanie oryginalnego obiektu Vector lub jego zawartości nie wpływa na obiekt TextBlock. Odczytanie właściwości tabStops powoduje zwrócenie kopii wewnętrznego obiektu Vector. Zmodyfikowanie tego zwróconego wektora lub jego zawartości nie wpływa na obiekt TextBlock.

Powiązane elementy interfejsu API

Określa obiekt TextJustifier stosowany podczas tworzenia.

Wartością domyślną jest domyślnie utworzony obiekt TextJustifier.

Po ustawieniu właściwości textJustifier obiekt TextBlock tworzy kopię obiektu do użytku wewnętrznego. Zmodyfikowanie oryginalnego obiektu nie wpływa na obiekt TextBlock. Odczytanie właściwości textJustifier powoduje zwrócenie kopii obiektu wewnętrznego. Zmodyfikowanie tak zwróconego obiektu także nie wpływa na obiekt TextBlock.

Powiązane elementy interfejsu API

Wskazuje na wynik operacji createTextLine(). Zmiana treści bloku unieważnia wcześniej podzielone wiersze i resetuje właściwość do wartości null.

Wartością domyślną jest null.

Wartości dla tej właściwości znajdują się w TextLineCreationResult.

Powiązane elementy interfejsu API

Umożliwia aplikacji skojarzenie dowolnych danych z blokiem tekstowym. Dane mogą stanowić informacje odnoszące się do treści, takie jak data korekty lub nazwisko autora, Mogą to być również dane buforowane używane podczas przetwarzania.

Tworzy obiekt TextBlock.

Powiązane elementy interfejsu API

Nakazuje blokowi tekstu utworzenie wiersza tekstu z jego treści, zaczynając w punkcie określonym przez parametr previousLine i podzielony w punkcie określonym przez parametr width. Wiersz tekstu to obiekt TextLine, który można dodać do listy odtwarzania.

Podział wierszy dotyczący zakresu bloku tekstu, który już został podzielony może doprowadzić do zmiany parametru validity wierszy w obszarze (i poza nim), w którym nastąpił podział. Status wierszy może zmienić się z VALID na INVALID lub POSSIBLY_INVALID. Jeśli ostatnio podzielony wiersz jest dokładnie wyrównany z wcześniej podzielonym wierszem ze statusem POSSIBLY_INVALID, to wcześniej podzielony wiersz oraz wszystkie następne wiersze POSSIBLY_INVALID zmienią status na VALID. Parametr validity wierszy, dla którego zostały ustawione wartości, które nie są elementami TextLineValidity nie zmieni się na VALID, ale może zmienić się na INVALID. Należy sprawdzić właściwość firstInvalidLine po każdej zmianie bloku tekstu, aby uzyskać informacje dotyczące miejsca, w którym należy rozpocząć podział lub kontynuować ponowny podział wierszy.

Można utworzyć sztuczne granice wyrazu poprzez uwzględnienie w tekście znaku przerwy zerowej długości Unicode (ZWSP, Zero Width Space). Jest to użyteczne dla języków takich jak tajski, który wymaga słownika do prawidłowego podziału wierszy. Środowisko wykonawcze Flash nie zawiera takiego słownika.

Aby ograniczyć zużycie pamięci, po utworzeniu wszystkich żądanych wierszy użytkownik powinien wywołać metodę releaseLineCreationData(), umożliwiając usunięcie danych tymczasowych związanych z podziałem wierszy, chyba że oczekuje się, że wiersze będą dzielone wielokrotnie z powodu, np. zmiany rozmiarów kontenera.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

Zrzuca podstawową treść obiektu TextBlock jako ciąg znaków XML. Może to być przydatne przy testowaniu zautomatyzowanym; zapisany ciąg zawiera tekst, informacje o formatowaniu i układzie.

Poniżej opisano wyniki:

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Opis wyników dla każdego wiersza znajduje się w omówieniu metody TextLine.dump().

Uwaga: Treść i format wyniku tej metody może w przyszłości ulec zmianie. Adobe nie gwarantuje kompatybilności wstecznej tej metody.

Powiązane elementy interfejsu API

Odszukuje indeks kolejnej granicy atomu z określonego indeksu znaku, nie uwzględniając znaku o określonym indeksie. Znaki pomiędzy granicami atomu łączą się w celu utworzenia jednego atomu w TextLine, takiego jak „e” z połączonym akcentem silnym.

Parametry

Powiązane elementy interfejsu API

Odszukuje indeks kolejnej granicy wyrazu z określonego indeksu znaku, nie uwzględniając znaku o określonym indeksie. Granice wyrazu są określane w oparciu o właściwości Unicode znaku.

Parametry

Odszukuje indeks poprzedniej granicy atomu do określonego indeksu znaku, nie uwzględniając znaku o określonym indeksie. Znaki pomiędzy granicami atomu łączą się w celu utworzenia jednego atomu w TextLine, takiego jak „e” z połączonym akcentem silnym.

Parametry

Powiązane elementy interfejsu API

Odszukuje indeks poprzedniej granicy wyrazu do określonego indeksu znaku, nie uwzględniając znaku o określonym indeksie. Granice wyrazu są określane w oparciu o właściwości Unicode znaku.

Parametry

Zwraca obiekt TextLine zawierający znak określony przez parametr charIndex.

Parametry

Nakazuje blokowi tekstu ponowne wykorzystanie istniejącego wiersza tekstu i utworzenie nowego wiersza z jego treści, zaczynając w punkcie określonym przez parametr previousLine, z podziałem w punkcie określonym przez parametr width. Wiersz tekstu to obiekt TextLine, który można dodać do listy odtwarzania. Ponowne wykorzystanie istniejącego wiersza poprawia wydajność, ponieważ liczba tworzonych od nowa obiektów jest mniejsza.

Ponownie tworzony obiekt textLine zostanie odłączony od bloku tekstu, w którym się znajduje (o ile znajduje się w bloku tekstu). Ponadto przywracane są domyślne wartości wszystkich właściwości, w tym właściwości odziedziczonych z klas DisplayObjectContainer, InteractiveObject i DisplayObject. Na koniec wszystkie elementy podrzędne wiersza, wraz z elementami graficznymi i innymi dekoracjami, są usuwane. Usuwane są także wszystkie detektory zdarzeń obiektu wiersza. Jedynym odstępstwem od zasady pełnego przywracania wiersza jest pozostawienie go w obiekcie nadrzędnym. Wiersz nie jest usuwany z obiektu nadrzędnego ze względów wydajnościowych.

Podział wierszy dotyczący zakresu bloku tekstu, który już został podzielony może doprowadzić do zmiany parametru validity wierszy w obszarze (i poza nim), w którym nastąpił podział. Status wierszy może zmienić się z VALID na INVALID lub POSSIBLY_INVALID. Jeśli ostatnio podzielony wiersz jest dokładnie wyrównany z wcześniej podzielonym wierszem ze statusem POSSIBLY_INVALID, to wcześniej podzielony wiersz oraz wszystkie następne wiersze POSSIBLY_INVALID zmienią status na VALID. Parametr validity wierszy, dla którego zostały ustawione wartości, które nie są elementami TextLineValidity nie zmieni się na VALID, ale może zmienić się na INVALID. Należy sprawdzić właściwość firstInvalidLine po każdej zmianie bloku tekstu, aby uzyskać informacje dotyczące miejsca, w którym należy rozpocząć podział lub kontynuować ponowny podział wierszy.

Można utworzyć sztuczne granice wyrazu poprzez uwzględnienie w tekście znaku przerwy zerowej długości Unicode (ZWSP, Zero Width Space). Jest to użyteczne dla języków takich jak tajski, który wymaga słownika do prawidłowego podziału wierszy. Środowisko wykonawcze Flash nie zawiera takiego słownika.

Aby ograniczyć zużycie pamięci, po utworzeniu wszystkich żądanych wierszy użytkownik powinien wywołać metodę releaseLineCreationData(), umożliwiając usunięcie danych tymczasowych związanych z podziałem wierszy, chyba że oczekuje się, że wiersze będą dzielone wielokrotnie z powodu, np. zmiany rozmiarów kontenera.

Parametry

Powiązane elementy interfejsu API

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Nakazuje blokowi tekstu zwolnienie wszystkich danych tymczasowych związanych z tworzeniem wierszy tekstu. Aby zminimalizować zużycie pamięci, należy wywołać metodę releaseLineCreationData() po zakończeniu tworzenia wierszy tekstu z bloku tekstowego. Aby jednak uzyskać maksymalną wydajność ponownego dzielenia wierszy (np. przy zmianie wymiarów kontenera), nie należy wywoływać metody releaseLineCreationData(). Autor aplikacji powinien podjąć decyzję o odpowiednim zrównoważeniu wykorzystania pamięci i wydajności.

Zalecany proces dla tekstu, który ma z założenia nie ulegać zmianom, jest następujący: zainicjowanie bloku tekstowego, wywołanie metody createTextLine() tyle razy, ile to konieczne do utworzenie żądanych wyników, wywołanie metody releaseLineCreationData().

Powiązane elementy interfejsu API

Powoduje usunięcie zakresu wierszy tekstu z listy wierszy obsługiwanych przez obiekt TextBlock. Pozwala to na zebranie zbędnych danych w przypadku braku innych odwołań.

Ustawia elementy usuniętej linii textBlock, nextLine oraz previousLine na wartość null. Ustawia parametr validity usuniętych wierszy spośród wszystkich wierszy znajdujących się za usuniętymi wierszami w obiekcie TextBlock jako TextLineValidity.INVALID.

Parametry

Powiązane elementy interfejsu API