RadioButtonGroup

Package	fl.controls
Classe	public class RadioButtonGroup
Héritage	RadioButtonGroup EventDispatcher Object

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

La classe RadioButtonGroup définit un groupe de composants RadioButton devant se comporter comme un composant unique. Lorsqu’un bouton radio est sélectionné, aucun autre bouton du même groupe ne peut l’être.

Consulter les exemples

Eléments de l’API associés

RadioButton
RadioButton.group

Propriétés publiques

Masquer les propriétés publiques héritées

Afficher les propriétés publiques héritées

	Propriété		Défini par
		constructor : Object Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet.	Object
		name : String [lecture seule] Récupère le nom d’occurrence du bouton radio.	RadioButtonGroup
		numRadioButtons : int [lecture seule] Récupère le nombre de boutons radio de ce groupe de boutons radio.	RadioButtonGroup
		selectedData : Object Récupère ou définit la propriété value du bouton radio sélectionné.	RadioButtonGroup
		selection : RadioButton Récupère ou définit une référence au bouton radio actuellement sélectionné dans le groupe de boutons radio.	RadioButtonGroup

Méthodes publiques

Masquer les méthodes publiques héritées

Afficher les méthodes publiques héritées

	Méthode		Défini par
		RadioButtonGroup(name:String) Crée une nouvelle occurrence RadioButtonGroup.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Enregistre un objet écouteur d’événement auprès d’un objet EventDispatcher afin que l’écouteur soit averti d’un événement.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Ajoute un bouton radio au tableau de boutons radio internes à utiliser avec l’indexation du groupe de boutons radio, afin de permettre la sélection d’un seul bouton radio du groupe.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Distribue un événement dans le flux d’événements.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [statique] Récupère une référence au groupe de boutons radio spécifié.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Récupère le composant RadioButton à l’emplacement d’index spécifié.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Renvoie l’index de l’occurrence de bouton radio spécifiée.	RadioButtonGroup
		hasEventListener(type:String):Boolean Vérifie si des écouteurs sont enregistrés auprès de l’objet EventDispatcher pour un type spécifique d’événement.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indique si la propriété spécifiée d’un objet est définie.	Object
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre.	Object
		propertyIsEnumerable(name:String):Boolean Indique si la propriété spécifiée existe et est énumérable.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Supprime un écouteur de l’objet EventDispatcher.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Supprime l’occurrence de RadioButton de la liste interne des boutons radio.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d’une propriété dynamique pour les opérations en boucle.	Object
		toLocaleString():String Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur.	Object
		toString():String Renvoie la représentation sous forme de chaîne de l’objet spécifié.	Object
		valueOf():Object Renvoie la valeur primitive de l’objet spécifié.	Object
		willTrigger(type:String):Boolean Vérifie si un écouteur d’événement est enregistré auprès de cet objet EventDispatcher ou de ses ancêtres pour le type d’événement spécifié.	EventDispatcher

Evénements

Cliquez pour plus d’informations sur les événements

Masquer les événements hérités

Afficher les événements hérités

	Synthèse	Défini par
activate	[Evénement de diffusion] Distribué lorsque l’application Flash Player obtient le focus du système d’exploitation et devient active.	EventDispatcher
change	Distribué lors du changement de l’occurrence RadioButton qui est sélectionnée dans un groupe.	RadioButtonGroup
click	Distribué lorsque l’utilisateur clique sur une occurrence de RadioButton.	RadioButtonGroup
deactivate	[Evénement de diffusion] Distribué lorsque l’application Flash Player ou AIR perd le focus du système d’exploitation et devient inactive.	EventDispatcher

Détails de la propriété

name

propriété

name:String [lecture seule]

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Récupère le nom d’occurrence du bouton radio.

La valeur par défaut est "RadioButtonGroup".

Implémentation
public function get name():String

numRadioButtons

propriété

numRadioButtons:int [lecture seule]

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Récupère le nombre de boutons radio de ce groupe de boutons radio.

La valeur par défaut est 0.

Implémentation
public function get numRadioButtons():int

selectedData

propriété

selectedData:Object

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Récupère ou définit la propriété value du bouton radio sélectionné. Si aucun bouton radio n’est sélectionné, cette propriété est null.

Implémentation
public function get selectedData():Object
public function set selectedData(value:Object):void

Exemple ( Comment utiliser cet exemple )

L’exemple suivant créé une occurrence du composant RadioButtonGroup et écoute son événement change :

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

propriété

selection:RadioButton

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Récupère ou définit une référence au bouton radio actuellement sélectionné dans le groupe de boutons radio.

Implémentation
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Exemple ( Comment utiliser cet exemple )

L’exemple suivant crée un nouveau groupe de deux boutons radio. Lorsque le bouton radio actuellement sélectionné change, l’étiquette et la valeur du bouton radio sélectionné sont recherchées :

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Détails du constructeur

()

Constructeur

public function RadioButtonGroup(name:String)

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Crée une nouvelle occurrence RadioButtonGroup. Cette opération est généralement effectuée automatiquement lorsque vous créez une occurrence de bouton radio.

Paramètres

name:String — Nom du groupe de boutons radio.

Détails de la méthode

addRadioButton

()

méthode

public function addRadioButton(radioButton:RadioButton):void

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Ajoute un bouton radio au tableau de boutons radio internes à utiliser avec l’indexation du groupe de boutons radio, afin de permettre la sélection d’un seul bouton radio du groupe. Cette méthode est utilisée de façon automatique par les boutons radio, mais peut être utilisée de façon manuelle pour ajouter un bouton radio à un groupe de façon explicite.

Paramètres

radioButton:RadioButton — Occurrence de RadioButton à ajouter au groupe de boutons radio actuel.

getGroup

()

méthode

public static function getGroup(name:String):RadioButtonGroup

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Récupère une référence au groupe de boutons radio spécifié.

Paramètres

name:String — Nom du groupe pour lequel une référence doit être récupérée.

Valeur renvoyée

RadioButtonGroup — Référence au RadioButtonGroup spécifié.

Exemple ( Comment utiliser cet exemple )

L’exemple suivant montre comment identifier le bouton radio sélectionné dans un groupe :

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

méthode

public function getRadioButtonAt(index:int):RadioButton

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Récupère le composant RadioButton à l’emplacement d’index spécifié.

Paramètres

index:int — Index du composant RadioButton dans le composant RadioButtonGroup, l’index du premier composant étant 0.

Valeur renvoyée

RadioButton — Composant RadioButton spécifié.

Valeur émise

RangeError — L’index spécifié est inférieur à 0 ou supérieur ou égal à la longueur du fournisseur de données.

getRadioButtonIndex

()

méthode

public function getRadioButtonIndex(radioButton:RadioButton):int

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Renvoie l’index de l’occurrence de bouton radio spécifiée.

Paramètres

radioButton:RadioButton — Occurrence de RadioButton à localiser dans le RadioButtonGroup actuel.

Valeur renvoyée

int — Index du composant RadioButton spécifié, ou -1 si le contrôle RadioButton spécifié est introuvable.

removeRadioButton

()

méthode

public function removeRadioButton(radioButton:RadioButton):void

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Supprime l’occurrence de RadioButton de la liste interne des boutons radio.

Paramètres

radioButton:RadioButton — Occurrence de RadioButton à supprimer.

Détails de l’événement

change

Evénement

Type d’objet d’événement: flash.events.Event
propriété Event.type = flash.events.Event.CHANGE

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Distribué lors du changement de l’occurrence RadioButton qui est sélectionnée dans un groupe.

La constante Event.CHANGE définit la valeur de la propriété type de l’objet d’événement change.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`true`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet dont la valeur a été modifiée. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d’événement. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d’affichage qui traite actuellement l’événement.

Exemple ( Comment utiliser cet exemple )

L’exemple suivant crée trois boutons radio et ajoute un écouteur de l’événement change pour ce groupe de boutons radio :

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Evénement

Type d’objet d’événement: flash.events.MouseEvent
propriété MouseEvent.type = flash.events.MouseEvent.CLICK

Version du langage:

ActionScript 3.0

Version du produit:

Flash CS3

Versions du moteur d’exécution:

Flash Player 9.0.28.0, AIR 1.0

Distribué lorsque l’utilisateur clique sur une occurrence de RadioButton.

Définit la valeur de la propriété type d’un objet d’événement click.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`altKey`	`true` si la touche Alt est activée (Windows).
`bubbles`	`true`
`buttonDown`	Pour les événements de clic, cette valeur est toujours définie sur `false`.
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`commandKey`	`true` sur le Mac si la touche Commande est activée ; `false` si elle est désactivée. Toujours `false` sur Windows.
`controlKey`	`true` si la touche Ctrl ou Contrôle est activée ; `false` si elle est désactivée.
`ctrlKey`	`true` sous Windows ou Linux si la touche Ctrl est enfoncée. `true` sur Mac si la touche Ctrl ou la touche Commande est activée. Sinon, la valeur `false` est renvoyée.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`localX`	Coordonnée horizontale à laquelle l’événement s’est produit, par rapport au sprite conteneur, si le verrouillage de la souris est désactivé.
`localY`	Coordonnée verticale à laquelle l’événement s’est produit, par rapport au sprite conteneur, si le verrouillage de la souris est désactivé.
`movementX`	Changement de coordonnées horizontales de la position de la souris depuis le dernier événement de souris, si le verrouillage de la souris est activé.
`movementY`	Changement de coordonnées verticales de la position de la souris depuis le dernier événement de souris, si le verrouillage de la souris est activé.
`shiftKey`	`true` si la touche Maj est activée ; `false` si elle ne l’est pas.
`stageX`	Coordonnée horizontale à laquelle l’événement s’est produit, par rapport aux coordonnées globales de la scène.
`stageY`	Coordonnée verticale à laquelle l’événement s’est produit, par rapport aux coordonnées globales de la scène.
`target`	Occurrence d’InteractiveObject sous le périphérique de pointage. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d’événement. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d’affichage qui traite actuellement l’événement.

Exemples Comment utiliser cet exemple

RadioButtonGroupExample.as

Cet exemple montre comment gérer de nombreux objets RadioButton dans plusieurs groupes.

Ajoutez les composants RadioButton et Label à votre bibliothèque.
Enregistrez ce code sous le nom RadioButtonGroupExample.as dans le même répertoire que votre fichier FLA.
Dans le fichier FLA, définissez DocumentClass sur RadioButtonGroupExample.

package
{
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import fl.controls.Label;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Informations juridiques | Politique de confidentialité en ligne

RadioButtonGroup - AS3 Flash

Packagesx

Eléments du langage

Annexes

Package fl.controls

name

numRadioButtons

selectedData

selection