| Paquete | flash.ui |
| Clase | public final class MouseCursorData |
| Herencia | MouseCursorData  Object |
| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.2, AIR 2.6 |
Para mostrar el cursor, utilice la función Mouse.registerCursor(). Para devolver el control de la imagen del cursor al sistema operativo, llame a Mouse.unregisterCursor(). Llame a Mouse.supportsNativeCursor para comprobar si los cursores nativos se admiten en el ordenador actual.
El tamaño máximo del cursor es 32x32 píxeles. Se admite la transparencia en la mayoría de los sistemas operativos.
Un cursor de ratón nativo se implementa directamente a través del mecanismo de cursores del sistema operativo y es un medio más eficiente para visualizar una imagen de cursor personalizado que mediante un objeto de visualización. Puede animar el cursor proporcionando más de una imagen en la propiedad data y estableciendo la velocidad de fotogramas.
El cursor sólo se muestra dentro de los límites del escenario. Fuera del escenario, el control de la imagen del cursor vuelve al sistema operativo
Más información
Elementos de API relacionados
Ocultar propiedades públicas heredadas
Mostrar propiedades públicas heredadas| Propiedad | Definido por | ||
|---|---|---|---|
 | constructor : Object
Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada. | Object | |
| data : Vector.<BitmapData>
Un vector de objetos BitmapData que contiene la imagen del cursor o imágenes. | MouseCursorData | ||
| frameRate : Number
La velocidad de fotogramas para animar el cursor. | MouseCursorData | ||
| hotSpot : Point
El punto interactivo del cursor en píxeles. | MouseCursorData | ||
| Método | Definido por | ||
|---|---|---|---|
Crea un objeto MouseCursorData. | MouseCursorData | ||
|
Indica si un objeto tiene definida una propiedad especificada. | Object | |
|
Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro. | Object | |
|
Indica si existe la propiedad especificada y si es enumerable. | Object | |
|
Establece la disponibilidad de una propiedad dinámica para operaciones de bucle. | Object | |
|
Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional. | Object | |
|
Devuelve la representación de cadena del objeto especificado. | Object | |
|
Devuelve el valor simple del objeto especificado. | Object | |
data | propiedad |
data:Vector.<BitmapData>| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.2, AIR 2.6 |
Un vector de objetos BitmapData que contiene la imagen del cursor o imágenes.
Proporcione más de una imagen y establezca la propiedad framerate para animar el cursor.
El tamaño máximo del cursor es 32x32 píxeles.
Implementación
public function get data():Vector.<BitmapData> public function set data(value:Vector.<BitmapData>):voidframeRate | propiedad |
frameRate:Number| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.2, AIR 2.6 |
La velocidad de fotogramas para animar el cursor.
Proporcione más de una imagen en la propiedad data y establezca la velocidad de fotogramas en un valor mayor que 0 para animar el cursor. La velocidad de fotogramas del cursor puede no coincidir con la velocidad de fotogramas actual del SWF.
Implementación
public function get frameRate():Number public function set frameRate(value:Number):voidhotSpot | propiedad |
hotSpot:Point| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.2, AIR 2.6 |
El punto interactivo del cursor en píxeles.
El punto interactivo es el punto del cursor donde se registran los clics del ratón. De forma predeterminada, el punto interactivo es la esquina superior izquierda (0,0).
Implementación
public function get hotSpot():Point public function set hotSpot(value:Point):voidMouseCursorData | () | Información sobre |
public function MouseCursorData()| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | Flash Player 10.2, AIR 2.6 |
Crea un objeto MouseCursorData.
Para mostrar el cursor, llame a la función Mouse.registerCursor().
Elementos de API relacionados
En el ejemplo se utilizan los comandos de dibujo disponibles a través de la clase Graphics para crear ocho imágenes giradas de una flecha. Estas imágenes se insertan en un vector y se asigna a la propiedad data del objeto MouseCursorData. (Tenga en cuenta que también puede utilizar imágenes preprocesadas de mapa de bits para su cursores.)
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.GraphicsPath;
import flash.ui.MouseCursorData;
import flash.ui.Mouse;
import flash.geom.Matrix;
public class MouseCursorDataExample extends Sprite {
//Graphics path data for an arrow
private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
public function MouseCursorDataExample() {
var mouseCursorData:MouseCursorData = new MouseCursorData();
mouseCursorData.data = makeCursorImages();
mouseCursorData.frameRate = 1;
Mouse.registerCursor( "spinningArrow", mouseCursorData );
Mouse.cursor = "spinningArrow";
}
//Returns a Vector containing 8 cursor images
private function makeCursorImages():Vector.<BitmapData>
{
var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
var cursorShape:Shape = new Shape();
cursorShape.graphics.beginFill( 0xff5555, .75 );
cursorShape.graphics.lineStyle( 1 );
cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
cursorShape.graphics.endFill();
var transformer:Matrix = new Matrix();
//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames
for( var i:int = 0; i < 8; i++ )
{
var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
cursorFrame.draw( cursorShape, transformer );
cursorData.push( cursorFrame );
transformer.translate(-15,-15);
transformer.rotate( 0.785398163 );
transformer.translate(15,15);
}
return cursorData;
}
}
}
Tue Jun 12 2018, 02:12 PM Z