StyleManager

パッケージ	fl.managers
クラス	public class StyleManager
継承	StyleManager Object

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

StyleManager クラスは、Flash ドキュメント内のコンポーネントインスタンス、コンポーネントタイプ全体、またはすべてのユーザーインターフェイスコンポーネントのスタイルを取得および設定するために使用できる、静的メソッドを提供します。スタイルは、パディング、テキストフォーマット、スキンなど、コンポーネントの表示に影響する値として定義されます。

例を表示

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		StyleManager() 新しい StyleManager オブジェクトを作成します。	StyleManager
		clearComponentStyle(component:Object, name:String):void [静的] 指定のコンポーネントからスタイルを削除します。	StyleManager
		clearStyle(name:String):void [静的] ドキュメント内のすべてのユーザーインターフェイスコンポーネントから、グローバルスタイルを削除します。	StyleManager
		getComponentStyle(component:Object, name:String):Object [静的] 特定のコンポーネントに存在するスタイルを取得します。	StyleManager
		getStyle(name:String):Object [静的] name に基づいてグローバルスタイルを設定します。	StyleManager
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		registerInstance(instance:UIComponent):void [静的] スタイルマネージャーにコンポーネントインスタンスを登録します。	StyleManager
		setComponentStyle(component:Object, name:String, style:Object):void [静的] 例えば Button コンポーネントのすべてのインスタンス、または ComboBox コンポーネントのすべてのインスタンスなど、あるコンポーネントタイプのすべてのインスタンスに対してスタイルを設定します。	StyleManager
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		setStyle(name:String, style:Object):void [静的] ドキュメント内のすべてのユーザーインターフェイスコンポーネントに対し、グローバルスタイルを設定します。	StyleManager
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

コンストラクターの詳細

()

コンストラクター

public function StyleManager()

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

新しい StyleManager オブジェクトを作成します。

メソッドの詳細

clearComponentStyle

()

メソッド

public static function clearComponentStyle(component:Object, name:String):void

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

指定のコンポーネントからスタイルを削除します。

パラメーター

	`component:Object` — スタイルを削除するコンポーネントの名前です。

	`name:String` — 削除するスタイルの名前です。

clearStyle

()

メソッド

public static function clearStyle(name:String):void

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

ドキュメント内のすべてのユーザーインターフェイスコンポーネントから、グローバルスタイルを削除します。

パラメーター

name:String — 削除するグローバルスタイルの名前です。

getComponentStyle

()

メソッド

public static function getComponentStyle(component:Object, name:String):Object

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

特定のコンポーネントに存在するスタイルを取得します。

パラメーター

	`component:Object` — 指定のスタイルを探すコンポーネントインスタンスの名前です。

	`name:String` — 取得するスタイルの名前です。

戻り値

Object — 指定のコンポーネントからの要求されたスタイルです。この関数は、指定のスタイルが見つからなかった場合、null を返します。

getStyle

()

メソッド

public static function getStyle(name:String):Object

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

name に基づいてグローバルスタイルを設定します。

パラメーター

name:String — 取得するスタイルの名前です。

戻り値

Object — 取得したグローバルスタイルの値です。

registerInstance

()

メソッド

public static function registerInstance(instance:UIComponent):void

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

スタイルマネージャーにコンポーネントインスタンスを登録します。コンポーネントインスタンスがインスタンス化された後、そのインスタンスをスタイルマネージャーに登録して、スタイルに変更があったときに通知を受け取ることができます。コンポーネントインスタンスは、コンポーネントベースのスタイル変更、またはグローバルな性質のスタイル変更の通知を受け取るように登録できます。

パラメーター

instance:UIComponent — スタイル管理のために登録されるコンポーネントインスタンスです。

setComponentStyle

()

メソッド

public static function setComponentStyle(component:Object, name:String, style:Object):void

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

例えば Button コンポーネントのすべてのインスタンス、または ComboBox コンポーネントのすべてのインスタンスなど、あるコンポーネントタイプのすべてのインスタンスに対してスタイルを設定します。

パラメーター

	`component:Object` — Button、ComboBox など、コンポーネントのタイプです。このパラメーターはまた、あるコンポーネントタイプのすべてのインスタンスの識別に使用できるコンポーネントのインスタンスまたはクラスも受け入れます。

	`name:String` — 設定するスタイルの名前です。

	`style:Object` — 設定するスタイルを記述するスタイルオブジェクトです。

setStyle

()

メソッド

public static function setStyle(name:String, style:Object):void

言語バージョン:

ActionScript 3.0

製品バージョン:

Flash CS3

ランタイムバージョン:

Flash Player 9.0.28.0, AIR 1.0

ドキュメント内のすべてのユーザーインターフェイスコンポーネントに対し、グローバルスタイルを設定します。

パラメーター

	`name:String` — 設定するスタイルの名前を指定するストリング値です。

	`style:Object` — 設定するスタイルオブジェクトです。このプロパティの値は、ユーザーが設定するスタイルによって異なります。例えば、スタイルが "textFormat" の場合、スタイルプロパティは TextFormat オブジェクトに設定する必要があります。スタイル名とスタイルプロパティの値が不一致の場合、コンポーネントが正しく動作しない可能性があります。

例この例の使用方法

StyleManagerExample.as

この例では、DataGrid を動的に作成し、そのイベントを監視する方法を示します。

例を実行するには、次の手順に従います。

DataGrid、Button、Label、および TextArea コンポーネントをライブラリに追加します。
このコードを FLA ファイルと同じディレクトリに StyleManagerExample.as という名前で保存します。
FLA ファイル内の Document クラスを StyleManagerExample に設定します。

package
{
    import fl.controls.Button;
    import fl.controls.DataGrid;
    import fl.controls.Label;
    import fl.controls.TextArea;
    import fl.core.UIComponent;
    import fl.managers.FocusManager;
    import fl.managers.StyleManager;
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    
    public class StyleManagerExample extends Sprite 
    {
        private var btn:Button;
        private var ta1:TextArea;
        private var ta2:TextArea;
        private var ta3:TextArea;
        private var ta4:TextArea;
        private var description:Label;
        private var dg:DataGrid;
        private var formatForInstance:TextFormat;
        private var formatForGlobal:TextFormat;
        
        private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
        private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
        
        public function StyleManagerExample() {
            setupComponents();
            setupUI();
            setupStyles();
        }
        private function setupUI():void {
            var setInstanceStyleBtn:Button = new Button();
            var clearInstanceStyleBtn:Button = new Button();
            var setClassStyleBtn:Button = new Button();
            var clearClassStyleBtn:Button = new Button();
            var setGlobalStyleBtn:Button = new Button();
            var clearGlobalStyleBtn:Button = new Button();
            
            setInstanceStyleBtn.label = "Set Instance Style";
            clearInstanceStyleBtn.label = "Clear Instance Style";
            setClassStyleBtn.label = "Set Class Style";
            clearClassStyleBtn.label = "Clear Class Style";
            setGlobalStyleBtn.label = "Set Global Style";
            clearGlobalStyleBtn.label = "Clear Global Style";
            setInstanceStyleBtn.focusEnabled = false;
            clearInstanceStyleBtn.focusEnabled = false;
            setClassStyleBtn.focusEnabled = false;
            clearClassStyleBtn.focusEnabled = false;
            setGlobalStyleBtn.focusEnabled = false;
            clearGlobalStyleBtn.focusEnabled = false;
            
            setInstanceStyleBtn.move(10,310);
            clearInstanceStyleBtn.move(10,340);
            setClassStyleBtn.move(140,310);
            clearClassStyleBtn.move(140,340);
            setGlobalStyleBtn.move(270,310);
            clearGlobalStyleBtn.move(270,340);
            setInstanceStyleBtn.setSize(120,24);
            clearInstanceStyleBtn.setSize(120,24);
            setClassStyleBtn.setSize(120,24);
            clearClassStyleBtn.setSize(120,24);
            setGlobalStyleBtn.setSize(120,24);
            clearGlobalStyleBtn.setSize(120,24);
            
            setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
            clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
            setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
            clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
            setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
            clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);

            description = new Label();
            description.move(10, 370);
            description.autoSize = TextFieldAutoSize.LEFT;
            description.text = "";

            addChild(setInstanceStyleBtn);
            addChild(clearInstanceStyleBtn);
            addChild(setClassStyleBtn);
            addChild(clearClassStyleBtn);
            addChild(setGlobalStyleBtn);
            addChild(clearGlobalStyleBtn);
            addChild(description);
        }
        private function setupComponents():void {
            dg = new DataGrid();
            dg.addItem( { Name:"John Alpha",     Number:"555-123-0101" } );
            dg.addItem( { Name:"Mary Bravo",     Number:"555-372-3322" } );
            dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
            dg.addItem( { Name:"Susan Delta",     Number:"555-987-3434" } );        
            dg.move(10,10);
            dg.setSize(200,290);
            dg.columns = ["Name","Number"];
            addChild(dg);
            
            ta1 = new TextArea();
            ta1.move(220,10);
            ta1.setSize(150,140);
            ta1.text = testString;
            ta1.tabEnabled = true;
            addChild(ta1);
            
            ta2 = new TextArea();
            ta2.move(380,10);
            ta2.setSize(150,140);
            ta2.text = testString;
            ta2.tabEnabled = true;
            addChild(ta2);
            
            ta3 = new TextArea();
            ta3.move(220,160);
            ta3.setSize(150,140);
            ta3.text = testString;
            ta3.tabEnabled = true;
            addChild(ta3);
            
            ta4 = new TextArea();
            ta4.move(380,160);
            ta4.setSize(150,140);
            ta4.text = testString;
            ta4.tabEnabled = true;
            addChild(ta4);
        }
        private function setupStyles():void {
            formatForGlobal = new TextFormat();
            formatForGlobal.font = "Georgia";
            formatForGlobal.size = 10;
            formatForInstance = new TextFormat();
            formatForInstance.underline = true;            
        }
        private function setInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.setStyle("textFormat",formatForInstance);    
                description.text = "The TextArea object with focus is now underlined.";            
            }
        }
        private function clearInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.clearStyle("textFormat");
                description.text = "The TextArea object with focus is no longer underlined.";
            }
        }
        private function setClassStyle(e:MouseEvent):void {
            var c:Class = TextArea;
            var styleName:String = "textPadding";
            var value:Number = 10;
            StyleManager.setComponentStyle(c,styleName,value);    
            description.text = "Padding for all TextArea instances is now 10.";
        }
        private function clearClassStyle(e:MouseEvent):void {
            var styleName:String = "textPadding";
            var c:Class = TextArea;
            StyleManager.clearComponentStyle(c,styleName);                    
            description.text = "TextArea padding has been reset to the default.";
        }
        private function setGlobalStyle(e:MouseEvent):void {            
            var styleName:String = "textFormat";
            var value:Object = formatForGlobal;
            StyleManager.setStyle(styleName,value);
            description.text = "All components now use font Georgia size 10.";
        }
        private function clearGlobalStyle(e:MouseEvent):void {
            var styleName:String = "textFormat";
            StyleManager.clearStyle(styleName);    
            description.text = "Font style for all components has been cleared.";
        }
    }
}

法律上の注意 | プライバシーポリシー

StyleManager - AS3 Flash

クラス x

StyleManager

clearComponentStyle

clearStyle

getComponentStyle

getStyle

registerInstance

setComponentStyle

setStyle