FocusEvent  - AS3

Określa kierunek przeniesienia fokusu dla zdarzenie focusIn.

Powiązane elementy interfejsu API

Jeśli wartość to true, właściwość relatedObject zostanie ustawiona na wartość null z przyczyn związanych z bezpiecznymi obszarami izolowanymi. Jeśli nominalną wartością właściwości relatedObject jest odwołanie do obiektu DisplayObject w innym obszarze izolowanym, właściwość relatedObject zostanie ustawiona na wartość null, chyba że ustanowiono uprawnienia w obu kierunkach przez granice obszaru izolowanego. Uprawnienie ustanawiane jest przez wywołanie metody Security.allowDomain() z pliku SWF lub przez dostarczenie pliku reguł z serwera pliku obrazu i ustawianie właściwości LoaderContext.checkPolicyFile podczas ładowania obrazu.

Powiązane elementy interfejsu API

Kod klawisza, którego naciśnięcie wywołało zdarzenie keyFocusChange.

Odwołanie do komplementarnej instancji klasy InteractiveObject, która zmieniła się wskutek przeniesienia aktywności. Na przykład gdy zachodzi zdarzenie focusOut, obiekt relatedObject jest instancją klasy InteractiveObject, która stała się aktywna.

Wartością tej właściwości może być null w dwóch przypadkach: jeśli nie istnieje powiązany obiekt lub istnieje powiązany obiekt, ale obiekt ten znajduje się w bezpiecznym obszarze izolowanym, do którego programista nie ma dostępu. Aby wskazać, który z tych powodów znajduje zastosowanie, należy użyć właściwości isRelatedObjectInaccessible().

Powiązane elementy interfejsu API

Określa, czy jest aktywny klawisz modyfikujący Shift (wówczas przyjmuje wartość true). W przeciwnym razie ma wartość false. Ta właściwość jest używana tylko wówczas, gdy obiekt FocusEvent należy do typu keyFocusChange.

Tworzy obiekt Event zawierający określone informacje o zdarzeniach dotyczących aktywności. Obiekty Event są przekazywane jako parametry do detektorów zdarzeń.

Powiązane elementy interfejsu API

Tworzy kopię obiektu FocusEvent i ustawia wartości poszczególnych właściwości zgodnie z właściwościami oryginału.

Zwraca ciąg znaków, który zawiera wszystkie właściwości obiektu FocusEvent. Format ciągu znaków jest następujący:

[FocusEvent type=wartość bubbles=wartość cancelable=wartość relatedObject=wartość shiftKey=wartość] keyCode=wartość]

Definiuje wartość właściwości type obiektu zdarzenia focusIn.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Definiuje wartość właściwości type obiektu zdarzenia focusOut.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Definiuje wartość właściwości type obiektu zdarzenia keyFocusChange.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Definiuje wartość właściwości type obiektu zdarzenia mouseFocusChange.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

1. Deklaruje właściwości child (typu Sprite) oraz childCount (typu uint).
2. Pętla for tworzy pięć jasnoniebieskich kwadratów we współrzędnych (0,0). Rozpoczyna się od przypisania właściwości child nowej instancji klasy CustomSprite. Za każdym razem, gdy tworzony jest obiekt CustomSprite, wykonywane są następujące czynności:
   • Właściwość size typu uint jest ustawiana na 50 pikseli, a właściwość bgColor na kolor jasnoniebieski.
   • Właściwościom buttonMode i useHandCursor klasy Sprite nadawana jest, w konstruktorze, wartość true.
   • Tworzona jest instancja detektora zdarzeń typu click wraz ze skojarzonym subskrybentem clickHandler(). Metoda będąca subskrybentem tworzy zmienną lokalną target typu Sprite i przypisuje jej kliknięty kwadrat. Fokus obiektu Stage jest wówczas przypisywany do obiektu target.
   • Wywoływana jest metoda draw(), która tworzy kwadrat o rozmiarach 50 x 50 pikseli, wywołując metody beginFill(), drawRect() i endFill() klasy Graphics oraz używając właściwości instancji.
3. W pętli for wywoływana jest metoda configureListeners(), która tworzy instancje trzech detektorów/subskrybentów zdarzeń:
   • focusIn/focusInHandler() to zdarzenie wywoływane za każdym razem, gdy pojawia się zdarzenie click dla któregokolwiek z obiektów (kwadratów) na liście wyświetlania.
   • focusOut/focusOutHandler() to zdarzenie wywoływane za każdym razem, gdy kliknięty zostanie inny kwadrat lub fokus zostanie przeniesiony poza stół montażowy (np. poprzez kliknięcie poza oknem programu Flash Player).
   • keyFocusChange/keyFocusChangeHandler() to zdarzenie wywoływane za każdym razem, gdy użytkownik wybierze obiekt na liście wyświetlania za pomocą klawisza Tab lub klawiszy ze strzałką w lewo lub w prawo. Metoda keyFocusChangeHandler() przechwytuje naciśnięcia klawiszy ze strzałką w lewo lub w prawo, ale dezaktywuje je, wywołując metodę preventDefault().
4. W pętli for poszczególne kwadraty są dodawane do listy wyświetlania i wyświetlane (wszystkie w tym samym obszarze) poprzez wywołania metody addChild().
5. Konstruktor wywołuje następnie metodę refreshLayout(), która rozmieszcza pomarańczowe kwadraty wzdłuż górnej krawędzi ekranu (y = 0), w odstępach 5-pikselowych.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}