FocusEvent  - AS3

Bepaalt de richting van de focus voor een focusIn-gebeurtenis.

Verwante API-elementen

Als de waarde true wordt geretourneerd, is de eigenschap relatedObject ingesteld op null vanwege redenen die te maken hebben met beveiligingssandboxen. Als de nominale waarde van relatedObject een verwijzing is naar een DisplayObject in een andere sandbox, wordt relatedObject ingesteld op null, tenzij er toestemming is de grens van deze sandbox in beide richtingen te overschrijden. Deze toestemming kan worden ingesteld door Security.allowDomain() aan te roepen vanuit een SWF-bestand of door vanaf de server een beleidsbestand beschikbaar te stellen voor een afbeeldingsbestand. In dat geval moet de eigenschap LoaderContext.checkPolicyFile worden ingesteld tijdens het laden van de afbeelding.

Verwante API-elementen

De waarde van de toetscode voor de toets waarop wordt gedrukt om een gebeurtenis keyFocusChange te activeren.

Een verwijzing naar de aanvullende instantie InteractiveObject die is beïnvloed door de gewijzigde focus. Wanneer bijvoorbeeld een gebeurtenis focusOut plaatsvindt, vertegenwoordigt relatedObject het InteractiveObject dat de focus heeft gekregen.

De waarde van deze eigenschap kan in twee gevallen null zijn: als er geen verwant object is of als er wel sprake is van een verwant object maar dit object zich in een beveiligingssandbox bevindt waartoe u geen toegang hebt. Gebruik de eigenschap isRelatedObjectInaccessible() om vast te stellen welke van deze redenen van toepassing is.

Verwante API-elementen

Geeft aan of de optie Shift-toets is geactiveerd; in dat geval is de waarde true. Anders is de waarde false. Deze eigenschap wordt alleen gebruikt wanneer de FocusEvent van het type keyFocusChange is.

Maakt een Event-object met specifieke informatie voor de gebeurtenissen Focus. Gebeurtenisobjecten worden als parameters aan gebeurtenislisteners doorgegeven.

Verwante API-elementen

Maakt een kopie van het object FocusEvent en stelt de waarde van elke eigenschap in zodat deze overeenkomt met die van het origineel.

Retourneert een tekenreeks die alle eigenschappen van het object FocusEvent bevat. De tekenreeks heeft de volgende indeling:

[FocusEvent type=value bubbles=value cancelable=value relatedObject=value shiftKey=value] keyCode=value]

Definieert de waarde van de eigenschap type van een gebeurtenisobject focusIn.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject focusOut.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject keyFocusChange.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject mouseFocusChange.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

1. Het declareert de eigenschappen child (van het type Sprite) en childCount (van het type uint).
2. Een lus for maakt vijf lichtblauwe vierkanten op (0,0). Het begint met het toewijzen van child aan een nieuwe instantie CustomSprite. Elke keer dat een object CustomSprite wordt gemaakt, gebeurt het volgende:
   • De eigenschap size van het type uint wordt ingesteld op 50 pixels en bgColor wordt ingesteld op lichtblauw.
   • De eigenschappen buttonMode and useHandCursor van de klasse Sprite zijn ingesteld op true binnen de constructor.
   • Een gebeurtenislistener van type click wordt geïnstantieerd, samen met de gekoppelde abonnee clickHandler(). De abonneemethode maakt een lokale variabele target van het type Sprite en wijst die toe, onafhankelijk van welk vakje was aangeklikt. De focus van het werkgebied wordt vervolgens toegewezen aan target.
   • De methode draw() wordt aangeroepen, die een vierkant van 50 x 50 pixels maakt door de methoden beginFill(), drawRect() en endFill() van de klasse Graphics aan te roepen en de instantie-eigenschappen.
3. In de lus for wordt de methode configureListeners() aangeroepen, die drie gebeurtenislisteners/-abonnees instantieert:
   • focusIn / focusInHandler() wordt verzonden nadat de gebeurtenis click voor willekeurige welk weergaveoverzichtobject (venster) wordt aangeklikt.
   • focusOut / focusOutHandler() wordt verzonden wanneer een ander venster wordt aangeklikt of wanneer de focus het werkgebied verlaat (bijvoorbeeld door buiten Flash Player te klikken).
   • keyFocusChange / keyFocusChangeHandler() wordt verzonden wanneer u de Tab-toets gebruikt of de pijltoetsen links of rechts om een weergaveoverzichtobject te selecteren. De methode keyFocusChangeHandler() vangt de pijltoetsen links en rechts af, maar roept de methode preventDefault() aan om ze uit te schakelen.
4. In de lus for wordt elk vierkant aan het weergaveoverzicht toegevoegd en met behulp van addChild() weergegeven (allemaal in hetzelfde gebied).
5. De constructor roept vervolgens refreshLayout() aan, die de oranje vierkanten langs de bovenkant van het scherm (y = 0) weergeeft met 5 pixels tussenruimte.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}