DataGridEvent  - AS3 Flash

Pobiera lub ustawia nazwę pola lub właściwości w danych skojarzonych z kolumną.

Pobiera mechanizm renderujący edytowanego elementu lub mechanizm renderujący nagłówka, który jest klikany lub którego rozmiar jest zmieniany.

Pobiera przyczynę wywołania zdarzenia itemEditEnd. Ta właściwość jest poprawna tylko dla zdarzeń typu DataGridEvent.ITEM_EDIT_END.

Możliwe wartości są zdefiniowane w klasie DataGridEventReason.

Powiązane elementy interfejsu API

Tworzy nowy obiekt DataGridEvent z określonymi parametrami.

Powiązane elementy interfejsu API

Tworzy kopię obiektu DataGridEvent i ustawia wartości poszczególnych właściwości zgodnie z właściwościami oryginału.

Zwraca ciąg znaków, który zawiera wszystkie właściwości obiektu DataGridEvent. Format ciągu znaków jest następujący:

[DataGridEvent type=wartość bubbles=wartość cancelable=wartość columnIndex=wartość rowIndex=wartość itemRenderer=wartość dataField=wartość reason=wartość]

Stała DataGridEvent.COLUMN_STRETCH definiuje wartość właściwości type obiektu zdarzenia columnStretch.

To zdarzenie ma następujące właściwości:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    var column:DataGridColumn;
    var columnArray:Array = dg.columns;
    var dgColWidth:String;
    trace("resized column:", event.dataField);
    trace("columnIndex:", event.columnIndex);
    for each (column in columnArray) {
        dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
        trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
    }
    trace("----------");
}

Stała DataGridEvent.HEADER_RELEASE definiuje wartość właściwości type obiektu zdarzenia headerRelease.

To zdarzenie ma następujące właściwości:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
    trace("sortIndex:", dg.sortIndex);
    trace("sortDescending:", dg.sortDescending);
    trace("----------");
}

Stała DataGridEvent.ITEM_EDIT_BEGIN definiuje wartość właściwości type obiektu zdarzenia itemEditBegin.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Stała DataGridEvent.ITEM__EDIT_BEGINNING definiuje wartość właściwości type obiektu zdarzenia itemEditBeginning.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Stała DataGridEvent.ITEM_EDIT_END definiuje wartość właściwości type obiektu zdarzenia itemEditEnd.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Stała DataGridEvent.ITEM_FOCUS_IN definiuje wartość właściwości type obiektu zdarzenia itemFocusIn.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Stała DataGridEvent.ITEM_FOCUS_OUT definiuje wartość właściwości type obiektu zdarzenia itemFocusOut.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

W celu uruchomienia przykładu należy wykonać poniższe czynności:

1. Dodaj składnik DataGrid do biblioteki.
2. Zapisz ten kod pod nazwą DataGridEventExample.as w tym samym katalogu, co plik FLA.
3. W pliku FLA ustaw klasę dokumentu na DataGridEventExample.

package
{
    import fl.controls.DataGrid;
    import fl.data.DataProvider;
    import fl.events.DataGridEvent;
    import fl.events.DataGridEventReason;
    import flash.display.Sprite;
    
    public class DataGridEventExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridEventExample() {
            createDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;
            dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
            dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
        }
        private function announceEditBegin(e:DataGridEvent):void {
            trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);    
        }
        private function announceEditEnd(e:DataGridEvent):void {
            var reason:String;
            switch(e.reason) {
                case DataGridEventReason.CANCELLED:
                    reason = "User cancelled edit";
                    break;
                case DataGridEventReason.NEW_ROW:
                    reason = "User focused to another row";
                    break;
                case DataGridEventReason.NEW_COLUMN:
                    reason = "User focused to another column";
                    break;
                case DataGridEventReason.OTHER:
                default:
                    reason = "Edit ended for other reason";
                    reason = e.reason;
                    break;                
            }
            trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
            trace("Reason: " + reason.toString());    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
    }
}