RadioButtonGroup

Pakiet	fl.controls
Klasa	public class RadioButtonGroup
Dziedziczenie	RadioButtonGroup EventDispatcher Object

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Klasa RadioButtonGroup definiuje grupę składników RadioButton działającą jako pojedynczy składnik. Po wybraniu jednego z przycisków opcji nie jest możliwy wybór żadnego innego przycisku w obrębie tej samej grupy.

Wyświetl przykłady

Powiązane elementy interfejsu API

RadioButton
RadioButton.group

Właściwości publiczne

Ukryj dziedziczone właściwości publiczne

Pokaż dziedziczone właściwości publiczne

	Właściwość		Zdefiniowane przez
		constructor : Object Odwołanie do obiektu klasy lub funkcji konstruktora, dotyczące danej instancji obiektu.	Object
		name : String [tylko do odczytu] Pobiera nazwę instancji przycisku opcji.	RadioButtonGroup
		numRadioButtons : int [tylko do odczytu] Pobiera liczbę przycisków opcji w tej grupie przycisków opcji.	RadioButtonGroup
		selectedData : Object Pobiera lub ustawia właściwość value wybranego przycisku opcji.	RadioButtonGroup
		selection : RadioButton Pobiera lub ustawia odwołanie do przycisku opcji należącego do grupy przycisków opcji, który jest obecnie wybrany.	RadioButtonGroup

Metody publiczne

Ukryj dziedziczone metody publiczne

Pokaż dziedziczone metody publiczne

	Metoda		Zdefiniowane przez
		RadioButtonGroup(name:String) Tworzy nową instancję RadioButtonGroup.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Rejestruje obiekt detektora zdarzeń w obiekcie EventDispatcher, dzięki czemu detektor będzie otrzymywał powiadomienia o zdarzeniu.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Dodaje przycisk opcji do wewnętrznej tablicy przycisków opcji, umożliwiając indeksowanie grupy przycisków opcji; zabieg ten pozwala na wybór pojedynczego przycisku opcji z grupy.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Wywołuje zdarzenie, tj. kieruje je do przepływu zdarzeń.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [statyczny] Pobiera odniesienie do określonej grupy przycisków opcji.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Pobiera składnik RadioButton o wskazanym indeksie.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Zwraca indeks wskazanego wystąpienia składnika RadioButton.	RadioButtonGroup
		hasEventListener(type:String):Boolean Sprawdza, czy obiekt EventDispatcher zawiera jakiekolwiek detektory zarejestrowane dla konkretnego typu zdarzeń.	EventDispatcher
		hasOwnProperty(name:String):Boolean Wskazuje, czy dla obiektu zdefiniowano określoną właściwość.	Object
		isPrototypeOf(theClass:Object):Boolean Wskazuje, czy instancja klasy Object należy do łańcucha prototypów obiektu określonego jako parametr.	Object
		propertyIsEnumerable(name:String):Boolean Wskazuje, czy określona właściwość istnieje i jest przeliczalna.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Usuwa detektor z obiektu EventDispatcher.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Kasuje instancję RadioButton z wewnętrznej listy przycisków opcji.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Ustawia dostępność właściwości dynamicznej używanej w pętlach.	Object
		toLocaleString():String Zwraca ciąg reprezentujący obiekt — sformatowany zgodnie z konwencjami właściwymi dla ustawień regionalnych.	Object
		toString():String Zwraca ciąg reprezentujący określony obiekt.	Object
		valueOf():Object Zwraca pierwotną wartość dla określonego obiektu.	Object
		willTrigger(type:String):Boolean Sprawdza, czy detektor zdarzeń określonego typu jest zarejestrowany w tym obiekcie EventDispatcher lub jego elementach macierzystych.	EventDispatcher

Zdarzenia

Kliknij, aby uzyskać więcej informacji o zdarzeniach

Ukryj zdarzenia dziedziczone

Pokaż zdarzenia dziedziczone

	Podsumowanie	Zdefiniowane przez
activate	[zdarzenie broadcast] Wywoływane, gdy program Flash Player lub aplikacja środowiska wykonawczego AIR uzyskuje fokus w systemie operacyjnym i przechodzi w stan aktywny.	EventDispatcher
change	Wywoływane, gdy zmieni się zaznaczona instancja składnika RadioButton w grupie.	RadioButtonGroup
click	Wywoływane po kliknięciu wystąpienia składnika RadioButton.	RadioButtonGroup
deactivate	[zdarzenie broadcast] Wywoływane, gdy program Flash Player lub aplikacja AIR traci fokus w systemie operacyjnym i przechodzi w stan nieaktywny.	EventDispatcher

Szczegół właściwości

name	właściwość

name:String [tylko do odczytu]

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera nazwę wystąpienia przycisku opcji.

Wartością domyślną jest "RadioButtonGroup".

Implementacja
public function get name():String

numRadioButtons

właściwość

numRadioButtons:int [tylko do odczytu]

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera liczbę przycisków opcji w tej grupie przycisków opcji.

Wartością domyślną jest 0.

Implementacja
public function get numRadioButtons():int

selectedData

właściwość

selectedData:Object

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera lub ustawia właściwość value wybranego przycisku opcji. Jeśli żaden z przycisków opcji nie jest wybrany, właściwość ta ma wartość null.

Implementacja
public function get selectedData():Object
public function set selectedData(value:Object):void

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje tworzenie nowej grupy RadioButtonGroup i detekcję jej zdarzenia change:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

właściwość

selection:RadioButton

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera lub ustawia odniesienie do przycisku opcji należącego do grupy przycisków opcji, który jest obecnie wybrany.

Implementacja
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje tworzenie nowej grupy przycisków opcji zawierającej dwa przyciski opcji. Z chwilą zmiany bieżąco wybranego przycisku opcji zaczynają być śledzone etykieta i wartość nowo wybranego przycisku opcji:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Konstruktor Szczegół

()

Konstruktor

public function RadioButtonGroup(name:String)

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Tworzy nową instancję RadioButtonGroup. Zwykle dzieje się to automatycznie po utworzeniu instancji przycisku opcji.

Parametry

name:String — Nazwa grupy przycisków opcji.

Szczegół metody

addRadioButton

()

metoda

public function addRadioButton(radioButton:RadioButton):void

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Dodaje przycisk opcji do wewnętrznej tablicy przycisków opcji, umożliwiając indeksowanie grupy przycisków opcji; zabieg ten pozwala na wybór pojedynczego przycisku opcji z grupy. Ta metoda jest automatycznie wykorzystywana przez przyciski opcji, lecz może również służyć do ręcznego, jawnego dodania przycisku opcji do grupy.

Parametry

radioButton:RadioButton — Dodawana do bieżącej grupy przycisków opcji instancja RadioButton.

getGroup

()

metoda

public static function getGroup(name:String):RadioButtonGroup

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera odwołanie do określonej grupy przycisków opcji.

Parametry

name:String — Nazwa grupy, dla której jest pobierane odwołanie.

Zwraca

RadioButtonGroup — Odwołanie do określonej grupy RadioButtonGroup.

Przykład ( Sposób korzystania z tego przykładu )

Poniższy przykład ilustruje sposób określania, który z przycisków opcji w grupie został wybrany:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

metoda

public function getRadioButtonAt(index:int):RadioButton

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera składnik RadioButton o wskazanym indeksie.

Parametry

index:int — Indeks składnika RadioButton w składniku RadioButtonGroup, gdzie indeks pierwszego składnika wynosi 0.

Zwraca

RadioButton — Wskazany składnik RadioButton.

Zgłasza

RangeError — Podany indeks jest mniejszy niż 0 albo większy lub równy długości obiektu dostarczającego dane.

getRadioButtonIndex

()

metoda

public function getRadioButtonIndex(radioButton:RadioButton):int

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Zwraca indeks wskazanej instancji składnika RadioButton.

Parametry

radioButton:RadioButton — Lokalizowana w bieżącej grupie RadioButtonGroup instancja RadioButton.

Zwraca

int — Indeks określonego składnika RadioButton lub -1, jeśli określonego składnika RadioButton nie znaleziono.

removeRadioButton

()

metoda

public function removeRadioButton(radioButton:RadioButton):void

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Czyści wystąpienie RadioButton z wewnętrznej listy przycisków opcji.

Parametry

radioButton:RadioButton — Instancja RadioButton do usunięcia.

Szczegół zdarzenia

change

Zdarzenie

Typ obiektu zdarzenia: flash.events.Event
właściwość Event.type = flash.events.Event.CHANGE

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Wywoływane, gdy zmieni się zaznaczone wystąpienie składnika RadioButton w grupie.

Stała Event.CHANGE definiuje wartość właściwości type obiektu zdarzenia change.

To zdarzenie ma następujące właściwości:

Właściwość	Wartość
`bubbles`	`true`
`cancelable`	`false`; nie ma domyślnego zachowania, które można byłoby anulować.
`currentTarget`	Obiekt przetwarzający aktywnie obiekt Event za pomocą detektora zdarzeń.
`target`	Wartość obiektu została zmodyfikowana. Obiekt `target` nie zawsze jest obiektem na liście wyświetlania, która zarejestrowała detektor zdarzeń. Właściwość `currentTarget` umożliwia uzyskanie dostępu do obiektu na liście wyświetlania, który obecnie przetwarza zdarzenie.

Przykład ( Sposób korzystania z tego przykładu )

W poniższym przykładzie utworzono trzy przyciski opcji i dodano detektor zdarzeń dla zdarzenia change grupy przycisków opcji:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Zdarzenie

Typ obiektu zdarzenia: flash.events.MouseEvent
właściwość MouseEvent.type = flash.events.MouseEvent.CLICK

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Wywoływane po kliknięciu instancji składnika RadioButton.

Definiuje wartość właściwości type obiektu zdarzenia click.

To zdarzenie ma następujące właściwości:

Właściwość	Wartość
`altKey`	`true`, jeśli klawisz Alt jest aktywny (Windows).
`bubbles`	`true`
`buttonDown`	W przypadku zdarzeń kliknięcia ta wartość zawsze jest równa `false`.
`cancelable`	`false`; nie ma domyślnego zachowania, które można byłoby anulować.
`commandKey`	`true` w systemach Mac, jeśli klawisz Command jest aktywny; `false`, jeśli jest nieaktywny. Zawsze `false` w systemach Windows.
`controlKey`	`true`, jeśli klawisz Ctrl lub Control jest aktywny; `false`, jeśli jest nieaktywny.
`ctrlKey`	`true` w systemach Windows lub Linux, jeśli klawisz Ctrl jest aktywny. `true` w systemach Mac, jeśli aktywny jest klawisz Ctrl albo Command. W przeciwnym razie `false`.
`currentTarget`	Obiekt przetwarzający aktywnie obiekt Event za pomocą detektora zdarzeń.
`localX`	Współrzędna pozioma miejsca wystąpienia zdarzenia (określana względem ikonki), jeśli jest wyłączone blokowanie myszy.
`localY`	Współrzędna pionowa miejsca wystąpienia zdarzenia (określana względem ikonki), jeśli jest wyłączone blokowanie myszy.
`movementX`	Zmiana współrzędnej poziomej pozycji myszy od ostatniego zdarzenia myszy, jeśli jest włączone blokowanie myszy.
`movementY`	Zmiana współrzędnej pionowej pozycji myszy od ostatniego zdarzenia myszy, jeśli jest włączone blokowanie myszy.
`shiftKey`	`true`, jeśli klawisz Shift jest aktywny; `false`, jeśli jest nieaktywny.
`stageX`	Współrzędna pozioma miejsca wystąpienia zdarzenia (w globalnym układzie współrzędnych stołu montażowego).
`stageY`	Współrzędna pionowa miejsca wystąpienia zdarzenia (w globalnym układzie współrzędnych stołu montażowego).
`target`	Instancja klasy InteractiveObject pod urządzeniem wskazującym. Obiekt `target` nie zawsze jest obiektem na liście wyświetlania, która zarejestrowała detektor zdarzeń. Właściwość `currentTarget` umożliwia uzyskanie dostępu do obiektu na liście wyświetlania, który obecnie przetwarza zdarzenie.

Przykłady Sposób korzystania z tego przykładu

RadioButtonGroupExample.as

Ten przykład ilustruje sposób zarządzania wieloma obiektami RadioButton należącymi do kilku różnych grup.

Dodaj składniki RadioButton i Label do biblioteki.
Zapisz ten kod pod nazwą RadioButtonGroupExample.as w tym samym katalogu, co plik FLA.
Ustaw właściwość DocumentClass w pliku FLA na wartość RadioButtonGroupExample.

package
{
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import fl.controls.Label;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Informacje prawne | Zasady prywatności online

RadioButtonGroup - AS3 Flash

Klasy x

name

numRadioButtons

selectedData

selection