WorkerDomain  - AS3

コードが現在実行中の WorkerDomain インスタンスです。これは、そのアプリケーションの唯一の WorkerDomain です。

現在のランタイムコンテキストが同時コード実行で WorkerDomain および Worker オブジェクトをサポートするかどうかを示します。

並行処理が使用可能な場合、このプロパティの値は true です。

swf のバイトから新しい Worker インスタンスを作成します。

各ワーカーは、分離した swf アプリケーションから作成され、分離した swf アプリケーションとして実行されます。Worker インスタンスを作成するには、SWF ファイルのバイトを ByteArray インスタンスとして取得し、このメソッドに渡します。この目的で swf のバイトにアクセスするには、次の 3 つの共通の方法があります。

• [Embed] メタタグを使用して、.swf ファイルをアプリケーションに ByteArray として埋め込みます。

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• URLLoader を使用して、外部 SWF ファイルをロードします。

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• 基本ワーカーおよびバックグラウンドワーカーとして単一の swf を使用します。

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

createWorker() を使用して Worker オブジェクトを作成しても、ワーカーの実行は開始されません。ワーカーのコード実行を開始するには、Worker オブジェクトの start() メソッドを呼び出します。

ワーカーは、メインレンダリングスレッドが他のコードにブロックされることが原因でフレームレートがドロップする可能性を減らすので、便利です。ただし、ワーカーは追加のシステムメモリおよび CPU の使用を必要とし、これにより、アプリケーション全体のパフォーマンスに影響する可能性があります。各ワーカーはそれぞれ独自のランタイム仮想マシンのインスタンス使用するので、通常のワーカーのオーバーヘッドでさえ大きくなる可能性があります。ワーカーを使用する場合は、すべての対象プラットフォームでコードをテストして、システムへの要求が大きすぎないことを確認します。一般的に、2 つ以上のバックグラウンドワーカーを使用しないようにすることをお勧めします。

パラメーター

現在実行中の WorkerDomain（Worker インスタンスの state プロパティは WorkerState.RUNNING）のワーカーのセットへのアクセスを提供します。