ElementFormat  - AS3

Określa typ linii bazowej w elemencie zawierającym, do której mają być wyrównywane dominujące linie bazowe elementów w tym formacie. Wartości tej właściwości powinny być stałymi z klasy TextBaseline.

Największy element pionowy w wierszu wyznacza wyrównanie linię bazowych, pod warunkiem, że właściwości TextBlock.baselineFontDescription oraz TextBlock.baselineFontSize nie zostały ustawione w celu przesłonięcia tej logiki.

Wartością domyślną jest TextBaseline.USE_DOMINANT_BASELINE.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Określa przezroczystość elementów wiersza, na które ma wpływ ten obiekt. Poprawne są wartości z zakresu od 0 (zupełnie przezroczyste) do 1 (zupełnie nieprzezroczyste). Obiekty wyświetlane z właściwością alpha ustawioną na 0 są aktywne, mimo iż są niewidoczne.

Wartość domyślna to 1.

Powiązane elementy interfejsu API

Wskazuje przesunięcie linii bazowej dla elementu, w pikselach.

Element zostaje odsunięty od elementu dominantBaseline o tę wartość. Przesunięcie zostaje dodane do położenia y wszystkich części składowych elementu, tak więc w tekście nieobróconym przesunięcie linii bazowej o wartość dodatnią powoduje przeniesienie elementu w dół, a przesunięcie o wartość ujemną przesunięcie w górę.

Wartością domyślną jest 0,0 wskazującą na brak przesunięcia.

Możliwość podziału tekstu zastosowana w tym tekście. Ta właściwość określa, które znaki mogą być użyte przy dzieleniu zawijanego tekstu na wiele wierszy. Wartości tej właściwości powinny być stałymi z klasy BreakOpportunity.

Wartość domyślna to BreakOpportunity.AUTO.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Określa kolor tekstu. Liczba całkowita zawierająca trzy 8-bitowe składniki RGB; na przykład: 0xFF0000 to kolor czerwony, a 0x00FF00 to kolor zielony.

Wartość domyślna to 0x000000, czyli kolor czarny.

Wielkość cyfr używana dla tego tekstu. Rozmiar cyfr ma wpływ na styl i ustalanie położenia grup znaków liczbowych. Wartości tej właściwości powinny być stałymi z klasy DigitCase.

Wartość domyślna to DigitCase.DEFAULT.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Szerokość cyfr używana dla tego tekstu. Wartości tej właściwości powinny być stałymi z klasy DigitWidth.

Wartość domyślna to DigitWidth.DEFAULT.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Określa typ dominującej linii bazowej. Dominująca linia bazowa jest wyrównywana do linii bazowej wyrównania w celu wyznaczenia pionowego położenia elementu w wierszu. Wartości tej właściwości powinny być stałymi z klasy TextBaseline.

Linie bazowe określane są na podstawie treści elementu. W przypadku obiektu TextElement linie bazowe określa czcionka i rozmiar punktu. W przypadku obiektu GraphicElement linie bazowe określa wysokość elementu.

Wartością domyślną jest TextBaseline.ROMAN.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Obiekt, którego właściwości opisują czcionkę.

Wartością domyślną jest domyślnie skonstruowany obiekt FontDescription.

Po ustawieniu właściwości fontDescription obiekt FontDescription będzie zablokowany (jego właściwość locked zostanie ustawiona na wartość true. Zablokowany obiekt FontDescription nie może być modyfikowany.

Powiązane elementy interfejsu API

Rozmiar tekstu w pikselach.

Wartość domyślna to 12.0.

Kerning dopasowuje piksele pomiędzy określonymi parami znaków w celu poprawienia czytelności. Kerning jest obsługiwany dla wszystkich rodzajów czcionek zawierających tabele kerningu.

Wartość domyślna to Kerning.ON.

Tej właściwości należy przypisywać następujące stałe z klasy Kerning:

Powiązane elementy interfejsu API

Poziom ligatur używany dla tego tekstu. Ligatura pojawia się w miejscach, w których dwie lub większa liczba liter jest połączona w jeden glif. Ligatury zazwyczaj zastępują sąsiednie znaki ze wspólnymi typowymi składnikami, takie jak pary liter „fi”, „fl” czy „ae”. Są używane zarówno z zestawami znaków łacińskich, jak i niełacińskich. Wartości tej właściwości powinny być stałymi z klasy LigatureLevel.

Wartość domyślna to LigatureLevel.COMMON.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Ustawienie regionalne tekstu. Steruje transformacjami i ustalaniem kształtów dla wielkości liter. Używane są standardowe identyfikatory ustawień regionalnych. Na przykład „en”, „en_US” i „en-US” oznaczają język angielski, a „ja” oznacza język japoński. Listę kodów ustawień regionalnych można znaleźć pod adresem iso639-2 code list.

Wartością domyślną jest „en”.

Wskazuje, czy obiekt ElementFormat jest zablokowany. Jeśli wartość true obiekt ElementFormat nie może być modyfikowany. Aby pobrać niezablokowaną kopię obiektu ElementFormat, należy użyć wywołania ElementFormat.clone().

Ustawia obrót zastosowany dla pojedynczych glifów. Wartości tej właściwości powinny być stałymi z klasy TextRotation.

Wartość domyślna to TextRotation.AUTO.

Końcowy obrót dowolnego glifu to suma właściwości ElementFormat.textRotation, ContentElement.textRotation oraz TextBlock.lineRotation.

Tej właściwości używa się zazwyczaj do tekstu w językach azjatyckich, w których znaki muszą być obrócone, aby były poprawnie wyświetlane w układzie pionowym. W tym celu należy wybrać ustawienie TextRotation.AUTO razem z ustawieniem TextBlock.lineRotation = TextRotation.ROTATE_90.

Ustawienie tej właściwości dla czcionek, które nie zawierają informacji o układzie pionowym, może wywołać niepożądane efekty. Czcionki zawierające tabelę vmtx lub VORG, np. czcionka w języku japońskim „MS Mincho”, działają prawidłowo, ponieważ te tabele dostarczają informacji wymaganych do utworzenia prawidłowego układu. Czcionki takie jak Verdana, które nie zawierają niezbędnych informacji, nie działają poprawnie.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Światło lub kerning ręczny zastosowany do lewej strony glifów, w pikselach. Jeśli kerning został włączony, wartość trackingLeft jest dodawana do wartości w tabeli kerningu czcionki. Jeśli kerning został wyłączony, wartość trackingLeft jest używana jako wartość kerningu ręcznego. Obsługuje wartości dodatnie i ujemne.

Zazwyczaj wymagana wartość światła jest dzielona pomiędzy trackingRight oraz trackingLeft. W przeciwnym razie w tekstach o mieszanej kierunkowości istnieje podwójne światło na jednej granicy zmiany kierunku i brak światła na drugiej.

Wartość domyślna to 0.0.

Przykład:

          //positive tracking added to kerning
          var ef1:ElementFormat = new ElementFormat();
          ef1.kerning = flash.text.engine.Kerning.ON;
          ef1.trackingLeft = 0.5;
     
          //negative manual kerning
          var ef2:ElementFormat = new ElementFormat();
          ef2.kerning = flash.text.engine.Kerning.OFF;
          ef2.trackingLeft = -1.0;
     

Światło lub kerning ręczny zastosowany do prawej strony glifów, w pikselach. Jeśli kerning został włączony, wartość trackingRight jest dodawana do wartości w tabeli kerningu czcionki. Jeśli kerning został wyłączony, wartość trackingRight jest używana jako wartość kerningu ręcznego. Obsługuje wartości dodatnie i ujemne.

Zazwyczaj wymagana wartość światła jest dzielona pomiędzy trackingRight oraz trackingLeft. W przeciwnym razie w tekstach o mieszanej kierunkowości istnieje podwójne światło na jednej granicy zmiany kierunku i brak światła na drugiej.

Wartość domyślna to 0.0.

Przykład:

          //positive tracking added to kerning
          var ef1:ElementFormat = new ElementFormat();
          ef1.kerning = flash.text.engine.Kerning.ON;
          ef1.trackingRight = 0.5;
     
          //negative manual kerning
          var ef2:ElementFormat = new ElementFormat();
          ef2.kerning = flash.text.engine.Kerning.OFF;
          ef2.trackingRight = -1.0;
     

Wielkość typograficzna używana dla tego tekstu. Wartości tej właściwości powinny być stałymi z klasy TypographicCase.

Wartość domyślna to TypographicCase.DEFAULT.

W celu ustawienia wartości tej właściwości należy użyć następujących wartości ciągu znaków:

Powiązane elementy interfejsu API

Tworzy obiekt ElementFormat.

Tworzy niezablokowany klon obiektu ElementFormat.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormat_cloneExample extends Sprite {
        private var ef1:ElementFormat;
        private var ef2:ElementFormat;
        
        public function ElementFormat_cloneExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize=20;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            ef2 = (ef1.locked) ? ef1.clone() : ef1;    
            ef2.fontSize = 32;

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

Zwraca obiekt FontMetrics z właściwościami opisującymi pole otaczające (emBox), położenie przekreślenia, grubość przekreślenia, położenie podkreślenia i grubość podkreślenia dla czcionki opisanej przez parametry fontDescription oraz fontSize.

Powiązane elementy interfejsu API

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontMetricsExample extends Sprite {
        
        public function FontMetricsExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 24;            
            var fm1:FontMetrics = ef1.getFontMetrics();

            trace(fm1.emBox);
            trace(fm1.strikethroughOffset);
            trace(fm1.strikethroughThickness);
            trace(fm1.subscriptScale);
            trace(fm1.subscriptOffset);
            trace(fm1.superscriptScale);
            trace(fm1.superscriptOffset);
            trace(fm1.underlineOffset);
            trace(fm1.underlineThickness);
            
            
        }
    }    
}

W tym przykładzie tworzone są dwa obiekty ElementFormat i ustawianych jest kilka właściwości tych obiektów. Następnie nowe obiekty ElementFormat zostają przypisane do obiektu TextElement, który z kolei został przypisany jako treść obiektu TextBlock. Zmiana obiektu ElementFormat należącego do obiektu TextElement nie ma wpływu na obiekty TextLine wcześniej utworzone przez element nadrzędny TextBlock.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormatExample extends Sprite {
        
        public function ElementFormatExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            ef1.alpha = 100;
            ef1.kerning = flash.text.engine.Kerning.ON;
            ef1.trackingRight = 2;
            ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
            ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
            ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
            
            var ef2:ElementFormat = new ElementFormat(fd);
            ef2.fontSize = 30;
            ef2.color = 0xFF0000;
            ef2.alpha = 0.3;
            ef2.kerning = flash.text.engine.Kerning.OFF;
            ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
            ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
            ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            line1.x = 15;
            line1.y = 30;

            tb.content.elementFormat = ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            line2.x = 15;
            line2.y = 60;
            
        }
    }    
}