| Package | fl.events |
| Classe | public class DataGridEvent |
| Héritage | DataGridEvent  ListEvent Event Object |
| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
-
DataGridEvent.COLUMN_STRETCH: diffusé après le redimensionnement horizontal d’une colonne par l’utilisateur. -
DataGridEvent.HEADER_RELEASE: diffusé après que l’utilisateur ait relâché la souris sur l’en-tête d’une colonne. -
DataGridEvent.ITEM_EDIT_BEGIN: diffusé lorsqu’un élément est prêt à être édité. -
DataGridEvent.ITEM_EDIT_BEGINNING: diffusé dès que l’utilisateur est prêt à éditer un élément ; par exemple, en relâchant le bouton de la souris sur l’élément. -
DataGridEvent.ITEM_EDIT_END: diffusé lorsqu’une session d’édition se termine. -
DataGridEvent.ITEM_FOCUS_IN: diffusé après qu’un élément ait reçu le focus. -
DataGridEvent.ITEM_FOCUS_OUT: diffusé après qu’un élément ait perdu le focus.
Eléments de l’API associés
Propriétés publiques
Masquer les propriétés publiques héritées
Afficher les propriétés publiques héritées| Propriété | Défini par | ||
|---|---|---|---|
 | bubbles : Boolean [lecture seule]
Indique si un événement peut se propager vers le haut (bubbling). | Event | |
| cancelable : Boolean [lecture seule]
Indique si le comportement associé à l’événement peut être évité. | Event | |
| columnIndex : int [lecture seule]
Récupère l’index de la colonne qui contient l’élément associé à cet événement. | ListEvent | |
| constructor : Object
Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet. | Object | |
| currentTarget : Object [lecture seule]
L’objet qui traite activement l’objet Event avec un écouteur d’événements. | Event | |
| dataField : String
Récupère ou définit le nom du champ ou de la propriété des données associées à la colonne. | DataGridEvent | ||
| eventPhase : uint [lecture seule]
Phase actuelle du flux d’événements. | Event | |
| index : int [lecture seule]
Récupère l’index de base zéro de la cellule qui contient la fonction de rendu. | ListEvent | |
| item : Object [lecture seule]
Récupère la donnée qui appartient à la fonction de rendu active. | ListEvent | |
| itemRenderer : Object [lecture seule]
Récupère le rendu de l’élément en cours de modification ou celui de l’en-tête qui reçoit un clic de souris ou est redimensionné. | DataGridEvent | ||
| reason : String [lecture seule]
Récupère le motif de la diffusion de l’événement itemEditEnd. | DataGridEvent | ||
| rowIndex : Object [lecture seule]
Récupère l’index de la ligne qui contient l’élément associé à cet événement. | ListEvent | |
| target : Object [lecture seule]
Cible de l’événement. | Event | |
| type : String [lecture seule]
Type d’événement. | Event | |
Méthodes publiques
| Méthode | Défini par | ||
|---|---|---|---|
DataGridEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, columnIndex:int = -1, rowIndex:int = -1, itemRenderer:Object = null, dataField:String = null, reason:String = null)
Crée un nouvel objet DataGridEvent avec les paramètres spécifiés. | DataGridEvent | ||
[override]
Crée une copie de l’objet DataGridEvent et définit la valeur de chaque propriété de sorte qu’elle corresponde à la valeur d’origine. | DataGridEvent | ||
|
Fonction d’un utilitaire permettant d’implémenter la méthode toString() dans des classes Event ActionScript 3.0 personnalisées. | Event | |
|
Indique si la propriété spécifiée d’un objet est définie. | Object | |
|
Vérifie si la méthode preventDefault() a été appelée pour l’événement. | Event | |
|
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre. | Object | |
|
Annule le comportement par défaut d’un événement si cette opération est possible. | Event | |
|
Indique si la propriété spécifiée existe et est énumérable. | Object | |
|
Définit la disponibilité d’une propriété dynamique pour les opérations en boucle. | Object | |
|
Bloque le traitement des écouteurs d’événement dans le nœud actuel et les suivants dans le flux d’événements. | Event | |
|
Bloque le traitement des écouteurs d’événement dans les nœuds qui suivent le nœud actuel dans le flux d’événements. | Event | |
|
Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur. | Object | |
[override]
Renvoie une chaîne répertoriant toutes les propriétés de l’objet DataGridEvent. | DataGridEvent | ||
|
Renvoie la valeur primitive de l’objet spécifié. | Object | |
Constantes publiques
| Constante | Défini par | ||
|---|---|---|---|
| COLUMN_STRETCH : String = "columnStretch" [statique]
La constante DataGridEvent.COLUMN_STRETCH définit la valeur de la propriété type d’un objet de l’événement columnStretch. | DataGridEvent | ||
| HEADER_RELEASE : String = "headerRelease" [statique]
La constante DataGridEvent.HEADER_RELEASE définit la valeur de la propriété type d’un objet de l’événement headerRelease. | DataGridEvent | ||
| ITEM_EDIT_BEGIN : String = "itemEditBegin" [statique]
La constante DataGridEvent.ITEM__EDIT_BEGIN définit la valeur de la propriété type d’un objet de l’événement itemEditBegin. | DataGridEvent | ||
| ITEM_EDIT_BEGINNING : String = "itemEditBeginning" [statique]
La constante DataGridEvent.ITEM__EDIT_BEGINNING définit la valeur de la propriété type d’un objet de l’événement itemEditBeginning. | DataGridEvent | ||
| ITEM_EDIT_END : String = "itemEditEnd" [statique]
La constante DataGridEvent.ITEM_EDIT_END définit la valeur de la propriété type d’un objet de l’événement itemEditEnd. | DataGridEvent | ||
| ITEM_FOCUS_IN : String = "itemFocusIn" [statique]
La constante DataGridEvent.ITEM_FOCUS_IN définit la valeur de la propriété type d’un objet de l’événement itemFocusIn. | DataGridEvent | ||
| ITEM_FOCUS_OUT : String = "itemFocusOut" [statique]
La constante DataGridEvent.ITEM_FOCUS_OUT définit la valeur de la propriété type d’un objet de l’événement itemFocusOut. | DataGridEvent | ||
Détails de la propriété
dataField | propriété |
dataField:String| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Récupère ou définit le nom du champ ou de la propriété des données associées à la colonne.
Implémentation
public function get dataField():String public function set dataField(value:String):voiditemRenderer | propriété |
itemRenderer:Object [lecture seule] | Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Récupère le rendu de l’élément en cours de modification ou celui de l’en-tête qui reçoit un clic de souris ou est redimensionné.
Implémentation
public function get itemRenderer():Objectreason | propriété |
reason:String [lecture seule] | Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Récupère le motif de la diffusion de l’événement itemEditEnd. Cette propriété n’est valide que pour les événements de type DataGridEvent.ITEM_EDIT_END.
Les valeurs possibles sont définies dans la classe DataGridEventReason.
Implémentation
public function get reason():StringEléments de l’API associés
Détails du constructeur
DataGridEvent | () | Constructeur |
public function DataGridEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, columnIndex:int = -1, rowIndex:int = -1, itemRenderer:Object = null, dataField:String = null, reason:String = null)| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Crée un nouvel objet DataGridEvent avec les paramètres spécifiés.
Paramètrestype:String — Type d’événement ; cette valeur indique l’action qui a déclenché l’événement.
| |
bubbles:Boolean (default = false) | |
cancelable:Boolean (default = false) | |
columnIndex:int (default = -1) | |
rowIndex:int (default = -1) | |
itemRenderer:Object (default = null) | |
dataField:String (default = null) | |
reason:String (default = null)itemEditEnd.
|
Eléments de l’API associés
Détails de la méthode
clone | () | méthode |
override public function clone():Event| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Crée une copie de l’objet DataGridEvent et définit la valeur de chaque propriété de sorte qu’elle corresponde à la valeur d’origine.
Valeur renvoyéeEvent — Nouvel objet DataGridEvent dont les paramètres ont la même valeur que ceux de l’objet d’origine.
|
toString | () | méthode |
override public function toString():String| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
Renvoie une chaîne répertoriant toutes les propriétés de l’objet DataGridEvent. La chaîne est écrite au format suivant :
[ DataGridEvent type= valeur bubbles= valeur cancelable= valeur columnIndex= valeur rowIndex= valeur itemRenderer= valeur dataField= valeur reason= valeur]
String — Chaîne répertoriant toutes les propriétés de l’objet DataGridEvent.
|
Détails de la constante
COLUMN_STRETCH | Constante |
public static const COLUMN_STRETCH:String = "columnStretch"| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
La constante DataGridEvent.COLUMN_STRETCH définit la valeur de la propriété type d’un objet de l’événement columnStretch.
Les propriétés de cet événement sont les suivantes :
| Propriété | Valeur |
|---|---|
bubbles | false |
cancelable | false ; il n’existe aucun comportement par défaut à annuler. |
columnIndex | Index de base zéro de la colonne d’en-tête dans le tableau columns de l’objet DataGrid. |
currentTarget | Objet qui traite activement l’objet de l’événement avec un écouteur d’événement. |
dataField | Nom du champ ou de la propriété des données associées à la colonne de l’élément. |
itemRenderer | Le rendu de l’en-tête de la colonne a été étiré. |
reason | null |
rowIndex | Index de base zéro de l’élément dans le fournisseur de données. |
target | Objet qui a distribué l’événement. La cible n’est pas toujours l’objet écoutant l’événement. Pour accéder à l’objet qui écoute l’événement, utilisez la propriété currentTarget. |
Exemple ( Comment utiliser cet exemple )
L’exemple suivant créé une occurrence du composant DataGrid et écoute son événement
columnStretch :
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);
function columnStretchHandler(event:DataGridEvent):void {
var dg:DataGrid = event.target as DataGrid;
var column:DataGridColumn;
var columnArray:Array = dg.columns;
var dgColWidth:String;
trace("resized column:", event.dataField);
trace("columnIndex:", event.columnIndex);
for each (column in columnArray) {
dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
}
trace("----------");
}
HEADER_RELEASE | Constante |
public static const HEADER_RELEASE:String = "headerRelease"| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
La constante DataGridEvent.HEADER_RELEASE définit la valeur de la propriété type d’un objet de l’événement headerRelease.
Les propriétés de cet événement sont les suivantes :
| Propriété | Valeur |
|---|---|
bubbles | false |
cancelable | false ; il n’existe aucun comportement par défaut à annuler. |
columnIndex | Index de base zéro de la colonne d’en-tête dans le tableau columns de l’objet DataGrid. |
currentTarget | Objet qui traite activement l’objet de l’événement avec un écouteur d’événement. |
dataField | Nom du champ ou de la propriété des données associées à la colonne de l’élément. |
itemRenderer | Rendu d’en-tête sur lequel l’utilisateur a cliqué. |
reason | null |
rowIndex | -1 |
target | Objet qui a distribué l’événement. La cible n’est pas toujours l’objet écoutant l’événement. Pour accéder à l’objet qui écoute l’événement, utilisez la propriété currentTarget. |
Exemple ( Comment utiliser cet exemple )
L’exemple suivant créé une occurrence du composant DataGrid et écoute son événement
headerRelease :
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);
function headerReleaseHandler(event:DataGridEvent):void {
var dg:DataGrid = event.target as DataGrid;
trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
trace("sortIndex:", dg.sortIndex);
trace("sortDescending:", dg.sortDescending);
trace("----------");
}
ITEM_EDIT_BEGIN | Constante |
public static const ITEM_EDIT_BEGIN:String = "itemEditBegin"| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
La constante DataGridEvent.ITEM__EDIT_BEGIN définit la valeur de la propriété type d’un objet de l’événement itemEditBegin.
Les propriétés de cet événement sont les suivantes :
| Propriété | Valeur |
|---|---|
bubbles | false |
cancelable | false ; il n’existe aucun comportement par défaut à annuler. |
columnIndex | Index de base zéro de la colonne d’en-tête dans le tableau columns de l’objet DataGrid. |
currentTarget | Objet qui traite activement l’objet de l’événement avec un écouteur d’événement. |
dataField | null |
itemRenderer | Rendu de l’élément à modifier. |
reason | null |
rowIndex | Index de base zéro de l’élément dans le fournisseur de données. |
target | Objet qui a distribué l’événement. La cible n’est pas toujours l’objet écoutant l’événement. Pour accéder à l’objet qui écoute l’événement, utilisez la propriété currentTarget. |
Eléments de l’API associés
ITEM_EDIT_BEGINNING | Constante |
public static const ITEM_EDIT_BEGINNING:String = "itemEditBeginning"| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
La constante DataGridEvent.ITEM__EDIT_BEGINNING définit la valeur de la propriété type d’un objet de l’événement itemEditBeginning.
Les propriétés de cet événement sont les suivantes :
| Propriété | Valeur |
|---|---|
bubbles | false |
cancelable | false ; il n’existe aucun comportement par défaut à annuler. |
columnIndex | Index de base zéro de la colonne d’en-tête dans le tableau columns de l’objet DataGrid. |
currentTarget | Objet qui traite activement l’objet de l’événement avec un écouteur d’événement. |
dataField | Nom du champ ou de la propriété des données associées à la colonne de l’élément. |
itemRenderer | Rendu de l’élément à modifier. |
reason | null |
rowIndex | Index de base zéro de l’élément dans le fournisseur de données. |
target | Objet qui a distribué l’événement. La cible n’est pas toujours l’objet écoutant l’événement. Pour accéder à l’objet qui écoute l’événement, utilisez la propriété currentTarget. |
Eléments de l’API associés
ITEM_EDIT_END | Constante |
public static const ITEM_EDIT_END:String = "itemEditEnd"| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
La constante DataGridEvent.ITEM_EDIT_END définit la valeur de la propriété type d’un objet de l’événement itemEditEnd.
Les propriétés de cet événement sont les suivantes :
| Propriété | Valeur |
|---|---|
bubbles | false |
cancelable | false ; il n’existe aucun comportement par défaut à annuler. |
columnIndex | Index de base zéro de la colonne d’en-tête dans le tableau columns de l’objet DataGrid. |
currentTarget | Objet qui traite activement l’objet de l’événement avec un écouteur d’événement. |
dataField | Nom du champ ou de la propriété des données associées à la colonne de l’élément. |
itemRenderer | Rendu de l’élément à modifier. |
reason | Constante qui justifie l’événement. La valeur doit être membre de la classe DataGridEventReason. |
rowIndex | Index de base zéro de l’élément dans le fournisseur de données. |
target | Objet qui a distribué l’événement. La cible n’est pas toujours l’objet écoutant l’événement. Pour accéder à l’objet qui écoute l’événement, utilisez la propriété currentTarget. |
Eléments de l’API associés
ITEM_FOCUS_IN | Constante |
public static const ITEM_FOCUS_IN:String = "itemFocusIn"| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
La constante DataGridEvent.ITEM_FOCUS_IN définit la valeur de la propriété type d’un objet de l’événement itemFocusIn.
Les propriétés de cet événement sont les suivantes :
| Propriété | Valeur |
|---|---|
bubbles | false |
cancelable | false ; il n’existe aucun comportement par défaut à annuler. |
columnIndex | Index de base zéro de la colonne d’en-tête dans le tableau columns de l’objet DataGrid. |
currentTarget | Objet qui traite activement l’objet de l’événement avec un écouteur d’événement. |
dataField | null |
itemRenderer | Rendu de l’élément à modifier. |
reason | null |
rowIndex | Index de base zéro de l’élément dans le fournisseur de données. |
target | Objet qui a distribué l’événement. La cible n’est pas toujours l’objet écoutant l’événement. Pour accéder à l’objet qui écoute l’événement, utilisez la propriété currentTarget. |
Eléments de l’API associés
ITEM_FOCUS_OUT | Constante |
public static const ITEM_FOCUS_OUT:String = "itemFocusOut"| Version du langage: | ActionScript 3.0 |
| Version du produit: | Flash CS3 |
| Versions du moteur d’exécution: | Flash Player 9.0.28.0, AIR 1.0 |
La constante DataGridEvent.ITEM_FOCUS_OUT définit la valeur de la propriété type d’un objet de l’événement itemFocusOut.
Les propriétés de cet événement sont les suivantes :
| Propriété | Valeur |
|---|---|
bubbles | false |
cancelable | false ; il n’existe aucun comportement par défaut à annuler. |
columnIndex | Index de base zéro de la colonne d’en-tête dans le tableau columns de l’objet DataGrid. |
currentTarget | Objet qui traite activement l’objet de l’événement avec un écouteur d’événement. |
dataField | null |
itemRenderer | Rendu de l’élément à modifier. |
reason | null |
rowIndex | Index de base zéro de l’élément dans le fournisseur de données. |
target | Objet qui a distribué l’événement. La cible n’est pas toujours l’objet écoutant l’événement. Pour accéder à l’objet qui écoute l’événement, utilisez la propriété currentTarget. |
Eléments de l’API associés
Exemples Comment utiliser cet exemple
DataGridEventExample.as
Cet exemple montre comment répondre aux événements diffusés à partir du DataGrid.
Pour exécuter l’exemple, suivez ces étapes :
- Ajoutez le composant DataGrid dans votre bibliothèque.
- Enregistrez ce code sous le nom DataGridEventExample.as dans le même répertoire que votre fichier FLA.
- Dans le fichier FLA, définissez la classe Document sur DataGridEventExample.
package
{
import fl.controls.DataGrid;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
import fl.events.DataGridEventReason;
import flash.display.Sprite;
public class DataGridEventExample extends Sprite
{
private var dg:DataGrid;
public function DataGridEventExample() {
createDataGrid();
}
private function createDataGrid():void {
dg = new DataGrid();
addChild(dg);
dg.setSize(200,300);
dg.editable = true;
var dp:DataProvider = new DataProvider();
var i:uint;
var totalRows:uint = 42;
for(i=0; i<totalRows; i++) {
dp.addItem( { col1:getRandomNumber(),
col2:getRandomNumber(),
col3:getRandomNumber() } );
}
dg.dataProvider = dp;
dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
}
private function announceEditBegin(e:DataGridEvent):void {
trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);
}
private function announceEditEnd(e:DataGridEvent):void {
var reason:String;
switch(e.reason) {
case DataGridEventReason.CANCELLED:
reason = "User cancelled edit";
break;
case DataGridEventReason.NEW_ROW:
reason = "User focused to another row";
break;
case DataGridEventReason.NEW_COLUMN:
reason = "User focused to another column";
break;
case DataGridEventReason.OTHER:
default:
reason = "Edit ended for other reason";
reason = e.reason;
break;
}
trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
trace("Reason: " + reason.toString());
}
private function getRandomNumber():uint {
return Math.round(Math.random()*100);
}
}
}
Tue Jun 12 2018, 09:30 AM Z