TextConverter - Referencia de la API de Adobe ActionScript® 3 (AS3 )

Paquete	flashx.textLayout.conversion
Clase	public class TextConverter
Herencia	TextConverter Object

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Ésta es la clase de puerta de enlace que la importación y la exportación. Sirve de punto de acceso unificado para la funcionalidad de conversión en Text Layout Framework. Contiene un registro de convertidores de salida y entrada predefinidos, así como definidos por el usuario, además de un conjunto de métodos de conversión.

El formato de los datos convertidos no es predefinido; los convertidores del usuario son libres de aceptar y devolver cualquier formato de su elección. Los formatos comunes son cadenas, XML e instancias de ByteArray. Los creadores del convertidor deben documentar qué formatos son compatibles.

Ver los ejemplos

Más ejemplos

Creating a TextFlow object with the TextConverter class

Propiedades públicas

Ocultar propiedades públicas heredadas

Mostrar propiedades públicas heredadas

	Propiedad		Definido por
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		numFormats : int [estática] [solo lectura] Número de formatos.	TextConverter

Métodos públicos

Ocultar métodos públicos heredados

Mostrar métodos públicos heredados

	Método		Definido por
		addFormat(format:String, importerClass:Class, exporterClass:Class, clipboardFormat:String):void [estática] Registre un nuevo formato para la importación/exportación.	TextConverter
		addFormatAt(index:int, format:String, importerClass:Class, exporterClass:Class = null, clipboardFormat:String = null):void [estática] Registre un nuevo formato para la importación/exportación en la ubicación especificada.	TextConverter
		export(source:flashx.textLayout.elements:TextFlow, format:String, conversionType:String):Object [estática] Exporta un objeto TextFlow a un formato especificado.	TextConverter
		getExporter(format:String):flashx.textLayout.conversion:ITextExporter [estática] Crea y devuelve un conversor de exportación que, posteriormente, se puede para exportar desde un objeto TextFlow a una cadena de origen o a un objeto XML.	TextConverter
		getFormatAt(index:int):String [estática] Devuelve el nombre de formato para el formato del enésimo índice.	TextConverter
		getFormatDescriptorAt(index:int):FormatDescriptor [estática] Devuelve FormatDescriptor para el formato del enésimo índice.	TextConverter
		getImporter(format:String, config:IConfiguration = null):flashx.textLayout.conversion:ITextImporter [estática] Crea y devuelve un convertidor de importación, que se puede utilizar para importar desde una cadena de origen, un objeto XML o cualquier formatos de datos definido por el usuario a un objeto TextFlow.	TextConverter
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		importToFlow(source:Object, format:String, config:IConfiguration = null):flashx.textLayout.elements:TextFlow [estática] Crea un objeto TextFlow desde el contenido de origen en un formato especificado.	TextConverter
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		removeFormat(format:String):void [estática] Elimina el formato.	TextConverter
		removeFormatAt(index:int):void [estática] Elimina el formato en la ubicación de índice.	TextConverter
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		toLocaleString():String Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional.	Object
		toString():String Devuelve la representación de cadena del objeto especificado.	Object
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object

Constantes públicas

	Constante		Definido por
		PLAIN_TEXT_FORMAT : String = "plainTextFormat" [estática] Formato de texto normal.	TextConverter
		TEXT_FIELD_HTML_FORMAT : String = "textFieldHTMLFormat" [estática] Formato HTML.	TextConverter
		TEXT_LAYOUT_FORMAT : String = "textLayoutFormat" [estática] Formato TextLayout.	TextConverter

Información sobre propiedades

numFormats

propiedad

numFormats:int [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Número de formatos.

Implementación
public static function get numFormats():int

Información sobre métodos

addFormat

()

método

public static function addFormat(format:String, importerClass:Class, exporterClass:Class, clipboardFormat:String):void

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Registre un nuevo formato para la importación/exportación. El nuevo formato se añadirá al final, como la prioridad más baja. La ubicación puede ser importante para los clientes que tienen múltiples opciones sobre el formato que utilizar, como al importar desde un portapapeles externo. El nuevo formato puede admitir importación y/o exportación. Si el formato ya se ha añadido, a continuación, estará presente en varias ubicaciones. Se utilizará el primero encontrado.

Parámetros

	`format:String` — La clase de convertidor de importación para registrar o null

	`importerClass:Class` — La clase de convertidor de importación para registrar o null

	`exporterClass:Class` — La cadena de formato que etiqueta las clases del convertidor. Los formatos se pueden tener cualquier nombre, pero debe ser exclusivo.

	`clipboardFormat:String` — La cadena utilizada como el formato del portapapeles al convertir a/desde el portapapeles. Asigne el valor null si el formato no admite acceso al portapapeles.

addFormatAt

()

método

 public static function addFormatAt(index:int, format:String, importerClass:Class, exporterClass:Class = null, clipboardFormat:String = null):void

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Registre un nuevo formato para la importación/exportación en la ubicación especificada. La ubicación puede ser importante para los clientes que tienen múltiples opciones sobre el formato que utilizar, como al importar desde un portapapeles externo. Números más pequeños indican una mayor prioridad; estos convertidores se utilizarán primero. El nuevo formato puede admitir importación y/o exportación. Si el formato ya se ha añadido, a continuación, estará presente en varias ubicaciones. Se utilizará el primero encontrado.

Parámetros

	`index:int` — La clase de convertidor de importación para registrar o null

	`format:String` — La clase de convertidor de importación para registrar o null

	`importerClass:Class` — La cadena de formato que etiqueta las clases del convertidor

	`exporterClass:Class` (default = `null`) — La cadena utilizada como el formato del portapapeles al convertir a/desde el portapapeles. Asigne el valor null si el formato no admite acceso al portapapeles.

	`clipboardFormat:String` (default = `null`)

export

()

método

public static function export(source:flashx.textLayout.elements:TextFlow, format:String, conversionType:String):Object

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Exporta un objeto TextFlow a un formato especificado.

Utilice una de las constantes estáticas suministradas con esta clase, un tipo MIME, o un formato definido por el usuario para que los exportadores definidos por el usuario especifiquen el parámetro format:

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

Especifique el tipo de los datos exportados en el parámetro conversionType con una de las constantes estáticas suministradas por la clase ConversionType o un tipo de datos definido por el usuario para exportadores definidos por el usuario:

ConversionType.STRING_TYPE
ConversionType.XML_TYPE

Devuelve una representación del objeto TextFlow en el formato especificado, o null si hay error.

Parámetros

	`source:flashx.textLayout.elements:TextFlow` — Contenido de origen

	`format:String` — Formato de salida

	`conversionType:String` — Tipo de datos exportados

Valor devuelto

Object — Objeto exportado desde el objeto TextFlow, o null si hay errores

Elementos de API relacionados

TEXT_FIELD_HTML_FORMAT
PLAIN_TEXT_FORMAT
TEXT_LAYOUT_FORMAT
flashx.textLayout.conversion.ConversionType

getExporter

()

método

public static function getExporter(format:String):flashx.textLayout.conversion:ITextExporter

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Crea y devuelve un conversor de exportación que, posteriormente, se puede para exportar desde un objeto TextFlow a una cadena de origen o a un objeto XML. Utilice esta función si necesita realizar varias exportaciones por separado. Equivale a llamar a flashx.textLayout.conversion.TextConverter.export().

Utilice una de las constantes estáticas suministradas con esta clase para especificar el parámetro format:

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

Si el formato se ha añadido varias veces, se utilizará el primero encontrado.

Parámetros

format:String — Formato de destino de los datos exportados

Valor devuelto

flashx.textLayout.conversion:ITextExporter — Exportador de texto de ITextExporter que puede exportar en el formato especificado

Elementos de API relacionados

TEXT_FIELD_HTML_FORMAT
PLAIN_TEXT_FORMAT
TEXT_LAYOUT_FORMAT

Ejemplo ( Cómo utilizar este ejemplo )

Este fragmento de código muestra un uso del método getExporter para llevar a cabo exportaciones repetidas de texto con formato.


package flashx.textLayout.conversion.examples
{
    import flashx.textLayout.conversion.ConversionType;
    import flashx.textLayout.conversion.ITextExporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;
    
    public class getExporter_example 
    {
        // Serialize the TextFlow into a String
        public function export(textFlow:TextFlow):String
        {
            var exporter:ITextExporter = TextConverter.getExporter(TextConverter.TEXT_LAYOUT_FORMAT);
            return exporter.export(textFlow, ConversionType.STRING_TYPE) as String;
        }
    }
}

getFormatAt

()

método

public static function getFormatAt(index:int):String

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Devuelve el nombre de formato para el formato del enésimo índice.

Parámetros

index:int

Valor devuelto

String

getFormatDescriptorAt

()

método

public static function getFormatDescriptorAt(index:int):FormatDescriptor

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Devuelve FormatDescriptor para el formato del enésimo índice.

Parámetros

index:int

Valor devuelto

FormatDescriptor

getImporter

()

método

 public static function getImporter(format:String, config:IConfiguration = null):flashx.textLayout.conversion:ITextImporter

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Crea y devuelve un convertidor de importación, que se puede utilizar para importar desde una cadena de origen, un objeto XML o cualquier formatos de datos definido por el usuario a un objeto TextFlow. Utilice este método si necesita realizar varias importaciones o si quiere gestionar los errores durante la importación. equivale a llamar a flashx.textLayout.conversion.TextConverter.importToFlow().

Utilice una de las constantes estáticas suministradas con esta clase para especificar el parámetro format, un tipo MIME o un formato de datos definido por el usuario.

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

Si el formato se ha añadido varias veces, se utilizará el primero encontrado.

Parámetros

	`format:String` — Formato del contenido de origen. Utilice constantes de flashx.textLayout.conversion.TextConverter.TEXT_LAYOUT_FORMAT, PLAIN_TEXT_FORMAT, TEXT_FIELD_HTML_FORMAT etc, un tipo MIME type o un formato definido por el usuario.

	`config:IConfiguration` (default = `null`) — configuración que se debe usar durante esta importación. null indica que se utilizarán los valores predeterminados actuales. También puede establecer la configuración a través de la propiedad `ITextImporter.configuration`.

Valor devuelto

flashx.textLayout.conversion:ITextImporter — Importador de texto de ITextImporter que puede importar los datos de origen

Elementos de API relacionados

TEXT_FIELD_HTML_FORMAT
PLAIN_TEXT_FORMAT
TEXT_LAYOUT_FORMAT

Ejemplo ( Cómo utilizar este ejemplo )

Este fragmento de código muestra un uso del método getImporter para llevar a cabo importaciones repetidas de texto con formato. Tenga en cuenta que los errores se borran al comenzar cada nueva llamada a importToFlow.


package flashx.textLayout.conversion.examples
{
    import flashx.textLayout.conversion.ITextImporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;
    
    public class getImporter_example 
    {
        public function importAndCheckErrors():TextFlow
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'><p><span>Hello, World</span></p></TextFlow>";
            var importer:ITextImporter = TextConverter.getImporter(TextConverter.TEXT_LAYOUT_FORMAT);
            importer.throwOnError = false;
            var textFlow:TextFlow = importer.importToFlow(markup);
            if (!textFlow)
            {
                var errors:Vector.<String> = importer.errors;
                //deal with import errors
            }
            return textFlow;
        }
    }
}

importToFlow

()

método

 public static function importToFlow(source:Object, format:String, config:IConfiguration = null):flashx.textLayout.elements:TextFlow

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Crea un objeto TextFlow desde el contenido de origen en un formato especificado.

Utilice una de las constantes estáticas suministradas con esta clase, un tipo MIME, para especificar el parámetro format o para utilizar un valor definido por el usuario para importadores registrados por usuarios:

TextConverter.TEXT_FIELD_HTML_FORMAT
TextConverter.PLAIN_TEXT_FORMAT
TextConverter.TEXT_LAYOUT_FORMAT

Parámetros

	`source:Object` — Contenido de origen

	`format:String` — Formato del contenido de origen

	`config:IConfiguration` (default = `null`) — Configuración que debe usarse al crear nuevos objetos TextFlow

Valor devuelto

flashx.textLayout.elements:TextFlow — Objeto TextFlow creado desde el origen, o null si hay error.

Elementos de API relacionados

TEXT_FIELD_HTML_FORMAT
PLAIN_TEXT_FORMAT
TEXT_LAYOUT_FORMAT

removeFormat

()

método

public static function removeFormat(format:String):void

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Elimina el formato. Si un formato se ha añadido varias veces, solo se eliminará la primera instancia encontrada.

Parámetros

format:String — La cadena en formato de convertidor para eliminar

removeFormatAt

()

método

public static function removeFormatAt(index:int):void

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Elimina el formato en la ubicación de índice.

Parámetros

index:int — Formato que se va a eliminar

Información sobre constantes

PLAIN_TEXT_FORMAT

Constante

public static const PLAIN_TEXT_FORMAT:String = "plainTextFormat"

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Formato de texto normal. Utilice esto para crear un objeto TextFlow a partir de una cadena sencilla y sin formato o para crear una cadena sencilla y sin formato a partir de un objeto TextFlow.

TEXT_FIELD_HTML_FORMAT

Constante

public static const TEXT_FIELD_HTML_FORMAT:String = "textFieldHTMLFormat"

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Formato HTML. Utilice esto para importar o exportar desde y a un objeto TextFlow con formato HTML. El HTML de Text Layout Framework admite un subconjunto de etiquetas y atributos admitidos por la clase TextField en el paquete flash.text.

La siguiente tabla muestra los atributos y etiquetas HTML compatibles con el proceso de importación y exportación (las etiquetas y atributos admitidos por TextField, pero no admitidos por Text Layout Framework se describen específicamente como no admitidas):

Etiqueta	Descripción
Etiqueta de anclaje	La etiqueta `<a>` crea un vínculo de hipertexto y admite los atributos siguientes: `target`: Especifica el nombre de la ventana de destino en la que se cargará la página. Entre las opciones posibles, se incluye `_self`, `_blank`, `_parent` y `_top`. La opción `_self` especifica el marco actual de la ventana actual, `_blank` especifica una ventana nueva, `_parent` especifica el nivel superior del marco actual y `_top` especifica el marco del nivel más alto de la ventana actual. `href`: especifica una URL. La URL puede ser absoluta o relativa a la ubicación del archivo SWF que carga la página. Un ejemplo de referencia absoluta a una URL es `http://www.adobe.com`; un ejemplo de referencia relativa es `/index.html`. Las URL absolutas deben llevar el prefijo http://, ya que, en caso contrario, Flash las considera URL relativas. Nota: al contrario de lo que ocurre con la clase TextField, los eventos link `de ActionScript` no son compatibles. Tampoco lo son los estilos `a:link`, `a:hover` y `a:active`.
Etiqueta de negrita	La etiqueta `<b>` muestra el texto en negrita. Debe haber un tipo de letra en negrita disponible para la fuente utilizada.
Etiqueta de salto de línea	La etiqueta `<br>` crea un salto de línea en el texto.
Etiqueta de fuente	La etiqueta `<font>` especifica una fuente o una lista de fuentes para mostrar el texto. La etiqueta de fuente admite los atributos siguientes: `color`: sólo se admiten valores de color hexadecimales (`#FFFFFF`). `face`: especifica el nombre de la fuente que se utiliza. Como se muestra en el siguiente ejemplo, puede especificar una lista de nombres de fuentes separados por comas, en cuyo caso Flash Player selecciona la primera fuente disponible. Si la fuente especificada no está instalada en el sistema local o no está incorporada al archivo SWF, Flash Player elegirá una fuente alternativa. `size`: especifica el tamaño de la fuente. Se pueden utilizar tamaños en píxeles absolutos, como 16 ó 18, o bien, tamaños en puntos relativos, como +2 ó -4. `letterspacing`: especifica el espaciado entre letras (kerning manual) en píxeles que se va a aplicar a la derecha de cada carácter. `kerning`: especifica si el ajuste entre caracteres está activado o desactivado. Un valor distinto de cero activa el kerning, mientras que cero lo desactiva.
Etiqueta de imagen	La etiqueta `<img>` permite incorporar archivos de imagen externos (JPEG, GIF, PNG), archivos SWF y clips de película dentro del texto. La etiqueta `<img>` admite los atributos siguientes: `src`: especifica la URL de un archivo de imagen o SWF o el identificador de vínculo de un símbolo de clip de película de la biblioteca. Este atributo es necesario; todos los demás son opcionales. Los archivos externos (JPEG, GIF, PNG y SWF) no se muestran hasta que no se han descargado completamente. `width`: anchura, en píxeles, de la imagen, el archivo SWF o el clip de película que se va a insertar. `height`: altura, en píxeles, de la imagen, el archivo SWF o el clip de película que se va a insertar. Nota: a diferencia de lo que ocurre con la clase TextField, no se admiten los siguientes atributos: `align`, `hspace`, `vspace`, `id` y `checkPolicyFile`.
Etiqueta de cursiva	La etiqueta `<i>` muestra el texto encerrado en cursiva. Debe haber un tipo de letra en cursiva disponible para la fuente utilizada.
Etiqueta de elemento de lista	Nota: a diferencia de la clase TextField, la etiqueta de elemento List no se admite.
Etiqueta de párrafo	La etiqueta `<p>` crea un párrafo nuevo. La etiqueta `<p>` admite los siguientes atributos: align: especifica la alineación del texto en el párrafo; los valores válidos son `left`, `right`, `justify` y`center`. class: especifica un nombre de clase que puede utilizarse para un estilo
Etiqueta de espacio	La etiqueta `<span>` admite los atributos siguientes: class: especifica un nombre de clase que puede utilizarse para un estilo. Mientras que las etiquetas span a menudo se utilizan para definir un estilo definido en una hoja de estilos, las instancias de TLFTextField no admiten hojas de estilos. La etiqueta span está disponible en instancias de TLFTextField para hacer referencia a una clase con las propiedades de estilos. También puede insertar propiedades directamente en la etiqueta span: `<span fontFamily="Arial">Hola</span>`. Sin embargo, no se admiten las etiquetas span anidadas.
Etiqueta de formato de texto	La etiqueta `<textformat>` permite utilizar un subconjunto de las propiedades de formato de párrafo de la clase TextFormat en los campos de texto, incluidos el interlineado, la sangría, los márgenes y las tabulaciones. Puede combinar las etiquetas `<textformat>` con las etiquetas HTML incorporadas. La etiqueta `<textformat>` tiene los atributos siguientes: `indent`: especifica la sangría desde el margen izquierdo hasta el primer carácter del párrafo; corresponde a `TextFormat.indent`. Acepta números positivos y negativos. `blockindent`: especifica la sangría que se aplica a todas las líneas del párrafo. `leftmargin`: especifica el margen izquierdo del párrafo, expresado en puntos; corresponde a `TextFormat.leftMargin`. `rightmargin`: especifica el margen izquierdo del párrafo, expresado en puntos; corresponde a `TextFormat.rightMargin`. `leading`: especifica el interlineado (altura) medido en píxeles entre el valor ascendente de una línea y el valor descendente de la línea anterior `tabstops`: especifica una lista de posiciones de tabulación separada por comas para el párrafo.
Etiqueta de subrayado	La etiqueta `<u>` subraya el texto encerrado.

Cuando se importa una etiqueta desconocida, el importador textFieldHTMLFormat define una sola propiedad typeName del objeto FlowElement a dicho nombre de etiqueta o crea un elemento DivElement o un elemento SubParagraphGroupElement con su propiedad typeName establecida en el nombre de la etiqueta.

El exportador textFieldHTMLFormat exporta typeName como etiqueta XML cuando es distinto del predeterminado.

Elementos de API relacionados

flashx.textLayout.elements.FlowElement.typeName

TEXT_LAYOUT_FORMAT

Constante

public static const TEXT_LAYOUT_FORMAT:String = "textLayoutFormat"

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Formato TextLayout. Utilice esto para importar o exportar desde y a un objeto TextFlow utilizando el formato de marcado TextLayout. El formato TextLayout detectará los errores siguientes:

Espacios de nombres inesperados
Elementos desconocidos
Atributos desconocidos

Ejemplos Cómo utilizar este ejemplo

TextConverter_example.as

Este ejemplo muestra un uso de la clase de conversión TextConverter. El texto en formato de marcado estándar se importa a un objeto TextFlow y, seguidamente, se visualiza. Luego el texto se exporta en formato XML.

package flashx.textLayout.conversion.examples 
{
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.conversion.ConversionType;

    public class TextConverter_example extends Sprite
    {
        public function TextConverter_example()
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'><p><span>Hello, World</span></p></TextFlow>";
            var textFlow:TextFlow = TextConverter.importToFlow(markup, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this, 200, 50));
            textFlow.flowComposer.updateAllControllers();
            //export to XML
            var xmlOut:XML = TextConverter.export(textFlow,TextConverter.TEXT_LAYOUT_FORMAT, ConversionType.XML_TYPE) as XML;
        }
    }
}

Avisos legales | Política de privacidad en línea

TextConverter - AS3

Clases x

numFormats

addFormat

addFormatAt

export

getExporter

getFormatAt

getFormatDescriptorAt

getImporter

importToFlow

removeFormat

removeFormatAt

PLAIN_TEXT_FORMAT

TEXT_FIELD_HTML_FORMAT

TEXT_LAYOUT_FORMAT