| Pakket | flashx.textLayout.elements |
| Klasse | public final class ParagraphElement |
| Overerving | ParagraphElement  ParagraphFormattedElement FlowGroupElement FlowElement Object |
| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
Standaard-MXML-eigenschapmxmlChildren
Meer voorbeelden
Verwante API-elementen
Openbare eigenschappen
Overerfde openbare eigenschappen verbergen
Overerfde openbare eigenschappen weergevenOpenbare methoden
| Methode | Gedefinieerd door | ||
|---|---|---|---|
Constructor: staat voor een alinea in een tekstflow. | ParagraphElement | ||
 |
Voegt een onderliggend FlowElement-object toe. | FlowGroupElement | |
|
Voegt een onderliggend FlowElement-object toe op de opgegeven indexpositie. | FlowGroupElement | |
| Hiermee wordt de stijl bepaald door de styleProp-parameter van dit FlowElement-object. | FlowElement | |
|
Maakt een uitgebreide kopie van dit FlowElement-object, inclusief alle onderliggende elementen, waarbij de inhoud tussen de twee opgegeven tekenposities wordt gekopieerd. De kopie wordt geretourneerd als een FlowElement-object. | FlowElement | |
| Vergelijk de userStyles van dit met element met de userStyles van otherElement. | FlowElement | |
|
Zoek op basis van een relatieve tekstpositie naar de index van het eerste onderliggende FlowElement met de relatieve positie. | FlowGroupElement | |
|
Zoek op basis van een relatieve tekstpositie naar het bladelement met de relatieve positie | FlowGroupElement | |
Scant voorwaarts vanaf de opgegeven positie en zoekt naar de locatie van het volgende atoom in de tekst; retourneert de index. | ParagraphElement | ||
Retourneert de index van de volgende woordgrens in de tekst. | ParagraphElement | ||
Scant achterwaarts vanaf de opgegeven positie en zoekt naar de locatie van het voorgaande atoom in de tekst; retourneert de index. | ParagraphElement | ||
Retourneert de index van de voorgaande woordgrens in de tekst. | ParagraphElement | ||
|
Retourneert de beginlocatie van het element in de tekstflow als een absolute index. | FlowElement | |
|
Retourneert het teken bij de opgegeven positie, relatief ten opzichte van dit FlowElement-object. | FlowElement | |
| Retourneert de tekencode bij de opgegeven positie, relatief ten opzichte van dit FlowElement-object. | FlowElement | |
|
Retourneert het onderliggende FlowElement-object op de opgegeven index. | FlowGroupElement | |
|
Zoekt in onderliggende items naar het opgegeven FlowElement-object en retourneert de bijbehorende indexpositie. | FlowGroupElement | |
|
Retourneert het begin van dit element, relatief ten opzichte van een bovenliggend element. | FlowElement | |
|
Retourneert de eerste FlowLeafElement-afstammeling van deze groep. | FlowGroupElement | |
|
Retourneert de laatste FlowLeafElement-afstammeling van deze groep. | FlowGroupElement | |
Retourneert de alinea die volgt op de huidige (of null als er niet meer alinea's zijn). | ParagraphElement | ||
| Retourneert het volgende FlowElement dat zich op hetzelfde niveau bevindt in de tekstflowhiërarchie. | FlowElement | |
|
Retourneert het ParagraphElement-object dat is gekoppeld aan dit element. | FlowElement | |
Retourneert de alinea die voorafgaat aan de huidige (of null als de huidige alinea de eerste alinea in TextFlow is). | ParagraphElement | ||
| Retourneert het voorgaande FlowElement dat zich op hetzelfde niveau bevindt in de tekstflowhiërarchie. | FlowElement | |
| Retourneert de waarde van de stijl die is opgegeven door de styleProp-parameter, die de stijlnaam aangeeft en eender welke gebruikersstijlnaam kan bevatten. | FlowElement | |
| [overschrijven] | FlowGroupElement | |
|
Klimt omhoog in de tekstflowhiërarchie en retourneert het basis-TextFlow-object voor het element. | FlowElement | |
|
Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd. | Object | |
| Opgeroepen voor MXML-objecten nadat het implementerende object is gemaakt en alle componenteigenschappen die op de MXML-tag zijn opgegeven, zijn geïnitialiseerd. | FlowElement | |
|
Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven. | Object | |
|
Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd. | Object | |
|
Verwijdert het opgegeven onderliggende FlowLeafElement-object van de groep | FlowGroupElement | |
|
Verwijdert het onderliggende FlowElement-object op de opgegeven indexpositie. | FlowGroupElement | |
|
Vervangt onderliggende elementen in de groep door de opgegeven nieuwe elementen. | FlowGroupElement | |
|
Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in. | Object | |
| Hiermee wordt de stijl, zoals bepaald door de styleProp-parameter, ingesteld op de waarde die is bepaald door de newValue-parameter. | FlowElement | |
|
Maakt een kopie van dit FlowElement-object, zodat de inhoud tussen twee opgegeven tekenposities wordt gekopieerd. | FlowElement | |
|
Hiermee wordt dit object opgedeeld op de positie die is opgegeven door de childIndex-parameter. | FlowGroupElement | |
|
Hiermee wordt dit FlowElement-object opgedeeld op de positie die wordt bepaald door de relativePosition-parameter. Dit is de relatieve positie in de tekst voor dit element. | FlowElement | |
|
Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies. | Object | |
|
Retourneert een tekenreeksrepresentatie van het opgegeven object. | Object | |
|
Retourneert de primitieve waarde van het opgegeven object. | Object | |
Constructordetails
ParagraphElement | () | Constructor |
public function ParagraphElement()| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
Constructor: staat voor een alinea in een tekstflow.
Methodedetails
findNextAtomBoundary | () | methode |
public function findNextAtomBoundary(relativePosition:int):int| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
Scant voorwaarts vanaf de opgegeven positie en zoekt naar de locatie van het volgende atoom in de tekst; retourneert de index. De term atoom verwijst zowel naar grafische elementen als naar tekens (inclusief groepen met gecombineerde tekens), de onzichtbare entiteiten waaruit een tekstregel bestaat.
Parameters
relativePosition:int — positie in de tekst waarvan wordt begonnen, geteld vanaf 0
|
int — index in de tekst van het volgende atoom
|
Verwante API-elementen
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld worden in een alinea de volgende atoomgrenzen gevonden van opgegeven verschuivingen.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextAtomBoundary extends Sprite
{
public function ParagraphElement_findNextAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next atom boundaries from offsets 5 and 10
var atomBoundary:int = paragraph.findNextAtomBoundary(4);
trace(atomBoundary); // 5
atomBoundary = paragraph.findNextAtomBoundary(10);
trace(atomBoundary); // 11
}
}
}
findNextWordBoundary | () | methode |
public function findNextWordBoundary(relativePosition:int):int| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
Retourneert de index van de volgende woordgrens in de tekst.
Scant voorwaarts vanaf de opgegeven positie en zoekt naar de volgende positie in de tekst waarmee een woord begint of eindigt.
Parameters
relativePosition:int — positie in de tekst waarvan wordt begonnen, geteld vanaf 0
|
int — index in de tekst van de volgende woordgrens
|
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld worden in een alinea de volgende woordgrenzen gevonden van opgegeven verschuivingen.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextWordBoundary extends Sprite
{
public function ParagraphElement_findNextWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findNextWordBoundary(0);
trace(wordBoundary); // 5
wordBoundary = paragraph.findNextWordBoundary(12);
trace(wordBoundary); // 13
}
}
}
findPreviousAtomBoundary | () | methode |
public function findPreviousAtomBoundary(relativePosition:int):int| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
Scant achterwaarts vanaf de opgegeven positie en zoekt naar de locatie van het voorgaande atoom in de tekst; retourneert de index. De term atoom verwijst zowel naar grafische elementen als naar tekens (inclusief groepen met gecombineerde tekens), de onzichtbare entiteiten waaruit een tekstregel bestaat.
Parameters
relativePosition:int — positie in de tekst waarvan wordt begonnen, geteld vanaf 0
|
int — index in de tekst van het vorige cluster
|
Verwante API-elementen
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld worden in een alinea de vorige atoomgrenzen gevonden van opgegeven verschuivingen.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousAtomBoundary extends Sprite
{
public function ParagraphElement_findPreviousAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous atom boundaries from offsets 6 and 13
var atomBoundary:int = paragraph.findPreviousAtomBoundary(6);
trace(atomBoundary); // 5
atomBoundary = paragraph.findPreviousAtomBoundary(13);
trace(atomBoundary); // 12
}
}
}
findPreviousWordBoundary | () | methode |
public function findPreviousWordBoundary(relativePosition:int):int| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
Retourneert de index van de voorgaande woordgrens in de tekst.
Scant achterwaarts vanaf de opgegeven positie en zoekt naar de vorige positie in de tekst waarmee een woord begint of eindigt.
Parameters
relativePosition:int — positie in de tekst waarvan wordt begonnen, geteld vanaf 0
|
int — index in de tekst van de vorige woordgrens
|
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld worden in een alinea de vorige woordgrenzen gevonden van opgegeven verschuivingen.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousWordBoundary extends Sprite
{
public function ParagraphElement_findPreviousWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findPreviousWordBoundary(22);
trace(wordBoundary); // 17
wordBoundary = paragraph.findPreviousWordBoundary(11);
trace(wordBoundary); // 6
}
}
}
getNextParagraph | () | methode |
public function getNextParagraph():ParagraphElement| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
Retourneert de alinea die volgt op de huidige (of null als er niet meer alinea's zijn).
Geretourneerde waardeParagraphElement — de volgende alinea of null als er niet meer alinea's zijn.
|
Verwante API-elementen
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld worden drie alinea's tekst geïmporteerd vanaf de xml-opmaak, wordt de eerste alinea geopend met getChildAtIndex(0) en de tweede alinea geopend met getNextParagraph().
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getNextParagraph extends Sprite
{
public function ParagraphElement_getNextParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get first paragraph
var p:ParagraphElement = textFlow.getChildAt(0) as ParagraphElement;
// get next paragraph and display its content
var nextParagraph:ParagraphElement = p.getNextParagraph();
trace("nextParagraph.text is: " + nextParagraph.getText());
}
}
}
getPreviousParagraph | () | methode |
public function getPreviousParagraph():ParagraphElement| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
Retourneert de alinea die voorafgaat aan de huidige (of null als de huidige alinea de eerste alinea in TextFlow is).
Geretourneerde waardeParagraphElement |
Verwante API-elementen
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld worden drie alinea's tekst geïmporteerd vanaf de xml-opmaak, wordt de tweede alinea geopend met getChildAtIndex(1) en de eerste alinea geopend met getPreviousParagraph().
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getPreviousParagraph extends Sprite
{
public function ParagraphElement_getPreviousParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get second paragraph (first = 0)
var p:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
// get previous paragraph and display its content
var prevParagraph:ParagraphElement = p.getPreviousParagraph();
trace("prevParagraph.text is: " + prevParagraph.getText());
}
}
}
Voorbeelden Hoe dit voorbeeld te gebruiken
ParagraphElementExample.as
In dit voorbeeld worden drie tekstalinea's gemaakt en geformatteerd.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flash.text.engine.FontPosture;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.formats.TextLayoutFormat;
public class ParagraphElementExample extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// Create Strings of text for the paragraphs
private var para1String:String = "In the first paragraph of a "
private var para1String2:String = "cheap"
private var para1String3:String ="Western novel, a cowboy meets a saloon girl.";
private var para2String:String = "In the middle of the cheap novel a really bad guy, "+
"who is having a relationship with the saloon girl, sees the cowboy help "+
"her onto her horse as she smiles at him warmly."
private var para3String:String = "In the last paragraph of the cheap novel, the cowboy kills "+
"the really bad guy in a shootout in the middle of main street and "+
"then rides into the sunset with the saloon girl on the back of his horse.";
public function ParagraphElementExample()
{
// create a TextLayoutFormat object to use in formatting the paragraphs
var textLayoutFormat:TextLayoutFormat = new TextLayoutFormat();
var paragraph1:ParagraphElement = new ParagraphElement();
// create the ParagraphElement objects
var paragraph2:ParagraphElement = new ParagraphElement();
var paragraph3:ParagraphElement = new ParagraphElement();
// create the SpanElement objects to hold the content of the paragraphs
var p1Span1:SpanElement = new SpanElement();
var p1Span2:SpanElement = new SpanElement();
var p1Span3:SpanElement = new SpanElement();
var p2Span:SpanElement = new SpanElement();
var p3Span:SpanElement = new SpanElement();
// assign the strings of text for the 1st paragraph to spans
p1Span1.text = para1String;
p1Span2.text = para1String2;
p1Span2.fontStyle = FontPosture.ITALIC; // italicize 'cheap'
p1Span3.text = para1String3;
// add spans to first paragraph
paragraph1.addChild(p1Span1);
paragraph1.addChild(p1Span2);
paragraph1.addChild(p1Span3);
// assign the string of text for the 2nd paragraph to a span
// and add the span to the second paragraph
p2Span.text = para2String;
paragraph2.addChild(p2Span);
// assign the string of text for the 3rd paragraph to a span
// and add the span to the third paragraph
p3Span.text = para3String;
paragraph3.addChild(p3Span);
// add the paragraphs to the TextFlow
textFlow.addChild(paragraph1);
textFlow.addChild(paragraph2);
textFlow.addChild(paragraph3);
// set the text formatting properties
textLayoutFormat.fontSize = 14;
textLayoutFormat.textIndent = 15;
textLayoutFormat.paragraphSpaceAfter = 15;
textLayoutFormat.paddingTop = 4;
textLayoutFormat.paddingLeft = 4;
// assign the format object to the TextFlow
textFlow.hostFormat = textLayoutFormat;
// assign a controller to the stage and update it to compose and
// display the text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
ParagraphElementExample2.as
In dit voorbeeld wordt xml-opmaak in een TextFlow-object geïmporteerd. De xml-opmaak definieert dezelfde drie tekstalinea's en hun opmaak zoals in het vorige voorbeeld.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
public class ParagraphElementExample2 extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// xml markup that defines the attributes and contents of a text flow
private var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>In the first paragraph of a </flow:span>"+
"<flow:span fontStyle=\"italic\">cheap</flow:span>"+
"<flow:span> Western novel, a cowboy meets a saloon girl.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the middle of the cheap novel a really bad guy, </flow:span>"+
"<flow:span>who is having a relationship with the saloon girl, sees the cowboy help </flow:span>"+
"<flow:span>her onto her horse as she smiles at him warmly.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the last paragraph of the cheap novel, the cowboy kills the really </flow:span>"+
"<flow:span> bad guy in a shootout in the middle of main street and then rides into the sunset with </flow:span>"+
"<flow:span>the saloon girl on the back of his horse.</flow:span>" +
"</flow:p>"+
"</flow:TextFlow>";
public function ParagraphElementExample2()
{
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
Wed Jun 13 2018, 11:42 AM Z