| Package | flash.display |
| Classe | public final class JointStyle |
| Héritage | JointStyle  Object |
| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | AIR 1.0, Flash Player 9 |
joints dans la méthode flash.display.Graphics.lineStyle(). Cette méthode prend en charge trois types de pointe : miter, round et bevel, comme indiqué dans l’exemple suivant :
Eléments de l’API associés
Propriétés publiques
Masquer les propriétés publiques héritées
Afficher les propriétés publiques héritées
Méthodes publiques
Constantes publiques
| Constante | Défini par | ||
|---|---|---|---|
| BEVEL : String = "bevel" [statique]
Spécifie des liaisons biseautées dans le paramètre joints de la méthode flash.display.Graphics.lineStyle(). | JointStyle | ||
| MITER : String = "miter" [statique]
Spécifie des liaisons en pointe dans le paramètre joints de la méthode flash.display.Graphics.lineStyle(). | JointStyle | ||
| ROUND : String = "round" [statique]
Spécifie des liaisons rondes dans le paramètre joints de la méthode flash.display.Graphics.lineStyle(). | JointStyle | ||
Détails de la constante
BEVEL | Constante |
public static const BEVEL:String = "bevel"| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | AIR 1.0, Flash Player 9 |
Spécifie des liaisons biseautées dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().
MITER | Constante |
public static const MITER:String = "miter"| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | AIR 1.0, Flash Player 9 |
Spécifie des liaisons en pointe dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().
ROUND | Constante |
public static const ROUND:String = "round"| Version du langage: | ActionScript 3.0 |
| Versions du moteur d’exécution: | AIR 1.0, Flash Player 9 |
Spécifie des liaisons rondes dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().
Exemples Comment utiliser cet exemple
JointStyleExample.as
L’exemple suivant utilise la classe JointStyleExample pour afficher le résultat de trois styles de joints distincts qui sont appliqués à trois ensembles de liaisons de lignes. Pour ce faire, procédez comme suit :
- Les propriétés de chaque ligne sont définies comme suit :
- La longueur de ligne est définie sur 80 pixels.
- La couleur de la bordure est définie sur orange.
- La taille de la bordure est définie sur 30 pixels.
- La couleur de surbrillance est définie sur gris.
- La taille de la surbrillance est définie sur zéro pixels.
- La valeur alpha est définie sur 1, ce qui rend la couleur unie.
- L’index de lissage des pixels est défini sur false (les traits ne sont pas transformés en pixels).
- Le mode de mise à l’échelle de la ligne est défini sur normal. Ce mode porte sur l’épaisseur de la ligne.
- Les extrémités de la bordure et la limite de pointe sont déclarées sans être définies, de façon à appliquer les valeurs par défaut.
- Le constructeur de classe crée trois ensembles de deux segments de ligne connectés. Les segments commencent à x = 0, y = 0 en appelant trois fois la méthode
doDrawCorner()à l’aide des trois styles de liaison (miter, round et bevel). Chacun des trois appels àdoDrawCorner()applique le style liaison et les propriétés énumérées précédemment pour dessiner deux segments de ligne connectés et les lignes de surbrillance correspondantes. Cette opération peut s’exécuter en créant un objet Shape,child, puis exploite les méthodes de la classe Graphics pour définir le style de ligne et dessiner les lignes et les surbrillances. Chaque occurrence dechilds’ajoute à la liste d’affichage et est dessinée rapidement sur la scène. - Les segments de ligne connectés sont redessinés avec la méthode
refreshLayout()à y = 80 pixels et commence à x = 80 pixels, avec une séparation de 25 pixels entre les segments de ligne.
package {
import flash.display.DisplayObject;
import flash.display.Graphics;
import flash.display.JointStyle;
import flash.display.LineScaleMode;
import flash.display.Shape;
import flash.display.Sprite;
public class JointStyleExample extends Sprite {
private var size:uint = 80;
private var borderColor:uint = 0xFFCC00;
private var borderSize:uint = 30;
private var highlightColor:uint = 0x666666;
private var highlightSize:uint = 0;
private var gutter:uint = 25;
private var borderAlpha:uint = 1;
private var borderPixelHinting:Boolean = false;
private var borderScaleMode:String = LineScaleMode.NORMAL;
private var borderCaps:String;
private var borderMiterLimit:uint;
public function JointStyleExample() {
doDrawCorner(JointStyle.MITER);
doDrawCorner(JointStyle.ROUND);
doDrawCorner(JointStyle.BEVEL);
refreshLayout();
}
private function doDrawCorner(jointStyle:String):void {
var halfSize:uint = Math.round(size / 2);
var child:Shape = new Shape();
child.graphics.lineStyle(borderSize,
borderColor,
borderAlpha,
borderPixelHinting,
borderScaleMode,
borderCaps,
jointStyle,
borderMiterLimit);
child.graphics.lineTo(0, 0);
child.graphics.lineTo(size, 0);
child.graphics.lineTo(halfSize, size);
child.graphics.endFill();
child.graphics.moveTo(0, 0);
child.graphics.lineStyle(highlightSize, highlightColor);
child.graphics.lineTo(0, 0);
child.graphics.lineTo(size, 0);
child.graphics.lineTo(halfSize, size);
addChild(child);
}
private function refreshLayout():void {
var ln:uint = numChildren;
var child:DisplayObject;
var lastChild:DisplayObject = getChildAt(0);
lastChild.x = size;
lastChild.y = size;
for (var i:uint = 1; i < ln; i++) {
child = getChildAt(i);
child.x = gutter + lastChild.x + lastChild.width;
child.y = size;
lastChild = child;
}
}
}
}
Tue Jun 12 2018, 09:30 AM Z