PrintJob  - AS3

Wskazuje, czy aktualnie aktywne jest zadanie drukowania. Zadanie drukowania jest aktywne (właściwość ma wartość true), gdy spełniony jest dowolny z dwóch warunków:

• Na ekranie jest wyświetlone okno dialogowe Ustawienia strony lub Drukowanie.
• Została wywołana metoda start() lub start2() z wartością zwracaną true, a metoda send() lub terminate() nie została wywołana.

Jeśli ta właściwość ma wartość true, a użytkownik wywołał metodę showPageSetupDialog(), start() lub start2(), wówczas środowisko wykonawcze zgłasza wyjątek.

Powiązane elementy interfejsu API

Liczba kopii stron dodawanych później do zadania drukowania, jaką drukuje system drukowania. Wartość jest liczbą kopii wprowadzoną przez użytkownika w oknie dialogowym Drukowanie systemu operacyjnego. Jeśli liczba kopii nie została wyświetlona w oknie dialogowym Drukowanie lub okno dialogowe nie zostało wyświetlone, wówczas wartość jest równa 1 (chyba że została zmieniona przez kod aplikacji).

Numer pierwszej strony z zakresu wprowadzonego przez użytkownika w oknie dialogowym Drukowanie systemu operacyjnego. Właściwość ma wartość zero, jeśli użytkownik zażądał wydrukowania wszystkich stron, jeśli zakres stron nie został wyświetlony w oknie dialogowym Drukowanie lub jeśli okno dialogowe Drukowanie nie zostało wyświetlone.

Wskazuje, czy drukarka aktualnie wybrana w bieżących ustawieniach drukowania drukuje kolory (true_, czy drukuje w skali szarości (false).

Jeśli nie ma możliwości określenia wartości, która jednoznacznie określałaby drukowanie w kolorze lub drukowanie w skali szarości, wartością jest true.

Wskazuje, czy klasa PrintJob jest obsługiwana w bieżącej platformie (true), czy nie (false).

Nazwa lub tytuł zadania drukowania. Nazwa zadania jest zwykle używana w systemie operacyjnym jako tytuł zadania w kolejce wydruku lub jako domyślna nazwa zadania drukowanego do pliku.

Jeśli nie wywołano metody start() lub metody start2() i nie ustawiono wartości dla właściwości, ta właściwość ma wartość null.

Dla każdego zadania drukowania wykonywanego z instancja klasy PrintJob należy ustawić tę właściwość przed wywołaniem metody start() lub start2().

Wartością domyślną jest null.

Numer ostatniej strony z zakresu wprowadzonego przez użytkownika w oknie dialogowym Drukowanie systemu operacyjnego. Właściwość ma wartość zero, jeśli użytkownik zażądał wydrukowania wszystkich stron, zakres stron nie został wyświetlony w oknie dialogowym Drukowanie lub okno dialogowe Drukowanie nie zostało wyświetlone.

Rozdzielczość wybranej drukarki, w pikselach na cal. Wartość jest obliczana zgodnie z bieżącymi ustawieniami drukowania, które są zgłaszane przez system operacyjny.

Jeśli nie można określić rozdzielczości, wartość jest standardową wartością domyślną. Wartość domyślna wynosi 600 ppi w systemie Linux i 360 ppi w systemie Mac OS. W systemie Windows informacja o rozdzielczości drukarki jest zawsze dostępna, dlatego nie jest potrzebna wartość domyślna.

Orientacja drukowanego obrazu. Akceptowalne wartości są zdefiniowane jako stałe w klasie PrintJobOrientation.

Uwaga: W środowisku AIR 2 i wersjach późniejszych tę właściwość należy ustawić przed uruchomieniem zadania drukowania, aby ustawić domyślną orientację w oknach dialogowych Ustawienia strony i Drukowanie. Tę właściwość należy ustawić w trakcie zadania drukowania (po wywołaniu start() lub start2()), aby ustawić orientację dla zakresu stron w zadaniu.

Powiązane elementy interfejsu API

Wysokość (w punktach) największego obszaru, jaki można wyśrodkować w faktycznym obszarze dostępnym do zadrukowania na stronie. Wszelkie marginesy zdefiniowane przez użytkownika są ignorowane. Ta właściwość jest dostępna tylko po wywołaniu metody PrintJob.start().

Uwaga: W środowisku AIR 2 i wersjach późniejszych ta właściwość jest nieaktualna. Należy zamiast niej używać właściwości printableArea, która zwraca wymiary obszaru dostępnego do zadrukowania w ułamkach punktów i precyzyjnie opisuje niewyśrodkowane obszary dostępne do zadrukowania.

Powiązane elementy interfejsu API

Szerokość (w punktach) największego obszaru, jaki można wyśrodkować w faktycznym obszarze dostępnym do zadrukowania na stronie. Wszelkie marginesy zdefiniowane przez użytkownika są ignorowane. Ta właściwość jest dostępna tylko po wywołaniu metody PrintJob.start().

Uwaga: W środowisku AIR 2 i wersjach późniejszych ta właściwość jest nieaktualna. Należy zamiast niej używać właściwości printableArea, która zwraca wymiary obszaru dostępnego do zadrukowania w ułamkach punktów i precyzyjnie opisuje niewyśrodkowane obszary dostępne do zadrukowania.

Powiązane elementy interfejsu API

Obwiednia nośnika w drukarce, w punktach. Ta wartość stosuje ten sam układ współrzędnych, jaki jest używany dla kolejnych wywołań metody addPage().

Całkowita wysokość papieru (w punktach). Ta właściwość jest dostępna tylko po wywołaniu metody PrintJob.start().

Uwaga: W środowisku AIR 2 i wersjach późniejszych ta właściwość jest nieaktualna. Zamiast niej należy używać metody paperArea, która zwraca wymiary papieru w ułamkach punktów.

Powiązane elementy interfejsu API

Całkowita szerokość papieru (w punktach). Ta właściwość jest dostępna tylko po wywołaniu metody PrintJob.start().

Uwaga: W środowisku AIR 2 i wersjach późniejszych ta właściwość jest nieaktualna. Zamiast niej należy używać metody paperArea, która zwraca wymiary papieru w ułamkach punktów.

Powiązane elementy interfejsu API

Obwiednia obszaru możliwego do zadrukowania na nośniku w drukarce, w punktach. Ta wartość wykorzystuje ten sam układ współrzędnych, jaki jest używany dla kolejnych wywołań metody addPage().

Odczytuje lub ustawia drukarkę, która ma być używana w bieżącym zadaniu drukowania. Obiekt String przekazany do funkcji ustawiającej i zwracany przez funkcję pobierającą powinien być równy jednemu z ciągów znaków w obiekcie Array zwracanym przez metodę printers(). Aby wskazać, że powinna być używana drukarka domyślna, ustaw wartość na null. W systemach operacyjnych, w których nie można określić domyślnej drukarki, wartość dla właściwości to null.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.printer = "HP_LaserJet_1";
     myPrintJob.start();
     

Ustawienie wartości tej właściwości powoduje natychmiastową próbę wybrania drukarki. Jeśli wybieranie drukarki nie powiedzie się, zostanie przywrócona poprzednia wartość tej właściwości. Aby sprawdzić, czy ustawienie wartości printer się powiodło, należy odczytać wartość po próbie jej ustawienia i upewnić się, że wartość jest zgodna z wartością ustawioną.

Nie można zmienić wartości właściwości printer aktywnego zadania drukowania. Próba zmiany wartości po pomyślnym wywołaniu metody start() lub start2() i przed wywołaniem metody send() lub terminate() zakończy się niepowodzeniem.

Zwraca listę dostępnych drukarek jako wartości obiektu String. Lista nie jest ustalana z góry; generowana jest każdorazowo po wywołaniu funkcji. Jeśli w systemie nie ma dostępnych drukarek lub system nie obsługuje drukowania, wartość jest równa null. Jeśli system obsługuje drukowanie, ale nie może zwrócić listy drukarek, wartością będzie obiekt Vector z pojedynczym elementem (jego właściwość length będzie równa 1). W takim przypadku pojedynczy element będzie rzeczywistą nazwą drukarki lub nazwą domyślną, jeśli nie można ustalić bieżącej nazwy drukarki.

Wskazuje, czy środowisko wykonawcze Flash obsługuje odrębne okno dialogowe Ustawienia strony. Jeśli ta właściwość ma wartość true, można wywołać metodę showPageSetupDialog() w celu wyświetlenia okna dialogowego Ustawienia strony w systemie operacyjnym.

Powiązane elementy interfejsu API

Tworzy obiekt PrintJob, który pozwala drukować strony. Po utworzeniu obiektu PrintJob należy uzyć (w określonej kolejności) metod PrintJob.start(), PrintJob.addPage() oraz PrintJob.send() w celu wysłania zadania drukowania do drukarki.

Przykład: tekst [params] można zastąpić dla wywołań metody myPrintJob.addPage(), stosując niestandardowe parametry, co przedstawiono w poniższym kodzie:

 // create PrintJob object
 var myPrintJob:PrintJob = new PrintJob();
  
 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (myPrintJob.start()) {
  
    // add specified page to print job
    // repeat once for each page to be printed
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
 
    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful 
    // calls to start() and addPage() before calling send().
    myPrintJob.send();
 }
 

W AIR 2 i wersjach późniejszych można tworzyć i wykorzystywać wiele instancji klasy PrintJob. Po zakończeniu drukowania właściwości ustawione w instancji klasy PrintJob są zachowywane. Dzięki temu możliwe jest ponowne wykorzystanie instancji klasy PrintJob i zachowanie wybranych przez użytkownika preferencji drukowania, a jednocześnie możliwe jest oferowanie innych preferencji drukowania dla innych treści w aplikacji. Dla treści w programie Flash Player oraz w środowisku AIR w wersjach wcześniejszych niż wersja 2 nie można utworzyć drugiego obiektu PrintJob, gdy pierwszy jest nadal aktywny. Jeśli drugi obiekt PrintJob zostanie utworzony (poprzez wywołanie metody new PrintJob()), podczas gdy aktywny jest pierwszy obiekt PrintJob, drugi obiekt PrintJob nie zostanie utworzony. Przed wywołaniem drugiego zadania PrintJob należy sprawdzić wartość myPrintJob.

Powiązane elementy interfejsu API

Wysyła określony obiekt Sprite, jako pojedynczą stronę, do bufora drukarki. Przed użyciem tej metody należy utworzyć obiekt PrintJob, a następnie użyć metody start() lub start2(). Następnie po wywołaniu metody addPage() jeden raz lub więcej dla zadania drukowania należy użyć metody send() w celu wysłania buforowanych stron do drukarki. Innymi słowy: po utworzeniu obiektu PrintJob należy użyć (w następującej kolejności) metody start() lub start2(), addPage(), a następnie metody send() w celu wysłania zadania drukowania do drukarki. W celu wydrukowania kilku stron w jednym zadaniu drukowania można wielokrotnie wywoływać metodę addPage() po pojedynczym wywołaniu metody start().

Jeśli metoda addPage() powoduje, że program Flash Player wywołuje wyjątek (na przykład: gdy nie wywołano metody start() lub użytkownik anulował zadanie drukowania), wszelkie kolejne wywołania metody addPage() zakończą się niepowodzeniem. Jeśli jednak poprzednie wywołania metody addPage() zakończyły się pomyślnie, końcowa komenda send() wysyła do drukarki strony, które zostały pomyślnie zapisane w buforze.

Jeśli wykonanie operacji addPage() w ramach zadania drukowania trwa dłużej niż 15 sekund, program Flash Player zwróci wyjątek przy kolejnym wywołaniu addPage().

Jeśli dla parametru printArea zostanie wprowadzona wartość, współrzędne x i y mapy prostokąta printArea zostaną odwzorowane na lewy górny narożnik (współrzędne 0, 0) drukowanego obszaru strony. Właściwości tylko do odczytu: pageHeight i pageWidth opisują obszar wydruku na stronie określony przez metodę start(). Obszar wydruku jest zrównany z lewym górnym narożnikiem drukowanego obszaru strony, dlatego jeśli obszar printArea jest większy niż obszar drukowania na stronie, wydruk zostanie przycięty u dołu i góry (lub w obydwu tych miejscach) obszaru zdefiniowanego przez printArea. W programie Flash Professional: jeśli nie zostanie wprowadzona wartość printArea i stół montażowy jest większy niż obszar wydruku, stosowany jest ten sam typ przycinania. W środowisku Flex lub Flash Builder: jeśli do parametru printArea nie zostanie przekazana wartość i ekran jest większy niż obszar wydruku, stosowany jest ten sam typ przycinania.

Jeśli przed drukowaniem użytkownik chce wyskalować obiekt Sprite, należy ustawić wartości dla właściwości skali (patrz flash.display.DisplayObject.scaleX i flash.display.DisplayObject.scaleY) przed wywołaniem tej metody, a następnie przywrócić ich oryginalne wartości po wydrukowaniu. Skala obiektu Sprite nie ma związku z parametrem printArea. Oznacza to, że po określeniu obszaru drukowanego równego 50 x 50 pikseli zostanie wydrukowanych 2500 pikseli. W przypadku zmiany skali obiektu Sprite również drukowane będą piksele (2500 pikseli), ale obiekt Sprite będzie drukowany w określonej skali.

Funkcja drukowania w programie Flash Player obsługuje drukarki obsługujące i nieobsługujące języka PostScript. Drukarki nieobsługujące języka PostScript konwertują wektory na bitmapy.

Parametry

Powiązane elementy interfejsu API

Ustawia rozmiar papieru. Akceptowalnymi wartościami parametru paperSize są stałe w klasie PaperSize. Wywołanie tej metody wpływa na ustawienia drukowania w taki sposób, jakby użytkownik wybrał rozmiar papieru w oknie dialogowym Ustawienia strony lub Drukowanie.

Tę metodę można wywołać w dowolnym momencie. Ta metoda powinna zostać wywołana przed rozpoczęciem zadania drukowania w celu ustawienia domyślnego rozmiaru papieru w oknach dialogowych Ustawienia strony i Drukowanie. Tę metodę można również wywołać w trakcie wykonywania zadania drukowania, w celu ustawienia rozmiaru strony dla zakresu stron w ramach zadania.

     import flash.printing.PrintJob;
     import flash.printing.PaperSize;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.selectPaperSize(PaperSize.ENV_10);
     

Parametry

Powiązane elementy interfejsu API

Wysyła buforowane strony do drukarki po pomyślnych wywołaniach metod start() lub start2() oraz addPage().

Wywołanie tej metody zakończy się niepowodzeniem, jeśli wywołanie metody start() lub start2() nie powiedzie się lub jeśli wywołanie metody addPage() zwróci wyjątek. Aby uniknąć błędu, należy się upewnić, że metoda start() lub start2() zwraca wartość true, a następnie wychwycić wyjątki addPage() przed wywołaniem tej metody. Poniższy przykład prezentuje sposób poprawnego sprawdzania, czy wystąpiły błędy, przed wywołaniem tej metody:

     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.start()) {
       try {
         myPrintJob.addPage([params]);
       }
       catch(e:Error) {
          // handle error 
       }
     
       myPrintJob.send();
     }
     

Powiązane elementy interfejsu API

Powoduje wyświetlenie okna dialogowego Ustawienia strony systemu operacyjnego, o ile bieżące środowisko obsługuje takie okno. Aby sprawdzić, czy okno dialogowe Ustawienia strony jest obsługiwane, należy skorzystać z właściwości supportsPageSetupDialog.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.supportsPageSetupDialog)
     {
         myPrintJob.showPageSetupDialog();
     }
     

Powiązane elementy interfejsu API

Wyświetla systemowe okno dialogowe Drukowanie i rozpoczyna buforowanie. W oknie dialogowym Drukowanie można zmieniać ustawienia drukowania. Jeśli metoda PrintJob.start() zadziała pomyślnie (użytkownik kliknął przycisk OK w oknie dialogowym Drukowanie), wprowadzone zostaną wartości dla następujących właściwości, które reprezentują wybrane ustawienia drukowania:

Uwaga: Jeśli użytkowink kliknie przycisk Anuluj w oknie dialogowym Drukuj, nie zostaną wprowadzone wartości właściwości.

Gdy użytkownik kliknie przycisk OK w oknie dialogowym Drukuj, odtwarzacz rozpocznie buforowanie zadania drukowania do systemu operacyjnego. Następnie system operacyjny rozpocznie wyświetlanie informacji dotyczących postępu drukowania, dlatego jak najszybciej należy wywołać metody PrintJob.addPage() i PrintJob.send() w celu wysłania stron do bufora. W celu formatowania wydruku można korzystać z właściwości (tylko do odczytu) height, width i orientation, których wartości określa ta metoda.

Przed kolejnymi wywołaniami metod PrintJob.addPage() i PrintJob.send() należy sprawdzić, czy metoda zwróci wartość true (gdy użytkownik kliknie OK w oknie dialogowym Drukuj systemu operacyjnego):

     var myPrintJob:PrintJob = new PrintJob();
        if(myPrintJob.start()) {
          // addPage() and send() statements here
        }
     

Dla konkretnej instancji zadania drukowania: jeśli dowolny z poniższych przedziałów czasowych trwa dłużej niż 15 sekund, kolejne wywołane metody PrintJob.start() spowoduje zwrócenie wartości false:

• Metoda PrintJob.start() oraz pierwsze wywołanie metody PrintJob.addPage()
• Jedna metoda PrintJob.addPage() i kolejne wywołanie PrintJob.addPage()
• Ostatnie wywołanie metody PrintJob.addPage() oraz wywołanie metody PrintJob.send()

Powiązane elementy interfejsu API

Opcjonalnie wyświetla okno dialogowe Drukowanie systemu operacyjnego, rozpoczyna buforowanie i ustawia właściwości tylko do odczytu obiektu PrintJob.

Parametr uiOptions umożliwia określenie w wywołaniu, które opcje mają być wyświetlane w oknie dialogowym Drukowanie. Patrz opis klasy PrintUIOptions. Ten parametr jest ignorowany, jeśli showPrintDialog ma wartość false.

Nawet gdy showPrintDialog ma wartość true, metoda ta może działać inaczej niż metoda start(). W niektórych systemach operacyjnych metoda start() powoduje wyświetlenie najpierw okna dialogowego Ustawienia strony, a potem okna dialogowego Drukowanie. Natomiast metoda start2() nigdy nie powoduje wyświetlenia okna dialogowego Ustawienia strony.

W poniższym przykładzie minimalne i maksymalne ustawienia dla stron w oknie dialogowym Drukowanie są ustawiane zanim zostanie wyświetlone okno dialogowe:

     import flash.printing.PrintJob;
     import flash.printing.PrintUIOptions;
     
     var myPrintJob:PrintJob = new PrintJob();
     var uiOpt:PrintUIOptions = new PrintUIOptions();
     uiOpt.minPage = 1;
     uiOpt.maxPage = 3;
     var accepted:Boolean = myPrintJob.start2(uiOpt);
     

Parametry

Powiązane elementy interfejsu API

Sygnalizuje, że zadanie drukowania powinno zostać zakończone bez wysyłania danych. Tej metody należy używać, gdy zadanie drukowania zostało już zainicjowane przez wywołanie metody start() lub start2(), ale żadne strony nie powinny być wysyłane do drukarki. Zwykle metoda terminate() jest używana tylko do przywracania poprawnego stanu po błędach.

Po wywołaniu tej metody można ponownie wykorzystać instancję klasy PrintJob. Zawsze, gdy jest to możliwe, ustawienia zadania drukowania są zachowywane do ponownego użycia.

1. Zadeklaruj dwie zmienne typu Sprite o nazwach sheet1 i sheet2.
2. Wywołaj metodę init(), która przypisze nową instancję Sprite do zmiennych sheet1 i sheet2, a następnie wywoła metodę createSheet() z innymi argumentami.
3. Metoda createSheet() ma następujące funkcje:
   1. Przekazywany obiekt Sprite jest używany do narysowania prostokąta o ciemnoszarym tle z czarnym obramowaniem o szerokości jednego piksela — prostokąt ma szerokość 100 pikseli i wysokość 200 pikseli (położenie x = 0, y = 0).
   2. Tworzony jest nowy obiekt TextField o nazwie txt o takich samych wymiarach, co obiekt Sprite. Dla właściwości wordWrap zostaje ustawiona wartość true, a dla właściwości zostaje ustawiony ciąg znaków przekazywany jako argument createSheet().
   3. Jeśli przekazywany argument Object ma wartość null, należy utworzyć nową instancję Sprite o nazwie img — posłuży ona do narysowania białego prostokąta, którego współrzędne i wymiary będą takie same, jak przekazanego argumentu Object. Biały prostokąt jest dodawany do listy wyświetlanej obiektu Sprite przez metodę addChild().
   4. Pole txt TextField jest dodawane do listy wyświetlania obiektu Sprite przez metodę addChild().
4. W konsturktorze zostaje wywołana metoda drukowania, która jest aktywna (nie jest oznaczona jako komentarz). Metody są bardzo podobne, dla tego metoda printOnePerPage() została opisana poniżej.
5. Metoda printOnePerPage() ma następujące funkcje:
   1. Zadeklaruj nowy obiekt PrintJob o nazwie pj i pagesToPrint jako uint.
   2. Otwiera systmowe okno dialogowe drukowania i czeka, aż uzytkownik kliknie przycisk OK.
   3. Sprawdza orientację i jeśli wybrana jest orientacja Landscape, zgłasza błąd i kończy działanie.
   4. Ustawia wysokośc i szerokość stronyu dl sheet1 i sheet2.
   5. Wysyła sheet1 i sheet2 do bufora drukowania za pomocą metody addPage().
   6. Jeśli liczba stron do wydrukowania jest > 0, drukowane są wszystkie buforowane strony.
6. Następuje wywołanie metody draw(), która powoduje zmianę wielkości dwóch właściwości Sprite w celu dopasowania na stole montażowy, a następnie zmienia położenie obiektu sheet2 w taki sposób, aby znalazł się po prawej stronie obiektu sheet1.

Uwaga: Konstruktor jest ustawiony w taki sposób, że możliwe jest wybranie jednej z trzech metod drukowania (jeden arkusz na stronę, dwa na stronę lub drukowanie na górnej połowie strony). Poniższy przykład nie będzie działał poprawnie, jeśli dokładnie dwie metody drukowania nie zostaną wyłączone poprzez zastosowanie oznaczenie ich jako komentarzy. W przykładzie zastosowano wywołanie metody printOnePerPage().

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;
       
    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;
           
        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }
        
        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }
        
        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();
            
            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;
            
            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }
        
        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {    
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }
        
        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;
            
            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;
            
            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }        
    }
}